class Pettanr.AppController
  
  constructor: (@params, @form, @operators, @gate) ->
    _.extend(this, Backbone.Events)
  
  @new2: (params, form, operators, gate) ->
    c = @controller_by_name(params['controller'])
    new c(params, form, operators, gate)
  
  @controller_by_name: (name) ->
    Pettanr[Pettanr.camelize(name) + 'Controller']
  
  set_model: () ->
    @my_controller = Manifest.manifest().controllers[@params['controller']]
    @my_action = @my_controller.actions[@params['action']]
    @my_model = Manifest.manifest().models[@my_action.item_name]
    @my_model_class = @my_model.classify()
    
  set_list: () ->
    @set_model()
    @my_list_model = Manifest.manifest().models[@my_action.item_name]
    @my_list_model_class = @my_list_model.classify()
    @list = Locmare.ListGroup.list(
      @my_action.path_name(), @my_action.name, @operators, @params
    )
  
  set_show: (render_func) ->
    @set_model()
    @empty_item = new @my_model_class({id: @params['id']})
    @item = Pettanr.cache.restore(@empty_item)
    if @item
      # got cached item
      render_func.call(this)
    else
      # built empty item
      @item = @empty_item
      @item.fetch().done =>
        Pettanr.cache.store(@item)
        render_func.call(this)
  
  filer_list: () ->
    @set_list()
    @list.open(() =>
      pager = Locmare.ListGroupModule.LibModule.Pager.factory(@list.page_status, @params)
      filer = new Locmare.Filer({
        item_name: @list.item_name, 
        items: @list.items(), 
        pager: pager, 
        operators: @operators
      })
      @listenTo(filer, 'navigate', @navigate)
      filer.render()
      @trigger('ready', filer)
    )
    false
  
  set_play: (render_func) ->
    @set_list()
    @binder_action = @my_action.original
    @binder_controller = @binder_action.controller()
    @binder_model = Manifest.manifest().models[@binder_action.item_name]
    @binder_model_class = @binder_model.classify()
    @empty_item = new @binder_model_class({id: @params['id']})
    @item = Pettanr.cache.restore(@empty_item)
    if @item
      # got cached item
      render_func.call(this)
    else
      # built empty item
      @item = @empty_item
      @item.fetch().done =>
        Pettanr.cache.store(@item)
        render_func.call(this)
  
  show_prof: () ->
    @item.boosts 'post'
    profiler = new Locmare.Profiler({
      item_name: @item.item_name(), 
      item: @item, 
      operators: @operators
    })
    @listenTo(profiler, 'navigate', @navigate)
    profiler.render()
    @trigger('ready', profiler)
    @trigger('title', @params)
    @trigger('done', @params)
  
  set_new: () ->
    @set_model()
    @item = new @my_model_class({id: @params['id']})
    # Backbone.Model has defaults property
    #@item.supply_default()
  
  set_edit: () ->
    @set_model()
    @empty_item = new @my_model_class({id: @params['id']})
    @item = Pettanr.cache.restore(@empty_item)
    if @item
      # got cached item
      @render_edit()
    else
      # built empty item
      @item = @empty_item
      Pettanr.cache.store(@empty_item)
      @item.fetch().done =>
        @render_edit()
  
  render_edit: () ->
    @item.boosts 'post'
    @render_form()
  
  render_form: () ->
    @form = Locmare.Form.factory({
      form_name: @item.item_name(), 
      use_name: 'default', 
      item: @item, 
      element_form: false, 
      submit: 'default', 
      operators: @operators,
    })
    @form.render()
    @trigger('ready', @form)
    @trigger('lock', @params, @form)
  
  form_new: () ->
    # how cansel on picker edit button?
    @set_new()
    @render_form()
  
  form_edit: () ->
    # how cansel on picker edit button?
    @set_edit()
  
  post_success: (model, response) ->
    @trigger('unlock', @params, @form)
    @trigger('redirect', @form.item.show_url())
    @trigger('success', model, response)
  
  post_fail: (model, response) ->
    @trigger('fail', response)
  
  destroy_success: (model, response) ->
    @trigger('redirect', '/home/' + model.path_name())
    @trigger('success', model, response)
  
  destroy_fail: (model, response) ->
    @trigger('fail', response)
  
  navigate: (url) ->
    @trigger('navigate', url)