SConstruct

   1 #
   2 #       SConstruct (10.09.09)
   3 #       SConscript for all components.
   4 #
   5 #       Copyright (C) 2010-2012  Andrew Nayenko
   6 #
   7 #       This program is free software: you can redistribute it and/or modify
   8 #       it under the terms of the GNU General Public License as published by
   9 #       the Free Software Foundation, either version 3 of the License, or
  10 #       (at your option) any later version.
  11 #
  12 #       This program is distributed in the hope that it will be useful,
  13 #       but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #       MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #       GNU General Public License for more details.
  16 #
  17 #       You should have received a copy of the GNU General Public License
  18 #       along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 import os
  22 import platform
  23 import SCons
  24
  25 env = Environment(**ARGUMENTS)
  26
  27 destdir = env.get('DESTDIR', '/sbin');
  28 targets = []
  29 libs = ['exfat']
  30 libfuse = 'fuse'
  31
  32 if not env.GetOption('clean'):
  33         conf = Configure(env)
  34
  35         if 'CC' in os.environ:
  36                 conf.env.Replace(CC = os.environ['CC'])
  37         if 'CCFLAGS' in os.environ:
  38                 conf.env.Replace(CCFLAGS = os.environ['CCFLAGS'])
  39         # Set default CCFLAGS for known compilers
  40         if not conf.env['CCFLAGS']:
  41                 if conf.env['CC'] == 'gcc':
  42                         conf.env.Replace(CCFLAGS = '-Wall -O2 -ggdb -std=c99')
  43                 elif conf.env['CC'] == 'clang':
  44                         conf.env.Replace(CCFLAGS = '-Wall -O2 -g -std=c99')
  45         if 'CPPFLAGS' in os.environ:
  46                 conf.env.Replace(CPPFLAGS = os.environ['CPPFLAGS'])
  47         conf.env.Append(CPPDEFINES = {'_FILE_OFFSET_BITS' : 64})
  48         conf.env.Append(CPPPATH = ['libexfat'])
  49         if 'LDFLAGS' in os.environ:
  50                 conf.env.Append(LINKFLAGS = os.environ['LDFLAGS'])
  51         conf.env.Append(LIBPATH = ['libexfat'])
  52
  53         # GNU/Linux requires _BSD_SOURCE define for vsyslog(), _XOPEN_SOURCE >= 500
  54         # for pread(), pwrite(), snprintf(), strdup(), etc. Everything needed is
  55         # enabled by _GNU_SOURCE.
  56         if platform.system() == 'Linux':
  57                 conf.env.Append(CPPDEFINES = '_GNU_SOURCE');
  58
  59         # Use 64-bit inode numbers (introduced in Mac OS X 10.5 Leopard). Require
  60         # OSXFUSE (http://osxfuse.github.com).
  61         if platform.system() == 'Darwin':
  62                 conf.env.Append(CPPDEFINES = '_DARWIN_USE_64_BIT_INODE')
  63                 conf.env.Append(CPPDEFINES = {'__DARWIN_UNIX03' : 1})
  64                 conf.env.Append(CPPPATH = ['/usr/local/include/osxfuse'])
  65                 conf.env.Append(CFLAGS    = '-mmacosx-version-min=10.5')
  66                 conf.env.Append(LINKFLAGS = '-mmacosx-version-min=10.5')
  67                 libfuse = 'osxfuse_i64'
  68
  69         # FreeBSD does not support block devices, only raw devices. Ublio is
  70         # required for unaligned I/O and caching.
  71         if platform.system() == 'FreeBSD':
  72                 conf.env.Append(CPPDEFINES = 'USE_UBLIO')
  73                 libs.append('ublio')
  74                 conf.env.Append(CPPPATH = ['/usr/local/include'])
  75                 conf.env.Append(LIBPATH = ['/usr/local/lib'])
  76
  77         if not conf.CheckCC():
  78                 print '''
  79         A working C compiler is needed very much.
  80 '''
  81                 Exit(1)
  82
  83         if not conf.CheckTypeSize('off_t', '#include <sys/types.h>', 'C', 8):
  84                 print '''
  85         The size of off_t type must be 64 bits. File systems larger than
  86         2 GB will be corrupted with 32-bit off_t.
  87 '''
  88                 Exit(1)
  89
  90         env = conf.Finish()
  91
  92
  93
  94 def make_symlink(dir, target, link_name):
  95         workdir = os.getcwd()
  96         os.chdir(dir)
  97         try:
  98                 os.remove(link_name)
  99         except OSError:
 100                 pass
 101         os.symlink(target, link_name)
 102         os.chdir(workdir)
 103
 104 symlink = SCons.Action.ActionFactory(make_symlink,
 105                 lambda dir, target, link_name:
 106                                 'make_symlink("%s", "%s", "%s")' % (dir, target, link_name))
 107
 108 def program(pattern, output, alias, libs):
 109         sources = Glob(pattern)
 110         if not sources:
 111                 return
 112         target = env.Program(output, sources, LIBS = libs)
 113         if alias:
 114                 Clean(Alias('install', Install(destdir, target),
 115                                 symlink(destdir, os.path.basename(output), alias)),
 116                                 destdir + '/' + alias)
 117         else:
 118                 Alias('install', Install(destdir, target))
 119         targets.append(target)
 120
 121 env.Library('libexfat/exfat', Glob('libexfat/*.c'))
 122
 123 program('fuse/*.c', 'fuse/mount.exfat-fuse', 'mount.exfat', [libs + [libfuse]])
 124 program('dump/*.c', 'dump/dumpexfat', None, libs)
 125 program('fsck/*.c', 'fsck/exfatfsck', 'fsck.exfat', libs)
 126 program('mkfs/*.c', 'mkfs/mkexfatfs', 'mkfs.exfat', libs)
 127 program('label/*.c', 'label/exfatlabel', None, libs)
 128
 129 Default(targets)