• アプリケーション開発用のプログラミング言語です。 → 用例
• ドメイン特化ライブラリ、フレームワークおよびツールの作成に使用できる汎用言語です。 → 方法
• ビジュアルプログラミング言語である Programming Without Coding Technology (PWCT) ソフトウェアの次世代版を作成するために設計された実用言語です。 → PWCT の公式サイト
• 小規模で高速な言語であり C/C++ プロジェクトへ組み込めます。 → 方法
• 文教用途およびコンパイラ・仮想計算機の概念における入門に使用できる単純明快な言語です。 → 方法
• 生産性と拡張性に優れた高品質な解決方法の開発。

Ring は非常に簡明な言語であり、非常にシンプルなシンタックスから構成されています。ボイラープレートコードを使用しないプログラムの記述がプログラマに奨励されています。 'See' 命令はメッセージを標準出力へ表示します。 → 理由

see "Hello, World!" 
			

Main 関数はオプション扱いであり、ステートメントの後に実行されるため、ローカルスコープで有用です。 → 理由

func main
	see "Hello, World!" 
			

動的型付け、およびレキシカルスコープを使用しています。変数名の先頭に $ は不要です！ → 理由
文字列の連結で ‘+’ 演算子を使用できます。 弱い型付け言語であり、文字列はコンテキストに基づいて数値と文字列の間で自動的に変換されます。 → 理由

nCount = 10	# グローバル変数
func main
	nID = 1	# ローカル変数
	see "Count = " + nCount + nl + " ID = " + nID
			

Ring は大小英数文字を区別しません。 → 理由

see "Enter your name ? " 
give name
see "Hello " + Name	# Name は name と同じです。 
			

リストのインデックス (添字番号) は 1 から開始します (Ring 1.11 以降は ZeroLib を使用することで 0 から始めることもできます)。 → 理由

aList = ["one","two","three"]
see aList[1]	# one を表示
			

定義前に関数を呼び出すには

one() 
two() 
three()
func one 
	see "One" + nl
func two 
	see "two" + nl
func three 
	see "three" + nl
			

代入演算子は深いコピーを使用します (この操作は参照ではありません)。 → 理由

aList = ["one","two","three"]
aList2 = aList
aList[1] = 1
see alist[1]	# 1 を表示
see aList2[1]	# one を表示
			

数値と文字列は値渡しですが、リストとオブジェクトは参照渡しです。
For in ループ でリストの項目 (アイテム、要素とも呼ばれています) を更新できます。

func main
	aList = [1,2,3]
	update(aList)
	see aList	# one two three を表示

func update aList
	for x in aList
		switch x
		on 1 x = "one"
		on 2 x = "two"
		on 3 x = "three"
		off
	next
			

定義するときにリストを使用するには

aList = [ [1,2,3,4,5] , aList[1] , aList[1] ]
see aList       # 1 2 3 4 5 1 2 3 4 5 1 2 3 4 5 を表示
			

一階層以上のループから脱出 → 理由

for x = 1 to 10
        for y = 1 to 10
                see "x=" + x + " y=" + y + nl
                if x = 3 and y = 5
                        exit 2     # 二階層のループから脱出
                ok
        next
next
			

Ring ではプログラムの組織化を奨励しています。まずは関数、次にクラス、 そして関数とヘンテコなモノと組み合わせるプログラミング言語を使用していた悪夢の日々を忘却の彼方へ追いやります！

ソースファイルの構造は:

• ファイルの読み込み
• ステートメントとグローバル変数
• 関数
• パッケージおよびクラス

これにより構成要素で end キーワードを記述しなくてもパッケージ、 クラスと関数の使用が可能になります。

一行コメントまたは複数行コメントを使用できます。
一行コメントは # または // で始まります。
複数行コメントは /* ～ */ の間に記述します。

/* 
	プログラム名	: Ring を使用したはじめてのプログラム
	日付		: 2017
*/

see "What is your name? " 	# 画面上にメッセージを表示します。
give cName 			# ユーザからの入力を取得
see "Hello " + cName		# hello を表示！

