vm/mterp/armv4/OP_SPUT_WIDE.S

   1 %verify "executed"
   2 %verify "field already resolved"
   3 %verify "field not yet resolved"
   4 %verify "field cannot be resolved"
   5     /*
   6      * 64-bit SPUT handler.
   7      */
   8     /* sput-wide vAA, field@BBBB */
   9     ldr     r2, [rGLUE, #offGlue_methodClassDex]    @ r2<- DvmDex
  10     FETCH(r1, 1)                        @ r1<- field ref BBBB
  11     ldr     r2, [r2, #offDvmDex_pResFields] @ r2<- dvmDex->pResFields
  12     mov     r9, rINST, lsr #8           @ r9<- AA
  13     ldr     r0, [r2, r1, lsl #2]        @ r0<- resolved StaticField ptr
  14     add     r9, rFP, r9, lsl #2         @ r9<- &fp[AA]
  15     cmp     r0, #0                      @ is resolved entry null?
  16     beq     .L${opcode}_resolve         @ yes, do resolve
  17 .L${opcode}_finish: @ field ptr in r0, AA in r9
  18     FETCH_ADVANCE_INST(2)               @ advance rPC, load rINST
  19     ldmia   r9, {r2-r3}                 @ r2/r3<- vAA/vAA+1
  20     GET_INST_OPCODE(ip)                 @ extract opcode from rINST
  21     add     r0, r0, #offStaticField_value
  22     stmia   r0, {r2-r3}                 @ field<- vAA/vAA+1
  23     GOTO_OPCODE(ip)                     @ jump to next instruction
  24 %break
  25
  26     /*
  27      * Continuation if the field has not yet been resolved.
  28      *  r1: BBBB field ref
  29      *  r9: &fp[AA]
  30      */
  31 .L${opcode}_resolve:
  32     ldr     r2, [rGLUE, #offGlue_method]    @ r2<- current method
  33     EXPORT_PC()                         @ resolve() could throw, so export now
  34     ldr     r0, [r2, #offMethod_clazz]  @ r0<- method->clazz
  35     bl      dvmResolveStaticField       @ r0<- resolved StaticField ptr
  36     cmp     r0, #0                      @ success?
  37     bne     .L${opcode}_finish          @ yes, finish
  38     b       common_exceptionThrown      @ no, handle exception
  39