configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [1])
  30 m4_define([va_api_minor_version], [4])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 # Wayland minimum version number
  81 # 1.11.0 for wl_proxy_create_wrapper
  82 m4_define([wayland_api_version], [1.11.0])
  83
  84 AC_PREREQ(2.57)
  85 AC_INIT([libva],
  86         [libva_version],
  87         [https://github.com/intel/libva/issues/new],
  88         [libva],
  89         [https://github.com/intel/libva])
  90
  91 AC_CONFIG_SRCDIR([Makefile.am])
  92 AC_CONFIG_MACRO_DIR([m4])
  93 AM_INIT_AUTOMAKE([dist-bzip2 -Wno-portability])
  94
  95 AC_CONFIG_HEADERS([config.h])
  96 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  97
  98 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  99 AC_SUBST(TODAY)
 100
 101 VA_API_MAJOR_VERSION=va_api_major_version
 102 VA_API_MINOR_VERSION=va_api_minor_version
 103 VA_API_MICRO_VERSION=va_api_micro_version
 104 VA_API_VERSION=va_api_version
 105 AC_SUBST(VA_API_MAJOR_VERSION)
 106 AC_SUBST(VA_API_MINOR_VERSION)
 107 AC_SUBST(VA_API_MICRO_VERSION)
 108 AC_SUBST(VA_API_VERSION)
 109
 110 LIBVA_MAJOR_VERSION=libva_major_version
 111 LIBVA_MINOR_VERSION=libva_minor_version
 112 LIBVA_MICRO_VERSION=libva_micro_version
 113 LIBVA_VERSION=libva_version
 114 AC_SUBST(LIBVA_MAJOR_VERSION)
 115 AC_SUBST(LIBVA_MINOR_VERSION)
 116 AC_SUBST(LIBVA_MICRO_VERSION)
 117 AC_SUBST(LIBVA_VERSION)
 118
 119 LIBVA_LT_CURRENT=libva_lt_current
 120 LIBVA_LT_REV=libva_lt_revision
 121 LIBVA_LT_AGE=libva_lt_age
 122 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 123 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 124 AC_SUBST(LIBVA_LT_VERSION)
 125 AC_SUBST(LIBVA_LT_LDFLAGS)
 126
 127 AC_ARG_ENABLE(docs,
 128     [AC_HELP_STRING([--enable-docs],
 129                     [build Doxygen documentation @<:@default=no@:>@])],
 130     [], [enable_docs="no"])
 131
 132 AC_ARG_ENABLE(drm,
 133     [AC_HELP_STRING([--enable-drm],
 134                     [build with VA/DRM API support @<:@default=yes@:>@])],
 135     [], [enable_drm="yes"])
 136
 137 AC_ARG_ENABLE(x11,
 138     [AC_HELP_STRING([--enable-x11],
 139                     [build with VA/X11 API support @<:@default=auto@:>@])],
 140     [], [enable_x11="auto"])
 141
 142 AC_ARG_ENABLE(glx,
 143     [AC_HELP_STRING([--enable-glx],
 144                     [build with VA/GLX API support @<:@default=auto@:>@])],
 145     [], [enable_glx="auto"])
 146
 147 AC_ARG_ENABLE([wayland],
 148     [AC_HELP_STRING([--enable-wayland],
 149                     [build with VA/Wayland API support @<:@default=auto@:>@])],
 150     [], [enable_wayland="auto"])
 151
 152 AC_ARG_ENABLE([va-messaging],
 153     [AC_HELP_STRING([--enable-va-messaging],
 154                     [build with va info and error messaging @<:@default=yes@:>@])],
 155     [], [enable_va_messaging="yes"])
 156
 157 AC_ARG_WITH(drivers-path,
 158     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 159                     [drivers path])],
 160     [], [with_drivers_path="$libdir/dri"])
 161
 162 LIBVA_DRIVERS_PATH="$with_drivers_path"
 163 AC_SUBST(LIBVA_DRIVERS_PATH)
 164
 165 AC_DISABLE_STATIC
 166 AC_PROG_LIBTOOL
 167 AC_PROG_CC
 168 AC_PROG_CXX
 169 AM_PROG_CC_C_O
 170 AC_PROG_SED
 171 PKG_PROG_PKG_CONFIG
 172
 173 AC_HEADER_STDC
 174 AC_SYS_LARGEFILE
 175
 176 # Check for Doxygen
 177 if test "$enable_docs" = "yes"; then
 178     AC_CHECK_TOOL([DOXYGEN], [doxygen], [no])
 179     if test "$DOXYGEN" = "no"; then
 180        enable_docs="no"
 181     fi
 182 fi
 183 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 184
 185 # Check for va messaging
 186 if test "$enable_va_messaging" = "yes"; then
 187     AC_DEFINE([ENABLE_VA_MESSAGING], [1], [Defined to 1 if va messaging is needed])
 188 fi
 189
 190 # Check for __attribute__((visibility()))
 191 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 192     ac_cv_have_gnuc_visibility_attribute,
 193     [cat > conftest.c <<EOF
 194 int foo __attribute__ ((visibility ("hidden"))) = 1;
 195 int bar __attribute__ ((visibility ("protected"))) = 1;
 196 EOF
 197     ac_cv_have_gnuc_visibility_attribute="no"
 198     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 199         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 200             if grep '\.protected.*bar' conftest.s >/dev/null; then
 201                 ac_cv_have_gnuc_visibility_attribute="yes"
 202             fi
 203         fi
 204     fi
 205     rm -f conftest.[cs]
 206 ])
 207 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 208     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 209               [Defined to 1 if GCC visibility attribute is supported])
 210 fi
 211
 212 # Check for -fstack-protector
 213 ssp_cc=yes
 214 if test "X$CC-cc" != "X"; then
 215     AC_MSG_CHECKING([whether ${CC-cc} accepts -fstack-protector])
 216     ssp_old_cflags="$CFLAGS"
 217     CFLAGS="$CFLAGS -fstack-protector"
 218     AC_LINK_IFELSE([AC_LANG_PROGRAM([[]], [[alloca(100);]])], [], [ssp_cc=no])
 219     AC_MSG_RESULT([$ssp_cc])
 220     if test "X$ssp_cc" = "Xno"; then
 221         CFLAGS="$ssp_old_cflags"
 222     else
 223         AC_DEFINE([ENABLE_SSP_CC], 1, [Define if SSP C support is enabled.])
 224     fi
 225 fi
 226 AM_CONDITIONAL(USE_SSP, test "$ssp_cc" = "yes")
 227
 228 # Check for DRM (mandatory)
 229 LIBDRM_VERSION=libdrm_version
 230 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 231 AC_SUBST(LIBDRM_VERSION)
 232
 233 USE_DRM="no"
 234 if test "$enable_drm" = "yes"; then
 235     USE_DRM="yes"
 236     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 237 fi
 238 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 239
 240 # Check for X11
 241 USE_X11="no"
 242 if test "x$enable_x11" != "xno"; then
 243     PKG_CHECK_MODULES([X11],    [x11 xext xfixes],    [USE_X11="yes"], [:])
 244
 245     if test "x$USE_X11" = "xno" -a "x$enable_x11" = "xyes"; then
 246        AC_MSG_ERROR([VA/X11 explicitly enabled, however $X11_PKG_ERRORS])
 247     fi
 248
 249     if test "$USE_X11" = "yes"; then
 250         AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 251     fi
 252 fi
 253 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 254
 255 # Check for GLX
 256 USE_GLX="no"
 257
 258 if test "$USE_X11:$enable_glx" = "no:yes"; then
 259    AC_MSG_ERROR([VA/GLX explicitly enabled, but VA/X11 isn't built])
 260 fi
 261
 262 if test "$USE_X11:$enable_glx" != "yes:no"; then
 263     PKG_CHECK_MODULES([GLX], [gl x11], [USE_GLX="yes"], [:])
 264     saved_CPPFLAGS="$CPPFLAGS"
 265     saved_LIBS="$LIBS"
 266     CPPFLAGS="$CPPFLAGS $GLX_CFLAGS"
 267     LIBS="$LIBS $GLX_LIBS"
 268     AC_CHECK_HEADERS([GL/gl.h GL/glx.h], [:], [USE_GLX="no"])
 269     AC_CHECK_LIB([GL], [glXCreateContext], [:] [USE_GLX="no"])
 270     CPPFLAGS="$saved_CPPFLAGS"
 271     LIBS="$saved_LIBS"
 272
 273     if test "x$USE_GLX" = "xno" -a "x$enable_glx" = "xyes"; then
 274        AC_MSG_ERROR([VA/GLX explicitly enabled, but libGL couldn't be found])
 275     fi
 276
 277     if test "$USE_GLX" = "yes"; then
 278         AC_DEFINE([HAVE_VA_GLX], [1], [Defined to 1 if VA/GLX API is built])
 279     fi
 280 fi
 281 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 282
 283 # Check for Wayland
 284 WAYLAND_API_VERSION=wayland_api_version
 285 AC_SUBST(WAYLAND_API_VERSION)
 286
 287 USE_WAYLAND="no"
 288 if test "x$enable_wayland" != "xno"; then
 289     PKG_CHECK_MODULES([WAYLAND], [wayland-client >= wayland_api_version],
 290         [USE_WAYLAND="yes"], [:])
 291
 292     if test "x$USE_WAYLAND" = "xno" -a "x$enable_wayland" = "xyes"; then
 293         AC_MSG_ERROR([wayland explicitly enabled, however $WAYLAND_PKG_ERRORS])
 294     fi
 295
 296     if test "$USE_WAYLAND" = "yes"; then
 297
 298         WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
 299         AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
 300                      [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
 301         if test "x$WAYLAND_SCANNER" = "x"; then
 302             AC_MSG_ERROR([wayland-scanner not found: Install it or use --disable-wayland])
 303         fi
 304
 305         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 306                   [Defined to 1 if VA/Wayland API is built])
 307     fi
 308 fi
 309
 310 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 311
 312 pkgconfigdir=${libdir}/pkgconfig
 313 AC_SUBST(pkgconfigdir)
 314
 315 # Check for builds without backend
 316 if test "$USE_DRM:$USE_X11:$USE_WAYLAND" = "no:no:no"; then
 317     AC_MSG_ERROR([Please select at least one backend (DRM, X11, Wayland)])
 318 fi
 319
 320 AC_OUTPUT([
 321     Makefile
 322     doc/Makefile
 323     pkgconfig/Makefile
 324     pkgconfig/libva-drm.pc
 325     pkgconfig/libva-glx.pc
 326     pkgconfig/libva-wayland.pc
 327     pkgconfig/libva-x11.pc
 328     pkgconfig/libva.pc
 329     va/Makefile
 330     va/drm/Makefile
 331     va/glx/Makefile
 332     va/va_version.h
 333     va/wayland/Makefile
 334     va/x11/Makefile
 335 ])
 336
 337 # Print a small summary
 338 BACKENDS=""
 339 AS_IF([test x$USE_DRM = xyes], [BACKENDS="$BACKENDS drm"])
 340 AS_IF([test x$USE_X11 = xyes], [BACKENDS="$BACKENDS x11"])
 341 AS_IF([test x$USE_GLX = xyes], [BACKENDS="$BACKENDS glx"])
 342 AS_IF([test x$USE_WAYLAND = xyes], [BACKENDS="$BACKENDS wayland"])
 343
 344 echo
 345 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 346 echo
 347 echo Installation prefix .............. : $prefix
 348 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 349 echo Extra window systems ............. : $BACKENDS
 350 echo Build documentation .............. : $enable_docs
 351 echo Build with messaging ............. : $enable_va_messaging
 352 echo