// See "Bye!"
			

ステートメントの後に ; を記述したり ENTER や TAB を押して 行の区別 する必要はありません。 つまり、このようなコードを書くことができます。

see "The First Message"	see " Another message in the same line! " + nl
see "Enter your name?" give Name see "Hello " + Name
			

このコードは三種類の属性 X, Y および Z を有する Point クラスを作成します。 パッケージ・クラス・関数の定義を終了するために end キーワードは使用していません。 また、クラスの名前の直下に属性の名前を書くことができます。

class Point X Y Z
			

定義前にクラスと関数を使用できます。 この用例では、オブジェクトの新規作成と属性の設定、および値を表示します。

o1 = new point	o1.x=10    o1.y=20   o1.z=30	see O1	class Point X Y Z
			

ドット演算子 ‘.’ でオブジェクトの属性とメソッドへアクセスするのではなく、 括弧 { } でオブジェクトへアクセスできます。その後にオブジェクトの属性とメソッドを使用できます。

 
o1 = new point { x=10 y=20 z=30 } see O1  class Point X Y Z
			 

メソッドの呼出し後に { } を使用してオブジェクトへアクセスします。

 
oPerson = new Person
{
	Name = "Somebody"
	Address = "Somewhere"
	Phone = "0000000"
	Print()			# ここでは Print() メソッドを呼び出します。
}
class Person Name Address Phone
	func Print
		see "Name :" + name + nl +
		    "Address :" + Address + nl +
		    "Phone : " + phone + nl

{ } を使用してオブジェクトへアクセスしてから任意のオブジェクトの名前を記述するとき、 自動的に呼び出される全ての setter/getter メソッドに対してクラスを検査します。

new Number {
		see one		# GetOne() の実行
		see two		# GetTwo() の実行
		see three	# GetThree() の実行
}
class Number one two three
	func GetOne
		see "Number : One" + nl
		return 1
	func GetTwo
		see "Number : Two" + nl
		return 2
	func GetThree
		see "Number : Three" + nl
		return 3	

{ } を使用してオブジェクトへアクセス後にクラスに BraceEnd() と呼ばれるメソッドがある場合は BraceEnd() メソッドを実行します！ → 理由

TimeForFun = new journey
# あっと驚く！
TimeForFun {
	Hello it is me		# なんと美しいプログラミングの世界でしょう！
}
# クラス本体
class journey
	hello=0 it=0 is=0 me=0
	func GetHello
		See "Hello" + nl
	func braceEnd
		See "Goodbye!" + nl	

Eval() 関数は文字列に記述されたコードを実行します。

cCode = "See 'Code that will be executed later!' "
Eval(cCode)	# コードを実行してメッセージを表示します。

リストの作成後にリストから実行用のコードを生成できます。

aWords = ["hello","it","is","me"]
for word in aWords cCode=word+"=0" eval(cCode) next

Read(cFileName) 関数はテキストファイルを読み取ります。 また Write(cFileName,cString) 関数はファイルへ書き込みます。

see "Enter File Name:" give cFileName see read(cFileName) # ファイルの内容を表示

この用例は二つの命令を定義するクラスの作成方法です。
最初の命令は : I want window
次の命令は : Window title = <式>
‘the’ などのキーワードは無視されます。

new App
{
        I want window
        The window title = "hello world"
}

class App

	# I want window 命令の属性
			i want window
			nIwantwindow = 0
	# Window title 命令の属性
	# ここでは window 属性を再定義しません。
			title
			nWindowTitle = 0
	# 値を与えると、キーワードは無視されます。
			the=0

        func geti
                if nIwantwindow = 0
                        nIwantwindow++
                ok

        func getwant
                if nIwantwindow = 1
                        nIwantwindow++
                ok

        func getwindow
                if nIwantwindow = 2
                        nIwantwindow= 0
                        see "Instruction : I want window" + nl
                ok
                if nWindowTitle = 0
                        nWindowTitle++
                ok

        func settitle cValue
                if nWindowTitle = 1
                        nWindowTitle=0
                        see "Instruction : Window Title = " + cValue + nl
                ok

        

