tools/perf/util/parse-events.l

   1
   2 %option reentrant
   3 %option bison-bridge
   4 %option prefix="parse_events_"
   5 %option stack
   6 %option bison-locations
   7 %option yylineno
   8
   9 %{
  10 #include <errno.h>
  11 #include "../perf.h"
  12 #include "parse-events-bison.h"
  13 #include "parse-events.h"
  14
  15 char *parse_events_get_text(yyscan_t yyscanner);
  16 YYSTYPE *parse_events_get_lval(yyscan_t yyscanner);
  17
  18 static int __value(YYSTYPE *yylval, char *str, int base, int token)
  19 {
  20         u64 num;
  21
  22         errno = 0;
  23         num = strtoull(str, NULL, base);
  24         if (errno)
  25                 return PE_ERROR;
  26
  27         yylval->num = num;
  28         return token;
  29 }
  30
  31 static int value(yyscan_t scanner, int base)
  32 {
  33         YYSTYPE *yylval = parse_events_get_lval(scanner);
  34         char *text = parse_events_get_text(scanner);
  35
  36         return __value(yylval, text, base, PE_VALUE);
  37 }
  38
  39 static int raw(yyscan_t scanner)
  40 {
  41         YYSTYPE *yylval = parse_events_get_lval(scanner);
  42         char *text = parse_events_get_text(scanner);
  43
  44         return __value(yylval, text + 1, 16, PE_RAW);
  45 }
  46
  47 static int str(yyscan_t scanner, int token)
  48 {
  49         YYSTYPE *yylval = parse_events_get_lval(scanner);
  50         char *text = parse_events_get_text(scanner);
  51
  52         yylval->str = strdup(text);
  53         return token;
  54 }
  55
  56 static int drv_str(yyscan_t scanner, int token)
  57 {
  58         YYSTYPE *yylval = parse_events_get_lval(scanner);
  59         char *text = parse_events_get_text(scanner);
  60
  61         /* Strip off the '@' */
  62         yylval->str = strdup(text + 1);
  63         return token;
  64 }
  65
  66 #define REWIND(__alloc)                         \
  67 do {                                                            \
  68         YYSTYPE *__yylval = parse_events_get_lval(yyscanner);   \
  69         char *text = parse_events_get_text(yyscanner);          \
  70                                                                 \
  71         if (__alloc)                                            \
  72                 __yylval->str = strdup(text);                   \
  73                                                                 \
  74         yycolumn -= strlen(text);                               \
  75         yyless(0);                                              \
  76 } while (0)
  77
  78 static int pmu_str_check(yyscan_t scanner)
  79 {
  80         YYSTYPE *yylval = parse_events_get_lval(scanner);
  81         char *text = parse_events_get_text(scanner);
  82
  83         yylval->str = strdup(text);
  84         switch (perf_pmu__parse_check(text)) {
  85                 case PMU_EVENT_SYMBOL_PREFIX:
  86                         return PE_PMU_EVENT_PRE;
  87                 case PMU_EVENT_SYMBOL_SUFFIX:
  88                         return PE_PMU_EVENT_SUF;
  89                 case PMU_EVENT_SYMBOL:
  90                         return PE_KERNEL_PMU_EVENT;
  91                 default:
  92                         return PE_NAME;
  93         }
  94 }
  95
  96 static int sym(yyscan_t scanner, int type, int config)
  97 {
  98         YYSTYPE *yylval = parse_events_get_lval(scanner);
  99
 100         yylval->num = (type << 16) + config;
 101         return type == PERF_TYPE_HARDWARE ? PE_VALUE_SYM_HW : PE_VALUE_SYM_SW;
 102 }
 103
 104 static int term(yyscan_t scanner, int type)
 105 {
 106         YYSTYPE *yylval = parse_events_get_lval(scanner);
 107
 108         yylval->num = type;
 109         return PE_TERM;
 110 }
 111
 112 #define YY_USER_ACTION                                  \
 113 do {                                                    \
 114         yylloc->last_column  = yylloc->first_column;    \
 115         yylloc->first_column = yycolumn;                \
 116         yycolumn += yyleng;                             \
 117 } while (0);
 118
 119 %}
 120
 121 %x mem
 122 %s config
 123 %x event
 124
 125 group           [^,{}/]*[{][^}]*[}][^,{}/]*
 126 event_pmu       [^,{}/]+[/][^/]*[/][^,{}/]*
 127 event           [^,{}/]+
 128 bpf_object      .*\.(o|bpf)
 129 bpf_source      .*\.c
 130
 131 num_dec         [0-9]+
 132 num_hex         0x[a-fA-F0-9]+
 133 num_raw_hex     [a-fA-F0-9]+
 134 name            [a-zA-Z_*?][a-zA-Z0-9_*?.]*
 135 name_minus      [a-zA-Z_*?][a-zA-Z0-9\-_*?.]*
 136 drv_cfg_term    [a-zA-Z0-9_\.]+(=[a-zA-Z0-9_*?\.:]+)?
 137 /* If you add a modifier you need to update check_modifier() */
 138 modifier_event  [ukhpPGHSDI]+
 139 modifier_bp     [rwx]{1,3}
 140
 141 %%
 142
 143 %{
 144         {
 145                 int start_token;
 146
 147                 start_token = parse_events_get_extra(yyscanner);
 148
 149                 if (start_token == PE_START_TERMS)
 150                         BEGIN(config);
 151                 else if (start_token == PE_START_EVENTS)
 152                         BEGIN(event);
 153
 154                 if (start_token) {
 155                         parse_events_set_extra(NULL, yyscanner);
 156                         /*
 157                          * The flex parser does not init locations variable
 158                          * via the scan_string interface, so we need do the
 159                          * init in here.
 160                          */
 161                         yycolumn = 0;
 162                         return start_token;
 163                 }
 164          }
 165 %}
 166
 167 <event>{
 168
 169 {group}         {
 170                         BEGIN(INITIAL);
 171                         REWIND(0);
 172                 }
 173
 174 {event_pmu}     |
 175 {bpf_object}    |
 176 {bpf_source}    |
 177 {event}         {
 178                         BEGIN(INITIAL);
 179                         REWIND(1);
 180                         return PE_EVENT_NAME;
 181                 }
 182
 183 <<EOF>>         {
 184                         BEGIN(INITIAL);
 185                         REWIND(0);
 186                 }
 187
 188 }
 189
 190 <config>{
 191         /*
 192          * Please update parse_events_formats_error_string any time
 193          * new static term is added.
 194          */
 195 config                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG); }
 196 config1                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG1); }
 197 config2                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CONFIG2); }
 198 name                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NAME); }
 199 period                  { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_PERIOD); }
 200 freq                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_SAMPLE_FREQ); }
 201 branch_type             { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_BRANCH_SAMPLE_TYPE); }
 202 time                    { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_TIME); }
 203 call-graph              { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_CALLGRAPH); }
 204 stack-size              { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_STACKSIZE); }
 205 inherit                 { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_INHERIT); }
 206 no-inherit              { return term(yyscanner, PARSE_EVENTS__TERM_TYPE_NOINHERIT); }
 207 ,                       { return ','; }
 208 "/"                     { BEGIN(INITIAL); return '/'; }
 209 {name_minus}            { return str(yyscanner, PE_NAME); }
 210 @{drv_cfg_term}         { return drv_str(yyscanner, PE_DRV_CFG_TERM); }
 211 }
 212
 213 <mem>{
 214 {modifier_bp}           { return str(yyscanner, PE_MODIFIER_BP); }
 215 :                       { return ':'; }
 216 "/"                     { return '/'; }
 217 {num_dec}               { return value(yyscanner, 10); }
 218 {num_hex}               { return value(yyscanner, 16); }
 219         /*
 220          * We need to separate 'mem:' scanner part, in order to get specific
 221          * modifier bits parsed out. Otherwise we would need to handle PE_NAME
 222          * and we'd need to parse it manually. During the escape from <mem>
 223          * state we need to put the escaping char back, so we dont miss it.
 224          */
 225 .                       { unput(*yytext); BEGIN(INITIAL); }
 226         /*
 227          * We destroy the scanner after reaching EOF,
 228          * but anyway just to be sure get back to INIT state.
 229          */
 230 <<EOF>>                 { BEGIN(INITIAL); }
 231 }
 232
 233 cpu-cycles|cycles                               { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CPU_CYCLES); }
 234 stalled-cycles-frontend|idle-cycles-frontend    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_FRONTEND); }
 235 stalled-cycles-backend|idle-cycles-backend      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_STALLED_CYCLES_BACKEND); }
 236 instructions                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_INSTRUCTIONS); }
 237 cache-references                                { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_REFERENCES); }
 238 cache-misses                                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_CACHE_MISSES); }
 239 branch-instructions|branches                    { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_INSTRUCTIONS); }
 240 branch-misses                                   { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BRANCH_MISSES); }
 241 bus-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_BUS_CYCLES); }
 242 ref-cycles                                      { return sym(yyscanner, PERF_TYPE_HARDWARE, PERF_COUNT_HW_REF_CPU_CYCLES); }
 243 cpu-clock                                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_CLOCK); }
 244 task-clock                                      { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_TASK_CLOCK); }
 245 page-faults|faults                              { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS); }
 246 minor-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MIN); }
 247 major-faults                                    { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_PAGE_FAULTS_MAJ); }
 248 context-switches|cs                             { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CONTEXT_SWITCHES); }
 249 cpu-migrations|migrations                       { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_CPU_MIGRATIONS); }
 250 alignment-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_ALIGNMENT_FAULTS); }
 251 emulation-faults                                { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_EMULATION_FAULTS); }
 252 dummy                                           { return sym(yyscanner, PERF_TYPE_SOFTWARE, PERF_COUNT_SW_DUMMY); }
 253
 254         /*
 255          * We have to handle the kernel PMU event cycles-ct/cycles-t/mem-loads/mem-stores separately.
 256          * Because the prefix cycles is mixed up with cpu-cycles.
 257          * loads and stores are mixed up with cache event
 258          */
 259 cycles-ct                                       { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 260 cycles-t                                        { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 261 mem-loads                                       { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 262 mem-stores                                      { return str(yyscanner, PE_KERNEL_PMU_EVENT); }
 263
 264 L1-dcache|l1-d|l1d|L1-data              |
 265 L1-icache|l1-i|l1i|L1-instruction       |
 266 LLC|L2                                  |
 267 dTLB|d-tlb|Data-TLB                     |
 268 iTLB|i-tlb|Instruction-TLB              |
 269 branch|branches|bpu|btb|bpc             |
 270 node                                    { return str(yyscanner, PE_NAME_CACHE_TYPE); }
 271
 272 load|loads|read                         |
 273 store|stores|write                      |
 274 prefetch|prefetches                     |
 275 speculative-read|speculative-load       |
 276 refs|Reference|ops|access               |
 277 misses|miss                             { return str(yyscanner, PE_NAME_CACHE_OP_RESULT); }
 278
 279 mem:                    { BEGIN(mem); return PE_PREFIX_MEM; }
 280 r{num_raw_hex}          { return raw(yyscanner); }
 281 {num_dec}               { return value(yyscanner, 10); }
 282 {num_hex}               { return value(yyscanner, 16); }
 283
 284 {modifier_event}        { return str(yyscanner, PE_MODIFIER_EVENT); }
 285 {bpf_object}            { return str(yyscanner, PE_BPF_OBJECT); }
 286 {bpf_source}            { return str(yyscanner, PE_BPF_SOURCE); }
 287 {name}                  { return pmu_str_check(yyscanner); }
 288 "/"                     { BEGIN(config); return '/'; }
 289 -                       { return '-'; }
 290 ,                       { BEGIN(event); return ','; }
 291 :                       { return ':'; }
 292 "{"                     { BEGIN(event); return '{'; }
 293 "}"                     { return '}'; }
 294 =                       { return '='; }
 295 \n                      { }
 296 .                       { }
 297
 298 %%
 299
 300 int parse_events_wrap(void *scanner __maybe_unused)
 301 {
 302         return 1;
 303 }