qtcreator.pri

   1 defineReplace(cleanPath) {
   2     win32:1 ~= s|\\\\|/|g
   3     contains(1, ^/.*):pfx = /
   4     else:pfx =
   5     segs = $$split(1, /)
   6     out =
   7     for(seg, segs) {
   8         equals(seg, ..):out = $$member(out, 0, -2)
   9         else:!equals(seg, .):out += $$seg
  10     }
  11     return($$join(out, /, $$pfx))
  12 }
  13
  14 defineReplace(targetPath) {
  15     win32:1 ~= s|/|\|g
  16     return($$1)
  17 }
  18
  19 # For use in custom compilers which just copy files
  20 win32:i_flag = i
  21 defineReplace(stripSrcDir) {
  22     win32 {
  23         !contains(1, ^.:.*):1 = $$OUT_PWD/$$1
  24     } else {
  25         !contains(1, ^/.*):1 = $$OUT_PWD/$$1
  26     }
  27     out = $$cleanPath($$1)
  28     out ~= s|^$$re_escape($$PWD/)||$$i_flag
  29     return($$out)
  30 }
  31
  32 isEmpty(TEST):CONFIG(debug, debug|release) {
  33     !debug_and_release|build_pass {
  34         TEST = 1
  35     }
  36 }
  37
  38 isEmpty(IDE_LIBRARY_BASENAME) {
  39     IDE_LIBRARY_BASENAME = lib
  40 }
  41
  42 DEFINES += IDE_LIBRARY_BASENAME=\\\"$$IDE_LIBRARY_BASENAME\\\"
  43
  44 equals(TEST, 1) {
  45     QT +=testlib
  46     DEFINES += WITH_TESTS
  47 }
  48
  49 IDE_SOURCE_TREE = $$PWD
  50 isEmpty(IDE_BUILD_TREE) {
  51     sub_dir = $$_PRO_FILE_PWD_
  52     sub_dir ~= s,^$$re_escape($$PWD),,
  53     IDE_BUILD_TREE = $$cleanPath($$OUT_PWD)
  54     IDE_BUILD_TREE ~= s,$$re_escape($$sub_dir)$,,
  55 }
  56 IDE_APP_PATH = $$IDE_BUILD_TREE/bin
  57 macx {
  58     IDE_APP_TARGET   = QtCreator
  59     IDE_LIBRARY_PATH = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/PlugIns
  60     IDE_PLUGIN_PATH  = $$IDE_LIBRARY_PATH
  61     IDE_LIBEXEC_PATH = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/Resources
  62     IDE_DATA_PATH    = $$IDE_APP_PATH/$${IDE_APP_TARGET}.app/Contents/Resources
  63     contains(QT_CONFIG, ppc):CONFIG += ppc x86
  64     copydata = 1
  65 } else {
  66     win32 {
  67         contains(TEMPLATE, vc.*)|contains(TEMPLATE_PREFIX, vc):vcproj = 1
  68         IDE_APP_TARGET   = qtcreator
  69     } else {
  70         IDE_APP_WRAPPER  = qtcreator
  71         IDE_APP_TARGET   = qtcreator.bin
  72     }
  73     IDE_LIBRARY_PATH = $$IDE_BUILD_TREE/$$IDE_LIBRARY_BASENAME/qtcreator
  74     IDE_PLUGIN_PATH  = $$IDE_LIBRARY_PATH/plugins
  75     IDE_LIBEXEC_PATH = $$IDE_APP_PATH # FIXME
  76     IDE_DATA_PATH    = $$IDE_BUILD_TREE/share/qtcreator
  77     !isEqual(IDE_SOURCE_TREE, $$IDE_BUILD_TREE):copydata = 1
  78 }
  79
  80 INCLUDEPATH += \
  81     $$IDE_SOURCE_TREE/src/libs \
  82     $$IDE_SOURCE_TREE/tools
  83
  84 DEPENDPATH += \
  85     $$IDE_SOURCE_TREE/src/libs \
  86     $$IDE_SOURCE_TREE/tools
  87
  88 LIBS += -L$$IDE_LIBRARY_PATH
  89
  90 # DEFINES += QT_NO_CAST_FROM_ASCII
  91 DEFINES += QT_NO_CAST_TO_ASCII
  92 DEFINES += QT_USE_STRINGBUILDER_FOR_CONCATENATION
  93 DEFINES += QT_USE_OPERATOR_PLUS_FOR_CONCATENATION
  94
  95 unix {
  96     debug:OBJECTS_DIR = $${OUT_PWD}/.obj/debug-shared
  97     release:OBJECTS_DIR = $${OUT_PWD}/.obj/release-shared
  98
  99     debug:MOC_DIR = $${OUT_PWD}/.moc/debug-shared
 100     release:MOC_DIR = $${OUT_PWD}/.moc/release-shared
 101
 102     RCC_DIR = $${OUT_PWD}/.rcc
 103     UI_DIR = $${OUT_PWD}/.uic
 104 }
 105
 106 linux-g++-* {
 107     # Bail out on non-selfcontained libraries. Just a security measure
 108     # to prevent checking in code that does not compile on other platforms.
 109     QMAKE_LFLAGS += -Wl,--allow-shlib-undefined -Wl,--no-undefined
 110 }