class Pettanr.AppController
  
  constructor: (@params, @form, @gate) ->
    _.extend(this, Backbone.Events)
  
  @new2: (params, form, gate) ->
    c = @controller_by_name(params['controller'])
    new c(params, form, gate)
  
  @controller_by_name: (name) ->
    Pettanr[Pettanr.camelize(name) + 'Controller']
  
  set_model: () ->
    @my_controller = Manifest.manifest().controllers[@params['controller']]
    @my_action = @my_controller.actions[@params['action']]
    @my_model = Manifest.manifest().models[@my_action.item_name]
    @my_model_class = @my_model.classify()
    
  set_list: () ->
    @set_model()
    @list = @my_action.find(@params)
  
  set_show: (render_func) ->
    @set_model()
    @my_model_class.retrieve(@params['id'], this, {
      success: render_func
      fail: (response, options) =>
        @trigger('fail', response, options)
    })
  
  filer_list: () ->
    @set_list()
    @list.to_filer(this, {
      success: (filer) =>
        @listenTo(filer, 'navigate', @navigate)
        filer.render()
        @trigger('ready', filer)
      fail: (response, options) =>
        @trigger('fail', response, options)
    })
    false
  
  set_play: (render_func) ->
    @set_list()
    @my_model_class.retrieve(@params['id'], this, {success: render_func})
  
  show_prof: () ->
    @item.boosts 'post'
    profiler = new Locmare.Profiler({
      item_name: @item.item_name(), 
      item: @item
    })
    @listenTo(profiler, 'navigate', @navigate)
    profiler.render()
    @trigger('ready', profiler)
    @trigger('title', @params)
    @trigger('done', @params)
  
  set_new: () ->
    @set_model()
    @item = new @my_model_class({id: @params['id']})
    # Backbone.Model has defaults property
    #@item.supply_default()
  
  set_edit: (options = {}) ->
    @set_model()
    retriever = new Pettanr.Cache.Retriever(@my_model_class, @params['id'])
    @listenTo(retriever, 'retrieve', @render_edit)
    @listenTo(retriever, 'fail', (response, opt) =>
      @trigger('fail', response, opt)
    )
    retriever.edit(options)
  
  render_edit: (@item) ->
    @item.boosts 'post'
    @render_form()
  
  render_form: () ->
    @form = Locmare.Form.factory({
      form_name: @item.item_name(), 
      use_name: 'default', 
      item: @item, 
      element_form: false, 
      submit: 'default'
    })
    @form.render()
    @trigger('ready', @form)
    @trigger('lock', @params, @form)
  
  form_new: () ->
    @set_new()
    @render_form()
  
  form_edit: () ->
    @set_edit()
  
  post_success: (model, response) ->
    @trigger('unlock', @params, @form)
    @trigger('redirect', @form.item.show_url())
    @trigger('success', model, response)
  
  post_fail: (model, response) ->
    @trigger('fail', response)
  
  destroy_success: (model, response) ->
    @trigger('redirect', 'home/' + model.path_name())
    @trigger('success', model, response)
  
  destroy_fail: (model, response) ->
    @trigger('fail', response)
  
  navigate: (url) ->
    @trigger('navigate', url)