SConstruct

   1 #
   2 #       SConstruct (10.09.09)
   3 #       SConscript for all components.
   4 #
   5 #       Copyright (C) 2009, 2010  Andrew Nayenko
   6 #
   7 #       This program is free software: you can redistribute it and/or modify
   8 #       it under the terms of the GNU General Public License as published by
   9 #       the Free Software Foundation, either version 3 of the License, or
  10 #       (at your option) any later version.
  11 #
  12 #       This program is distributed in the hope that it will be useful,
  13 #       but WITHOUT ANY WARRANTY; without even the implied warranty of
  14 #       MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.  See the
  15 #       GNU General Public License for more details.
  16 #
  17 #       You should have received a copy of the GNU General Public License
  18 #       along with this program.  If not, see <http://www.gnu.org/licenses/>.
  19 #
  20
  21 import os
  22 import platform
  23 import SCons
  24
  25 env = Environment(**ARGUMENTS)
  26 conf = Configure(env)
  27
  28 destdir = env.get('DESTDIR', '/sbin');
  29 targets = []
  30 libs = ['exfat']
  31
  32 if 'CC' in os.environ:
  33         conf.env.Replace(CC = os.environ['CC'])
  34 if 'CCFLAGS' in os.environ:
  35         conf.env.Replace(CCFLAGS = os.environ['CCFLAGS'])
  36 # Set default CCFLAGS for known compilers
  37 if not conf.env['CCFLAGS']:
  38         if conf.env['CC'] == 'gcc':
  39                 conf.env.Replace(CCFLAGS = '-Wall -O2 -ggdb')
  40         elif conf.env['CC'] == 'clang':
  41                 conf.env.Replace(CCFLAGS = '-Wall -O2 -g')
  42 if 'CPPFLAGS' in os.environ:
  43         conf.env.Replace(CPPFLAGS = os.environ['CPPFLAGS'])
  44 conf.env.Append(CPPDEFINES = {'FUSE_USE_VERSION': 26})
  45 conf.env.Append(CPPDEFINES = {'_FILE_OFFSET_BITS' : 64})
  46 conf.env.Append(CPPPATH = ['libexfat'])
  47 if 'LDFLAGS' in os.environ:
  48         conf.env.Append(LINKFLAGS = os.environ['LDFLAGS'])
  49 conf.env.Append(LIBPATH = ['libexfat'])
  50
  51 # __DARWIN_64_BIT_INO_T=0 define is needed because since Snow Leopard inode
  52 # numbers are 64-bit by default, but libfuse operates 32-bit ones. This define
  53 # forces 32-bit inode declaration in system headers, but it's also possible to
  54 # link against libfuse_ino64 instead.
  55 if platform.system() == 'Darwin':
  56         conf.env.Append(CPPDEFINES = {'__DARWIN_64_BIT_INO_T' : 0})
  57         conf.env.Append(CPPDEFINES = {'__DARWIN_UNIX03' : 1})
  58
  59 # FreeBSD does not support block devices, only raw devices. Ublio is required
  60 # for unaligned I/O and caching.
  61 if platform.system() == 'FreeBSD':
  62         conf.env.Append(CPPDEFINES = 'USE_UBLIO')
  63         libs.append('ublio')
  64         conf.env.Append(CPPPATH = ['/usr/local/include'])
  65         conf.env.Append(LIBPATH = ['/usr/local/lib'])
  66
  67 env = conf.Finish()
  68
  69 def make_symlink(dir, target, link_name):
  70         workdir = os.getcwd()
  71         os.chdir(dir)
  72         try:
  73                 os.remove(link_name)
  74         except OSError:
  75                 pass
  76         os.symlink(target, link_name)
  77         os.chdir(workdir)
  78
  79 symlink = SCons.Action.ActionFactory(make_symlink,
  80                 lambda dir, target, link_name:
  81                                 'make_symlink("%s", "%s", "%s")' % (dir, target, link_name))
  82
  83 def program(pattern, output, alias, libs):
  84         sources = Glob(pattern)
  85         if not sources:
  86                 return
  87         target = env.Program(output, sources, LIBS = libs)
  88         if alias:
  89                 Alias('install', Install(destdir, target),
  90                                 symlink(destdir, os.path.basename(output), alias))
  91         else:
  92                 Alias('install', Install(destdir, target))
  93         targets.append(target)
  94
  95 env.Library('libexfat/exfat', Glob('libexfat/*.c'))
  96
  97 program('fuse/*.c', 'fuse/mount.exfat-fuse', 'mount.exfat', [libs + ['fuse']])
  98 program('dump/*.c', 'dump/dumpexfat', None, libs)
  99 program('fsck/*.c', 'fsck/exfatfsck', 'fsck.exfat', libs)
 100 program('mkfs/*.c', 'mkfs/mkexfatfs', 'mkfs.exfat', libs)
 101 program('label/*.c', 'label/exfatlabel', None, libs)
 102
 103 Default(targets)