src/mesa/SConscript

   1 #######################################################################
   2 # SConscript for Mesa
   3
   4
   5 Import('*')
   6 import filecmp
   7 import os
   8 import subprocess
   9 from sys import executable as python_cmd
  10
  11 env = env.Clone()
  12
  13 env.Append(CPPPATH = [
  14     '#/src/mapi',
  15     '#/src/glsl',
  16     '#/src/mesa',
  17     Dir('../mapi'), # src/mapi build path
  18     Dir('.'), # src/mesa build path
  19 ])
  20
  21 enabled_apis = []
  22 enabled_apis += ['GL']
  23
  24 if env['platform'] == 'windows':
  25     env.Append(CPPDEFINES = [
  26         '_GDI32_', # prevent gl* being declared __declspec(dllimport) in MS headers
  27         'BUILD_GL32', # declare gl* as __declspec(dllexport) in Mesa headers
  28     ])
  29     if not env['gles']:
  30         # prevent _glapi_* from being declared __declspec(dllimport)
  31         env.Append(CPPDEFINES = ['_GLAPI_NO_EXPORTS'])
  32 else:
  33     env.Append(CPPDEFINES = [
  34         ('HAVE_DLOPEN', '1'),
  35     ])
  36
  37 #
  38 # Source files
  39 #
  40
  41 main_sources = [
  42     'main/api_arrayelt.c',
  43     'main/api_exec.c',
  44     'main/api_loopback.c',
  45     'main/api_validate.c',
  46     'main/accum.c',
  47     'main/arbprogram.c',
  48     'main/atifragshader.c',
  49     'main/attrib.c',
  50     'main/arrayobj.c',
  51     'main/blend.c',
  52     'main/bufferobj.c',
  53     'main/buffers.c',
  54     'main/clear.c',
  55     'main/clip.c',
  56     'main/colortab.c',
  57     'main/condrender.c',
  58     'main/context.c',
  59     'main/convolve.c',
  60     'main/cpuinfo.c',
  61     'main/debug.c',
  62     'main/depth.c',
  63     'main/dlist.c',
  64     'main/drawpix.c',
  65     'main/drawtex.c',
  66     'main/enable.c',
  67     'main/enums.c',
  68     'main/errors.c',
  69     'main/es1_conversion.c',
  70     'main/eval.c',
  71     'main/execmem.c',
  72     'main/extensions.c',
  73     'main/fbobject.c',
  74     'main/feedback.c',
  75     'main/ff_fragment_shader.cpp',
  76     'main/ffvertex_prog.c',
  77     'main/fog.c',
  78     'main/formatquery.c',
  79     'main/formats.c',
  80     'main/format_pack.c',
  81     'main/format_unpack.c',
  82     'main/framebuffer.c',
  83     'main/getstring.c',
  84     'main/glformats.c',
  85     'main/hash.c',
  86     'main/hash_table.c',
  87     'main/hint.c',
  88     'main/histogram.c',
  89     'main/image.c',
  90     'main/imports.c',
  91     'main/light.c',
  92     'main/lines.c',
  93     'main/matrix.c',
  94     'main/mipmap.c',
  95     'main/mm.c',
  96     'main/multisample.c',
  97     'main/pack.c',
  98     'main/pbo.c',
  99     'main/pixel.c',
 100     'main/pixelstore.c',
 101     'main/pixeltransfer.c',
 102     'main/points.c',
 103     'main/polygon.c',
 104     'main/querymatrix.c',
 105     'main/queryobj.c',
 106     'main/rastpos.c',
 107     'main/readpix.c',
 108     'main/remap.c',
 109     'main/renderbuffer.c',
 110     'main/samplerobj.c',
 111     'main/scissor.c',
 112     'main/set.c',
 113     'main/shaderapi.c',
 114     'main/shaderobj.c',
 115     'main/shader_query.cpp',
 116     'main/shared.c',
 117     'main/state.c',
 118     'main/stencil.c',
 119     'main/syncobj.c',
 120     'main/texcompress.c',
 121     'main/texcompress_cpal.c',
 122     'main/texcompress_rgtc.c',
 123     'main/texcompress_s3tc.c',
 124     'main/texcompress_fxt1.c',
 125     'main/texcompress_etc.c',
 126     'main/texenv.c',
 127     'main/texformat.c',
 128     'main/texgen.c',
 129     'main/texgetimage.c',
 130     'main/teximage.c',
 131     'main/texobj.c',
 132     'main/texparam.c',
 133     'main/texstate.c',
 134     'main/texstorage.c',
 135     'main/texstore.c',
 136     'main/texturebarrier.c',
 137     'main/transformfeedback.c',
 138     'main/uniform_query.cpp',
 139     'main/uniforms.c',
 140     'main/varray.c',
 141     'main/version.c',
 142     'main/viewport.c',
 143     'main/vtxfmt.c',
 144 ]
 145
 146 glget_sources = [
 147     'main/get.c',
 148 ]
 149
 150 math_sources = [
 151     'math/m_debug_clip.c',
 152     'math/m_debug_norm.c',
 153     'math/m_debug_xform.c',
 154     'math/m_eval.c',
 155     'math/m_matrix.c',
 156     'math/m_translate.c',
 157     'math/m_vector.c',
 158     'math/m_xform.c',
 159 ]
 160
 161 swrast_sources = [
 162     'swrast/s_aaline.c',
 163     'swrast/s_aatriangle.c',
 164     'swrast/s_alpha.c',
 165     'swrast/s_atifragshader.c',
 166     'swrast/s_bitmap.c',
 167     'swrast/s_blend.c',
 168     'swrast/s_blit.c',
 169     'swrast/s_clear.c',
 170     'swrast/s_copypix.c',
 171     'swrast/s_context.c',
 172     'swrast/s_depth.c',
 173     'swrast/s_drawpix.c',
 174     'swrast/s_feedback.c',
 175     'swrast/s_fog.c',
 176     'swrast/s_fragprog.c',
 177     'swrast/s_lines.c',
 178     'swrast/s_logic.c',
 179     'swrast/s_masking.c',
 180     'swrast/s_points.c',
 181     'swrast/s_renderbuffer.c',
 182     'swrast/s_span.c',
 183     'swrast/s_stencil.c',
 184     'swrast/s_texcombine.c',
 185     'swrast/s_texfetch.c',
 186     'swrast/s_texfilter.c',
 187     'swrast/s_texrender.c',
 188     'swrast/s_texture.c',
 189     'swrast/s_triangle.c',
 190     'swrast/s_zoom.c',
 191 ]
 192
 193 swrast_setup_sources = [
 194     'swrast_setup/ss_context.c',
 195     'swrast_setup/ss_triangle.c',
 196 ]
 197
 198 tnl_sources = [
 199     'tnl/t_context.c',
 200     'tnl/t_pipeline.c',
 201     'tnl/t_draw.c',
 202     'tnl/t_rasterpos.c',
 203     'tnl/t_vb_program.c',
 204     'tnl/t_vb_render.c',
 205     'tnl/t_vb_texgen.c',
 206     'tnl/t_vb_texmat.c',
 207     'tnl/t_vb_vertex.c',
 208     'tnl/t_vb_fog.c',
 209     'tnl/t_vb_light.c',
 210     'tnl/t_vb_normals.c',
 211     'tnl/t_vb_points.c',
 212     'tnl/t_vp_build.c',
 213     'tnl/t_vertex.c',
 214     'tnl/t_vertex_sse.c',
 215     'tnl/t_vertex_generic.c',
 216 ]
 217
 218 vbo_sources = [
 219     'vbo/vbo_context.c',
 220     'vbo/vbo_exec.c',
 221     'vbo/vbo_exec_api.c',
 222     'vbo/vbo_exec_array.c',
 223     'vbo/vbo_exec_draw.c',
 224     'vbo/vbo_exec_eval.c',
 225     'vbo/vbo_noop.c',
 226     'vbo/vbo_primitive_restart.c',
 227     'vbo/vbo_rebase.c',
 228     'vbo/vbo_split.c',
 229     'vbo/vbo_split_copy.c',
 230     'vbo/vbo_split_inplace.c',
 231     'vbo/vbo_save.c',
 232     'vbo/vbo_save_api.c',
 233     'vbo/vbo_save_draw.c',
 234     'vbo/vbo_save_loopback.c',
 235 ]
 236
 237 statetracker_sources = [
 238     'state_tracker/st_atom.c',
 239     'state_tracker/st_atom_array.c',
 240     'state_tracker/st_atom_blend.c',
 241     'state_tracker/st_atom_clip.c',
 242     'state_tracker/st_atom_constbuf.c',
 243     'state_tracker/st_atom_depth.c',
 244     'state_tracker/st_atom_framebuffer.c',
 245     'state_tracker/st_atom_msaa.c',
 246     'state_tracker/st_atom_pixeltransfer.c',
 247     'state_tracker/st_atom_sampler.c',
 248     'state_tracker/st_atom_scissor.c',
 249     'state_tracker/st_atom_shader.c',
 250     'state_tracker/st_atom_rasterizer.c',
 251     'state_tracker/st_atom_stipple.c',
 252     'state_tracker/st_atom_texture.c',
 253     'state_tracker/st_atom_viewport.c',
 254     'state_tracker/st_cb_bitmap.c',
 255     'state_tracker/st_cb_blit.c',
 256     'state_tracker/st_cb_bufferobjects.c',
 257     'state_tracker/st_cb_clear.c',
 258     'state_tracker/st_cb_condrender.c',
 259     'state_tracker/st_cb_flush.c',
 260     'state_tracker/st_cb_drawpixels.c',
 261     'state_tracker/st_cb_drawtex.c',
 262     'state_tracker/st_cb_eglimage.c',
 263     'state_tracker/st_cb_fbo.c',
 264     'state_tracker/st_cb_feedback.c',
 265     'state_tracker/st_cb_msaa.c',
 266     'state_tracker/st_cb_program.c',
 267     'state_tracker/st_cb_queryobj.c',
 268     'state_tracker/st_cb_rasterpos.c',
 269     'state_tracker/st_cb_readpixels.c',
 270     'state_tracker/st_cb_syncobj.c',
 271     'state_tracker/st_cb_strings.c',
 272     'state_tracker/st_cb_texture.c',
 273     'state_tracker/st_cb_texturebarrier.c',
 274     'state_tracker/st_cb_viewport.c',
 275     'state_tracker/st_cb_xformfb.c',
 276     'state_tracker/st_context.c',
 277     'state_tracker/st_debug.c',
 278     'state_tracker/st_draw.c',
 279     'state_tracker/st_draw_feedback.c',
 280     'state_tracker/st_extensions.c',
 281     'state_tracker/st_format.c',
 282     'state_tracker/st_glsl_to_tgsi.cpp',
 283     'state_tracker/st_gen_mipmap.c',
 284     'state_tracker/st_manager.c',
 285     'state_tracker/st_mesa_to_tgsi.c',
 286     'state_tracker/st_program.c',
 287     'state_tracker/st_texture.c',
 288 ]
 289
 290 env.Append(YACCFLAGS = '-d -p "_mesa_program_"')
 291 program_lex = env.CFile('program/lex.yy.c', 'program/program_lexer.l')
 292 program_parse = env.CFile('program/program_parse.tab.c',
 293                           'program/program_parse.y')
 294
 295 program_sources = [
 296     'program/arbprogparse.c',
 297     'program/prog_hash_table.c',
 298     'program/ir_to_mesa.cpp',
 299     'program/program.c',
 300     'program/program_parse_extra.c',
 301     'program/prog_cache.c',
 302     'program/prog_execute.c',
 303     'program/prog_instruction.c',
 304     'program/prog_noise.c',
 305     'program/prog_optimize.c',
 306     'program/prog_opt_constant_fold.c',
 307     'program/prog_parameter.c',
 308     'program/prog_parameter_layout.c',
 309     'program/prog_print.c',
 310     'program/prog_statevars.c',
 311     'program/programopt.c',
 312     'program/sampler.cpp',
 313     'program/symbol_table.c',
 314     'program/string_to_uint_map.cpp',
 315     program_lex,
 316     program_parse[0],
 317 ]
 318
 319 common_driver_sources = [
 320     'drivers/common/driverfuncs.c',
 321     'drivers/common/meta.c',
 322 ]
 323
 324 mesa_sources = (
 325     main_sources +
 326     glget_sources +
 327     math_sources +
 328     program_sources +
 329     vbo_sources +
 330     tnl_sources +
 331     swrast_sources +
 332     swrast_setup_sources +
 333     common_driver_sources +
 334     statetracker_sources
 335 )
 336
 337 GLAPI = '#src/mapi/glapi/'
 338
 339 if env['gles']:
 340
 341     enabled_apis += ['ES1', 'ES2']
 342
 343 get_hash_header = env.CodeGenerate(
 344       target = 'main/get_hash.h',
 345       script = 'main/get_hash_generator.py',
 346       source = GLAPI + 'gen/gl_and_es_API.xml',
 347       command = python_cmd + ' $SCRIPT ' + ' -f $SOURCE > $TARGET'
 348 )
 349
 350 #
 351 # Assembly sources
 352 #
 353 if (env['gcc'] or env['clang']) and \
 354    env['platform'] not in ('cygwin', 'darwin', 'windows', 'haiku'):
 355     if env['machine'] == 'x86':
 356         env.Append(CPPDEFINES = [
 357             'USE_X86_ASM',
 358             'USE_MMX_ASM',
 359             'USE_3DNOW_ASM',
 360             'USE_SSE_ASM',
 361         ])
 362         mesa_sources += [
 363             'x86/common_x86.c',
 364             'x86/x86_xform.c',
 365             'x86/3dnow.c',
 366             'x86/sse.c',
 367             'x86/common_x86_asm.S',
 368             'x86/x86_xform2.S',
 369             'x86/x86_xform3.S',
 370             'x86/x86_xform4.S',
 371             'x86/x86_cliptest.S',
 372             'x86/mmx_blend.S',
 373             'x86/3dnow_xform1.S',
 374             'x86/3dnow_xform2.S',
 375             'x86/3dnow_xform3.S',
 376             'x86/3dnow_xform4.S',
 377             'x86/3dnow_normal.S',
 378             'x86/sse_xform1.S',
 379             'x86/sse_xform2.S',
 380             'x86/sse_xform3.S',
 381             'x86/sse_xform4.S',
 382             'x86/sse_normal.S',
 383             'x86/read_rgba_span_x86.S',
 384         ]
 385     elif env['machine'] == 'x86_64':
 386         env.Append(CPPDEFINES = [
 387             'USE_X86_64_ASM',
 388         ])
 389         mesa_sources += [
 390             'x86-64/x86-64.c',
 391             'x86-64/xform4.S',
 392         ]
 393     elif env['machine'] == 'sparc':
 394         mesa_sources += [
 395             'sparc/sparc.c',
 396             'sparc/sparc_clip.S',
 397             'sparc/norm.S',
 398             'sparc/xform.S',
 399         ]
 400     else:
 401         pass
 402
 403     # Generate matypes.h
 404     if env['machine'] in ('x86', 'x86_64'):
 405         # See http://www.scons.org/wiki/UsingCodeGenerators
 406         gen_matypes = env.Program(
 407             target = 'gen_matypes',
 408             source = 'x86/gen_matypes.c',
 409         )
 410         matypes = env.Command(
 411             'matypes.h',
 412             gen_matypes,
 413             gen_matypes[0].abspath + ' > $TARGET',
 414         )
 415         # Add the dir containing the generated header (somewhere inside  the
 416         # build dir) to the include path
 417         env.Append(CPPPATH = [matypes[0].dir])
 418
 419
 420 # The enums.c file is generated from the GL/ES API.xml file
 421 env.CodeGenerate(
 422     target = 'main/enums.c',
 423     script = GLAPI + 'gen/gl_enums.py',
 424     source = GLAPI + 'gen/gl_and_es_API.xml',
 425     command = python_cmd + ' $SCRIPT -f $SOURCE > $TARGET'
 426     )
 427
 428 # The api_exec.c file is generated from the GL/ES API.xml file
 429 env.CodeGenerate(
 430     target = 'main/api_exec.c',
 431     script = GLAPI + 'gen/gl_genexec.py',
 432     source = GLAPI + 'gen/gl_and_es_API.xml',
 433     command = python_cmd + ' $SCRIPT -f $SOURCE > $TARGET'
 434     )
 435
 436
 437 def write_git_sha1_h_file(filename):
 438     """Mesa looks for a git_sha1.h file at compile time in order to display
 439     the current git hash id in the GL_VERSION string.  This function tries
 440     to retrieve the git hashid and write the header file.  An empty file
 441     will be created if anything goes wrong."""
 442
 443     args = [ 'git', 'log', '-n', '1', '--oneline' ]
 444     try:
 445         (commit, foo) = subprocess.Popen(args, stdout=subprocess.PIPE).communicate()
 446     except:
 447         # git log command didn't work
 448         if not os.path.exists(filename):
 449             # create an empty file if none already exists
 450             f = open(filename, "w")
 451             f.close()
 452         return
 453
 454     commit = '#define MESA_GIT_SHA1 "git-%s"\n' % commit[0:7]
 455     tempfile = "git_sha1.h.tmp"
 456     f = open(tempfile, "w")
 457     f.write(commit)
 458     f.close()
 459     if not os.path.exists(filename) or not filecmp.cmp(tempfile, filename):
 460         # The filename does not exist or it's different from the new file,
 461         # so replace old file with new.
 462         if os.path.exists(filename):
 463             os.remove(filename)
 464         os.rename(tempfile, filename)
 465     return
 466
 467
 468 # Create the git_sha1.h header file
 469 write_git_sha1_h_file("main/git_sha1.h")
 470 # and update CPPPATH so the git_sha1.h header can be found
 471 env.Append(CPPPATH = ["#" + env['build_dir'] + "/mesa/main"])
 472
 473
 474 #
 475 # Libraries
 476 #
 477
 478 mesa = env.ConvenienceLibrary(
 479     target = 'mesa',
 480     source = mesa_sources,
 481 )
 482
 483 env.Alias('mesa', mesa)
 484
 485 Export('mesa')
 486
 487 SConscript('drivers/SConscript')