translations/translations.pri

   1
   2 LANGUAGES = ja
   3
   4 qtPrepareTool(LRELEASE, lrelease)
   5 qtPrepareTool(LCONVERT, lconvert)
   6 qtPrepareTool(LUPDATE, lupdate)
   7 LUPDATE += -locations relative -no-ui-lines
   8
   9 defineReplace(prependAll) {
  10     for(a,$$1):result += $$2$${a}$$3
  11     return($$result)
  12 }
  13
  14 wd = $$replace(SOURCE_TREE_ROOT, /, $$QMAKE_DIR_SEP)
  15 sources = . qml/fontmanager
  16
  17 TRANSLATIONS = $$prependAll(LANGUAGES, $$PWD/fontmanager_,.ts)
  18
  19 files = $$files($$PWD/*_??.ts) $$PWD/fontmanager_untranslated.ts
  20 for(file, files) {
  21     lang = $$replace(file, .*_([^/]*)\\.ts, \\1)
  22     v = ts-$${lang}.commands
  23     $$v = cd $$wd && $$LUPDATE $$sources -ts $$file
  24     QMAKE_EXTRA_TARGETS += ts-$$lang
  25 }
  26 ts-all.commands = cd $$wd && $$LUPDATE $$sources -ts $$files
  27 QMAKE_EXTRA_TARGETS += ts-all
  28
  29 updateqm.input = TRANSLATIONS
  30 updateqm.output = $${BUILD_TREE_ROOT}/translations/${QMAKE_FILE_BASE}.qm
  31 isEmpty(vcproj):updateqm.variable_out = PRE_TARGETDEPS
  32 updateqm.commands = $$LRELEASE ${QMAKE_FILE_IN} -qm ${QMAKE_FILE_OUT}
  33 updateqm.name = LRELEASE ${QMAKE_FILE_IN}
  34 updateqm.CONFIG += no_link
  35 QMAKE_EXTRA_COMPILERS += updateqm
  36
  37 installPrefix = /opt/fontmanager
  38
  39 qmfiles.files = $$prependAll(LANGUAGES, $$OUT_PWD/translations/fontmanager_,.qm)
  40 qmfiles.path = $${installPrefix}/i18n
  41 qmfiles.CONFIG += no_check_exist
  42 INSTALLS += qmfiles