tools/llvm-shlib/CMakeLists.txt

   1 # This tool creates a shared library from the LLVM libraries. Generating this
   2 # library is enabled by setting LLVM_BUILD_LLVM_DYLIB=yes on the CMake
   3 # commandline. By default the shared library only exports the LLVM C API.
   4
   5 set(SOURCES
   6   libllvm.cpp
   7   )
   8
   9 if(LLVM_LINK_LLVM_DYLIB AND LLVM_DYLIB_EXPORTED_SYMBOL_FILE)
  10   message(WARNING "Using LLVM_LINK_LLVM_DYLIB with LLVM_DYLIB_EXPORTED_SYMBOL_FILE may not work. Use at your own risk.")
  11 endif()
  12
  13 if(LLVM_BUILD_LLVM_DYLIB)
  14   if(MSVC)
  15     message(FATAL_ERROR "Generating libLLVM is not supported on MSVC")
  16   endif()
  17
  18   llvm_map_components_to_libnames(LIB_NAMES ${LLVM_DYLIB_COMPONENTS})
  19
  20   # libLLVM.so should not have any dependencies on any other LLVM
  21   # shared libraries. When using the "all" pseudo-component,
  22   # LLVM_AVAILABLE_LIBS is added to the dependencies, which may
  23   # contain shared libraries (e.g. libLTO).
  24   #
  25   # Also exclude libLLVMTableGen for the following reasons:
  26   #  - it is only used by internal *-tblgen utilities;
  27   #  - it pollutes the global options space.
  28   foreach(lib ${LIB_NAMES})
  29     get_target_property(t ${lib} TYPE)
  30     if("${lib}" STREQUAL "LLVMTableGen")
  31     elseif("x${t}" STREQUAL "xSTATIC_LIBRARY")
  32       list(APPEND FILTERED_LIB_NAMES ${lib})
  33     endif()
  34   endforeach()
  35   set(LIB_NAMES ${FILTERED_LIB_NAMES})
  36
  37   if(LLVM_DYLIB_EXPORTED_SYMBOL_FILE)
  38     set(LLVM_EXPORTED_SYMBOL_FILE ${LLVM_DYLIB_EXPORTED_SYMBOL_FILE})
  39     add_custom_target(libLLVMExports DEPENDS ${LLVM_EXPORTED_SYMBOL_FILE})
  40   endif()
  41
  42   add_llvm_library(LLVM SHARED DISABLE_LLVM_LINK_LLVM_DYLIB SONAME ${SOURCES})
  43
  44   list(REMOVE_DUPLICATES LIB_NAMES)
  45   if(("${CMAKE_SYSTEM_NAME}" STREQUAL "Linux") OR (MINGW) OR (HAIKU)
  46      OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "FreeBSD")
  47      OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "GNU")
  48      OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "OpenBSD")
  49      OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "Fuchsia")
  50      OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "DragonFly")
  51      OR ("${CMAKE_SYSTEM_NAME}" STREQUAL "SunOS")) # FIXME: It should be "GNU ld for elf"
  52     configure_file(
  53     ${CMAKE_CURRENT_SOURCE_DIR}/simple_version_script.map.in
  54     ${LLVM_LIBRARY_DIR}/tools/llvm-shlib/simple_version_script.map)
  55
  56     # GNU ld doesn't resolve symbols in the version script.
  57     set(LIB_NAMES -Wl,--whole-archive ${LIB_NAMES} -Wl,--no-whole-archive)
  58     if (NOT LLVM_LINKER_IS_SOLARISLD)
  59       # Solaris ld does not accept global: *; so there is no way to version *all* global symbols
  60       set(LIB_NAMES -Wl,--version-script,${LLVM_LIBRARY_DIR}/tools/llvm-shlib/simple_version_script.map ${LIB_NAMES})
  61     endif()
  62   elseif("${CMAKE_SYSTEM_NAME}" STREQUAL "Darwin")
  63     set(LIB_NAMES -Wl,-all_load ${LIB_NAMES})
  64   endif()
  65
  66   target_link_libraries(LLVM PRIVATE ${LIB_NAMES})
  67
  68   if (APPLE)
  69     set_property(TARGET LLVM APPEND_STRING PROPERTY
  70                 LINK_FLAGS
  71                 " -compatibility_version 1 -current_version ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH}")
  72   endif()
  73
  74   if(TARGET libLLVMExports)
  75     add_dependencies(LLVM libLLVMExports)
  76   endif()
  77 endif()
  78
  79 if(LLVM_BUILD_LLVM_C_DYLIB AND NOT MSVC)
  80   if(NOT APPLE)
  81     message(FATAL_ERROR "Generating libLLVM-c is only supported on Darwin")
  82   endif()
  83
  84   if(NOT LLVM_BUILD_LLVM_DYLIB)
  85     message(FATAL_ERROR "Generating libLLVM-c requires LLVM_BUILD_LLVM_C_DYLIB on Darwin")
  86   endif()
  87
  88   # To get the export list for a single llvm library:
  89   # nm ${LIB_PATH} | awk "/T _LLVM/ { print $3 }" | sort -u | sed -e "s/^_//g" > ${LIB_PATH}.exports
  90
  91   set(LLVM_EXPORTED_SYMBOL_FILE ${CMAKE_BINARY_DIR}/libllvm-c.exports)
  92
  93   set(LIB_DIR ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib${LLVM_LIBDIR_SUFFIX})
  94   set(LIB_NAME ${LIB_DIR}/${CMAKE_SHARED_LIBRARY_PREFIX}LLVM)
  95   set(LIB_PATH ${LIB_NAME}${CMAKE_SHARED_LIBRARY_SUFFIX})
  96   set(LIB_EXPORTS_PATH ${LIB_NAME}.exports)
  97   list(APPEND LLVM_DYLIB_REQUIRED_EXPORTS ${LIB_EXPORTS_PATH})
  98
  99   add_custom_command(OUTPUT ${LLVM_EXPORTED_SYMBOL_FILE}
 100     COMMAND nm ${LIB_PATH} | awk "/T _LLVM/ || /T LLVM/ { print $3 }" | sort -u | sed -e "s/^_//g" > ${LLVM_EXPORTED_SYMBOL_FILE}
 101     WORKING_DIRECTORY ${LIB_DIR}
 102     DEPENDS LLVM
 103     COMMENT "Generating Export list for LLVM..."
 104     VERBATIM )
 105
 106   add_custom_target(libLLVMCExports DEPENDS ${LLVM_EXPORTED_SYMBOL_FILE})
 107
 108   add_llvm_library(LLVM-C SHARED ${SOURCES})
 109
 110   target_link_libraries(LLVM-C PUBLIC LLVM)
 111   add_dependencies(LLVM-C libLLVMCExports)
 112
 113   set_property(TARGET LLVM-C APPEND_STRING PROPERTY
 114               LINK_FLAGS
 115               " -compatibility_version 1 -current_version ${LLVM_VERSION_MAJOR}.${LLVM_VERSION_MINOR}.${LLVM_VERSION_PATCH} -Wl,-reexport_library ${LIB_PATH}")
 116 endif()
 117
 118 if(MSVC)
 119   # Build the LLVM-C.dll library that exports the C API.
 120
 121   set(LLVM_LINK_COMPONENTS
 122     ${LLVM_DYLIB_COMPONENTS}
 123     )
 124
 125   llvm_map_components_to_libnames(LIB_NAMES ${LLVM_DYLIB_COMPONENTS})
 126   list(REMOVE_DUPLICATES LIB_NAMES)
 127
 128   # The python script needs to know whether symbols are prefixed with underscores or not.
 129   if(LLVM_HOST_TRIPLE STREQUAL "i686-pc-win32")
 130     set(GEN_UNDERSCORE "--underscore")
 131   else()
 132     set(GEN_UNDERSCORE "")
 133   endif()
 134
 135   # Set this name here, not used in multi conf loop,
 136   # but add script will pick the right one.
 137   set(LIBSFILE ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/libllvm-c.args)
 138
 139   # Get the full name to the libs so the python script understands them.
 140   foreach(lib ${LIB_NAMES})
 141     list(APPEND FULL_LIB_NAMES ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/lib/${lib}.lib)
 142   endforeach()
 143
 144   # Need to seperate lib names with newlines.
 145   string(REPLACE ";" "\n" FILE_CONTENT "${FULL_LIB_NAMES}")
 146
 147   if(NOT "${CMAKE_CFG_INTDIR}" STREQUAL ".")
 148     foreach(BUILD_MODE ${CMAKE_CONFIGURATION_TYPES})
 149       # Replace the special string with a per config directory.
 150       string(REPLACE ${CMAKE_CFG_INTDIR} ${BUILD_MODE} PER_CONF_CONTENT "${FILE_CONTENT}")
 151
 152       # Write out the full lib names into file to be read by the python script.
 153       # One libsfile per build, the add_custom_command should expand
 154       # ${CMAKE_CFG_INTDIR} correctly and select the right one.
 155       file(WRITE ${CMAKE_BINARY_DIR}/${BUILD_MODE}/libllvm-c.args "${PER_CONF_CONTENT}")
 156     endforeach()
 157   else()
 158     # Write out the full lib names into file to be read by the python script.
 159     file(WRITE ${LIBSFILE} "${FILE_CONTENT}")
 160   endif()
 161
 162   # Generate the exports file dynamically.
 163   set(GEN_SCRIPT ${CMAKE_CURRENT_SOURCE_DIR}/gen-msvc-exports.py)
 164
 165   set(LLVM_EXPORTED_SYMBOL_FILE ${CMAKE_BINARY_DIR}/${CMAKE_CFG_INTDIR}/libllvm-c.exports)
 166
 167   if(CMAKE_CROSSCOMPILING)
 168     build_native_tool(llvm-nm llvm_nm)
 169     set(llvm_nm_target "${llvm_nm}")
 170   else()
 171     set(llvm_nm $<TARGET_FILE:llvm-nm>)
 172     set(llvm_nm_target llvm-nm)
 173   endif()
 174
 175   add_custom_command(OUTPUT ${LLVM_EXPORTED_SYMBOL_FILE}
 176     COMMAND ${PYTHON_EXECUTABLE} ${GEN_SCRIPT} --libsfile ${LIBSFILE} ${GEN_UNDERSCORE} --nm "${llvm_nm}" -o ${LLVM_EXPORTED_SYMBOL_FILE}
 177     DEPENDS ${LIB_NAMES} ${llvm_nm_target}
 178     COMMENT "Generating export list for LLVM-C"
 179     VERBATIM )
 180
 181   # Finally link the target.
 182   add_llvm_library(LLVM-C SHARED ${SOURCES} DEPENDS intrinsics_gen)
 183
 184 endif()