tk/library/demos/rolodex

   1 #!/bin/sh
   2 # the next line restarts using wish \
   3 exec wish "$0" "$@"
   4
   5 # rolodex --
   6 # This script was written as an entry in Tom LaStrange's rolodex
   7 # benchmark.  It creates something that has some of the look and
   8 # feel of a rolodex program, although it's lifeless and doesn't
   9 # actually do the rolodex application.
  10 #
  11 # SCCS: @(#) rolodex 1.7 96/02/16 10:49:23
  12
  13 foreach i [winfo child .] {
  14     catch {destroy $i}
  15 }
  16
  17 #------------------------------------------
  18 # Phase 0: create the front end.
  19 #------------------------------------------
  20
  21 frame .frame -relief flat
  22 pack .frame -side top -fill y -anchor center
  23
  24 set names {{} Name: Address: {} {} {Home Phone:} {Work Phone:} Fax:}
  25 foreach i {1 2 3 4 5 6 7} {
  26     frame .frame.$i
  27     pack .frame.$i -side top -pady 2 -anchor e
  28
  29     label .frame.$i.label -text [lindex $names $i] -anchor e
  30     entry .frame.$i.entry -width 30 -relief sunken
  31     pack .frame.$i.entry .frame.$i.label -side right
  32 }
  33
  34 frame .buttons
  35 pack .buttons -side bottom -pady 2 -anchor center
  36 button .buttons.clear -text Clear
  37 button .buttons.add -text Add
  38 button .buttons.search -text Search
  39 button .buttons.delete -text "Delete ..."
  40 pack .buttons.clear .buttons.add .buttons.search .buttons.delete \
  41         -side left -padx 2
  42
  43 #------------------------------------------
  44 # Phase 1: Add menus, dialog boxes
  45 #------------------------------------------
  46
  47 frame .menu -relief raised -borderwidth 1
  48 pack .menu -before .frame -side top -fill x
  49
  50 menubutton .menu.file -text "File" -menu .menu.file.m -underline 0
  51 menu .menu.file.m
  52 .menu.file.m add command -label "Load ..." -command fileAction -underline 0
  53 .menu.file.m add command -label "Exit" -command {destroy .} -underline 0
  54 pack .menu.file -side left
  55
  56 menubutton .menu.help -text "Help" -menu .menu.help.m -underline 0
  57 menu .menu.help.m
  58 pack .menu.help -side right
  59
  60 proc deleteAction {} {
  61     if {[tk_dialog .delete {Confirm Action} {Are you sure?} {} 0  Cancel]
  62             == 0} {
  63         clearAction
  64     }
  65 }
  66 .buttons.delete config -command deleteAction
  67
  68 proc fileAction {} {
  69     tk_dialog .fileSelection {File Selection} {This is a dummy file selection dialog box, which is used because there isn't a good file selection dialog built into Tk yet.} {} 0 OK
  70     puts stderr {dummy file name}
  71 }
  72
  73 #------------------------------------------
  74 # Phase 3: Print contents of card
  75 #------------------------------------------
  76
  77 proc addAction {} {
  78     global names
  79     foreach i {1 2 3 4 5 6 7} {
  80         puts stderr [format "%-12s %s" [lindex $names $i] [.frame.$i.entry get]]
  81     }
  82 }
  83 .buttons.add config -command addAction
  84
  85 #------------------------------------------
  86 # Phase 4: Miscellaneous other actions
  87 #------------------------------------------
  88
  89 proc clearAction {} {
  90     foreach i {1 2 3 4 5 6 7} {
  91         .frame.$i.entry delete 0 end
  92     }
  93 }
  94 .buttons.clear config -command clearAction
  95
  96 proc fillCard {} {
  97     clearAction
  98     .frame.1.entry insert 0 "John Ousterhout"
  99     .frame.2.entry insert 0 "CS Division, Department of EECS"
 100     .frame.3.entry insert 0 "University of California"
 101     .frame.4.entry insert 0 "Berkeley, CA 94720"
 102     .frame.5.entry insert 0 "private"
 103     .frame.6.entry insert 0 "510-642-0865"
 104     .frame.7.entry insert 0 "510-642-5775"
 105 }
 106 .buttons.search config -command "addAction; fillCard"
 107
 108 #----------------------------------------------------
 109 # Phase 5: Accelerators, mnemonics, command-line info
 110 #----------------------------------------------------
 111
 112 .buttons.clear config -text "Clear    Ctrl+C"
 113 bind . <Control-c> clearAction
 114 .buttons.add config -text "Add    Ctrl+A"
 115 bind . <Control-a> addAction
 116 .buttons.search config -text "Search    Ctrl+S"
 117 bind . <Control-s> "addAction; fillCard"
 118 .buttons.delete config -text "Delete...    Ctrl+D"
 119 bind . <Control-d> deleteAction
 120
 121 .menu.file.m entryconfig 1 -accel Ctrl+F
 122 bind . <Control-f> fileAction
 123 .menu.file.m entryconfig 2 -accel Ctrl+Q
 124 bind . <Control-q> {destroy .}
 125
 126 focus .frame.1.entry
 127
 128 #----------------------------------------------------
 129 # Phase 6: help
 130 #----------------------------------------------------
 131
 132 proc Help {topic {x 0} {y 0}} {
 133     global helpTopics helpCmds
 134     if {$topic == ""} return
 135     while {[info exists helpCmds($topic)]} {
 136         set topic [eval $helpCmds($topic)]
 137     }
 138     if [info exists helpTopics($topic)] {
 139         set msg $helpTopics($topic)
 140     } else {
 141         set msg "Sorry, but no help is available for this topic"
 142     }
 143     tk_dialog .help {Rolodex Help} "Information on $topic:\n\n$msg" \
 144             {} 0 OK
 145 }
 146
 147 proc getMenuTopic {w x y} {
 148     return $w.[$w index @[expr $y-[winfo rooty $w]]]
 149 }
 150
 151 bind . <Any-F1> {Help [winfo containing %X %Y] %X %Y}
 152 bind . <Any-Help> {Help [winfo containing %X %Y] %X %Y}
 153
 154 # Help text and commands follow:
 155
 156 set helpTopics(.menu.file) {This is the "file" menu.  It can be used to invoke some overall operations on the rolodex applications, such as loading a file or exiting.}
 157
 158 set helpCmds(.menu.file.m) {getMenuTopic $topic $x $y}
 159 set helpTopics(.menu.file.m.0) {The "Load" entry in the "File" menu posts a dialog box that you can use to select a rolodex file}
 160 set helpTopics(.menu.file.m.1) {The "Exit" entry in the "File" menu causes the rolodex application to terminate}
 161 set helpCmds(.menu.file.m.none) {set topic ".menu.file"}
 162
 163 set helpTopics(.frame.1.entry) {In this field of the rolodex entry you should type the person's name}
 164 set helpTopics(.frame.2.entry) {In this field of the rolodex entry you should type the first line of the person's address}
 165 set helpTopics(.frame.3.entry) {In this field of the rolodex entry you should type the second line of the person's address}
 166 set helpTopics(.frame.4.entry) {In this field of the rolodex entry you should type the third line of the person's address}
 167 set helpTopics(.frame.5.entry) {In this field of the rolodex entry you should type the person's home phone number, or "private" if the person doesn't want his or her number publicized}
 168 set helpTopics(.frame.6.entry) {In this field of the rolodex entry you should type the person's work phone number}
 169 set helpTopics(.frame.7.entry) {In this field of the rolodex entry you should type the phone number for the person's FAX machine}
 170
 171 set helpCmds(.frame.1.label) {set topic .frame.1.entry}
 172 set helpCmds(.frame.2.label) {set topic .frame.2.entry}
 173 set helpCmds(.frame.3.label) {set topic .frame.3.entry}
 174 set helpCmds(.frame.4.label) {set topic .frame.4.entry}
 175 set helpCmds(.frame.5.label) {set topic .frame.5.entry}
 176 set helpCmds(.frame.6.label) {set topic .frame.6.entry}
 177 set helpCmds(.frame.7.label) {set topic .frame.7.entry}
 178
 179 set helpTopics(context) {Unfortunately, this application doesn't support context-sensitive help in the usual way, because when this demo was written Tk didn't have a grab mechanism and this is needed for context-sensitive help.  Instead, you can achieve much the same effect by simply moving the mouse over the window you're curious about and pressing the Help or F1 keys.  You can do this anytime.}
 180 set helpTopics(help) {This application provides only very crude help.  Besides the entries in this menu, you can get help on individual windows by moving the mouse cursor over the window and pressing the Help or F1 keys.}
 181 set helpTopics(window) {This window is a dummy rolodex application created as part of Tom LaStrange's toolkit benchmark.  It doesn't really do anything useful except to demonstrate a few features of the Tk toolkit.}
 182 set helpTopics(keys) "The following accelerator keys are defined for this application (in addition to those already available for the entry windows):\n\nCtrl+A:\t\tAdd\nCtrl+C:\t\tClear\nCtrl+D:\t\tDelete\nCtrl+F:\t\tEnter file name\nCtrl+Q:\t\tExit application (quit)\nCtrl+S:\t\tSearch (dummy operation)"
 183 set helpTopics(version) {This is version 1.0.}
 184
 185 # Entries in "Help" menu
 186
 187 .menu.help.m add command -label "On Context..." -command {Help context} \
 188         -underline 3
 189 .menu.help.m add command -label "On Help..." -command {Help help} \
 190         -underline 3
 191 .menu.help.m add command -label "On Window..." -command {Help window} \
 192         -underline 3
 193 .menu.help.m add command -label "On Keys..." -command {Help keys} \
 194         -underline 3
 195 .menu.help.m add command -label "On Version..." -command {Help version}  \
 196         -underline 3