qtcreator.pro

   1 include(qtcreator.pri)
   2
   3 #version check qt
   4 !minQtVersion(4, 7, 4) {
   5     message("Cannot build Qt Creator with Qt version $${QT_VERSION}.")
   6     error("Use at least Qt 4.7.4.")
   7 }
   8
   9 include(doc/doc.pri)
  10
  11 TEMPLATE  = subdirs
  12 CONFIG   += ordered
  13
  14 SUBDIRS = src share lib/qtcreator/qtcomponents
  15 unix:!macx:!isEmpty(copydata):SUBDIRS += bin
  16
  17 OTHER_FILES += dist/copyright_template.txt \
  18     $$files(dist/changes-*)
  19
  20 macx {
  21     APPBUNDLE = "$$OUT_PWD/bin/Qt Creator.app"
  22     deployqt.commands = $$PWD/scripts/deployqtHelper_mac.sh \"$${APPBUNDLE}\"
  23     bindist.commands = 7z a -mx9 $$OUT_PWD/qt-creator-mac$(INSTALL_EDITION)-$${QTCREATOR_VERSION}$(INSTALL_POSTFIX).7z \"$$OUT_PWD/bin/Qt Creator.app/\"
  24     dmg.commands = $$PWD/scripts/makedmg.sh $$OUT_PWD/bin qt-creator-mac$(INSTALL_EDITION)-$${QTCREATOR_VERSION}$(INSTALL_POSTFIX).dmg
  25     dmg.depends = deployqt
  26     QMAKE_EXTRA_TARGETS += dmg
  27 } else {
  28     deployqt.commands = $$PWD/scripts/deployqt.py -i $(INSTALL_ROOT)
  29     deployqt.depends = install
  30     win32 {
  31         bindist.commands ~= s,/,\\\\,g
  32         deployqt.commands ~= s,/,\\\\,g
  33         deployartifacts.depends = install
  34         PLATFORM="windows"
  35         deployartifacts.commands = git clone "git://gitorious.org/qt-creator/binary-artifacts.git"&& xcopy /s /q /y /i "binary-artifacts\\win32" $(INSTALL_ROOT)&& rmdir /s binary-artifacts
  36         QMAKE_EXTRA_TARGETS += deployartifacts
  37     }
  38     else:linux-*:PLATFORM="linux-$${QT_ARCH}"
  39     else:PLATFORM="unknown"
  40     bindist.commands = $$PWD/scripts/bindistHelper.py "$(INSTALL_ROOT)" "$${PLATFORM}$(INSTALL_EDITION)-$${QTCREATOR_VERSION}$(INSTALL_POSTFIX)"
  41 }
  42 bindist.depends = deployqt
  43 QMAKE_EXTRA_TARGETS += deployqt bindist