alter-stable/any/plymouth/PKGBUILD

   1 # Maintainer: Taijian <taijian@posteo.de>
   2 # Contributor: Sebastian Lau <lauseb644@gmail.com>
   3 # Contributor Damian01w <damian01w@gmail.com>
   4 # Contributor: Padfoot <padfoot@exemail.com.au>
   5 #
   6
   7 pkgname=plymouth
   8 pkgver=0.9.5
   9 pkgrel=6
  10 pkgdesc="A graphical boot splash screen with kernel mode-setting support"
  11 url="https://www.freedesktop.org/wiki/Software/Plymouth/"
  12 arch=('i686' 'x86_64')
  13 license=('GPL')
  14
  15 depends=('libdrm' 'pango' 'systemd')
  16 makedepends=('docbook-xsl')
  17 optdepends=('ttf-dejavu: For true type font support'
  18         'xf86-video-fbdev: Support special graphic cards on early startup'
  19         'cantarell-fonts: True Type support for BGRT theme')
  20 conflicts=('plymouth-legacy' 'plymouth-nosystemd')
  21 backup=('etc/plymouth/plymouthd.conf')
  22
  23 options=('!libtool' '!emptydirs')
  24
  25 source=("https://gitlab.freedesktop.org/${pkgname}/${pkgname}/-/archive/${pkgver}/${pkgname}-${pkgver}.tar.gz"
  26        'arch-logo.png'
  27        'plymouth.encrypt_hook'
  28        'plymouth.encrypt_install'
  29        'lxdm-plymouth.service'
  30        'lightdm-plymouth.service'
  31        'slim-plymouth.service'
  32        'sddm-plymouth.service'
  33        'plymouth-deactivate.service'
  34        'plymouth-start.service.in.patch'
  35        'plymouth-start.path'
  36        'plymouth.initcpio_hook'
  37        'plymouth.initcpio_install'
  38        'sd-plymouth.initcpio_install'
  39        'plymouth-quit.service.in.patch'
  40        'plymouth-update-initrd.patch'
  41 )
  42
  43 sha256sums=('55a461003ece0a4daeffb8b7ac2178977c5ce024a7e688d24f6d2230465b50ba'
  44             'de4369ad5a5511b684305e3a882c2c56204696514ea8ccdb556dd656eca062e7'
  45             '7afa97d21444cbac7a6213edda09d9fa73ecbef1a6cea1e745f56669760c6120'
  46             '373ec20fe4c47e693a0c45cc06dd906e35dd1d70a85546bd1d571391de11763a'
  47             '06b31999cf60f49e536c7a12bc1c4f75f2671feb848bf5ccb91a963147e2680d'
  48             '4b7e47fb8d1e00d8b550c1fa21c193480643dfc40965bc7b925657f720bd189f'
  49             '9b5534921c5bf92a9285ba53b323209e812145c204ac5fed6899b7aad78300ef'
  50             'c39f526f7e99173bc8f012900f53257537a25e2d8c19e23df630f1fe9a7627ba'
  51             '3b17ed58b59a4b60d904c60bba52bae7ad685aa8273f6ceaae08a15870c0a9eb'
  52             '3a46f7faced877a913506d59757f0af60ad3d5f0bc365c56ed7ecc7aef75c5eb'
  53             'ce3d62f4c5a1b5c0ccadd15406c7430251d1a42b232721bfbfc747da1b13e3ff'
  54             '2a80e2cad8de428358647677afa166219589d3338c5f94838146c804a29e2769'
  55             '2dd996a86beb1dc1fa5e45a14e98daa8fc505c5d1dff94bc5fdb3246a113d5ca'
  56             '50a32014540c6603910b95ce0e40097089dde11fdde3f502c721b6b160a0b997'
  57             'a1766e3fae000e5158a23b5c01d2c615894e6c3f9923877ccc5ca1bcb36351fa'
  58             '74908ba59cea53c6a9ab67bb6dec1de1616f3851a0fd89bb3c157a1c54e6633a')
  59
  60 prepare() {
  61         cd "$srcdir"/${pkgname}-${pkgver}
  62         patch -p1 -i $srcdir/plymouth-update-initrd.patch
  63         patch -p1 -i $srcdir/plymouth-quit.service.in.patch
  64         patch -p1 -i $srcdir/plymouth-start.service.in.patch
  65 }
  66
  67 build() {
  68         cd "$srcdir"/${pkgname}-${pkgver}
  69
  70         LDFLAGS="$LDFLAGS -ludev" ./autogen.sh \
  71                 --prefix=/usr \
  72                 --exec-prefix=/usr \
  73                 --sysconfdir=/etc \
  74                 --localstatedir=/var \
  75                 --libdir=/usr/lib \
  76                 --libexecdir=/usr/lib \
  77                 --sbindir=/usr/bin \
  78                 --enable-systemd-integration \
  79                 --enable-drm \
  80                 --enable-tracing \
  81                 --enable-pango \
  82                 --enable-gtk=no \
  83                 --with-release-file=/etc/os-release \
  84                 --with-logo=/usr/share/plymouth/arch-logo.png \
  85                 --with-background-color=0x000000 \
  86                 --with-background-start-color-stop=0x000000 \
  87                 --with-background-end-color-stop=0x4D4D4D \
  88                 --without-rhgb-compat-link \
  89                 --without-system-root-install \
  90                 --with-runtimedir=/run
  91
  92         make
  93 }
  94
  95 package() {
  96         cd "$srcdir"/${pkgname}-${pkgver}
  97
  98         make DESTDIR="$pkgdir" install
  99
 100         install -Dm644 "$srcdir/arch-logo.png" "$pkgdir/usr/share/plymouth/arch-logo.png"
 101
 102         install -Dm644 "$srcdir/plymouth.encrypt_hook" "$pkgdir/usr/lib/initcpio/hooks/plymouth-encrypt"
 103         install -Dm644 "$srcdir/plymouth.encrypt_install" "$pkgdir/usr/lib/initcpio/install/plymouth-encrypt"
 104         install -Dm644 "$srcdir/plymouth.initcpio_hook" "$pkgdir/usr/lib/initcpio/hooks/plymouth"
 105         install -Dm644 "$srcdir/plymouth.initcpio_install" "$pkgdir/usr/lib/initcpio/install/plymouth"
 106         install -Dm644 "$srcdir/sd-plymouth.initcpio_install" "$pkgdir/usr/lib/initcpio/install/sd-plymouth"
 107
 108         for i in {sddm,lxdm,slim,lightdm}-plymouth.service; do
 109                 install -Dm644 "$srcdir/$i" "$pkgdir/usr/lib/systemd/system/$i"
 110         done
 111
 112         ln -s "/usr/lib/systemd/system/gdm.service" "$pkgdir/usr/lib/systemd/system/gdm-plymouth.service"
 113
 114         install -Dm644 "$srcdir/plymouth-deactivate.service"    "$pkgdir/usr/lib/systemd/system/plymouth-deactivate.service"
 115         install -Dm644 "$srcdir/plymouth-start.path"    "$pkgdir/usr/lib/systemd/system/plymouth-start.path"
 116         install -Dm644 "$pkgdir/usr/share/plymouth/plymouthd.defaults" "$pkgdir/etc/plymouth/plymouthd.conf"
 117 }