src/mesa/x86/sse_normal.S

   1
   2 /*
   3  * Mesa 3-D graphics library
   4  * Version:  3.5
   5  *
   6  * Copyright (C) 1999-2001  Brian Paul   All Rights Reserved.
   7  *
   8  * Permission is hereby granted, free of charge, to any person obtaining a
   9  * copy of this software and associated documentation files (the "Software"),
  10  * to deal in the Software without restriction, including without limitation
  11  * the rights to use, copy, modify, merge, publish, distribute, sublicense,
  12  * and/or sell copies of the Software, and to permit persons to whom the
  13  * Software is furnished to do so, subject to the following conditions:
  14  *
  15  * The above copyright notice and this permission notice shall be included
  16  * in all copies or substantial portions of the Software.
  17  *
  18  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  19  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  20  * FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  21  * BRIAN PAUL BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN
  22  * AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  23  * CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  24  */
  25
  26 /** TODO:
  27   * - insert PREFETCH instructions to avoid cache-misses !
  28   * - some more optimizations are possible...
  29   * - for 40-50% more performance in the SSE-functions, the
  30   *   data (trans-matrix, src_vert, dst_vert) needs to be 16byte aligned !
  31   */
  32
  33 #ifdef USE_SSE_ASM
  34 #include "matypes.h"
  35 #include "norm_args.h"
  36
  37    SEG_TEXT
  38
  39 #define M(i)    REGOFF(i * 4, EDX)
  40 #define S(i)    REGOFF(i * 4, ESI)
  41 #define D(i)    REGOFF(i * 4, EDI)
  42 #define STRIDE  REGOFF(12, ESI)
  43
  44
  45 ALIGNTEXT16
  46 GLOBL GLNAME(_mesa_sse_transform_rescale_normals_no_rot)
  47 HIDDEN(_mesa_sse_transform_rescale_normals_no_rot)
  48 GLNAME(_mesa_sse_transform_rescale_normals_no_rot):
  49
  50 #define FRAME_OFFSET 8
  51         PUSH_L  ( ESI )
  52         PUSH_L  ( EDI )
  53
  54         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
  55         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
  56
  57         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
  58         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
  59
  60         MOV_L   ( REGOFF(V4F_COUNT, ESI), ECX )         /* source count */
  61
  62         TEST_L  ( ECX, ECX )
  63         JZ( LLBL(K_G3TRNNRR_finish) )                   /* count was zero; go to finish */
  64
  65         MOV_L   ( STRIDE, EAX )                         /* stride */
  66         MOV_L   ( ECX, REGOFF(V4F_COUNT, EDI) )         /* set dest-count */
  67
  68         IMUL_L( CONST(16), ECX )                        /* count *= 16 */
  69         MOV_L( REGOFF(V4F_START, ESI), ESI )            /* ptr to first source vertex */
  70
  71         MOV_L( REGOFF(V4F_START, EDI), EDI )            /* ptr to first dest vertex */
  72         ADD_L( EDI, ECX )                               /* count += dest ptr */
  73
  74 ALIGNTEXT32
  75         MOVSS   ( M(0), XMM1 )                          /* m0 */
  76         MOVSS   ( M(5), XMM2 )                          /* m5 */
  77         UNPCKLPS( XMM2, XMM1 )                          /* m5 | m0 */
  78         MOVSS   ( ARG_SCALE, XMM0 )                     /* scale */
  79         SHUFPS  ( CONST(0x0), XMM0, XMM0 )              /* scale | scale */
  80         MULPS   ( XMM0, XMM1 )                          /* m5*scale | m0*scale */
  81         MULSS   ( M(10), XMM0 )                         /* m10*scale */
  82
  83 ALIGNTEXT32
  84 LLBL(K_G3TRNNRR_top):
  85         MOVLPS  ( S(0), XMM2 )                          /* uy | ux */
  86         MULPS   ( XMM1, XMM2 )                          /* uy*m5*scale | ux*m0*scale */
  87         MOVLPS  ( XMM2, D(0) )                          /* ->D(1) | D(0) */
  88
  89         MOVSS   ( S(2), XMM2 )                          /* uz */
  90         MULSS   ( XMM0, XMM2 )                          /* uz*m10*scale */
  91         MOVSS   ( XMM2, D(2) )                          /* ->D(2) */
  92
  93 LLBL(K_G3TRNNRR_skip):
  94         ADD_L   ( CONST(16), EDI )
  95         ADD_L   ( EAX, ESI )
  96         CMP_L   ( ECX, EDI )
  97         JNE     ( LLBL(K_G3TRNNRR_top) )
  98
  99 LLBL(K_G3TRNNRR_finish):
 100         POP_L   ( EDI )
 101         POP_L   ( ESI )
 102         RET
 103 #undef FRAME_OFFSET
 104
 105
 106
 107 ALIGNTEXT16
 108 GLOBL GLNAME(_mesa_sse_transform_rescale_normals)
 109 HIDDEN(_mesa_sse_transform_rescale_normals)
 110 GLNAME(_mesa_sse_transform_rescale_normals):
 111
 112 #define FRAME_OFFSET 8
 113         PUSH_L  ( ESI )
 114         PUSH_L  ( EDI )
 115
 116         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
 117         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
 118
 119         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
 120         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
 121
 122         MOV_L   ( REGOFF(V4F_COUNT, ESI), ECX )         /* source count */
 123
 124         TEST_L  ( ECX, ECX )
 125         JZ( LLBL(K_G3TRNR_finish) )                     /* count was zero; go to finish */
 126
 127         MOV_L   ( STRIDE, EAX )                         /* stride */
 128         MOV_L   ( ECX, REGOFF(V4F_COUNT, EDI) )         /* set dest-count */
 129
 130         IMUL_L( CONST(16), ECX )                        /* count *= 16 */
 131         MOV_L( REGOFF(V4F_START, ESI), ESI )            /* ptr to first source vertex */
 132
 133         MOV_L( REGOFF(V4F_START, EDI), EDI )            /* ptr to first dest vertex */
 134         ADD_L( EDI, ECX )                               /* count += dest ptr */
 135
 136 ALIGNTEXT32
 137         MOVSS   ( M(0), XMM0 )                          /* m0 */
 138         MOVSS   ( M(4), XMM1 )                          /* m4 */
 139         UNPCKLPS( XMM1, XMM0 )                          /* m4 | m0 */
 140
 141         MOVSS   ( ARG_SCALE, XMM4 )                     /* scale */
 142         SHUFPS  ( CONST(0x0), XMM4, XMM4 )              /* scale | scale */
 143
 144         MULPS   ( XMM4, XMM0 )                          /* m4*scale | m0*scale */
 145         MOVSS   ( M(1), XMM1 )                          /* m1 */
 146         MOVSS   ( M(5), XMM2 )                          /* m5 */
 147         UNPCKLPS( XMM2, XMM1 )                          /* m5 | m1 */
 148         MULPS   ( XMM4, XMM1 )                          /* m5*scale | m1*scale */
 149         MOVSS   ( M(2), XMM2 )                          /* m2 */
 150         MOVSS   ( M(6), XMM3 )                          /* m6 */
 151         UNPCKLPS( XMM3, XMM2 )                          /* m6 | m2 */
 152         MULPS   ( XMM4, XMM2 )                          /* m6*scale | m2*scale */
 153
 154         MOVSS   ( M(8), XMM6 )                          /* m8 */
 155         MULSS   ( ARG_SCALE, XMM6 )                     /* m8*scale */
 156         MOVSS   ( M(9), XMM7 )                          /* m9 */
 157         MULSS   ( ARG_SCALE, XMM7 )                     /* m9*scale */
 158
 159 ALIGNTEXT32
 160 LLBL(K_G3TRNR_top):
 161         MOVSS   ( S(0), XMM3 )                          /* ux */
 162         SHUFPS  ( CONST(0x0), XMM3, XMM3 )              /* ux | ux */
 163         MULPS   ( XMM0, XMM3 )                          /* ux*m4 | ux*m0 */
 164         MOVSS   ( S(1), XMM4 )                          /* uy */
 165         SHUFPS  ( CONST(0x0), XMM4, XMM4 )              /* uy | uy */
 166         MULPS   ( XMM1, XMM4 )                          /* uy*m5 | uy*m1 */
 167         MOVSS   ( S(2), XMM5 )                          /* uz */
 168         SHUFPS  ( CONST(0x0), XMM5, XMM5 )              /* uz | uz */
 169         MULPS   ( XMM2, XMM5 )                          /* uz*m6 | uz*m2 */
 170
 171         ADDPS   ( XMM4, XMM3 )
 172         ADDPS   ( XMM5, XMM3 )
 173         MOVLPS  ( XMM3, D(0) )
 174
 175         MOVSS   ( M(10), XMM3 )                         /* m10 */
 176         MULSS   ( ARG_SCALE, XMM3 )                     /* m10*scale */
 177         MULSS   ( S(2), XMM3 )                          /* m10*scale*uz */
 178         MOVSS   ( S(1), XMM4 )                          /* uy */
 179         MULSS   ( XMM7, XMM4 )                          /* uy*m9*scale */
 180         MOVSS   ( S(0), XMM5 )                          /* ux */
 181         MULSS   ( XMM6, XMM5 )                          /* ux*m8*scale */
 182
 183         ADDSS   ( XMM4, XMM3 )
 184         ADDSS   ( XMM5, XMM3 )
 185         MOVSS   ( XMM3, D(2) )
 186
 187 LLBL(K_G3TRNR_skip):
 188         ADD_L   ( CONST(16), EDI )
 189         ADD_L   ( EAX, ESI )
 190         CMP_L   ( ECX, EDI )
 191         JNE     ( LLBL(K_G3TRNR_top) )
 192
 193 LLBL(K_G3TRNR_finish):
 194         POP_L   ( EDI )
 195         POP_L   ( ESI )
 196         RET
 197 #undef FRAME_OFFSET
 198
 199
 200 ALIGNTEXT16
 201 GLOBL GLNAME(_mesa_sse_transform_normals_no_rot)
 202 HIDDEN(_mesa_sse_transform_normals_no_rot)
 203 GLNAME(_mesa_sse_transform_normals_no_rot):
 204
 205 #define FRAME_OFFSET 8
 206         PUSH_L  ( ESI )
 207         PUSH_L  ( EDI )
 208
 209         MOV_L   ( ARG_IN, ESI )                         /* ptr to source GLvector3f */
 210         MOV_L   ( ARG_DEST, EDI )                       /* ptr to dest GLvector3f */
 211
 212         MOV_L   ( ARG_MAT, EDX )                        /* ptr to matrix */
 213         MOV_L   ( REGOFF(MATRIX_INV, EDX), EDX)         /* matrix->inv */
 214
 215         MOV_L   ( REGOFF(V4F_COUNT, ESI), ECX )         /* source count */
 216
 217         TEST_L  ( ECX, ECX )
 218         JZ( LLBL(K_G3TNNRR_finish) )                    /* count was zero; go to finish */
 219
 220         MOV_L   ( STRIDE, EAX )                         /* stride */
 221         MOV_L   ( ECX, REGOFF(V4F_COUNT, EDI) )         /* set dest-count */
 222
 223         IMUL_L( CONST(16), ECX )                        /* count *= 16 */
 224         MOV_L( REGOFF(V4F_START, ESI), ESI )            /* ptr to first source vertex */
 225
 226         MOV_L( REGOFF(V4F_START, EDI), EDI )            /* ptr to first dest vertex */
 227         ADD_L( EDI, ECX )                               /* count += dest ptr */
 228
 229 ALIGNTEXT32
 230         MOVSS( M(0), XMM0 )                             /* m0 */
 231         MOVSS( M(5), XMM1 )                             /* m5 */
 232         UNPCKLPS( XMM1, XMM0 )                          /* m5 | m0 */
 233         MOVSS( M(10), XMM1 )                            /* m10 */
 234
 235 ALIGNTEXT32
 236 LLBL(K_G3TNNRR_top):
 237         MOVLPS( S(0), XMM2 )                            /* uy | ux */
 238         MULPS( XMM0, XMM2 )                             /* uy*m5 | ux*m0 */
 239         MOVLPS( XMM2, D(0) )
 240
 241         MOVSS( S(2), XMM2 )                             /* uz */
 242         MULSS( XMM1, XMM2 )                             /* uz*m10 */
 243         MOVSS( XMM2, D(2) )
 244
 245 LLBL(K_G3TNNRR_skip):
 246         ADD_L   ( CONST(16), EDI )
 247         ADD_L   ( EAX, ESI )
 248         CMP_L   ( ECX, EDI )
 249         JNE     ( LLBL(K_G3TNNRR_top) )
 250
 251 LLBL(K_G3TNNRR_finish):
 252         POP_L   ( EDI )
 253         POP_L   ( ESI )
 254         RET
 255 #undef FRAME_OFFSET
 256 #endif
 257
 258 #if defined (__ELF__) && defined (__linux__)
 259         .section .note.GNU-stack,"",%progbits
 260 #endif