sim/configure.in

   1 dnl Process this file with autoconf to produce a configure script.
   2 AC_PREREQ(2.12.1)dnl
   3 AC_INIT(Makefile.in)
   4
   5 AC_PROG_CC
   6 AC_PROG_INSTALL
   7 AC_CHECK_TOOL(AR, ar)
   8 AC_CHECK_TOOL(RANLIB, ranlib, :)
   9
  10 AC_CONFIG_AUX_DIR(`cd $srcdir;pwd`/..)
  11 AC_CANONICAL_SYSTEM
  12 AC_ARG_PROGRAM
  13 AC_PROG_CC
  14 AC_SUBST(CFLAGS)
  15 AC_SUBST(HDEFINES)
  16 AR=${AR-ar}
  17 AC_SUBST(AR)
  18 AC_PROG_RANLIB
  19
  20 # Put a plausible default for CC_FOR_BUILD in Makefile.
  21 AC_C_CROSS
  22 if test "x$cross_compiling" = "xno"; then
  23   CC_FOR_BUILD='$(CC)'
  24 else
  25   CC_FOR_BUILD=gcc
  26 fi
  27 AC_SUBST(CC_FOR_BUILD)
  28
  29 # If a cpu ever has more than one simulator to choose from, use
  30 # --enable-sim=... to choose.
  31 AC_ARG_ENABLE(sim,
  32 [  --enable-sim ],
  33 [case "${enableval}" in
  34 yes | no) ;;
  35 *)      AC_MSG_ERROR(bad value ${enableval} given for --enable-sim option) ;;
  36 esac])
  37
  38 # Assume simulator can be built with cc.
  39 # If the user passes --enable-sim built it regardless of $(CC).
  40 only_if_gcc=no
  41 only_if_enabled=no
  42 extra_subdirs=common
  43
  44 # WHEN ADDING ENTRIES TO THIS MATRIX:
  45 #  Make sure that the left side always has two dashes.  Otherwise you
  46 #  can get spurious matches.  Even for unambiguous cases, do this as a
  47 #  convention, else the table becomes a real mess to understand and maintain.
  48
  49 case "${target}" in
  50   arm*-*-* | thumb*-*-*)
  51         sim_target=arm
  52         extra_subdirs="${extra_subdirs} testsuite"
  53         ;;
  54   strongarm*-*-*)       sim_target=arm ;;
  55   d10v-*-*)             sim_target=d10v ;;
  56   d30v-*-*)
  57         sim_target=d30v
  58         only_if_gcc=yes
  59         extra_subdirs="${extra_subdirs} igen"
  60         ;;
  61   fr30-*-*)             sim_target=fr30 ;;
  62   h8300*-*-*)           sim_target=h8300 ;;
  63   h8500-*-*)            sim_target=h8500 ;;
  64   i960-*-*)             sim_target=i960 ;;
  65   m32r-*-*)             sim_target=m32r ;;
  66   mcore-*-*)            sim_target=mcore ;;
  67   mips*-*-*)
  68         # The MIPS simulator can only be compiled by gcc.
  69         sim_target=mips
  70         only_if_gcc=yes
  71         extra_subdirs="${extra_subdirs} igen"
  72         ;;
  73   mn10300*-*-*)
  74         # The mn10300 simulator can only be compiled by gcc.
  75         sim_target=mn10300
  76         only_if_gcc=yes
  77         extra_subdirs="${extra_subdirs} igen"
  78         ;;
  79   mn10200*-*-*)
  80         sim_target=mn10200
  81         ;;
  82   sh*-*-*)              sim_target=sh ;;
  83   powerpc*-*-eabi* | powerpc*-*-solaris* | powerpc*-*-sysv4* | powerpc*-*-elf* | powerpc*-*-linux* )
  84         # The PowerPC simulator uses the GCC extension long long as well as
  85         # ANSI prototypes, so don't enable it for random host compilers
  86         # unless asked to.
  87         sim_target=ppc
  88         only_if_gcc=yes
  89         #extra_subdirs="${extra_subdirs}"
  90         ;;
  91   v850-*-*)
  92         # The V850 simulator can only be compiled by gcc.
  93         sim_target=v850
  94         extra_subdirs="${extra_subdirs} igen"
  95         only_if_gcc=yes
  96         ;;
  97   v850e-*-*)
  98         # The V850 simulator can only be compiled by gcc.
  99         sim_target=v850
 100         extra_subdirs="${extra_subdirs} igen"
 101         only_if_gcc=yes
 102         ;;
 103   v850ea-*-*)
 104         # The V850 simulator can only be compiled by gcc.
 105         sim_target=v850
 106         extra_subdirs="${extra_subdirs} igen"
 107         only_if_gcc=yes
 108         ;;
 109   w65-*-*)
 110         sim_target=w65
 111         # The w65 is suffering from gradual decay.
 112         only_if_enabled=yes
 113         ;;
 114   z8k*-*-*)             sim_target=z8k ;;
 115   sparc64-*-*)
 116         only_if_gcc=yes
 117         sim_target=none # Don't build erc32 if sparc64.
 118         ;;
 119   sparclite*-*-* | sparc86x*-*-*)
 120         # The SPARC simulator can only be compiled by gcc.
 121         only_if_gcc=yes
 122         sim_target=erc32
 123         ;;
 124   sparc*-*-*)
 125         # The SPARC simulator can only be compiled by gcc.
 126         only_if_gcc=yes
 127         # Unfortunately erc32 won't build on many hosts, so only enable
 128         # it if the user really really wants it.
 129         only_if_enabled=yes
 130         sim_target=erc32
 131         ;;
 132   *)                    sim_target=none ;;
 133 esac
 134
 135
 136 # Is there a testsuite directory for the target?
 137 testdir=`echo ${target} | sed -e 's/-.*-/-/'`
 138 if test -r ${srcdir}/testsuite/${testdir}/configure ; then
 139   extra_subdirs="${extra_subdirs} testsuite"
 140 fi
 141
 142
 143 case "${enable_sim}" in
 144 no)     sim_target=none ;;
 145 yes)
 146         if test ${only_if_gcc} = yes ; then
 147                 if test "${GCC}" != yes ; then
 148                         echo "Can't enable simulator since not compiling with GCC."
 149                         sim_target=none
 150                 fi
 151         fi
 152         ;;
 153 *)
 154         if test ${only_if_enabled} = yes ; then
 155                 sim_target=none
 156         else
 157                 if test ${only_if_gcc} = yes ; then
 158                         if test "${GCC}" != yes ; then
 159                                 sim_target=none
 160                         fi
 161                 fi
 162         fi
 163         ;;
 164 esac
 165
 166 if test x"${sim_target}" != xnone ; then
 167         configdirs="${extra_subdirs} ${sim_target}"
 168         AC_CONFIG_SUBDIRS($configdirs)
 169 fi
 170
 171 AC_OUTPUT(Makefile)
 172
 173 exit 0