/****************************************************************************
**
** Copyright (C) 2011 Takumi Asaki
** All rights reserved.
** Contact: Takumi Asaki (takumi.asaki@gmail.com)
**
** This file is part of the fontmanager application.
**
** You may use this file under the terms of the BSD license as follows:
**
** "Redistribution and use in source and binary forms, with or without
** modification, are permitted provided that the following conditions are
** met:
**   * Redistributions of source code must retain the above copyright
**     notice, this list of conditions and the following disclaimer.
**   * Redistributions in binary form must reproduce the above copyright
**     notice, this list of conditions and the following disclaimer in
**     the documentation and/or other materials provided with the
**     distribution.
**   * Neither the name of Nokia Corporation and its Subsidiary(-ies) nor
**     the names of its contributors may be used to endorse or promote
**     products derived from this software without specific prior written
**     permission.
**
** THIS SOFTWARE IS PROVIDED BY THE COPYRIGHT HOLDERS AND CONTRIBUTORS
** "AS IS" AND ANY EXPRESS OR IMPLIED WARRANTIES, INCLUDING, BUT NOT
** LIMITED TO, THE IMPLIED WARRANTIES OF MERCHANTABILITY AND FITNESS FOR
** A PARTICULAR PURPOSE ARE DISCLAIMED. IN NO EVENT SHALL THE COPYRIGHT
** OWNER OR CONTRIBUTORS BE LIABLE FOR ANY DIRECT, INDIRECT, INCIDENTAL,
** SPECIAL, EXEMPLARY, OR CONSEQUENTIAL DAMAGES (INCLUDING, BUT NOT
** LIMITED TO, PROCUREMENT OF SUBSTITUTE GOODS OR SERVICES; LOSS OF USE,
** DATA, OR PROFITS; OR BUSINESS INTERRUPTION) HOWEVER CAUSED AND ON ANY
** THEORY OF LIABILITY, WHETHER IN CONTRACT, STRICT LIABILITY, OR TORT
** (INCLUDING NEGLIGENCE OR OTHERWISE) ARISING IN ANY WAY OUT OF THE USE
** OF THIS SOFTWARE, EVEN IF ADVISED OF THE POSSIBILITY OF SUCH DAMAGE."
**
****************************************************************************/

import QtQuick 1.1
import com.nokia.meego 1.0
import com.nokia.extras 1.1
import 'UIConstants.js' as UI

Page {
    tools: mainTools

    Label {
        id: pageHeader
        anchors.top: parent.top
        anchors.horizontalCenter: parent.horizontalCenter
        anchors.margins: UI.DEFAULT_MARGIN

        horizontalAlignment: Text.AlignHCenter
        font.pixelSize: UI.FONT_LARGE
        font.bold: true
        text: qsTr("Installed Fonts")
    }

    Connections {
        target: controller
        onClearInstalledFontList: {
            installedFontList.clear()
        }
        onAppendInstalledFont: {
            installedFontList.append({ "title": family, "subtitle": fullname })
        }
    }

    ListModel {
        id: installedFontList
    }

    ListView {
        id: listView
        anchors.top: pageHeader.bottom
        anchors.bottom: parent.bottom
        anchors.left: parent.left
        anchors.right: parent.right
        anchors.margins: UI.DEFAULT_MARGIN
        clip: true

        model: installedFontList

        delegate: ListDelegate {
            onClicked: {
                if (mainMenu.status != DialogStatus.Closed)
                    mainMenu.close()
                pageStack.push(installedFontInfoPage, { "fontInfo": controller.fontInfo(title) } );
            }
        }

    }

    Text {
        id: warningText
        anchors.centerIn: parent
        text: qsTr("No Fonts Found!")
        font.pixelSize: UI.FONT_XLARGE
        font.bold: true
        color: "gray"
        visible: listView.count == 0
    }

    Component {
        id: installedFontInfoPage
        InstalledFontInfoPage { }
    }

    Component {
        id: fontsConfViewPageComponent
        FontsConfViewPage { }
    }

    ToolBarLayout {
        id: mainTools
        visible: true
        ToolIcon {
            platformIconId: "toolbar-add"
            onClicked: {
                if (mainMenu.status != DialogStatus.Closed)
                    mainMenu.close()
                pageStack.push(fontSelectPage)
            }
        }
        ToolIcon {
            platformIconId: "toolbar-view-menu"
            anchors.right: (parent === undefined) ? undefined : parent.right
            onClicked: (mainMenu.status == DialogStatus.Closed) ? mainMenu.open() : mainMenu.close()
        }
    }

    Menu {
        id: mainMenu
        visualParent: pageStack
        MenuLayout {
            MenuItem {
                text: qsTr("View current fonts config");
                enabled: controller.localFontsConfExists
                onClicked: {
                    mainMenu.close()
                    pageStack.push(fontsConfViewPageComponent, { "text": controller.localFontsConf } )
                }
            }
            MenuItem {
                text: qsTr("Remove uninstalled fonts from config");
                enabled: controller.configHasUninstalledFonts
                onClicked: {
                    mainMenu.close()
                    controller.removeUninstalledFontsFromConfig()
                    controller.saveFontsConf()
                }
            }
        }
    }

}