implementations/defs.txt

   1 eq [false] [true] [false] cmp
   2 gt [true] [false] [false] cmp
   3 lt [false] [false] [true] cmp
   4 neq [true] [false] [true] cmp
   5 le [false] [true] [true] cmp
   6 ge [true] [true] [false] cmp
   7 -- 1 -
   8 ? dup bool
   9 and nulco [nullary [false]] dip branch
  10 ++ 1 +
  11 or nulco [nullary] dip [true] branch
  12 !- 0 >=
  13 <{} [] swap
  14 <<{} [] rollup
  15 abs dup 0 < [] [neg] branch
  16 anamorphism [pop []] swap [dip swons] genrec
  17 app1 grba infrst
  18 app2 [grba swap grba swap] dip [infrst] cons ii
  19 app3 3 appN
  20 appN [grabN] codi map reverse disenstacken
  21 at drop first
  22 average [sum] [size] cleave /
  23 b [i] dip i
  24 binary unary popd
  25 ccccons ccons ccons
  26 ccons cons cons
  27 clear [] swaack pop
  28 cleave fork popdd
  29 clop cleave popdd
  30 cmp [[>] swap] dipd [ifte] ccons [=] swons ifte
  31 codi cons dip
  32 codireco codi reco
  33 dinfrirst dip infrst
  34 dipd [dip] codi
  35 disenstacken swaack pop
  36 divmod [/] [%] clop
  37 down_to_zero [0 >] [dup --] while
  38 drop [rest] times
  39 dupd [dup] dip
  40 dupdd [dup] dipd
  41 dupdip dupd dip
  42 dupdipd dup dipd
  43 enstacken stack [clear] dip
  44 first uncons pop
  45 flatten <{} [concat] step
  46 fork [i] app2
  47 fourth rest third
  48 gcd true [tuck mod dup 0 >] loop pop
  49 genrec [[genrec] ccccons] nullary swons concat ifte
  50 grabN <{} [cons] times
  51 grba [stack popd] dip
  52 hypot [sqr] ii + sqrt
  53 ifte [nullary] dipd swap branch
  54 ii [dip] dupdip i
  55 infra swons swaack [i] dip swaack
  56 infrst infra first
  57 make_generator [codireco] ccons
  58 mod %
  59 neg 0 swap -
  60 not [true] [false] branch
  61 nulco [nullary] cons
  62 null [] concat bool not
  63 nullary [stack] dinfrirst
  64 of swap at
  65 pam [i] map
  66 pm [+] [-] clop
  67 popd [pop] dip
  68 popdd [pop] dipd
  69 popop pop pop
  70 popopop pop popop
  71 popopd [popop] dip
  72 popopdd [popop] dipd
  73 product 1 swap [*] step
  74 quoted [unit] dip
  75 range [0 <=] [-- dup] anamorphism
  76 range_to_zero unit [down_to_zero] infra
  77 reco rest cons
  78 rest uncons popd
  79 reverse <{} shunt
  80 roll> swap swapd
  81 roll< swapd swap
  82 rollup roll>
  83 rolldown roll<
  84 rrest rest rest
  85 run <{} infra
  86 second rest first
  87 shift uncons [swons] dip
  88 shunt [swons] step
  89 size [pop ++] step_zero
  90 small dup null [rest null] [pop true] branch
  91 spiral_next [[[abs] ii <=] [[<>] [pop !-] or] and] [[!-] [[++]] [[--]] ifte dip] [[pop !-] [--] [++] ifte] ifte
  92 split_at [drop] [take] clop
  93 split_list [take reverse] [drop] clop
  94 sqr dup mul
  95 stackd [stack] dip
  96 step_zero 0 roll> step
  97 stuncons stack uncons
  98 sum [+] step_zero
  99 swapd [swap] dip
 100 swons swap cons
 101 swoncat swap concat
 102 tailrec [i] genrec
 103 take <<{} [shift] times pop
 104 ternary binary popd
 105 third rest second
 106 tuck dup swapd
 107 unary nullary popd
 108 uncons [first] [rest] cleave
 109 unit [] cons
 110 unquoted [i] dip
 111 unstack [[] swaack] dip swoncat swaack pop
 112 unswons uncons swap
 113 while swap nulco dupdipd concat loop
 114 x dup i
 115 step [_step0] x
 116 _step0 _step1 [popopop] [_stept] branch
 117 _step1 [?] dipd roll<
 118 _stept [uncons] dipd [dupdipd] dip x
 119 times [_times0] x
 120 _times0 _times1 [popopop] [_timest] branch
 121 _times1 [dup 0 >] dipd roll<
 122 _timest [[--] dip dupdipd] dip x
 123 map [_map0] cons [[] [_map?] [_mape]] dip tailrec
 124 _map? pop bool not
 125 _mape popd reverse
 126 _map0 [_map1] dipd _map2
 127 _map1 stackd shift
 128 _map2 [infrst] cons dipd roll< swons
 129 _\/_ [not not] [not] branch
 130 /\ [not not] ii [pop false] [] branch
 131 \/ [not not] ii [] [pop true] branch