z_build.bat

   1 @echo off
   2 REM ///////////////////////////////////////////////////////////////////////////
   3 REM // Set Paths
   4 REM ///////////////////////////////////////////////////////////////////////////
   5 set "MSVC_PATH=C:\Program Files\Microsoft Visual Studio 10.0\VC"
   6 set "NSIS_PATH=C:\Program Files\NSIS\Unicode"
   7 set "QTVC_PATH=C:\Qt\4.8.4"
   8 set "UPX3_PATH=C:\Program Files\UPX"
   9
  10 REM ###############################################
  11 REM # DO NOT MODIFY ANY LINES BELOW THIS LINE !!! #
  12 REM ###############################################
  13
  14
  15 REM ///////////////////////////////////////////////////////////////////////////
  16 REM // Setup environment
  17 REM ///////////////////////////////////////////////////////////////////////////
  18 if exist "%QTVC_PATH%\bin\qtvars.bat" ( call "%QTVC_PATH%\bin\qtvars.bat" )
  19 if exist "%QTVC_PATH%\bin\qtenv2.bat" ( call "%QTVC_PATH%\bin\qtenv2.bat" )
  20 call "%MSVC_PATH%\vcvarsall.bat" x86
  21
  22 REM ///////////////////////////////////////////////////////////////////////////
  23 REM // Check environment
  24 REM ///////////////////////////////////////////////////////////////////////////
  25 if "%VCINSTALLDIR%"=="" (
  26         echo %%VCINSTALLDIR%% not specified. Please check your MSVC_PATH var!
  27         goto BuildError
  28 )
  29 if "%QTDIR%"=="" (
  30         echo %%QTDIR%% not specified. Please check your MSVC_PATH var!
  31         goto BuildError
  32 )
  33 if not exist "%VCINSTALLDIR%\bin\cl.exe" (
  34         echo C++ compiler not found. Please check your MSVC_PATH var!
  35         goto BuildError
  36 )
  37 if not exist "%QTDIR%\bin\moc.exe" (
  38         echo Qt meta compiler not found. Please check your QTVC_PATH var!
  39         goto BuildError
  40 )
  41
  42 REM ///////////////////////////////////////////////////////////////////////////
  43 REM // Get current date and time (in ISO format)
  44 REM ///////////////////////////////////////////////////////////////////////////
  45 set "ISO_DATE="
  46 set "ISO_TIME="
  47 if not exist "%~dp0\etc\date.exe" BuildError
  48 for /F "tokens=1,2 delims=:" %%a in ('"%~dp0\etc\date.exe" +ISODATE:%%Y-%%m-%%d') do (
  49         if "%%a"=="ISODATE" set "ISO_DATE=%%b"
  50 )
  51 for /F "tokens=1,2,3,4 delims=:" %%a in ('"%~dp0\etc\date.exe" +ISOTIME:%%T') do (
  52         if "%%a"=="ISOTIME" set "ISO_TIME=%%b:%%c:%%d"
  53 )
  54 if "%ISO_DATE%"=="" goto BuildError
  55 if "%ISO_TIME%"=="" goto BuildError
  56
  57 REM ///////////////////////////////////////////////////////////////////////////
  58 REM // Build the binaries
  59 REM ///////////////////////////////////////////////////////////////////////////
  60 echo ---------------------------------------------------------------------
  61 echo BEGIN BUILD
  62 echo ---------------------------------------------------------------------
  63 MSBuild.exe /property:Configuration=release /target:clean   "%~dp0\x264_launcher_MSVC2010.sln"
  64 if not "%ERRORLEVEL%"=="0" goto BuildError
  65 MSBuild.exe /property:Configuration=release /target:rebuild "%~dp0\x264_launcher_MSVC2010.sln"
  66 if not "%ERRORLEVEL%"=="0" goto BuildError
  67
  68 REM ///////////////////////////////////////////////////////////////////////////
  69 REM // Detect build number
  70 REM ///////////////////////////////////////////////////////////////////////////
  71 set "BUILD_NO="
  72 for /F "tokens=2,*" %%s in (%~dp0\src\version.h) do (
  73         if "%%s"=="VER_X264_BUILD" set "BUILD_NO=%%~t"
  74 )
  75 if "%BUILD_NO%"=="" goto BuildError
  76
  77 REM ///////////////////////////////////////////////////////////////////////////
  78 REM // Copy base files
  79 REM ///////////////////////////////////////////////////////////////////////////
  80 echo ---------------------------------------------------------------------
  81 echo BEGIN PACKAGING
  82 echo ---------------------------------------------------------------------
  83 set "PACK_PATH=%TMP%\~%RANDOM%%RANDOM%.tmp"
  84 mkdir "%PACK_PATH%"
  85 mkdir "%PACK_PATH%\imageformats"
  86 mkdir "%PACK_PATH%\toolset"
  87 copy "%~dp0\bin\Release\*.exe" "%PACK_PATH%"
  88 copy "%~dp0\bin\Release\toolset\*.exe" "%PACK_PATH%\toolset"
  89 copy "%~dp0\*.txt" "%PACK_PATH%"
  90
  91 REM ///////////////////////////////////////////////////////////////////////////
  92 REM // Copy dependencies
  93 REM ///////////////////////////////////////////////////////////////////////////
  94 for %%i in (100, 110) do (
  95         if exist "%MSVC_PATH%\redist\x86\Microsoft.VC%%i.CRT\*.dll" (
  96                 copy "%MSVC_PATH%\redist\x86\Microsoft.VC%%i.CRT\msvc?%%i.dll" "%PACK_PATH%"
  97         )
  98 )
  99 copy "%QTVC_PATH%\bin\QtCore4.dll" "%PACK_PATH%"
 100 copy "%QTVC_PATH%\bin\QtGui4.dll" "%PACK_PATH%"
 101 copy "%QTVC_PATH%\bin\QtSvg4.dll" "%PACK_PATH%"
 102 copy "%QTVC_PATH%\bin\QtXml4.dll" "%PACK_PATH%"
 103 copy "%QTVC_PATH%\bin\QtXml4.dll" "%PACK_PATH%"
 104 copy "%QTVC_PATH%\plugins\imageformats\*.dll" "%PACK_PATH%\imageformats"
 105 del "%PACK_PATH%\imageformats\*d4.dll"
 106
 107 REM ///////////////////////////////////////////////////////////////////////////
 108 REM // Compress
 109 REM ///////////////////////////////////////////////////////////////////////////
 110 "%UPX3_PATH%\upx.exe" --brute "%PACK_PATH%\*.exe"
 111 "%UPX3_PATH%\upx.exe" --best  "%PACK_PATH%\*.dll"
 112
 113 REM ///////////////////////////////////////////////////////////////////////////
 114 REM // Attributes
 115 REM ///////////////////////////////////////////////////////////////////////////
 116 attrib +R "%PACK_PATH%\*.exe"
 117 attrib +R "%PACK_PATH%\*.dll"
 118 attrib +R "%PACK_PATH%\*.txt"
 119
 120 REM ///////////////////////////////////////////////////////////////////////////
 121 REM // Setup install parameters
 122 REM ///////////////////////////////////////////////////////////////////////////
 123 set "NSI_FILE=%TMP%\~%RANDOM%%RANDOM%.nsi"
 124 set "OUT_NAME=x264_x64.%ISO_DATE%"
 125 set "OUT_PATH=%~dp0\bin"
 126 set "OUT_FULL=%OUT_PATH%\%OUT_NAME%.exe"
 127 :GenerateOutfileName
 128 if exist "%OUT_FULL%" (
 129         set "OUT_NAME=%OUT_NAME%.new"
 130         set "OUT_FULL=%OUT_PATH%\%OUT_NAME%.exe"
 131         goto GenerateOutfileName
 132 )
 133
 134 REM ///////////////////////////////////////////////////////////////////////////
 135 REM // Generate install script
 136 REM ///////////////////////////////////////////////////////////////////////////
 137 echo #Generated File - Do NOT modify! > "%NSI_FILE%"
 138 echo !define ZIP2EXE_NAME `Simple x264 Launcher (%ISO_DATE%)` >> "%NSI_FILE%"
 139 echo !define ZIP2EXE_OUTFILE `%OUT_FULL%` >> "%NSI_FILE%"
 140 echo !define ZIP2EXE_COMPRESSOR_LZMA >> "%NSI_FILE%"
 141 echo !define ZIP2EXE_COMPRESSOR_SOLID  >> "%NSI_FILE%"
 142 echo !define ZIP2EXE_INSTALLDIR `$PROGRAMFILES\MuldeR\Simple x264 Launcher v2` >> "%NSI_FILE%"
 143 echo !define ZIP2EXE_REGPATH `SOFTWARE\Microsoft\Windows\CurrentVersion\Uninstall\{986E454F-DACA-4326-A9C7-3E46C0BFFDCE}` >> "%NSI_FILE%"
 144 echo !define MUI_INSTFILESPAGE_COLORS "C5DEFB 000000" >> "%NSI_FILE%"
 145 echo RequestExecutionLevel Admin >> "%NSI_FILE%"
 146 echo ShowInstDetails show >> "%NSI_FILE%"
 147 echo BrandingText `Created: %ISO_DATE%, %ISO_TIME% [Build #%BUILD_NO%]` >> "%NSI_FILE%"
 148 echo InstallDirRegKey HKLM `${ZIP2EXE_REGPATH}` InstallLocation >> "%NSI_FILE%"
 149 echo !include `${NSISDIR}\Contrib\zip2exe\Base.nsh` >> "%NSI_FILE%"
 150 echo SetCompressorDictSize 96 >> "%NSI_FILE%"
 151 echo !include `${NSISDIR}\Contrib\zip2exe\Modern.nsh` >> "%NSI_FILE%"
 152 echo !include `%~dp0\etc\check_os.nsh` >> "%NSI_FILE%"
 153 echo !include `%~dp0\etc\finalization.nsh` >> "%NSI_FILE%"
 154 echo !include `%~dp0\etc\version.nsh` >> "%NSI_FILE%"
 155 echo !insertmacro X264_VERSIONINFO `%ISO_DATE%` `%ISO_TIME%` `%BUILD_NO%` >> "%NSI_FILE%"
 156 echo !insertmacro SECTION_BEGIN >> "%NSI_FILE%"
 157 echo Delete `$INSTDIR\*.exe` >> "%NSI_FILE%"
 158 echo Delete `$INSTDIR\*.dll` >> "%NSI_FILE%"
 159 echo Delete `$INSTDIR\toolset\*.exe` >> "%NSI_FILE%"
 160 echo File /a /r `%PACK_PATH%\*.exe` >> "%NSI_FILE%"
 161 echo File /a /r `%PACK_PATH%\*.dll` >> "%NSI_FILE%"
 162 echo File /a /r `%PACK_PATH%\*.txt` >> "%NSI_FILE%"
 163 echo WriteRegStr HKLM `${ZIP2EXE_REGPATH}` InstallLocation `$INSTDIR` >> "%NSI_FILE%"
 164 echo !include `%~dp0\etc\shortcut.nsh` >> "%NSI_FILE%"
 165 echo !insertmacro SECTION_END >> "%NSI_FILE%"
 166
 167 REM ///////////////////////////////////////////////////////////////////////////
 168 REM // Build the installer
 169 REM ///////////////////////////////////////////////////////////////////////////
 170 "%NSIS_PATH%\makensis.exe" "%NSI_FILE%"
 171 if not "%ERRORLEVEL%"=="0" goto BuildError
 172 attrib +R "%OUT_FULL%"
 173 del "%NSI_FILE%"
 174 rmdir /Q /S "%PACK_PATH%"
 175
 176 REM ///////////////////////////////////////////////////////////////////////////
 177 REM // COMPLETE
 178 REM ///////////////////////////////////////////////////////////////////////////
 179 echo.
 180 echo Build completed.
 181 echo.
 182 pause
 183 goto:eof
 184
 185 REM ///////////////////////////////////////////////////////////////////////////
 186 REM // FAILED
 187 REM ///////////////////////////////////////////////////////////////////////////
 188 :BuildError
 189 echo.
 190 echo Build has failed !!!
 191 echo.
 192 pause