alter-stable/x86_64/libgksu/PKGBUILD

   1 # $Id: PKGBUILD 310007 2017-11-15 14:11:34Z foutrelis $
   2 # Maintainer: Jan de Groot <jgc@archlinux.org>
   3
   4 pkgname=libgksu
   5 pkgver=2.0.12
   6 pkgrel=8
   7 pkgdesc="gksu authorization library"
   8 arch=(x86_64)
   9 url="http://www.nongnu.org/gksu/index.html"
  10 license=(GPL)
  11 depends=('gconf' 'gtk2' 'libgnome-keyring' 'libgtop' 'startup-notification')
  12 makedepends=('intltool' 'gtk-doc')
  13 options=('!emptydirs')
  14 source=(http://people.debian.org/~kov/gksu/${pkgname}-${pkgver}.tar.gz
  15         libgksu-2.0.0-fbsd.patch
  16         libgksu-2.0.12-automake-1.11.2.patch
  17         libgksu-2.0.12-fix-make-3.82.patch
  18         libgksu-2.0.12-notests.patch
  19         libgksu-2.0.12-revert-forkpty.patch
  20         libgksu-2.0.7-libs.patch
  21         libgksu-2.0.7-polinguas.patch)
  22 md5sums=('c7154c8806f791c10e7626ff123049d3'
  23          '063a2b45d8e7cbba898d1db413242da0'
  24          '2eeb34ad9b5bf29e8e2ebf8c8a5a28b6'
  25          'afeaf5caab03d793258d62d60a9bf0f0'
  26          '4179d0487d6032e56b8a925010694c0a'
  27          'aebbe57e5286c654e27cf714cf3b704a'
  28          '58d3a4a9d2ac741951720043ea3f7b5f'
  29          '0b5c3d5d9b32cb3e65d9f0bfbcb11a76')
  30
  31 prepare() {
  32   cd "${srcdir}/${pkgname}-${pkgver}"
  33   patch -Np1 -i "${srcdir}/libgksu-2.0.0-fbsd.patch"
  34   patch -Np1 -i "${srcdir}/libgksu-2.0.7-libs.patch"
  35   patch -Np1 -i "${srcdir}/libgksu-2.0.7-polinguas.patch"
  36   patch -Np1 -i "${srcdir}/libgksu-2.0.12-revert-forkpty.patch"
  37   patch -Np0 -i "${srcdir}/libgksu-2.0.12-fix-make-3.82.patch"
  38   patch -Np1 -i "${srcdir}/libgksu-2.0.12-notests.patch"
  39   patch -Np1 -i "${srcdir}/libgksu-2.0.12-automake-1.11.2.patch"
  40
  41   touch NEWS README
  42
  43   intltoolize --force --copy --automake
  44   autoreconf -fi
  45 }
  46
  47 build() {
  48   cd "${srcdir}/${pkgname}-${pkgver}"
  49   ./configure --prefix=/usr --sysconfdir=/etc \
  50       --localstatedir=/var --disable-static --disable-schemas-install --disable-gtk-doc
  51   sed -i -e 's/ -shared / -Wl,-O1,--as-needed\0/g' libtool
  52   make
  53 }
  54
  55 package() {
  56   cd "${srcdir}/${pkgname}-${pkgver}"
  57   make GCONF_DISABLE_MAKEFILE_SCHEMA_INSTALL=1 DESTDIR="${pkgdir}" install
  58   rm -f ${pkgdir}/usr/lib/*.a
  59   install -m755 -d "${pkgdir}/usr/share/gconf/schemas"
  60   gconf-merge-schema "${pkgdir}/usr/share/gconf/schemas/${pkgname}.schemas" --domain libgksu ${pkgdir}/etc/gconf/schemas/*.schemas
  61   rm -f ${pkgdir}/etc/gconf/schemas/*.schemas
  62 }