implementations/defs.txt

   1 eq [false] [true] [false] cmp
   2 gt [true] [false] [false] cmp
   3 lt [false] [false] [true] cmp
   4 neq [true] [false] [true] cmp
   5 le [false] [true] [true] cmp
   6 ge [true] [true] [false] cmp
   7 ? dup bool
   8 !- 0 >=
   9 ++ 1 +
  10 -- 1 -
  11 <{} [] swap
  12 <<{} [] rollup
  13 abs dup 0 < [] [neg] branch
  14 anamorphism [pop []] swap [dip swons] genrec
  15 and nulco [nullary [false]] dip branch
  16 app1 grba infrst
  17 app2 [grba swap grba swap] dip [infrst] cons ii
  18 app3 3 appN
  19 appN [grabN] codi map reverse disenstacken
  20 at drop first
  21 average [sum] [size] cleave /
  22 b [i] dip i
  23 binary unary popd
  24 ccccons ccons ccons
  25 ccons cons cons
  26 choice [pop] [popd] branch
  27 clear [] swaack pop
  28 cleave fork popdd
  29 clop cleave popdd
  30 cmp [[>] swap] dipd [ifte] ccons [=] swons ifte
  31 codi cons dip
  32 codireco codi reco
  33 dinfrirst dip infrst
  34 dipd [dip] codi
  35 dipdd [dip] cons dipd
  36 dipddd [dipd] cons dipd
  37 disenstacken swaack pop
  38 divmod [/] [%] clop
  39 down_to_zero [0 >] [dup --] while
  40 drop [rest] times
  41 dupdd [dup] dipd
  42 dupd [dup] dip
  43 dupdipd dup dipd
  44 dupdip dupd dip
  45 enstacken stack [clear] dip
  46 first uncons pop
  47 first_two uncons first
  48 flatten <{} [concat] step
  49 fork [i] app2
  50 fourth rest third
  51 gcd true [tuck mod dup 0 >] loop pop
  52 genrec [[genrec] ccccons] nullary swons concat ifte
  53 getitem [rest] times first
  54 grabN <{} [cons] times
  55 grba [stack popd] dip
  56 ifte [nullary] dipd swap branch
  57 ii [dip] dupdip i
  58 infra swons swaack [i] dip swaack
  59 infrst infra first
  60 << lshift
  61 lshift [2 *] times
  62 make_generator [codireco] ccons
  63 mod %
  64 modulus %
  65 neg 0 swap -
  66 not [true] [false] branch
  67 nulco [nullary] cons
  68 nullary [stack] dinfrirst
  69 null _isnt_list bool not
  70 of swap at
  71 or nulco [nullary] dip [true] branch
  72 over [dup] dip swap
  73 pam [i] map
  74 pick getitem
  75 pm [+] [-] clop
  76 popdd [pop] dipd
  77 popd [pop] dip
  78 popopdd [popop] dipd
  79 popopd [popop] dip
  80 popopop pop popop
  81 popop pop pop
  82 pow 1 roll> swap [*] cons times
  83 pred --
  84 product 1 swap [*] step
  85 quoted [unit] dip
  86 range [0 <=] [-- dup] anamorphism
  87 range_to_zero unit [down_to_zero] infra
  88 reco rest cons
  89 rest uncons popd
  90 reverse <{} shunt
  91 rolldown roll<
  92 roll< swapd swap
  93 roll> swap swapd
  94 rollup roll>
  95 rrest rest rest
  96 >> rshift
  97 rshift [2 /] times
  98 run <{} infra
  99 second rest first
 100 shift uncons [swons] dip
 101 shunt [swons] step
 102 select [first] [second] branch
 103 size [pop ++] step_zero
 104 small empty? [rest null] [pop true] branch
 105 spiral_next [[[abs] ii <=] [[<>] [pop !-] or] and] [[!-] [[++]] [[--]] ifte dip] [[pop !-] [--] [++] ifte] ifte
 106 split_at [drop] [take] clop
 107 split_list [take reverse] [drop] clop
 108 sqr dup mul
 109 stackd [stack] dip
 110 step_zero 0 roll> step
 111 stuncons stack uncons
 112 succ --
 113 sum [+] step_zero
 114 swapd [swap] dip
 115 swoncat swap concat
 116 swons swap cons
 117 tailrec [i] genrec
 118 take <<{} [shift] times pop
 119 ternary binary popd
 120 third rest second
 121 tuck dup swapd
 122 unary nullary popd
 123 uncons [first] dupdip rest
 124 unit [] cons
 125 unquoted [i] dip
 126 unstack [[] swaack] dip swoncat swaack pop
 127 unswons uncons swap
 128 while swap nulco dupdipd concat loop
 129 x dup i
 130 step [_step0] x
 131 _step0 _step1 [popopop] [_stept] branch
 132 _step1 [?] dipd roll<
 133 _stept [uncons] dipd [dupdipd] dip x
 134 times [_times0] x
 135 _times0 _times1 [popopop] [_timest] branch
 136 _times1 [dup 0 >] dipd roll<
 137 _timest [[--] dip dupdipd] dip x
 138 map [_map0] cons [[] [_map?] [_mape]] dip tailrec
 139 _map? pop bool not
 140 _mape popd reverse
 141 _map0 [_map1] dipd _map2
 142 _map1 stackd shift
 143 _map2 [infrst] cons dipd roll< swons
 144 _isnt_bool [false] [true] branch
 145 _isnt_two_bools [_isnt_bool] ii
 146 _\/_ [_isnt_bool] [not] branch
 147 /\ _isnt_two_bools [pop false] [] branch
 148 \/ _isnt_two_bools [] [pop true] branch
 149 _isnt_list [] swoncat
 150 zip [null] [pop] [uncons-pair] [i cons] genrec
 151 uncons-pair uncons-two [quote-two] dipd
 152 uncons-two [uncons] ii swapd
 153 quote-two unit cons
 154 empty? dup null
 155 max-of-two [>] [pop] [popd] ifte
 156 max [uncons [max-of-two] step] on-non-empty-list
 157 min-of-two [<] [pop] [popd] ifte
 158 min [uncons [min-of-two] step] on-non-empty-list
 159 on-non-empty-list [empty?] dip [first] branch