class Pettanr.Views.GroundColor.Element extends Backbone.View
  tagName: 'div'
  className: 'pettanr-comic-ground-color'
  
  initialize: (options) ->
    @element = options.element
    @root = options.root
    @spot = options.spot
  
  render: () ->
    attr = {
      style: Pettanr.to_style(@style(@spot))
    }
    this.$el.attr(attr)
    this
  
  div_offset: () ->
    if @element.get('xy')
      @element.get('xy')
    else
      0
  
  div_size: () ->
    if @element.get('wh')
      @element.get('wh')
    else
      100 - @div_offset()
  
  div_x: () ->
    if @element.get('orientation') == 0
      0
    else
      @div_offset()
  
  div_y: () ->
    if @element.get('orientation') == 0
      @div_offset()
    else
      0
  
  div_width: () ->
    if @element.get('orientation') == 0
      100
    else
      @div_size()
  
  div_height: () ->
    if @element.get('orientation') == 0
      @div_size()
    else
      100
  
  style: (spot = null, opacity = 20) ->
    r = {
      position: 'absolute', 
      'z-index': @element.get('z'), 
      top: Pettanr.to_s(@div_y()) + '%', 
      left: Pettanr.to_s(@div_x()) + '%', 
      width: Pettanr.to_s(@div_width()) + '%', 
      height: Pettanr.to_s(@div_height()) + '%', 
      'background-color': '#' + ('000000' + Pettanr.to_s(@element.get('code'))).slice(-6)
    }
    @merge_opacity(r, opacity) if spot and spot != @element
    r