+++ /dev/null
-; match686.asm -- Asm portion of the optimized longest_match for 32 bits x86\r
-; Copyright (C) 1995-1996 Jean-loup Gailly, Brian Raiter and Gilles Vollant.\r
-; File written by Gilles Vollant, by converting match686.S from Brian Raiter\r
-; for MASM. This is as assembly version of longest_match\r
-; from Jean-loup Gailly in deflate.c\r
-;\r
-; http://www.zlib.net\r
-; http://www.winimage.com/zLibDll\r
-; http://www.muppetlabs.com/~breadbox/software/assembly.html\r
-;\r
-; For Visual C++ 4.x and higher and ML 6.x and higher\r
-; ml.exe is distributed in\r
-; http://www.microsoft.com/downloads/details.aspx?FamilyID=7a1c9da0-0510-44a2-b042-7ef370530c64\r
-;\r
-; this file contain two implementation of longest_match\r
-;\r
-; this longest_match was written by Brian raiter (1998), optimized for Pentium Pro\r
-; (and the faster known version of match_init on modern Core 2 Duo and AMD Phenom)\r
-;\r
-; for using an assembly version of longest_match, you need define ASMV in project\r
-;\r
-; compile the asm file running\r
-; ml /coff /Zi /c /Flmatch686.lst match686.asm\r
-; and do not include match686.obj in your project\r
-;\r
-; note: contrib of zLib 1.2.3 and earlier contained both a deprecated version for\r
-; Pentium (prior Pentium Pro) and this version for Pentium Pro and modern processor\r
-; with autoselect (with cpu detection code)\r
-; if you want support the old pentium optimization, you can still use these version\r
-;\r
-; this file is not optimized for old pentium, but it compatible with all x86 32 bits\r
-; processor (starting 80386)\r
-;\r
-;\r
-; see below : zlib1222add must be adjuster if you use a zlib version < 1.2.2.2\r
-\r
-;uInt longest_match(s, cur_match)\r
-; deflate_state *s;\r
-; IPos cur_match; /* current match */\r
-\r
- NbStack equ 76\r
- cur_match equ dword ptr[esp+NbStack-0]\r
- str_s equ dword ptr[esp+NbStack-4]\r
-; 5 dword on top (ret,ebp,esi,edi,ebx)\r
- adrret equ dword ptr[esp+NbStack-8]\r
- pushebp equ dword ptr[esp+NbStack-12]\r
- pushedi equ dword ptr[esp+NbStack-16]\r
- pushesi equ dword ptr[esp+NbStack-20]\r
- pushebx equ dword ptr[esp+NbStack-24]\r
-\r
- chain_length equ dword ptr [esp+NbStack-28]\r
- limit equ dword ptr [esp+NbStack-32]\r
- best_len equ dword ptr [esp+NbStack-36]\r
- window equ dword ptr [esp+NbStack-40]\r
- prev equ dword ptr [esp+NbStack-44]\r
- scan_start equ word ptr [esp+NbStack-48]\r
- wmask equ dword ptr [esp+NbStack-52]\r
- match_start_ptr equ dword ptr [esp+NbStack-56]\r
- nice_match equ dword ptr [esp+NbStack-60]\r
- scan equ dword ptr [esp+NbStack-64]\r
-\r
- windowlen equ dword ptr [esp+NbStack-68]\r
- match_start equ dword ptr [esp+NbStack-72]\r
- strend equ dword ptr [esp+NbStack-76]\r
- NbStackAdd equ (NbStack-24)\r
-\r
- .386p\r
-\r
- name gvmatch\r
- .MODEL FLAT\r
-\r
-\r
-\r
-; all the +zlib1222add offsets are due to the addition of fields\r
-; in zlib in the deflate_state structure since the asm code was first written\r
-; (if you compile with zlib 1.0.4 or older, use "zlib1222add equ (-4)").\r
-; (if you compile with zlib between 1.0.5 and 1.2.2.1, use "zlib1222add equ 0").\r
-; if you compile with zlib 1.2.2.2 or later , use "zlib1222add equ 8").\r
-\r
- zlib1222add equ 8\r
-\r
-; Note : these value are good with a 8 bytes boundary pack structure\r
- dep_chain_length equ 74h+zlib1222add\r
- dep_window equ 30h+zlib1222add\r
- dep_strstart equ 64h+zlib1222add\r
- dep_prev_length equ 70h+zlib1222add\r
- dep_nice_match equ 88h+zlib1222add\r
- dep_w_size equ 24h+zlib1222add\r
- dep_prev equ 38h+zlib1222add\r
- dep_w_mask equ 2ch+zlib1222add\r
- dep_good_match equ 84h+zlib1222add\r
- dep_match_start equ 68h+zlib1222add\r
- dep_lookahead equ 6ch+zlib1222add\r
-\r
-\r
-_TEXT segment\r
-\r
-IFDEF NOUNDERLINE\r
- public longest_match\r
- public match_init\r
-ELSE\r
- public _longest_match\r
- public _match_init\r
-ENDIF\r
-\r
- MAX_MATCH equ 258\r
- MIN_MATCH equ 3\r
- MIN_LOOKAHEAD equ (MAX_MATCH+MIN_MATCH+1)\r
-\r
-\r
-\r
-MAX_MATCH equ 258\r
-MIN_MATCH equ 3\r
-MIN_LOOKAHEAD equ (MAX_MATCH + MIN_MATCH + 1)\r
-MAX_MATCH_8_ equ ((MAX_MATCH + 7) AND 0FFF0h)\r
-\r
-\r
-;;; stack frame offsets\r
-\r
-chainlenwmask equ esp + 0 ; high word: current chain len\r
- ; low word: s->wmask\r
-window equ esp + 4 ; local copy of s->window\r
-windowbestlen equ esp + 8 ; s->window + bestlen\r
-scanstart equ esp + 16 ; first two bytes of string\r
-scanend equ esp + 12 ; last two bytes of string\r
-scanalign equ esp + 20 ; dword-misalignment of string\r
-nicematch equ esp + 24 ; a good enough match size\r
-bestlen equ esp + 28 ; size of best match so far\r
-scan equ esp + 32 ; ptr to string wanting match\r
-\r
-LocalVarsSize equ 36\r
-; saved ebx byte esp + 36\r
-; saved edi byte esp + 40\r
-; saved esi byte esp + 44\r
-; saved ebp byte esp + 48\r
-; return address byte esp + 52\r
-deflatestate equ esp + 56 ; the function arguments\r
-curmatch equ esp + 60\r
-\r
-;;; Offsets for fields in the deflate_state structure. These numbers\r
-;;; are calculated from the definition of deflate_state, with the\r
-;;; assumption that the compiler will dword-align the fields. (Thus,\r
-;;; changing the definition of deflate_state could easily cause this\r
-;;; program to crash horribly, without so much as a warning at\r
-;;; compile time. Sigh.)\r
-\r
-dsWSize equ 36+zlib1222add\r
-dsWMask equ 44+zlib1222add\r
-dsWindow equ 48+zlib1222add\r
-dsPrev equ 56+zlib1222add\r
-dsMatchLen equ 88+zlib1222add\r
-dsPrevMatch equ 92+zlib1222add\r
-dsStrStart equ 100+zlib1222add\r
-dsMatchStart equ 104+zlib1222add\r
-dsLookahead equ 108+zlib1222add\r
-dsPrevLen equ 112+zlib1222add\r
-dsMaxChainLen equ 116+zlib1222add\r
-dsGoodMatch equ 132+zlib1222add\r
-dsNiceMatch equ 136+zlib1222add\r
-\r
-\r
-;;; match686.asm -- Pentium-Pro-optimized version of longest_match()\r
-;;; Written for zlib 1.1.2\r
-;;; Copyright (C) 1998 Brian Raiter <breadbox@muppetlabs.com>\r
-;;; You can look at http://www.muppetlabs.com/~breadbox/software/assembly.html\r
-;;;\r
-;;\r
-;; This software is provided 'as-is', without any express or implied\r
-;; warranty. In no event will the authors be held liable for any damages\r
-;; arising from the use of this software.\r
-;;\r
-;; Permission is granted to anyone to use this software for any purpose,\r
-;; including commercial applications, and to alter it and redistribute it\r
-;; freely, subject to the following restrictions:\r
-;;\r
-;; 1. The origin of this software must not be misrepresented; you must not\r
-;; claim that you wrote the original software. If you use this software\r
-;; in a product, an acknowledgment in the product documentation would be\r
-;; appreciated but is not required.\r
-;; 2. Altered source versions must be plainly marked as such, and must not be\r
-;; misrepresented as being the original software\r
-;; 3. This notice may not be removed or altered from any source distribution.\r
-;;\r
-\r
-;GLOBAL _longest_match, _match_init\r
-\r
-\r
-;SECTION .text\r
-\r
-;;; uInt longest_match(deflate_state *deflatestate, IPos curmatch)\r
-\r
-;_longest_match:\r
- IFDEF NOUNDERLINE\r
- longest_match proc near\r
- ELSE\r
- _longest_match proc near\r
- ENDIF\r
-\r
-;;; Save registers that the compiler may be using, and adjust esp to\r
-;;; make room for our stack frame.\r
-\r
- push ebp\r
- push edi\r
- push esi\r
- push ebx\r
- sub esp, LocalVarsSize\r
-\r
-;;; Retrieve the function arguments. ecx will hold cur_match\r
-;;; throughout the entire function. edx will hold the pointer to the\r
-;;; deflate_state structure during the function's setup (before\r
-;;; entering the main loop.\r
-\r
- mov edx, [deflatestate]\r
- mov ecx, [curmatch]\r
-\r
-;;; uInt wmask = s->w_mask;\r
-;;; unsigned chain_length = s->max_chain_length;\r
-;;; if (s->prev_length >= s->good_match) {\r
-;;; chain_length >>= 2;\r
-;;; }\r
-\r
- mov eax, [edx + dsPrevLen]\r
- mov ebx, [edx + dsGoodMatch]\r
- cmp eax, ebx\r
- mov eax, [edx + dsWMask]\r
- mov ebx, [edx + dsMaxChainLen]\r
- jl LastMatchGood\r
- shr ebx, 2\r
-LastMatchGood:\r
-\r
-;;; chainlen is decremented once beforehand so that the function can\r
-;;; use the sign flag instead of the zero flag for the exit test.\r
-;;; It is then shifted into the high word, to make room for the wmask\r
-;;; value, which it will always accompany.\r
-\r
- dec ebx\r
- shl ebx, 16\r
- or ebx, eax\r
- mov [chainlenwmask], ebx\r
-\r
-;;; if ((uInt)nice_match > s->lookahead) nice_match = s->lookahead;\r
-\r
- mov eax, [edx + dsNiceMatch]\r
- mov ebx, [edx + dsLookahead]\r
- cmp ebx, eax\r
- jl LookaheadLess\r
- mov ebx, eax\r
-LookaheadLess: mov [nicematch], ebx\r
-\r
-;;; register Bytef *scan = s->window + s->strstart;\r
-\r
- mov esi, [edx + dsWindow]\r
- mov [window], esi\r
- mov ebp, [edx + dsStrStart]\r
- lea edi, [esi + ebp]\r
- mov [scan], edi\r
-\r
-;;; Determine how many bytes the scan ptr is off from being\r
-;;; dword-aligned.\r
-\r
- mov eax, edi\r
- neg eax\r
- and eax, 3\r
- mov [scanalign], eax\r
-\r
-;;; IPos limit = s->strstart > (IPos)MAX_DIST(s) ?\r
-;;; s->strstart - (IPos)MAX_DIST(s) : NIL;\r
-\r
- mov eax, [edx + dsWSize]\r
- sub eax, MIN_LOOKAHEAD\r
- sub ebp, eax\r
- jg LimitPositive\r
- xor ebp, ebp\r
-LimitPositive:\r
-\r
-;;; int best_len = s->prev_length;\r
-\r
- mov eax, [edx + dsPrevLen]\r
- mov [bestlen], eax\r
-\r
-;;; Store the sum of s->window + best_len in esi locally, and in esi.\r
-\r
- add esi, eax\r
- mov [windowbestlen], esi\r
-\r
-;;; register ush scan_start = *(ushf*)scan;\r
-;;; register ush scan_end = *(ushf*)(scan+best_len-1);\r
-;;; Posf *prev = s->prev;\r
-\r
- movzx ebx, word ptr [edi]\r
- mov [scanstart], ebx\r
- movzx ebx, word ptr [edi + eax - 1]\r
- mov [scanend], ebx\r
- mov edi, [edx + dsPrev]\r
-\r
-;;; Jump into the main loop.\r
-\r
- mov edx, [chainlenwmask]\r
- jmp short LoopEntry\r
-\r
-align 4\r
-\r
-;;; do {\r
-;;; match = s->window + cur_match;\r
-;;; if (*(ushf*)(match+best_len-1) != scan_end ||\r
-;;; *(ushf*)match != scan_start) continue;\r
-;;; [...]\r
-;;; } while ((cur_match = prev[cur_match & wmask]) > limit\r
-;;; && --chain_length != 0);\r
-;;;\r
-;;; Here is the inner loop of the function. The function will spend the\r
-;;; majority of its time in this loop, and majority of that time will\r
-;;; be spent in the first ten instructions.\r
-;;;\r
-;;; Within this loop:\r
-;;; ebx = scanend\r
-;;; ecx = curmatch\r
-;;; edx = chainlenwmask - i.e., ((chainlen << 16) | wmask)\r
-;;; esi = windowbestlen - i.e., (window + bestlen)\r
-;;; edi = prev\r
-;;; ebp = limit\r
-\r
-LookupLoop:\r
- and ecx, edx\r
- movzx ecx, word ptr [edi + ecx*2]\r
- cmp ecx, ebp\r
- jbe LeaveNow\r
- sub edx, 00010000h\r
- js LeaveNow\r
-LoopEntry: movzx eax, word ptr [esi + ecx - 1]\r
- cmp eax, ebx\r
- jnz LookupLoop\r
- mov eax, [window]\r
- movzx eax, word ptr [eax + ecx]\r
- cmp eax, [scanstart]\r
- jnz LookupLoop\r
-\r
-;;; Store the current value of chainlen.\r
-\r
- mov [chainlenwmask], edx\r
-\r
-;;; Point edi to the string under scrutiny, and esi to the string we\r
-;;; are hoping to match it up with. In actuality, esi and edi are\r
-;;; both pointed (MAX_MATCH_8 - scanalign) bytes ahead, and edx is\r
-;;; initialized to -(MAX_MATCH_8 - scanalign).\r
-\r
- mov esi, [window]\r
- mov edi, [scan]\r
- add esi, ecx\r
- mov eax, [scanalign]\r
- mov edx, 0fffffef8h; -(MAX_MATCH_8)\r
- lea edi, [edi + eax + 0108h] ;MAX_MATCH_8]\r
- lea esi, [esi + eax + 0108h] ;MAX_MATCH_8]\r
-\r
-;;; Test the strings for equality, 8 bytes at a time. At the end,\r
-;;; adjust edx so that it is offset to the exact byte that mismatched.\r
-;;;\r
-;;; We already know at this point that the first three bytes of the\r
-;;; strings match each other, and they can be safely passed over before\r
-;;; starting the compare loop. So what this code does is skip over 0-3\r
-;;; bytes, as much as necessary in order to dword-align the edi\r
-;;; pointer. (esi will still be misaligned three times out of four.)\r
-;;;\r
-;;; It should be confessed that this loop usually does not represent\r
-;;; much of the total running time. Replacing it with a more\r
-;;; straightforward "rep cmpsb" would not drastically degrade\r
-;;; performance.\r
-\r
-LoopCmps:\r
- mov eax, [esi + edx]\r
- xor eax, [edi + edx]\r
- jnz LeaveLoopCmps\r
- mov eax, [esi + edx + 4]\r
- xor eax, [edi + edx + 4]\r
- jnz LeaveLoopCmps4\r
- add edx, 8\r
- jnz LoopCmps\r
- jmp short LenMaximum\r
-LeaveLoopCmps4: add edx, 4\r
-LeaveLoopCmps: test eax, 0000FFFFh\r
- jnz LenLower\r
- add edx, 2\r
- shr eax, 16\r
-LenLower: sub al, 1\r
- adc edx, 0\r
-\r
-;;; Calculate the length of the match. If it is longer than MAX_MATCH,\r
-;;; then automatically accept it as the best possible match and leave.\r
-\r
- lea eax, [edi + edx]\r
- mov edi, [scan]\r
- sub eax, edi\r
- cmp eax, MAX_MATCH\r
- jge LenMaximum\r
-\r
-;;; If the length of the match is not longer than the best match we\r
-;;; have so far, then forget it and return to the lookup loop.\r
-\r
- mov edx, [deflatestate]\r
- mov ebx, [bestlen]\r
- cmp eax, ebx\r
- jg LongerMatch\r
- mov esi, [windowbestlen]\r
- mov edi, [edx + dsPrev]\r
- mov ebx, [scanend]\r
- mov edx, [chainlenwmask]\r
- jmp LookupLoop\r
-\r
-;;; s->match_start = cur_match;\r
-;;; best_len = len;\r
-;;; if (len >= nice_match) break;\r
-;;; scan_end = *(ushf*)(scan+best_len-1);\r
-\r
-LongerMatch: mov ebx, [nicematch]\r
- mov [bestlen], eax\r
- mov [edx + dsMatchStart], ecx\r
- cmp eax, ebx\r
- jge LeaveNow\r
- mov esi, [window]\r
- add esi, eax\r
- mov [windowbestlen], esi\r
- movzx ebx, word ptr [edi + eax - 1]\r
- mov edi, [edx + dsPrev]\r
- mov [scanend], ebx\r
- mov edx, [chainlenwmask]\r
- jmp LookupLoop\r
-\r
-;;; Accept the current string, with the maximum possible length.\r
-\r
-LenMaximum: mov edx, [deflatestate]\r
- mov dword ptr [bestlen], MAX_MATCH\r
- mov [edx + dsMatchStart], ecx\r
-\r
-;;; if ((uInt)best_len <= s->lookahead) return (uInt)best_len;\r
-;;; return s->lookahead;\r
-\r
-LeaveNow:\r
- mov edx, [deflatestate]\r
- mov ebx, [bestlen]\r
- mov eax, [edx + dsLookahead]\r
- cmp ebx, eax\r
- jg LookaheadRet\r
- mov eax, ebx\r
-LookaheadRet:\r
-\r
-;;; Restore the stack and return from whence we came.\r
-\r
- add esp, LocalVarsSize\r
- pop ebx\r
- pop esi\r
- pop edi\r
- pop ebp\r
-\r
- ret\r
-; please don't remove this string !\r
-; Your can freely use match686 in any free or commercial app if you don't remove the string in the binary!\r
- db 0dh,0ah,"asm686 with masm, optimised assembly code from Brian Raiter, written 1998",0dh,0ah\r
-\r
-\r
- IFDEF NOUNDERLINE\r
- longest_match endp\r
- ELSE\r
- _longest_match endp\r
- ENDIF\r
-\r
- IFDEF NOUNDERLINE\r
- match_init proc near\r
- ret\r
- match_init endp\r
- ELSE\r
- _match_init proc near\r
- ret\r
- _match_init endp\r
- ENDIF\r
-\r
-\r
-_TEXT ends\r
-end\r