This notebook is about using the "zipper" with joy datastructures. See the Zipper wikipedia entry or the original paper: "FUNCTIONAL PEARL The Zipper" by GĂ©rard Huet
Given a datastructure on the stack we can navigate through it, modify it, and rebuild it using the "zipper" technique.
from notebook_preamble import J, V, define
J('[1 [2 [3 4 25 6] 7] 8]')
Zippers work by keeping track of the current item, the already-seen items, and the yet-to-be seen items as you traverse a datastructure (the datastructure used to keep track of these items is the zipper.)
In Joy we can do this with the following words:
z-down == [] swap uncons swap
z-up == swons swap shunt
z-right == [swons] cons dip uncons swap
z-left == swons [uncons swap] dip swap
Let's use them to change 25 into 625. The first time a word is used I show the trace so you can see how it works. If we were going to use these a lot it would make sense to write Python versions for efficiency, but see below.
define('z-down == [] swap uncons swap')
define('z-up == swons swap shunt')
define('z-right == [swons] cons dip uncons swap')
define('z-left == swons [uncons swap] dip swap')
V('[1 [2 [3 4 25 6] 7] 8] z-down')
V('[] [[2 [3 4 25 6] 7] 8] 1 z-right')
J('[1] [8] [2 [3 4 25 6] 7] z-down')
J('[1] [8] [] [[3 4 25 6] 7] 2 z-right')
J('[1] [8] [2] [7] [3 4 25 6] z-down')
J('[1] [8] [2] [7] [] [4 25 6] 3 z-right')
J('[1] [8] [2] [7] [3] [25 6] 4 z-right')
J('[1] [8] [2] [7] [4 3] [6] 25 sqr')
V('[1] [8] [2] [7] [4 3] [6] 625 z-up')
J('[1] [8] [2] [7] [3 4 625 6] z-up')
J('[1] [8] [2 [3 4 625 6] 7] z-up')
dip
and infra
¶In Joy we have the dip
and infra
combinators which can "target" or "address" any particular item in a Joy tree structure.
V('[1 [2 [3 4 25 6] 7] 8] [[[[[[sqr] dipd] infra] dip] infra] dip] infra')
If you read the trace carefully you'll see that about half of it is the dip
and infra
combinators de-quoting programs and "digging" into the subject datastructure. Instead of maintaining temporary results on the stack they are pushed into the pending expression (continuation). When sqr
has run the rest of the pending expression rebuilds the datastructure.
Z
¶Imagine a function Z
that accepts a sequence of dip
and infra
combinators, a quoted program [Q]
, and a datastructure to work on. It would effectively execute the quoted program as if it had been embedded in a nested series of quoted programs, e.g.:
[...] [Q] [dip dip infra dip infra dip infra] Z
-------------------------------------------------------------
[...] [[[[[[[Q] dip] dip] infra] dip] infra] dip] infra
The Z
function isn't hard to make.
define('Z == [[] cons cons] step i')
Here it is in action in a simplified scenario.
V('1 [2 3 4] Z')
And here it is doing the main thing.
J('[1 [2 [3 4 25 6] 7] 8] [sqr] [dip dip infra dip infra dip infra] Z')
Because we are only using two combinators we could replace the list with a string made from only two characters.
[...] [Q] 'ddididi' Zstr
-------------------------------------------------------------
[...] [[[[[[[Q] dip] dip] infra] dip] infra] dip] infra
The string can be considered a name or address for an item in the subject datastructure.
It's easy to read off (in reverse) the right sequence of "d" and "i" from the subject datastructure:
[ n [ n [ n n x ...
i d i d i d d Bingo!