Add PuTTY 0.61 to contrib directory.

[ffftp/ffftp.git] / contrib / putty / UNIX / CONFIGUR.AC

diff --git a/contrib/putty/UNIX/CONFIGUR.AC b/contrib/putty/UNIX/CONFIGUR.AC
new file mode 100644 (file)
index 0000000..382bf2a
--- /dev/null
+++ b/contrib/putty/UNIX/CONFIGUR.AC
@@ -0,0 +1,107 @@
+# To compile this into a configure script, you need:\r
+# * Autoconf 2.50 or newer\r
+# * Gtk (for $prefix/share/aclocal/gtk.m4)\r
+# * Automake (for aclocal)\r
+# If you've got them, running "autoreconf" should work.\r
+\r
+AC_INIT\r
+AC_CONFIG_FILES([Makefile])\r
+AC_CONFIG_HEADERS([uxconfig.h:uxconfig.in])\r
+\r
+AC_PROG_INSTALL\r
+AC_PROG_CC\r
+if test "X$GCC" = Xyes; then\r
+    PUTTYCFLAGS="-Wall -Werror"\r
+else\r
+    PUTTYCFLAGS=""\r
+fi\r
+AC_SUBST(PUTTYCFLAGS)\r
+\r
+AC_ARG_WITH([gssapi],\r
+  [AS_HELP_STRING([--without-gssapi],\r
+                  [disable GSSAPI support])],\r
+  [],\r
+  [with_gssapi=yes])\r
+\r
+WITH_GSSAPI=\r
+AS_IF([test "x$with_gssapi" != xno],\r
+  [AC_DEFINE([WITH_GSSAPI], [1], [Define if building with GSSAPI support.])])\r
+\r
+AC_CHECK_HEADERS([utmpx.h sys/select.h],,,[\r
+#include <sys/types.h>\r
+#include <utmp.h>])\r
+\r
+# Look for both GTK 1 and GTK 2.\r
+AM_PATH_GTK([1.2.0], [gtk=1], [gtk=none])\r
+AM_PATH_GTK_2_0([2.0.0], [gtk=2], [])\r
+if test "$gtk" = "none"; then\r
+  all_targets="all-cli"\r
+else\r
+  all_targets="all-cli all-gtk"\r
+fi\r
+if test "$gtk" = "2"; then\r
+  ac_save_CFLAGS="$CFLAGS"\r
+  ac_save_LIBS="$LIBS"\r
+  CFLAGS="$CFLAGS $GTK_CFLAGS"\r
+  LIBS="$GTK_LIBS $LIBS"\r
+  AC_CHECK_FUNCS([pango_font_family_is_monospace pango_font_map_list_families])\r
+  CFLAGS="$ac_save_CFLAGS"\r
+  LIBS="$ac_save_LIBS"\r
+fi\r
+AC_SUBST([all_targets])\r
+\r
+AC_SEARCH_LIBS([socket], [xnet])\r
+\r
+AS_IF([test "x$with_gssapi" != xno],\r
+  [AC_SEARCH_LIBS(\r
+    [dlopen],[dl],\r
+    [],\r
+    [AC_DEFINE([NO_LIBDL], [1], [Define if we could not find libdl.])\r
+     AC_CHECK_HEADERS([gssapi/gssapi.h])\r
+     AC_SEARCH_LIBS(\r
+       [gss_init_sec_context],[gssapi gssapi_krb5 gss],\r
+       [],\r
+       [AC_DEFINE([NO_GSSAPI_LIB], [1], [Define if we could not find a gssapi library])])])])\r
+\r
+AC_CHECK_LIB(X11, XOpenDisplay)\r
+\r
+AC_CHECK_FUNCS([getaddrinfo ptsname setresuid strsignal updwtmpx])\r
+\r
+AC_OUTPUT\r
+\r
+AH_BOTTOM([\r
+/* Convert autoconf definitions to ones that PuTTY wants. */\r
+\r
+#ifndef HAVE_GETADDRINFO\r
+# define NO_IPV6\r
+#endif\r
+#ifndef HAVE_SETRESUID\r
+# define HAVE_NO_SETRESUID\r
+#endif\r
+#ifndef HAVE_STRSIGNAL\r
+# define HAVE_NO_STRSIGNAL\r
+#endif\r
+#if !defined(HAVE_UTMPX_H) || !defined(HAVE_UPDWTMPX)\r
+# define OMIT_UTMP\r
+#endif\r
+#ifndef HAVE_PTSNAME\r
+# define BSD_PTYS\r
+#endif\r
+#ifndef HAVE_SYS_SELECT_H\r
+# define HAVE_NO_SYS_SELECT_H\r
+#endif\r
+#ifndef HAVE_PANGO_FONT_FAMILY_IS_MONOSPACE\r
+# define PANGO_PRE_1POINT4\r
+#endif\r
+#ifndef HAVE_PANGO_FONT_MAP_LIST_FAMILIES\r
+# define PANGO_PRE_1POINT6\r
+#endif\r
+#if !defined(WITH_GSSAPI)\r
+# define NO_GSSAPI\r
+#endif\r
+#if !defined(NO_GSSAPI) && defined(NO_LIBDL)\r
+# if !defined(HAVE_GSSAPI_GSSAPI_H) || defined(NO_GSSAPI_LIB)\r
+#  define NO_GSSAPI\r
+# endif\r
+#endif\r
+])\r