src/shaders/vme/inter_bframe_ivb.asm

   1 /*
   2  * Copyright © <2010>, Intel Corporation.
   3  *
   4  * Permission is hereby granted, free of charge, to any person obtaining a
   5  * copy of this software and associated documentation files (the
   6  * "Software"), to deal in the Software without restriction, including
   7  * without limitation the rights to use, copy, modify, merge, publish,
   8  * distribute, sub license, and/or sell copies of the Software, and to
   9  * permit persons to whom the Software is furnished to do so, subject to
  10  * the following conditions:
  11  *
  12  * The above copyright notice and this permission notice (including the
  13  * next paragraph) shall be included in all copies or substantial portions
  14  * of the Software.
  15  *
  16  * THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  17  * OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  18  * MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  19  * IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  20  * ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  21  * TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  22  * SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  23  * Authors: Zhao Yakui <yakui.zhao@intel.com>
  24  *
  25  */
  26 // Modual name: InterFrame_ivy.asm
  27 //
  28 // Make intra predition estimation for Inter-B frame
  29 //
  30
  31 //
  32 //  Now, begin source code....
  33 //
  34
  35 #define SAVE_RET        add (1) RETURN_REG<1>:ud   ip:ud        32:ud
  36 #define RETURN          mov (1) ip:ud   RETURN_REG<0,1,0>:ud
  37
  38 /*
  39  * __START
  40  */
  41 __INTER_START:
  42 mov  (16) tmp_reg0.0<1>:UD      0x0:UD {align1};
  43 mov  (16) tmp_reg2.0<1>:UD      0x0:UD {align1};
  44 mov  (16) tmp_reg4.0<1>:UD      0x0:UD {align1} ;
  45 mov  (16) tmp_reg6.0<1>:UD      0x0:UD {align1} ;
  46
  47 shl  (2) read0_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  48 add  (1) read0_header.0<1>:D    read0_header.0<0,1,0>:D -8:W {align1};     /* X offset */
  49 add  (1) read0_header.4<1>:D    read0_header.4<0,1,0>:D -1:W {align1};     /* Y offset */
  50 mov  (1) read0_header.8<1>:UD   BLOCK_32X1 {align1};
  51 mov  (1) read0_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  52
  53 shl  (2) read1_header.0<1>:D    orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  54 add  (1) read1_header.0<1>:D    read1_header.0<0,1,0>:D -4:W {align1};     /* X offset */
  55 mov  (1) read1_header.8<1>:UD   BLOCK_4X16 {align1};
  56 mov  (1) read1_header.20<1>:UB  thread_id_ub {align1};                  /* dispatch id */
  57
  58 shl  (2) vme_m0.8<1>:UW         orig_xy_ub<2,2,1>:UB 4:UW {align1};    /* (x, y) * 16 */
  59 mov  (1) vme_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  60
  61 mul  (1) obw_m0.8<1>:UD         w_in_mb_uw<0,1,0>:UW orig_y_ub<0,1,0>:UB {align1};
  62 add  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD orig_x_ub<0,1,0>:UB {align1};
  63 mul  (1) obw_m0.8<1>:UD         obw_m0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
  64 mov  (1) obw_m0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
  65
  66 /*
  67  * Media Read Message -- fetch Luma neighbor edge pixels
  68  */
  69 /* ROW */
  70 mov  (8) msg_reg0.0<1>:UD       read0_header.0<8,8,1>:UD {align1};
  71 send (8) msg_ind INEP_ROW<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 1 {align1};
  72
  73 /* COL */
  74 mov  (8) msg_reg0.0<1>:UD       read1_header.0<8,8,1>:UD {align1};
  75 send (8) msg_ind INEP_COL0<1>:UB null read(BIND_IDX_INEP, 0, 0, 4) mlen 1 rlen 2 {align1};
  76
  77 mov  (8) mb_mvp_ref.0<1>:ud     0:ud            {align1};
  78 mov  (8) mb_ref_win.0<1>:ud     0:ud            {align1};
  79 and.z.f0.0 (1)          null:uw mb_hwdep<0,1,0>:uw              0x04:uw   {align1};
  80 (f0.0) jmpi (1) __mb_hwdep_end;
  81 /* read back the data for MB A */
  82 /* the layout of MB result is: rx.0(Available). rx.4(MVa), rX.8(MVb), rX.16(Pred_L0 flag),
  83 *  rX.18 (Pred_L1 flag), rX.20(Forward reference ID), rX.22(Backwared reference ID)
  84 */
  85 mov  (8) mba_result.0<1>:ud     0x0:ud          {align1};
  86 mov  (8) mbb_result.0<1>:ud     0x0:ud          {align1};
  87 mov  (8) mbc_result.0<1>:ud     0x0:ud          {align1};
  88 mba_start:
  89 mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
  90 and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
  91 /* MB A doesn't exist. Zero MV. mba_flag is zero and ref ID = -1 */
  92 (f0.0)  mov  (2)        mba_result.20<1>:w      -1:w    {align1};
  93 (f0.0)  jmpi (1)        mbb_start;
  94 mov  (1) mba_result.0<1>:d      MB_AVAIL                {align1};
  95 mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
  96 add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     -1:w    {align1};
  97 mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
  98 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
  99 mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
 100 mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
 101 mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
 102
 103 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
 104 /* bind index 3, read 1 oword (16bytes), msg type: 0(OWord Block Read) */
 105 send (16)
 106         mb_ind
 107         mb_wb.0<1>:ud
 108         NULL
 109         data_port(
 110                 OBR_CACHE_TYPE,
 111                 OBR_MESSAGE_TYPE,
 112                 OBR_CONTROL_0,
 113                 OBR_BIND_IDX,
 114                 OBR_WRITE_COMMIT_CATEGORY,
 115                 OBR_HEADER_PRESENT
 116         )
 117         mlen 1
 118         rlen 1
 119         {align1};
 120
 121 /* TODO: RefID is required after multi-references are added */
 122 and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0 <0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
 123 (-f0.0)   mov (2)       mba_result.20<1>:w                      -1:w    {align1};
 124 (-f0.0)   jmpi  (1)     mbb_start;
 125
 126 mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud  {align1};
 127 /* Read MV for MB A */
 128 /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
 129 send (16)
 130         mb_ind
 131         mb_mv0.0<1>:ud
 132         NULL
 133         data_port(
 134                 OBR_CACHE_TYPE,
 135                 OBR_MESSAGE_TYPE,
 136                 OBR_CONTROL_8,
 137                 OBR_BIND_IDX,
 138                 OBR_WRITE_COMMIT_CATEGORY,
 139                 OBR_HEADER_PRESENT
 140         )
 141         mlen 1
 142         rlen 4
 143         {align1};
 144 /* TODO: RefID is required after multi-references are added */
 145 /* MV */
 146 mov     (2)     mba_result.4<1>:ud              mb_mv1.8<2,2,1>:ud      {align1};
 147 mov     (2)     mba_result.20<1>:w              -1:w            {align1};
 148 mov     (1)     INPUT_ARG0.0<1>:ud      mb_mode_wb.4<0,1,0>:ud  {align1};
 149 mov     (1)     INPUT_ARG0.4<1>:ud      mb_mode_wb.0<0,1,0>:ud  {align1};
 150 mov     (1)     INPUT_ARG0.8<1>:ud      INTER_BLOCK1:ud {align1};
 151 SAVE_RET        {align1};
 152 jmpi    (1)     mb_pred_func;
 153 mov     (1)     mb_pred_mode.0<1>:uw    RET_ARG<0,1,0>:uw       {align1};
 154 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L0 {align1};
 155 (f0.0)  mov   (1)       mba_result.16<1>:uw             MB_PRED_FLAG            {align1};
 156 (f0.0)  mov   (1)       mba_result.20<1>:w              0:w             {align1};
 157 (f0.0)  jmpi    (1) mbb_start;
 158 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L1 {align1};
 159 (f0.0)  mov   (1)       mba_result.18<1>:uw             MB_PRED_FLAG            {align1};
 160 (f0.0)  mov   (1)       mba_result.22<1>:w              0:w             {align1};
 161 (f0.0)  jmpi    (1) mbb_start;
 162 mov   (2)       mba_result.16<1>:uw             MB_PRED_FLAG            {align1};
 163 mov   (2)       mba_result.20<1>:w              0:w             {align1};
 164
 165 mbb_start:
 166 mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
 167 and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
 168 /* MB B doesn't exist. Zero MV. mba_flag is zero */
 169 /* If MB B doesn't exist, neither MB C nor D exists */
 170 (f0.0)  mov  (2)        mbb_result.20<1>:w      -1:w            {align1};
 171 (f0.0)  mov  (2)        mbc_result.20<1>:w      -1:w            {align1};
 172 (f0.0)  jmpi (1)        mb_mvp_start;
 173 mov  (1) mbb_result.0<1>:d      MB_AVAIL                {align1};
 174 mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
 175 add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
 176 mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
 177 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
 178 mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
 179 mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
 180 mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
 181
 182 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
 183
 184 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
 185 send (16)
 186         mb_ind
 187         mb_wb.0<1>:ud
 188         NULL
 189         data_port(
 190                 OBR_CACHE_TYPE,
 191                 OBR_MESSAGE_TYPE,
 192                 OBR_CONTROL_0,
 193                 OBR_BIND_IDX,
 194                 OBR_WRITE_COMMIT_CATEGORY,
 195                 OBR_HEADER_PRESENT
 196         )
 197         mlen 1
 198         rlen 1
 199         {align1};
 200
 201 /* TODO: RefID is required after multi-references are added */
 202 and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0 <0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
 203 (-f0.0)   mov (2)       mbb_result.20<1>:w                      -1:w    {align1};
 204 (-f0.0)   jmpi  (1)     mbc_start;
 205
 206 mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud  {align1};
 207 /* Read MV for MB B */
 208 /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
 209 send (16)
 210         mb_ind
 211         mb_mv0.0<1>:ud
 212         NULL
 213         data_port(
 214                 OBR_CACHE_TYPE,
 215                 OBR_MESSAGE_TYPE,
 216                 OBR_CONTROL_8,
 217                 OBR_BIND_IDX,
 218                 OBR_WRITE_COMMIT_CATEGORY,
 219                 OBR_HEADER_PRESENT
 220         )
 221         mlen 1
 222         rlen 4
 223         {align1};
 224 /* TODO: RefID is required after multi-references are added */
 225
 226 mov     (2)     mbb_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
 227 mov     (2)     mbb_result.20<1>:w              -1:w            {align1};
 228 mov     (1)     INPUT_ARG0.0<1>:ud      mb_mode_wb.4<0,1,0>:ud  {align1};
 229 mov     (1)     INPUT_ARG0.4<1>:ud      mb_mode_wb.0<0,1,0>:ud  {align1};
 230 mov     (1)     INPUT_ARG0.8<1>:ud      INTER_BLOCK2:ud {align1};
 231 SAVE_RET        {align1};
 232 jmpi    (1)     mb_pred_func;
 233 mov     (1)     mb_pred_mode.0<1>:uw    RET_ARG<0,1,0>:uw       {align1};
 234 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L0 {align1};
 235 (f0.0)  mov   (1)       mbb_result.16<1>:uw             MB_PRED_FLAG            {align1};
 236 (f0.0)  mov   (1)       mbb_result.20<1>:w              0:w             {align1};
 237 (f0.0)  jmpi    (1) mbc_start;
 238 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L1 {align1};
 239 (f0.0)  mov   (1)       mbb_result.18<1>:uw             MB_PRED_FLAG            {align1};
 240 (f0.0)  mov   (1)       mbb_result.22<1>:w              0:w             {align1};
 241 (f0.0)  jmpi    (1) mbc_start;
 242 mov   (2)       mbb_result.16<1>:uw             MB_PRED_FLAG            {align1};
 243
 244 mbc_start:
 245 mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
 246 and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_C:uw   {align1};
 247 /* MB C doesn't exist. Zero MV. mba_flag is zero */
 248 /* Based on h264 spec the MB D will be replaced if MB C doesn't exist */
 249 (f0.0)  jmpi (1)        mbd_start;
 250 mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};
 251 mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
 252 add  (1) tmp_reg0.2<1>:w        tmp_reg0.2<0,1,0>:w     -1:w    {align1};
 253 add  (1) tmp_reg0.0<1>:w        tmp_reg0.0<0,1,0>:w     1:w     {align1};
 254 mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
 255 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
 256 mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
 257 mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
 258
 259 mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
 260
 261 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
 262 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
 263 send (16)
 264         mb_ind
 265         mb_wb.0<1>:ud
 266         NULL
 267         data_port(
 268                 OBR_CACHE_TYPE,
 269                 OBR_MESSAGE_TYPE,
 270                 OBR_CONTROL_0,
 271                 OBR_BIND_IDX,
 272                 OBR_WRITE_COMMIT_CATEGORY,
 273                 OBR_HEADER_PRESENT
 274         )
 275         mlen 1
 276         rlen 1
 277         {align1};
 278
 279 /* TODO: RefID is required after multi-references are added */
 280 and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0 <0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
 281 (-f0.0)   mov (2)       mbc_result.20<1>:w                      -1:w    {align1};
 282 (-f0.0)   jmpi  (1)     mb_mvp_start;
 283 mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud {align1};
 284 /* Read MV for MB C */
 285 /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
 286 send (16)
 287         mb_ind
 288         mb_mv0.0<1>:ud
 289         NULL
 290         data_port(
 291                 OBR_CACHE_TYPE,
 292                 OBR_MESSAGE_TYPE,
 293                 OBR_CONTROL_8,
 294                 OBR_BIND_IDX,
 295                 OBR_WRITE_COMMIT_CATEGORY,
 296                 OBR_HEADER_PRESENT
 297         )
 298         mlen 1
 299         rlen 4
 300         {align1};
 301 /* TODO: RefID is required after multi-references are added */
 302 /* Forward MV */
 303 mov        (2)          mbc_result.4<1>:ud              mb_mv2.16<2,2,1>:ud     {align1};
 304 mov        (2)          mbc_result.20<1>:w              -1:w    {align1};
 305 mov     (1)     INPUT_ARG0.0<1>:ud      mb_mode_wb.4<0,1,0>:ud  {align1};
 306 mov     (1)     INPUT_ARG0.4<1>:ud      mb_mode_wb.0<0,1,0>:ud  {align1};
 307 mov     (1)     INPUT_ARG0.8<1>:ud      INTER_BLOCK2:ud {align1};
 308 SAVE_RET        {align1};
 309 jmpi    (1)     mb_pred_func;
 310 mov     (1)     mb_pred_mode.0<1>:uw    RET_ARG<0,1,0>:uw       {align1};
 311 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L0 {align1};
 312 (f0.0)  mov    (1) mbc_result.16<1>:uw          MB_PRED_FLAG            {align1};
 313 (f0.0)  mov    (1) mbc_result.20<1>:w           0:w             {align1};
 314 (f0.0)  jmpi   (1) mb_mvp_start;
 315 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L1 {align1};
 316 (f0.0)  mov   (1)       mbc_result.18<1>:uw             MB_PRED_FLAG            {align1};
 317 (f0.0)  mov    (1) mbc_result.22<1>:w           0:w             {align1};
 318 (f0.0)  jmpi  (1) mb_mvp_start;
 319 mov  (2)  mbc_result.16<1>:uw           MB_PRED_FLAG            {align1};
 320 mov  (2)  mbc_result.20<1>:w            0:w     {align1};
 321
 322 jmpi   (1)    mb_mvp_start;
 323 mbd_start:
 324 mov  (8) mb_msg0.0<1>:ud        0:ud            {align1};
 325 and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_D:uw   {align1};
 326 (f0.0)  jmpi (1)        mb_mvp_start;
 327 mov  (1) mbc_result.0<1>:d      MB_AVAIL                {align1};
 328 mov  (2) tmp_reg0.0<1>:UW       orig_xy_ub<2,2,1>:UB    {align1};
 329 add  (2) tmp_reg0.0<1>:w        tmp_reg0.0<2,2,1>:w     -1:w    {align1};
 330 mul  (1) mb_msg0.8<1>:UD       w_in_mb_uw<0,1,0>:UW tmp_reg0.2<0,1,0>:UW {align1};
 331 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD   tmp_reg0.0<0,1,0>:uw {align1};
 332
 333 mul  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD INTER_VME_OUTPUT_IN_OWS:UD {align1};
 334 mov  (1) mb_msg0.20<1>:UB        thread_id_ub {align1};                  /* dispatch id */
 335 mov  (1) mb_msg_tmp.8<1>:ud     mb_msg0.8<0,1,0>:ud     {align1};
 336
 337 add  (1) mb_msg0.8<1>:UD       mb_msg0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
 338 /* bind index 3, read 4 oword (64bytes), msg type: 0(OWord Block Read) */
 339 send (16)
 340         mb_ind
 341         mb_wb.0<1>:ud
 342         NULL
 343         data_port(
 344                 OBR_CACHE_TYPE,
 345                 OBR_MESSAGE_TYPE,
 346                 OBR_CONTROL_0,
 347                 OBR_BIND_IDX,
 348                 OBR_WRITE_COMMIT_CATEGORY,
 349                 OBR_HEADER_PRESENT
 350         )
 351         mlen 1
 352         rlen 1
 353         {align1};
 354
 355 and.z.f0.0      (1)     null<1>:ud        mb_mode_wb.0 <0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
 356 (-f0.0)   mov (2)       mbc_result.20<1>:w                      -1:w    {align1};
 357 (-f0.0)   jmpi  (1)     mb_mvp_start;
 358
 359 mov   (1) mb_msg0.8<1>:UD       mb_msg_tmp.8<0,1,0>:ud  {align1};
 360 /* Read MV for MB D */
 361 /* bind index 3, read 8 oword (128bytes), msg type: 0(OWord Block Read) */
 362 send (16)
 363         mb_ind
 364         mb_mv0.0<1>:ub
 365         NULL
 366         data_port(
 367                 OBR_CACHE_TYPE,
 368                 OBR_MESSAGE_TYPE,
 369                 OBR_CONTROL_8,
 370                 OBR_BIND_IDX,
 371                 OBR_WRITE_COMMIT_CATEGORY,
 372                 OBR_HEADER_PRESENT
 373         )
 374         mlen 1
 375         rlen 4
 376         {align1};
 377
 378 /* TODO: RefID is required after multi-references are added */
 379
 380 /* Forward MV */
 381 mov        (2)          mbc_result.4<1>:ud              mb_mv3.24<2,2,1>:ud     {align1};
 382 mov        (2)          mbc_result.20<1>:w              -1:w    {align1};
 383 mov     (1)     INPUT_ARG0.0<1>:ud      mb_mode_wb.4<0,1,0>:ud  {align1};
 384 mov     (1)     INPUT_ARG0.4<1>:ud      mb_mode_wb.0<0,1,0>:ud  {align1};
 385 mov     (1)     INPUT_ARG0.8<1>:ud      INTER_BLOCK3:ud {align1};
 386 SAVE_RET        {align1};
 387 jmpi    (1)     mb_pred_func;
 388 mov     (1)     mb_pred_mode.0<1>:uw    RET_ARG<0,1,0>:uw       {align1};
 389 mov        (1)  mbc_result.18<1>:w              MB_PRED_FLAG            {align1};
 390 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L0 {align1};
 391 (f0.0)  mov    (1) mbc_result.16<1>:uw          MB_PRED_FLAG            {align1};
 392 (f0.0)  mov    (1) mbc_result.20<1>:w           0:w             {align1};
 393 (f0.0)  jmpi    (1) mb_mvp_start;
 394 cmp.e.f0.0 (1)  null:uw         mb_pred_mode.0<0,1,0>:uw        PRED_L1 {align1};
 395 (f0.0)  mov   (1)       mbc_result.18<1>:uw             MB_PRED_FLAG            {align1};
 396 (f0.0)  mov    (1) mbc_result.22<1>:w           0:w             {align1};
 397 (f0.0)  jmpi  (1) mb_mvp_start;
 398 mov  (2)  mbc_result.16<1>:uw           MB_PRED_FLAG            {align1};
 399 mov  (2)  mbc_result.20<1>:w            0:w     {align1};
 400
 401 mb_mvp_start:
 402 /*TODO: Add the skip prediction */
 403 /* Check whether both MB B and C are invailable */
 404 add     (1)     tmp_reg0.0<1>:d         mbb_result.0<0,1,0>:d   mbc_result.0<0,1,0>:d   {align1};
 405 cmp.z.f0.0 (1)  null:d                  tmp_reg0.0<0,1,0>:d     0:d     {align1};
 406 (-f0.0) jmpi (1)        mb_median_start;
 407 cmp.nz.f0.0 (1) null:d  mba_result.0<0,1,0>:d           0:d             {align1};
 408 (f0.0)  mov     (2)     mbb_result.4<1>:ud              mba_result.4<2,2,1>:ud  {align1};
 409 (f0.0)  mov     (2)     mbc_result.4<1>:ud              mba_result.4<2,2,1>:ud  {align1};
 410 (f0.0)  mov     (2)     mbb_result.20<1>:uw             mba_result.20<2,2,1>:uw {align1};
 411 (f0.0)  mov     (2)     mbc_result.20<1>:uw             mba_result.20<2,2,1>:uw {align1};
 412 (f0.0)  mov     (2)     mb_mvp_ref.0<1>:ud              mba_result.4<2,2,1>:ud  {align1};
 413 (-f0.0) mov     (2)     mb_mvp_ref.0<1>:ud              0:ud                    {align1};
 414 jmpi    (1)     __mb_hwdep_end;
 415
 416 mb_median_start:
 417 /* forward_MVP */
 418 /* check whether only one neighbour MB has the same ref ID with the current MB */
 419 mov (8) tmp_reg0.0<1>:ud                0:ud            {align1};
 420 cmp.z.f0.0      (1)     null:d  mba_result.20<1>:w      0:w     {align1};
 421 (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
 422 (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mba_result.4<0,1,0>:ud  {align1};
 423 cmp.z.f0.0      (1)     null:d  mbb_result.20<1>:w      0:w     {align1};
 424 (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
 425 (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbb_result.4<0,1,0>:ud  {align1};
 426 cmp.z.f0.0      (1)     null:d  mbc_result.20<1>:w      0:w     {align1};
 427 (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
 428 (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbc_result.4<0,1,0>:ud  {align1};
 429 cmp.e.f0.0      (1)     null:d  tmp_reg0.0<1>:w  1:w    {align1};
 430 (f0.0)  mov     (1)     mb_mvp_ref.0<1>:ud      tmp_reg0.4<0,1,0>:ud    {align1};
 431 (f0.0)  jmpi (1)  mvp_backward;
 432
 433 mov     (1)     INPUT_ARG0.0<1>:w       mba_result.4<0,1,0>:w   {align1};
 434 mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.4<0,1,0>:w   {align1};
 435 mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.4<0,1,0>:w   {align1};
 436 SAVE_RET        {align1};
 437  jmpi   (1)     word_imedian;
 438 mov     (1)     mb_mvp_ref.0<1>:w               RET_ARG<0,1,0>:w        {align1};
 439 mov     (1)     INPUT_ARG0.0<1>:w       mba_result.6<0,1,0>:w   {align1};
 440 mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.6<0,1,0>:w   {align1};
 441 mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.6<0,1,0>:w   {align1};
 442 SAVE_RET        {align1};
 443 jmpi    (1)     word_imedian;
 444 mov     (1)     mb_mvp_ref.2<1>:w               RET_ARG<0,1,0>:w        {align1};
 445
 446
 447 mvp_backward:
 448 /* check whether only one neighbour MB has the same ref ID with the current MB */
 449 mov (8) tmp_reg0.0<1>:ud                0:ud            {align1};
 450 cmp.z.f0.0      (1)     null:d  mba_result.22<1>:w      0:w     {align1};
 451 (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
 452 (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mba_result.8<0,1,0>:ud  {align1};
 453 cmp.z.f0.0      (1)     null:d  mbb_result.22<1>:w      0:w     {align1};
 454 (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
 455 (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbb_result.8<0,1,0>:ud  {align1};
 456 cmp.z.f0.0      (1)     null:d  mbc_result.22<1>:w      0:w     {align1};
 457 (f0.0)  add     (1)     tmp_reg0.0<1>:w         tmp_reg0.0<1>:w 1:w     {align1};
 458 (f0.0)  mov     (1)     tmp_reg0.4<1>:ud        mbc_result.8<0,1,0>:ud  {align1};
 459 cmp.e.f0.0      (1)     null:d  tmp_reg0.0<1>:w  1:w    {align1};
 460 (f0.0)  mov     (1)     mb_mvp_ref.4<1>:ud      tmp_reg0.4<0,1,0>:ud    {align1};
 461 (f0.0)  jmpi (1) __mb_hwdep_end;
 462
 463 mov     (1)     INPUT_ARG0.0<1>:w       mba_result.8<0,1,0>:w   {align1};
 464 mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.8<0,1,0>:w   {align1};
 465 mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.8<0,1,0>:w   {align1};
 466 SAVE_RET        {align1};
 467  jmpi   (1)     word_imedian;
 468 mov     (1)     mb_mvp_ref.4<1>:w               RET_ARG<0,1,0>:w        {align1};
 469 mov     (1)     INPUT_ARG0.0<1>:w       mba_result.10<0,1,0>:w  {align1};
 470 mov     (1)     INPUT_ARG0.4<1>:w       mbb_result.10<0,1,0>:w  {align1};
 471 mov     (1)     INPUT_ARG0.8<1>:w       mbc_result.10<0,1,0>:w  {align1};
 472 SAVE_RET        {align1};
 473 jmpi    (1)     word_imedian;
 474 mov     (1)     mb_mvp_ref.6<1>:w               RET_ARG<0,1,0>:w        {align1};
 475
 476 __mb_hwdep_end:
 477 asr     (4)     mb_ref_win.0<1>:w       mb_mvp_ref.0<4,4,1>:w   2:w     {align1};
 478 add     (4)     mb_ref_win.8<1>:w       mb_ref_win.0<4,4,1>:w   3:w     {align1};
 479 and     (4)     mb_ref_win.16<1>:uw     mb_ref_win.8<4,4,1>:uw  0xFFFC:uw {align1};
 480
 481 /* m2 */
 482 mov  (8) vme_msg_2<1>:UD        0x0:UD {align1};
 483
 484 /* m3 */
 485 mov  (1) INEP_ROW.0<1>:UD       0x0:UD {align1};
 486 and  (1) INEP_ROW.4<1>:UD       INEP_ROW.4<0,1,0>:UD            0xFF000000:UD {align1};
 487 mov  (8) vme_msg_3<1>:UD        INEP_ROW.0<8,8,1>:UD {align1};
 488
 489 /* m4 */
 490 mov  (8) vme_msg_4<1>:UD        0x0 {align1};
 491 mov (16) vme_msg_4.0<1>:UB      INEP_COL0.3<32,8,4>:UB {align1};
 492 mov  (1) vme_msg_4.16<1>:UD     INTRA_PREDICTORE_MODE {align1};
 493
 494
 495 /* m1 */
 496 mov  (8) vme_m1.0<1>:ud         0x0:ud  {align1};
 497 and.z.f0.0 (1) null<1>:UW transform_8x8_ub<0,1,0>:UB 1:UW {align1};
 498 (f0.0) mov  (1) intra_part_mask_ub<1>:UB  LUMA_INTRA_8x8_DISABLE:uw {align1};
 499
 500 /* assign MB intra struct from the thread payload*/
 501 mov (1) mb_intra_struct_ub<1>:UB input_mb_intra_ub<0,1,0>:UB {align1};
 502
 503
 504 /* M0 */
 505 /* IME search */
 506 mov  (1) vme_m0.12<1>:UD   SEARCH_CTRL_DUAL_REFERENCE + INTER_PART_MASK + INTER_SAD_HAAR + SUB_PEL_MODE_QUARTER:UD {align1};
 507 /* 16x16 Source, 1/4 pixel, harr */
 508 mov  (1) vme_m0.22<1>:UW        DREF_REGION_SIZE {align1};         /* Reference Width&Height, 48x40 */
 509
 510 mov  (1) vme_m0.0<1>:UD         vme_m0.8<0,1,0>:UD      {align1};
 511
 512 mov  (1) vme_m0.0<1>:W          -8:W                    {align1};
 513 mov  (1) vme_m0.2<1>:W          -8:W                    {align1};
 514
 515 mov  (1) vme_m0.4<1>:UD         vme_m0.0<0,1,0>:UD      {align1};
 516 and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_AE:uw   {align1};
 517 (f0.0)  add     (1)     vme_m0.0<1>:w   vme_m0.0<0,1,0>:w       4:w     {align1};
 518 (f0.0)  add     (1)     vme_m0.4<1>:w   vme_m0.4<0,1,0>:w       4:w     {align1};
 519 and.z.f0.0 (1)          null:uw input_mb_intra_ub<0,1,0>:ub     INTRA_PRED_AVAIL_FLAG_B:uw   {align1};
 520 (f0.0)  add     (1)     vme_m0.2<1>:w   vme_m0.2<0,1,0>:w       4:w     {align1};
 521 (f0.0)  add     (1)     vme_m0.6<1>:w   vme_m0.6<0,1,0>:w       4:w     {align1};
 522
 523 mov  (1) vme_m0.4<1>:UD         vme_m0.0<0,1,0>:UD      {align1};
 524
 525 add  (2) vme_m0.0<1>:w          vme_m0.0<2,2,1>:w       mb_ref_win.16<2,2,1>:w  {align1};
 526 add  (2) vme_m0.4<1>:w          vme_m0.4<2,2,1>:w       mb_ref_win.20<2,2,1>:w  {align1};
 527 mov  (8) vme_msg_0.0<1>:UD      vme_m0.0<8,8,1>:UD {align1};
 528
 529 /* m1 */
 530
 531 mov  (1) vme_m1.0<1>:UD         ADAPTIVE_SEARCH_ENABLE:ud {align1} ;
 532 /* MV num is passed by constant buffer. R4.28 */
 533 mov  (1) vme_m1.4<1>:UB         r4.28<0,1,0>:UB {align1};
 534 add  (1) vme_m1.4<1>:UD         vme_m1.4<0,1,0>:UD      FB_PRUNING_ENABLE:UD {align1};
 535 add  (1) vme_m1.6<1>:uw         vme_m1.6<0,1,0>:uw      BI_WEIGHT       {align1};
 536
 537
 538 mov  (1) vme_m1.8<1>:UD         DSTART_CENTER + DSEARCH_PATH_LEN:UD {align1};
 539
 540 /* Set the MV cost center */
 541 mov  (1) vme_m1.16<1>:ud        mb_mvp_ref.0<0,1,0>:ud  {align1};
 542 mov  (1) vme_m1.20<1>:ud        mb_mvp_ref.4<0,1,0>:ud  {align1};
 543 mov  (8) vme_msg_1.0<1>:UD      vme_m1.0<8,8,1>:UD {align1};
 544
 545 /* Use one register as the descriptor of send instruction */
 546 mov  (1) a0.0<1>:ud              0x0a686000:ud {align1};
 547 send (1) vme_wb.0<1>:ud   vme_msg_0    0x08   a0.0<0,1,0>:ud {align1};
 548
 549 and.z.f0.0      (1)     null<1>:ud              vme_wb0.0<0,1,0>:ud     INTRAMBFLAG_MASK:ud {align1} ;
 550
 551 (-f0.0)jmpi     (1)     __INTRA_INFO ;
 552
 553 __INTER_INFO:
 554 /* Write MV pairs */
 555 mov  (8) msg_reg0.0<1>:UD       obw_m0.0<8,8,1>:UD {align1};
 556
 557 mov  (8) msg_reg1.0<1>:UD       vme_wb1.0<8,8,1>:UD   {align1};
 558
 559 mov  (8) msg_reg2.0<1>:UD       vme_wb2.0<8,8,1>:UD   {align1};
 560
 561 mov  (8) msg_reg3.0<1>:UD       vme_wb3.0<8,8,1>:UD   {align1};
 562
 563 mov  (8) msg_reg4.0<1>:UD       vme_wb4.0<8,8,1>:UD   {align1};
 564 /* bind index 3, write  8 oword (128 bytes), msg type: 8(OWord Block Write) */
 565 send (16)
 566         msg_ind
 567         obw_wb
 568         null
 569         data_port(
 570                 OBW_CACHE_TYPE,
 571                 OBW_MESSAGE_TYPE,
 572                 OBW_CONTROL_8,
 573                 OBW_BIND_IDX,
 574                 OBW_WRITE_COMMIT_CATEGORY,
 575                 OBW_HEADER_PRESENT
 576         )
 577         mlen 5
 578         rlen obw_wb_length
 579         {align1};
 580
 581 mov             (1)     tmp_uw1<1>:uw           0:uw {align1} ;
 582 mov             (1)     tmp_ud1<1>:ud           0:ud {align1} ;
 583 and             (1)     tmp_uw1<1>:uw           vme_wb0.2<0,1,0>:uw     MV32_BIT_MASK:uw {align1} ;
 584 shr             (1)     tmp_uw1<1>:uw           tmp_uw1<1>:uw           MV32_BIT_SHIFT:uw {align1} ;
 585 mul       (1)     tmp_ud1<1>:ud           tmp_uw1<0,1,0>:uw       96:uw {align1} ;
 586 add       (1)     tmp_ud1<1>:ud           tmp_ud1<0,1,0>:ud       32:uw {align1} ;
 587 shl       (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       MFC_MV32_BIT_SHIFT:uw {align1} ;
 588 add       (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       MVSIZE_UW_BASE:uw {align1} ;
 589 add             (1)     tmp_uw1<1>:uw           tmp_uw1<0,1,0>:uw       CBP_DC_YUV_UW:uw {align1} ;
 590
 591 mov             (1)     msg_reg1.0<1>:uw        vme_wb0.0<0,1,0>:uw     {align1} ;
 592 mov             (1)     msg_reg1.2<1>:uw        tmp_uw1<0,1,0>:uw       {align1} ;
 593 mov             (1)     msg_reg1.4<1>:UD        vme_wb0.28<0,1,0>:UD    {align1};
 594 mov             (1)     msg_reg1.8<1>:ud        tmp_ud1<0,1,0>:ud       {align1} ;
 595 mov             (1)     msg_reg1.12<1>:ud        vme_wb0.0<0,1,0>:ud     {align1} ;
 596 mov             (1)     msg_reg1.16<1>:ud        0x25:ud     {align1} ;
 597 jmpi            (1)     __OUTPUT_INFO;
 598
 599 __INTRA_INFO:
 600 mov             (1)     msg_reg1.0<1>:UD        vme_wb.0<0,1,0>:UD      {align1};
 601 mov             (1)     msg_reg1.4<1>:UD        vme_wb.16<0,1,0>:UD     {align1};
 602 mov             (1)     msg_reg1.8<1>:UD        vme_wb.20<0,1,0>:UD     {align1};
 603 mov             (1)     msg_reg1.12<1>:UD       vme_wb.24<0,1,0>:UD     {align1};
 604 mov             (1)     msg_reg1.16<1>:ud        0x35:ud     {align1} ;
 605
 606 __OUTPUT_INFO:
 607
 608 mov     (1)     msg_reg1.20<1>:ud       obw_m0.8<0,1,0>:ud      {align1};
 609 add     (1)     obw_m0.8<1>:UD       obw_m0.8<0,1,0>:UD      INTER_VME_OUTPUT_MV_IN_OWS:UD {align1};
 610 mov     (8)     msg_reg0.0<1>:ud        obw_m0.0<8,8,1>:ud      {align1};
 611
 612
 613 /* bind index 3, write 1 oword, msg type: 8(OWord Block Write) */
 614 send (16)
 615         msg_ind
 616         obw_wb
 617         null
 618         data_port(
 619                 OBW_CACHE_TYPE,
 620                 OBW_MESSAGE_TYPE,
 621                 OBW_CONTROL_2,
 622                 OBW_BIND_IDX,
 623                 OBW_WRITE_COMMIT_CATEGORY,
 624                 OBW_HEADER_PRESENT
 625         )
 626         mlen 2
 627         rlen obw_wb_length
 628         {align1};
 629
 630 NOP;
 631
 632 /* Issue message fence so that the previous write message is committed */
 633 send (16)
 634         mb_ind
 635         mb_wb.0<1>:ud
 636         NULL
 637         data_port(
 638                 OBR_CACHE_TYPE,
 639                 OBR_MESSAGE_FENCE,
 640                 OBR_MF_COMMIT,
 641                 OBR_BIND_IDX,
 642                 OBR_WRITE_COMMIT_CATEGORY,
 643                 OBR_HEADER_PRESENT
 644         )
 645         mlen 1
 646         rlen 1
 647         {align1};
 648
 649 __EXIT:
 650 /*
 651  * kill thread
 652  */
 653 mov  (8) ts_msg_reg0<1>:UD         r0<8,8,1>:UD {align1};
 654 send (16) ts_msg_ind acc0<1>UW null thread_spawner(0, 0, 1) mlen 1 rlen 0 {align1 EOT};
 655
 656
 657         nop             ;
 658         nop             ;
 659 /* Compare three word data to get the min value */
 660 word_imin:
 661         cmp.le.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
 662         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
 663         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
 664         cmp.le.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
 665         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
 666         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
 667         RETURN          {align1};
 668
 669 /* Compare three word data to get the max value */
 670 word_imax:
 671         cmp.ge.f0.0 (1)         null:w          INPUT_ARG0.0<0,1,0>:w   INPUT_ARG0.4<0,1,0>:w {align1};
 672         (f0.0) mov  (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.0<0,1,0>:w                    {align1};
 673         (-f0.0) mov (1)         TEMP_VAR0.0<1>:w INPUT_ARG0.4<0,1,0>:w                    {align1};
 674         cmp.ge.f0.0 (1)         null:w          TEMP_VAR0.0<0,1,0>:w    INPUT_ARG0.8<0,1,0>:w {align1};
 675         (f0.0) mov  (1)         RET_ARG<1>:w TEMP_VAR0.0<0,1,0>:w                         {align1};
 676         (-f0.0) mov (1)         RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w                        {align1};
 677         RETURN          {align1};
 678
 679 word_imedian:
 680         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.4<0,1,0>:w {align1};
 681         (f0.0)  jmpi (1) cmp_a_ge_b;
 682         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
 683         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
 684         (f0.0) jmpi (1) cmp_end;
 685         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
 686         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
 687         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
 688         jmpi (1) cmp_end;
 689 cmp_a_ge_b:
 690         cmp.ge.f0.0 (1) null:w INPUT_ARG0.4<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
 691         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.4<0,1,0>:w {align1};
 692         (f0.0) jmpi (1) cmp_end;
 693         cmp.ge.f0.0 (1) null:w INPUT_ARG0.0<0,1,0>:w INPUT_ARG0.8<0,1,0>:w {align1};
 694         (f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.8<0,1,0>:w {align1};
 695         (-f0.0) mov (1) RET_ARG<1>:w INPUT_ARG0.0<0,1,0>:w {align1};
 696 cmp_end:
 697         RETURN  {align1};
 698
 699 /* This is to get the prediction mode for the correspongding partions/sub-mb
 700  * Parameter description:
 701         ARG0.0: INTER_SHAPE/PRED_MODE
 702         ARG0.4: INTER_MODE(16x16, 16x8, 8x16 or 8X8)
 703         ARG0.8: sub-mb block number(block 0/1/2/3)
 704 */
 705
 706 mb_pred_func:
 707         mov     (8)     TEMP_VAR0.0<1>:ud       0:ud    {align1};
 708         mov     (1)     TEMP_VAR0.0<1>:ub       INPUT_ARG0.1<0,1,0>:ub  {align1};
 709         and     (1)   TEMP_VAR0.4<1>:uw   INPUT_ARG0.4<0,1,0>:uw        INTER_MASK:uw   {align1};
 710         /* INTER16x16 mode. The bit1-0 is the prediction mode */
 711         cmp.e.f0.0 (1) null:uw  TEMP_VAR0.4<1>:uw       INTER_16X16MODE:uw      {align1};
 712         (f0.0)  and (1) RET_ARG<1>:uw   TEMP_VAR0.0<0,1,0>:uw   PRED_MASK {align1};
 713         (f0.0)  jmpi (1) end_mb_pred;
 714         /* Check whether it is INTER8x8 mode. */
 715         cmp.e.f0.0 (1) null:uw  TEMP_VAR0.4<1>:uw       INTER_8X8MODE:uw        {align1};
 716         (f0.0)  jmpi (1) mb_pred_func_8;
 717
 718         /* Check whether it is INTER16x8 mode. */
 719         cmp.e.f0.0 (1) null:uw  TEMP_VAR0.4<1>:uw       INTER_16X8MODE:uw       {align1};
 720         (f0.0)  jmpi (1) mb_pred_func_168;
 721 mb_pred_func_816:
 722         /* Block 0/2 uses the bit1-0. Block 1/3 uses the bit3-2 */
 723         mov     (1) TEMP_VAR0.8<1>:uw INPUT_ARG0.8<0,1,0>:uw    {align1};
 724         and.z.f0.0 (1)  null:uw TEMP_VAR0.8<1>:uw       INTER_BLOCK1:uw {align1};
 725         (f0.0)  and     (1) RET_ARG<1>:uw       TEMP_VAR0.0<0,1,0>:uw   PRED_MASK {align1};
 726         (f0.0)  jmpi (1) end_mb_pred;
 727         shr     (1)  TEMP_VAR0.16<1>:uw TEMP_VAR0.0<0,1,0>:uw   2:uw {align1};
 728         and     (1)  RET_ARG<1>:uw      TEMP_VAR0.16<1>:uw      PRED_MASK  {align1};
 729         jmpi    (1) end_mb_pred;
 730
 731 mb_pred_func_168:
 732         /* Block 0/1 uses the bit1-0. Block 2/3 uses the bit3-2 */
 733         mov     (1) TEMP_VAR0.8<1>:uw INPUT_ARG0.8<0,1,0>:uw    {align1};
 734         cmp.l.f0.0 (1)  null:uw TEMP_VAR0.8<1>:uw       INTER_BLOCK2:uw {align1};
 735         (f0.0)  and  (1) RET_ARG<1>:uw  TEMP_VAR0.0<0,1,0>:uw   PRED_MASK {align1};
 736         (f0.0)  jmpi (1) end_mb_pred;
 737         shr     (1)  TEMP_VAR0.16<1>:uw TEMP_VAR0.0<0,1,0>:uw   2:uw {align1};
 738         and     (1)  RET_ARG<1>:uw      TEMP_VAR0.16<1>:uw      PRED_MASK  {align1};
 739         jmpi    (1) end_mb_pred;
 740
 741 mb_pred_func_8:
 742         /* 8X8 mode. Every block uses two bits as the prediction mode. */
 743         mul     (1)  TEMP_VAR0.8<1>:uw  INPUT_ARG0.8<0,1,0>:uw  2:uw {align1};
 744         shr     (1)  TEMP_VAR0.16<1>:uw TEMP_VAR0.0<0,1,0>:uw   TEMP_VAR0.8<0,1,0>:uw {align1};
 745         and     (1)  RET_ARG<1>:uw      TEMP_VAR0.16<1>:uw      PRED_MASK  {align1};
 746 end_mb_pred:
 747         RETURN  {align1};
 748