three.jsをThirdPartyに追加

[webglgame/webgl_framework.git] / webglFramework / Thirdparty / three.js-master / src / renderers / shaders / ShaderChunk / lights_template.glsl

diff --git a/webglFramework/Thirdparty/three.js-master/src/renderers/shaders/ShaderChunk/lights_template.glsl b/webglFramework/Thirdparty/three.js-master/src/renderers/shaders/ShaderChunk/lights_template.glsl
new file mode 100644 (file)
index 0000000..154483c
--- /dev/null
+++ b/webglFramework/Thirdparty/three.js-master/src/renderers/shaders/ShaderChunk/lights_template.glsl
@@ -0,0 +1,149 @@
+/**
+ * This is a template that can be used to light a material, it uses pluggable
+ * RenderEquations (RE)for specific lighting scenarios.
+ *
+ * Instructions for use:
+ * - Ensure that both RE_Direct, RE_IndirectDiffuse and RE_IndirectSpecular are defined
+ * - If you have defined an RE_IndirectSpecular, you need to also provide a Material_LightProbeLOD. <---- ???
+ * - Create a material parameter that is to be passed as the third parameter to your lighting functions.
+ *
+ * TODO:
+ * - Add area light support.
+ * - Add sphere light support.
+ * - Add diffuse light probe (irradiance cubemap) support.
+ */
+
+GeometricContext geometry;
+
+geometry.position = - vViewPosition;
+geometry.normal = normal;
+geometry.viewDir = normalize( vViewPosition );
+
+IncidentLight directLight;
+
+#if ( NUM_POINT_LIGHTS > 0 ) && defined( RE_Direct )
+
+       PointLight pointLight;
+
+       for ( int i = 0; i < NUM_POINT_LIGHTS; i ++ ) {
+
+               pointLight = pointLights[ i ];
+
+               getPointDirectLightIrradiance( pointLight, geometry, directLight );
+
+               #ifdef USE_SHADOWMAP
+               directLight.color *= all( bvec2( pointLight.shadow, directLight.visible ) ) ? getPointShadow( pointShadowMap[ i ], pointLight.shadowMapSize, pointLight.shadowBias, pointLight.shadowRadius, vPointShadowCoord[ i ], pointLight.shadowCameraNear, pointLight.shadowCameraFar ) : 1.0;
+               #endif
+
+               RE_Direct( directLight, geometry, material, reflectedLight );
+
+       }
+
+#endif
+
+#if ( NUM_SPOT_LIGHTS > 0 ) && defined( RE_Direct )
+
+       SpotLight spotLight;
+
+       for ( int i = 0; i < NUM_SPOT_LIGHTS; i ++ ) {
+
+               spotLight = spotLights[ i ];
+
+               getSpotDirectLightIrradiance( spotLight, geometry, directLight );
+
+               #ifdef USE_SHADOWMAP
+               directLight.color *= all( bvec2( spotLight.shadow, directLight.visible ) ) ? getShadow( spotShadowMap[ i ], spotLight.shadowMapSize, spotLight.shadowBias, spotLight.shadowRadius, vSpotShadowCoord[ i ] ) : 1.0;
+               #endif
+
+               RE_Direct( directLight, geometry, material, reflectedLight );
+
+       }
+
+#endif
+
+#if ( NUM_DIR_LIGHTS > 0 ) && defined( RE_Direct )
+
+       DirectionalLight directionalLight;
+
+       for ( int i = 0; i < NUM_DIR_LIGHTS; i ++ ) {
+
+               directionalLight = directionalLights[ i ];
+
+               getDirectionalDirectLightIrradiance( directionalLight, geometry, directLight );
+
+               #ifdef USE_SHADOWMAP
+               directLight.color *= all( bvec2( directionalLight.shadow, directLight.visible ) ) ? getShadow( directionalShadowMap[ i ], directionalLight.shadowMapSize, directionalLight.shadowBias, directionalLight.shadowRadius, vDirectionalShadowCoord[ i ] ) : 1.0;
+               #endif
+
+               RE_Direct( directLight, geometry, material, reflectedLight );
+
+       }
+
+#endif
+
+#if ( NUM_RECT_AREA_LIGHTS > 0 ) && defined( RE_Direct_RectArea )
+
+       RectAreaLight rectAreaLight;
+
+       for ( int i = 0; i < NUM_RECT_AREA_LIGHTS; i ++ ) {
+
+               rectAreaLight = rectAreaLights[ i ];
+               RE_Direct_RectArea( rectAreaLight, geometry, material, reflectedLight );
+
+       }
+
+#endif
+
+#if defined( RE_IndirectDiffuse )
+
+       vec3 irradiance = getAmbientLightIrradiance( ambientLightColor );
+
+       #ifdef USE_LIGHTMAP
+
+               vec3 lightMapIrradiance = texture2D( lightMap, vUv2 ).xyz * lightMapIntensity;
+
+               #ifndef PHYSICALLY_CORRECT_LIGHTS
+
+                       lightMapIrradiance *= PI; // factor of PI should not be present; included here to prevent breakage
+
+               #endif
+
+               irradiance += lightMapIrradiance;
+
+       #endif
+
+       #if ( NUM_HEMI_LIGHTS > 0 )
+
+               for ( int i = 0; i < NUM_HEMI_LIGHTS; i ++ ) {
+
+                       irradiance += getHemisphereLightIrradiance( hemisphereLights[ i ], geometry );
+
+               }
+
+       #endif
+
+       #if defined( USE_ENVMAP ) && defined( PHYSICAL ) && defined( ENVMAP_TYPE_CUBE_UV )
+
+               // TODO, replace 8 with the real maxMIPLevel
+               irradiance += getLightProbeIndirectIrradiance( /*lightProbe,*/ geometry, 8 );
+
+       #endif
+
+       RE_IndirectDiffuse( irradiance, geometry, material, reflectedLight );
+
+#endif
+
+#if defined( USE_ENVMAP ) && defined( RE_IndirectSpecular )
+
+       // TODO, replace 8 with the real maxMIPLevel
+       vec3 radiance = getLightProbeIndirectRadiance( /*specularLightProbe,*/ geometry, Material_BlinnShininessExponent( material ), 8 );
+
+       #ifndef STANDARD
+               vec3 clearCoatRadiance = getLightProbeIndirectRadiance( /*specularLightProbe,*/ geometry, Material_ClearCoat_BlinnShininessExponent( material ), 8 );
+       #else
+               vec3 clearCoatRadiance = vec3( 0.0 );
+       #endif
+
+       RE_IndirectSpecular( radiance, clearCoatRadiance, geometry, material, reflectedLight );
+
+#endif