前述の用例を完了するには read() を使用してファイルの内容を取得します。

        I want window
        The window title = "hello world"

そして eval() を使用してファイルの内容を実行します！
また、 GUI ライブラリでウィンドウを作成するために GetWindow() と SetTitle() メソッドを更新します。

自然言語 (Natural) ステートメントを使用したコードの実行、 および入れ子構造を使用したコードの実行方法について既に学んでいます。

この用例は Web ライブラリからのものであり Bootstrap ライブラリで HTML ドキュメントを生成します。 この用例では HTML コードを直接記述せずに類似言語を作成しています (ただの用例です)。 その後、宣言型言語を使用するために入れ子構造を使用して、 HTML ドキュメントを生成しています。
この用例での考え方として GetDiv() および GetH1() メソッドは { } を使用してアクセスできるオブジェクトを返します。 各オブジェクトへのアクセス後に BraceEnd() メソッドが実行されると生成された HTML を BraceEnd() の出力表示がルートに到達するまで親オブジェクトへ送信します。

load "weblib.ring"
import System.Web

func Main

  BootStrapWebPage()
  {
        div
        {
          classname = :container
          div
          {
                classname = :jumbotron
                H1 {   text("Bootstrap Page")   }
          }
          div
          {
                classname = :row
                for x = 1 to 3
                  div
                  {
                        classname = "col-sm-4"
                        H3 { html("Welcome to the Ring programming language") }
                        P  { html("Using a scripting language is very fun!") }
                  }
                next
          }
        }
  }

宣言型インタフェースを強化するクラスはこのようなものなります。

	class Link from ObjsBase
		title  link
		func braceend			
			cOutput = nl+GetTabs() + "<a href='" + 
				  Link + "'> "+ Title + " </a> " + nl			

	class Div from ObjsBase 
		func braceend
			cOutput += nl+'<div'
			addattributes()
			AddStyle()
			getobjsdata()
			cOutput += nl+"</div>" + nl
			cOutput = TabMLString(cOutput)
	 

ソースコードの記述に関して様々な記法があります！

また、言語のキーワードと演算子を変更することで、お好みの記法を作成できます！

Ring は透過型実装です。コンパイラの処理段階および仮想計算機による実行中の処理内容を把握できます。
例えば : ring helloworld.ring -tokens -rules -ic

see "Hello, World!" 
			

実行結果

==================================================================
Tokens - Generated by the Scanner
==================================================================

   Keyword : SEE
   Literal : Hello, World!
   EndLine

==================================================================

==================================================================
Grammar Rules Used by The Parser
==================================================================

Rule : Program --> {Statement}

Line 1
Rule : Factor --> Literal
Rule : Range --> Factor
Rule : Term --> Range
Rule : Arithmetic --> Term
Rule : BitShift --> Arithmetic
Rule : BitAnd --> BitShift
Rule : BitOrXOR -->  BitAnd
Rule : Compare --> BitOrXOR
Rule : EqualOrNot --> Compare
Rule : LogicNot -> EqualOrNot
Rule : Expr --> LogicNot
Rule : Statement  --> 'See' Expr

==================================================================



==================================================================
Byte Code - Before Execution by the VM
==================================================================

     PC      OPCode        Data

      1     FuncExE
      2       PushC   Hello, World!
      3       Print
      4  ReturnNull

==================================================================

Hello, World!
			

プログラミング言語 Ring はビジュアルプログラミングツール PWCT (外部サイト) で設計されています。 Ring 言語のビジュアルソースは “visualsrc” フォルダの *.ssf ファイルにあります。 生成された C 言語ソースコードは src フォルダおよび include フォルダにあります。 GitHub (外部サイト) から fork する。



このスクリーンショットは ring_vm.ssf (ring_vm.c と ring_vm.h を生成) および ring_list.ssf (ring_list.c と ring_list.h を生成) ファイルからの引用です 。