SConstruct

   1 #
   2 #       SConstruct (10.09.09)
   3 #       SConscript for all components.
   4 #
   5 #       Copyright (C) 2009, 2010  Andrew Nayenko
   6 #
   7 #       This program is free software: you can redistribute it and/or modify
   8 #       it under the terms of the GNU General Public License as published by
   9 #       the Free Software Foundation, either version 3 of the License, or
  10 #       (at your option) any later version.
  11 #
  12 #       This program is distributed in the hope that it will be useful,
  13 #       but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #       MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #       GNU General Public License for more details.
  16 #
  17 #       You should have received a copy of the GNU General Public License
  18 #       along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 import os
  22 import platform
  23 import SCons
  24
  25 env = Environment(**ARGUMENTS)
  26 conf = Configure(env)
  27
  28 destdir = env.get('DESTDIR', '/sbin');
  29 targets = []
  30
  31 if 'CC' in os.environ:
  32         conf.env.Replace(CC = os.environ['CC'])
  33 if 'CCFLAGS' in os.environ:
  34         conf.env.Replace(CCFLAGS = os.environ['CCFLAGS'])
  35 # Set default CCFLAGS for known compilers
  36 if not conf.env['CCFLAGS']:
  37         if conf.env['CC'] == 'gcc':
  38                 conf.env.Replace(CCFLAGS = '-Wall -O2 -ggdb')
  39         elif conf.env['CC'] == 'clang':
  40                 conf.env.Replace(CCFLAGS = '-Wall -O2 -g')
  41 conf.env.Append(CPPDEFINES = {'FUSE_USE_VERSION': 26})
  42 conf.env.Append(CPPDEFINES = {'_FILE_OFFSET_BITS' : 64})
  43 # __DARWIN_64_BIT_INO_T=0 define is needed because since Snow Leopard inode
  44 # numbers are 64-bit by default, but libfuse operates 32-bit ones. This define
  45 # forces 32-bit inode declaration in system headers, but it's also possible to
  46 # link against libfuse_ino64 instead.
  47 if platform.system() == 'Darwin':
  48         conf.env.Append(CPPDEFINES = {'__DARWIN_64_BIT_INO_T' : 0})
  49         conf.env.Append(CPPDEFINES = {'__DARWIN_UNIX03' : 1})
  50 conf.env.Append(CPPPATH = ['libexfat'])
  51 if 'LDFLAGS' in os.environ:
  52         conf.env.Append(LINKFLAGS = os.environ['LDFLAGS'])
  53
  54 env = conf.Finish()
  55
  56 def make_symlink(dir, target, link_name):
  57         workdir = os.getcwd()
  58         os.chdir(dir)
  59         try:
  60                 os.remove(link_name)
  61         except OSError:
  62                 pass
  63         os.symlink(target, link_name)
  64         os.chdir(workdir)
  65
  66 symlink = SCons.Action.ActionFactory(make_symlink,
  67                 lambda dir, target, link_name:
  68                                 'make_symlink("%s", "%s", "%s")' % (dir, target, link_name))
  69
  70 def program(pattern, output, alias = None, lib = None):
  71         sources = Glob(pattern)
  72         if not sources:
  73                 return
  74         libs = ['exfat']
  75         if lib:
  76                 libs.append(lib)
  77         target = env.Program(output, sources, LIBS = libs, LIBPATH = 'libexfat')
  78         if alias:
  79                 Alias('install', Install(destdir, target),
  80                                 symlink(destdir, os.path.basename(output), alias))
  81         else:
  82                 Alias('install', Install(destdir, target))
  83         targets.append(target)
  84
  85 env.Library('libexfat/exfat', Glob('libexfat/*.c'))
  86
  87 program('fuse/*.c', 'fuse/mount.exfat-fuse', 'mount.exfat', ['fuse'])
  88 program('dump/*.c', 'dump/dumpexfat')
  89 program('fsck/*.c', 'fsck/exfatfsck', 'fsck.exfat')
  90 program('mkfs/*.c', 'mkfs/mkexfatfs', 'mkfs.exfat')
  91 program('label/*.c', 'label/exfatlabel')
  92
  93 Default(targets)