tools/llvm-config/CMakeLists.txt

   1 set(LLVM_LINK_COMPONENTS support)
   2
   3 set(BUILDVARIABLES_SRCPATH ${CMAKE_CURRENT_SOURCE_DIR}/BuildVariables.inc.in)
   4 set(BUILDVARIABLES_OBJPATH ${CMAKE_CURRENT_BINARY_DIR}/BuildVariables.inc)
   5
   6 # Add the llvm-config tool.
   7 add_llvm_tool(llvm-config
   8   llvm-config.cpp
   9   )
  10
  11 # Compute the substitution values for various items.
  12 get_property(LLVM_SYSTEM_LIBS_LIST TARGET LLVMSupport PROPERTY LLVM_SYSTEM_LIBS)
  13 foreach(l ${LLVM_SYSTEM_LIBS_LIST})
  14   if(MSVC)
  15     set(SYSTEM_LIBS ${SYSTEM_LIBS} "${l}.lib")
  16   else()
  17     if (l MATCHES "^-")
  18       # If it's an option, pass it without changes.
  19       set(SYSTEM_LIBS ${SYSTEM_LIBS} "${l}")
  20     else()
  21       # Otherwise assume it's a library name we need to link with.
  22       set(SYSTEM_LIBS ${SYSTEM_LIBS} "-l${l}")
  23     endif()
  24   endif()
  25 endforeach()
  26 string(REPLACE ";" " " SYSTEM_LIBS "${SYSTEM_LIBS}")
  27
  28 # Fetch target specific compile options, e.g. RTTI option
  29 get_property(COMPILE_FLAGS TARGET llvm-config PROPERTY COMPILE_FLAGS)
  30
  31 # Use configure_file to create BuildVariables.inc.
  32 set(LLVM_SRC_ROOT ${LLVM_MAIN_SRC_DIR})
  33 set(LLVM_OBJ_ROOT ${LLVM_BINARY_DIR})
  34 set(LLVM_CPPFLAGS "${CMAKE_CPP_FLAGS} ${CMAKE_CPP_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  35 set(LLVM_CFLAGS "${CMAKE_C_FLAGS} ${CMAKE_C_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${LLVM_DEFINITIONS}")
  36 set(LLVM_CXXFLAGS "${CMAKE_CXX_FLAGS} ${CMAKE_CXX_FLAGS_${uppercase_CMAKE_BUILD_TYPE}} ${COMPILE_FLAGS} ${LLVM_DEFINITIONS}")
  37 set(LLVM_BUILD_SYSTEM cmake)
  38 set(LLVM_HAS_RTTI ${LLVM_CONFIG_HAS_RTTI})
  39 set(LLVM_DYLIB_VERSION "${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}${LLVM_VERSION_SUFFIX}")
  40 set(LLVM_HAS_GLOBAL_ISEL "ON")
  41
  42 # Use the C++ link flags, since they should be a superset of C link flags.
  43 set(LLVM_LDFLAGS "${CMAKE_CXX_LINK_FLAGS}")
  44 set(LLVM_BUILDMODE ${CMAKE_BUILD_TYPE})
  45 set(LLVM_SYSTEM_LIBS ${SYSTEM_LIBS})
  46 string(REPLACE ";" " " LLVM_TARGETS_BUILT "${LLVM_TARGETS_TO_BUILD}")
  47 llvm_canonicalize_cmake_booleans(
  48   LLVM_BUILD_LLVM_DYLIB
  49   LLVM_LINK_LLVM_DYLIB
  50   LLVM_HAS_RTTI
  51   LLVM_HAS_GLOBAL_ISEL
  52   BUILD_SHARED_LIBS)
  53 configure_file(${BUILDVARIABLES_SRCPATH} ${BUILDVARIABLES_OBJPATH} @ONLY)
  54
  55 # Set build-time environment(s).
  56 add_definitions(-DCMAKE_CFG_INTDIR="${CMAKE_CFG_INTDIR}")
  57
  58 if(LLVM_ENABLE_MODULES)
  59   target_compile_options(llvm-config PUBLIC
  60     "-fmodules-ignore-macro=CMAKE_CFG_INTDIR"
  61     )
  62 endif()
  63
  64 # Add the dependency on the generation step.
  65 add_file_dependencies(${CMAKE_CURRENT_SOURCE_DIR}/llvm-config.cpp ${BUILDVARIABLES_OBJPATH})
  66
  67 if(CMAKE_CROSSCOMPILING AND NOT LLVM_CONFIG_PATH)
  68   set(LLVM_CONFIG_PATH "${LLVM_NATIVE_BUILD}/bin/llvm-config" CACHE STRING "")
  69
  70   add_custom_command(OUTPUT "${LLVM_CONFIG_PATH}"
  71     COMMAND ${CMAKE_COMMAND} --build . --target llvm-config --config $<CONFIGURATION>
  72     DEPENDS ${LLVM_NATIVE_BUILD}/CMakeCache.txt
  73     WORKING_DIRECTORY ${LLVM_NATIVE_BUILD}
  74     COMMENT "Building native llvm-config..."
  75     USES_TERMINAL)
  76   add_custom_target(NativeLLVMConfig DEPENDS ${LLVM_CONFIG_PATH})
  77   add_dependencies(NativeLLVMConfig CONFIGURE_LLVM_NATIVE)
  78
  79   add_dependencies(llvm-config NativeLLVMConfig)
  80 endif()