configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.60],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  33
  34 # Enable quiet compiles on automake 1.11.
  35 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  36
  37 # Check for programs
  38 AC_PROG_CC
  39
  40 AC_USE_SYSTEM_EXTENSIONS
  41 AC_SYS_LARGEFILE
  42 AC_FUNC_ALLOCA
  43
  44 AC_CHECK_HEADERS([sys/mkdev.h])
  45
  46 # Initialize libtool
  47 LT_PREREQ([2.2])
  48 LT_INIT([disable-static])
  49
  50
  51 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  52 AC_SUBST(PTHREADSTUBS_CFLAGS)
  53 AC_SUBST(PTHREADSTUBS_LIBS)
  54
  55 pkgconfigdir=${libdir}/pkgconfig
  56 AC_SUBST(pkgconfigdir)
  57 AC_ARG_ENABLE([udev],
  58               [AS_HELP_STRING([--enable-udev],
  59                               [Enable support for using udev instead of mknod (default: disabled)])],
  60               [UDEV=$enableval], [UDEV=no])
  61
  62 AC_ARG_ENABLE(libkms,
  63               AS_HELP_STRING([--disable-libkms],
  64               [Disable KMS mm abstraction library (default: auto, enabled on supported platforms)]),
  65               [LIBKMS=$enableval], [LIBKMS=auto])
  66
  67 AC_ARG_ENABLE(intel,
  68               AS_HELP_STRING([--disable-intel],
  69               [Enable support for intel's KMS API (default: auto, enabled on x86)]),
  70               [INTEL=$enableval], [INTEL=auto])
  71
  72 AC_ARG_ENABLE(radeon,
  73               AS_HELP_STRING([--disable-radeon],
  74               [Enable support for radeon's KMS API (default: auto)]),
  75               [RADEON=$enableval], [RADEON=auto])
  76
  77 AC_ARG_ENABLE(nouveau,
  78               AS_HELP_STRING([--disable-nouveau],
  79               [Enable support for nouveau's KMS API (default: auto)]),
  80               [NOUVEAU=$enableval], [NOUVEAU=auto])
  81
  82 AC_ARG_ENABLE(vmwgfx,
  83               AS_HELP_STRING([--disable-vmwgfx],
  84               [Enable support for vmwgfx's KMS API (default: yes)]),
  85               [VMWGFX=$enableval], [VMWGFX=yes])
  86
  87 AC_ARG_ENABLE(omap-experimental-api,
  88               AS_HELP_STRING([--enable-omap-experimental-api],
  89               [Enable support for OMAP's experimental API (default: disabled)]),
  90               [OMAP=$enableval], [OMAP=no])
  91
  92 AC_ARG_ENABLE(exynos-experimental-api,
  93               AS_HELP_STRING([--enable-exynos-experimental-api],
  94               [Enable support for EXYNOS's experimental API (default: disabled)]),
  95               [EXYNOS=$enableval], [EXYNOS=no])
  96
  97 AC_ARG_ENABLE(freedreno,
  98               AS_HELP_STRING([--disable-freedreno],
  99               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
 100               [FREEDRENO=$enableval], [FREEDRENO=auto])
 101
 102 AC_ARG_ENABLE(freedreno-kgsl,
 103               AS_HELP_STRING([--enable-freedreno-kgsl],
 104               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 105               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 106
 107 AC_ARG_ENABLE(tegra-experimental-api,
 108               AS_HELP_STRING([--enable-tegra-experimental-api],
 109               [Enable support for Tegra's experimental API (default: disabled)]),
 110               [TEGRA=$enableval], [TEGRA=no])
 111
 112 AC_ARG_ENABLE(install-test-programs,
 113                   AS_HELP_STRING([--enable-install-test-programs],
 114                   [Install test programs (default: no)]),
 115                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 116
 117 dnl ===========================================================================
 118 dnl check compiler flags
 119 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 120   AC_MSG_CHECKING([whether $CC supports $1])
 121
 122   libdrm_save_CFLAGS="$CFLAGS"
 123   CFLAGS="$CFLAGS $1"
 124
 125   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 126   CFLAGS="$libdrm_save_CFLAGS"
 127
 128   if test "x$libdrm_cc_flag" = "xyes"; then
 129     ifelse([$2], , :, [$2])
 130   else
 131     ifelse([$3], , :, [$3])
 132   fi
 133   AC_MSG_RESULT([$libdrm_cc_flag])
 134 ])
 135
 136 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 137
 138 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 139                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 140                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 141 AC_SUBST([CLOCK_LIB])
 142
 143 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 144
 145 dnl Use lots of warning flags with with gcc and compatible compilers
 146
 147 dnl Note: if you change the following variable, the cache is automatically
 148 dnl skipped and all flags rechecked.  So there's no need to do anything
 149 dnl else.  If for any reason you need to force a recheck, just change
 150 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 151
 152 MAYBE_WARN="-Wall -Wextra \
 153 -Wsign-compare -Werror-implicit-function-declaration \
 154 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 155 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 156 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 157 -Wstrict-aliasing=2 -Winit-self \
 158 -Wdeclaration-after-statement -Wold-style-definition \
 159 -Wno-missing-field-initializers -Wno-unused-parameter \
 160 -Wno-attributes -Wno-long-long -Winline"
 161
 162 # invalidate cached value if MAYBE_WARN has changed
 163 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 164         unset libdrm_cv_warn_cflags
 165 fi
 166 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 167         echo
 168         WARN_CFLAGS=""
 169
 170         # Some warning options are not supported by all versions of
 171         # gcc, so test all desired options against the current
 172         # compiler.
 173         #
 174         # Note that there are some order dependencies
 175         # here. Specifically, an option that disables a warning will
 176         # have no net effect if a later option then enables that
 177         # warnings, (perhaps implicitly). So we put some grouped
 178         # options (-Wall and -Wextra) up front and the -Wno options
 179         # last.
 180
 181         for W in $MAYBE_WARN; do
 182                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 183         done
 184
 185         libdrm_cv_warn_cflags=$WARN_CFLAGS
 186         libdrm_cv_warn_maybe=$MAYBE_WARN
 187
 188         AC_MSG_CHECKING([which warning flags were supported])])
 189 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 190
 191 # Check for atomic intrinsics
 192 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 193         drm_cv_atomic_primitives="none"
 194
 195         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 196         int atomic_add(int i) { return __sync_fetch_and_add (&i, 1); }
 197         int atomic_cmpxchg(int i, int j, int k) { return __sync_val_compare_and_swap (&i, j, k); }
 198                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 199
 200         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 201                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 202         fi
 203
 204         # atomic functions defined in <atomic.h> & libc on Solaris
 205         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 206                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 207         fi
 208 ])
 209
 210 if test "x$drm_cv_atomic_primitives" = xIntel; then
 211         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 212                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 213 fi
 214 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 215         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 216 fi
 217
 218 dnl Print out the approapriate message considering the value set be the
 219 dnl respective in $1.
 220 dnl $1 - value to be evaluated. Eg. $INTEL, $NOUVEAU, ...
 221 dnl $2 - libdrm shortname. Eg. intel, freedreno, ...
 222 dnl $3 - GPU name/brand. Eg. Intel, NVIDIA Tegra, ...
 223 dnl $4 - Configure switch. Eg. intel, omap-experimental-api, ...
 224 AC_DEFUN([LIBDRM_ATOMICS_NOT_FOUND_MSG], [
 225         case "x$1" in
 226                 xyes)   AC_MSG_ERROR([libdrm_$2 depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for $3 GPUs by passing --disable-$4 to ./configure]) ;;
 227                 xauto)  AC_MSG_WARN([Disabling $2. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.]) ;;
 228                 *)      ;;
 229         esac
 230 ])
 231
 232 if test "x$drm_cv_atomic_primitives" = "xnone"; then
 233         LIBDRM_ATOMICS_NOT_FOUND_MSG($INTEL, intel, Intel, intel)
 234         INTEL=no
 235
 236         LIBDRM_ATOMICS_NOT_FOUND_MSG($RADEON, radeon, Radeon, radeon)
 237         RADEON=no
 238
 239         LIBDRM_ATOMICS_NOT_FOUND_MSG($NOUVEAU, nouveau, NVIDIA, nouveau)
 240         NOUVEAU=no
 241
 242         LIBDRM_ATOMICS_NOT_FOUND_MSG($OMAP, omap, OMAP, omap-experimental-api)
 243         OMAP=no
 244
 245         LIBDRM_ATOMICS_NOT_FOUND_MSG($FREEDRENO, freedreno, Qualcomm Adreno, freedreno)
 246         FREEDRENO=no
 247
 248         LIBDRM_ATOMICS_NOT_FOUND_MSG($TEGRA, tegra, NVIDIA Tegra, tegra-experimental-api)
 249         TEGRA=no
 250 else
 251         if test "x$INTEL" = xauto; then
 252                 case $host_cpu in
 253                         i?86|x86_64)    INTEL=yes ;;
 254                         *)              INTEL=no ;;
 255                 esac
 256         fi
 257         if test "x$RADEON" = xauto; then
 258                 RADEON=yes
 259         fi
 260         if test "x$NOUVEAU" = xauto; then
 261                 NOUVEAU=yes
 262         fi
 263         if test "x$FREEDRENO" = xauto; then
 264                 case $host_cpu in
 265                         arm*|aarch64)   FREEDRENO=yes ;;
 266                         *)              FREEDRENO=no ;;
 267                 esac
 268         fi
 269 fi
 270
 271 if test "x$INTEL" != "xno"; then
 272         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 273 fi
 274 AC_SUBST(PCIACCESS_CFLAGS)
 275 AC_SUBST(PCIACCESS_LIBS)
 276
 277 if test "x$UDEV" = xyes; then
 278         AC_DEFINE(UDEV, 1, [Have UDEV support])
 279 fi
 280
 281 AC_CANONICAL_HOST
 282 if test "x$LIBKMS" = xauto ; then
 283         case $host_os in
 284                 linux*)         LIBKMS="yes" ;;
 285                 freebsd* | kfreebsd*-gnu)
 286                                 LIBKMS="yes" ;;
 287                 dragonfly*)     LIBKMS="yes" ;;
 288                 *)              LIBKMS="no" ;;
 289         esac
 290 fi
 291
 292 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 293
 294 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 295 if test "x$INTEL" = xyes; then
 296         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 297 fi
 298
 299 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 300 if test "x$VMWGFX" = xyes; then
 301         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 302 fi
 303
 304 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 305 if test "x$NOUVEAU" = xyes; then
 306         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 307 fi
 308
 309 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 310 if test "x$OMAP" = xyes; then
 311         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 312 fi
 313
 314 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 315 if test "x$EXYNOS" = xyes; then
 316         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 317 fi
 318
 319 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 320 if test "x$FREEDRENO" = xyes; then
 321         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 322 fi
 323
 324 if test "x$FREEDRENO_KGSL" = xyes; then
 325         if test "x$FREEDRENO" != xyes; then
 326                 AC_MSG_ERROR([Cannot enable freedreno KGSL interface if freedreno is disabled])
 327         fi
 328 fi
 329 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 330 if test "x$FREEDRENO_KGSL" = xyes; then
 331         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 332 fi
 333
 334 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 335 if test "x$RADEON" = xyes; then
 336         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 337 fi
 338
 339 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 340 if test "x$TEGRA" = xyes; then
 341         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 342 fi
 343
 344 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 345 if test "x$INSTALL_TESTS" = xyes; then
 346         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 347 fi
 348
 349 AC_ARG_ENABLE([cairo-tests],
 350               [AS_HELP_STRING([--enable-cairo-tests],
 351                               [Enable support for Cairo rendering in tests (default: auto)])],
 352               [CAIRO=$enableval], [CAIRO=auto])
 353 PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 354 AC_MSG_CHECKING([whether to enable Cairo tests])
 355 if test "x$CAIRO" = xauto; then
 356         CAIRO="$HAVE_CAIRO"
 357 fi
 358 if test "x$CAIRO" = xyes; then
 359         if ! test "x$HAVE_CAIRO" = xyes; then
 360                 AC_MSG_ERROR([Cairo support required but not present])
 361         fi
 362         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 363 fi
 364 AC_MSG_RESULT([$CAIRO])
 365 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 366
 367 # For enumerating devices in test case
 368 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 369 if test "x$HAVE_LIBUDEV" = xyes; then
 370         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 371 fi
 372 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 373
 374 # xsltproc for docbook manpages
 375 AC_ARG_ENABLE([manpages],
 376               AS_HELP_STRING([--disable-manpages], [disable manpages @<:@default=enabled@:>@]),
 377               [MANS=$enableval], [MANS=auto])
 378 AC_PATH_PROG(XSLTPROC, xsltproc)
 379 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 380
 381 # check for offline man-pages stylesheet
 382 AC_MSG_CHECKING([for docbook manpages stylesheet])
 383 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 384 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 385                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 386                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 387 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 388         AC_SUBST(MANPAGES_STYLESHEET)
 389         AC_MSG_RESULT([yes])
 390 else
 391         AC_MSG_RESULT([no])
 392 fi
 393 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 394
 395 PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 396 if test "x$have_valgrind" = "xyes"; then
 397         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 398 fi
 399
 400 AC_ARG_WITH([kernel-source],
 401             [AS_HELP_STRING([--with-kernel-source],
 402               [specify path to linux kernel source])],
 403             [kernel_source="$with_kernel_source"])
 404 AC_SUBST(kernel_source)
 405
 406 dnl Add flags for gcc and g++
 407 if test "x$GCC" = xyes; then
 408     # Enable -fvisibility=hidden if using a gcc that supports it
 409     save_CFLAGS="$CFLAGS"
 410     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 411     VISIBILITY_CFLAGS="-fvisibility=hidden"
 412     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 413     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 414                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 415
 416     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 417     CFLAGS=$save_CFLAGS
 418     AC_SUBST([VISIBILITY_CFLAGS])
 419 fi
 420
 421 AC_MSG_CHECKING([whether $CC supports __attribute__((visibility))])
 422 AC_LINK_IFELSE([AC_LANG_PROGRAM([
 423     int foo_default( void ) __attribute__((visibility("default")));
 424     int foo_hidden( void ) __attribute__((visibility("hidden")));
 425 ])], HAVE_ATTRIBUTE_VISIBILITY="yes"; AC_MSG_RESULT([yes]), AC_MSG_RESULT([no]));
 426
 427 if test "x$HAVE_ATTRIBUTE_VISIBILITY" = xyes; then
 428     AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler supports __attribute__((visibility))])
 429 fi
 430
 431 AC_SUBST(WARN_CFLAGS)
 432 AC_CONFIG_FILES([
 433         Makefile
 434         libkms/Makefile
 435         libkms/libkms.pc
 436         intel/Makefile
 437         intel/libdrm_intel.pc
 438         radeon/Makefile
 439         radeon/libdrm_radeon.pc
 440         nouveau/Makefile
 441         nouveau/libdrm_nouveau.pc
 442         omap/Makefile
 443         omap/libdrm_omap.pc
 444         exynos/Makefile
 445         exynos/libdrm_exynos.pc
 446         freedreno/Makefile
 447         freedreno/libdrm_freedreno.pc
 448         tegra/Makefile
 449         tegra/libdrm_tegra.pc
 450         tests/Makefile
 451         tests/modeprint/Makefile
 452         tests/modetest/Makefile
 453         tests/kmstest/Makefile
 454         tests/proptest/Makefile
 455         tests/radeon/Makefile
 456         tests/vbltest/Makefile
 457         tests/exynos/Makefile
 458         tests/tegra/Makefile
 459         tests/nouveau/Makefile
 460         man/Makefile
 461         libdrm.pc])
 462 AC_OUTPUT
 463
 464 echo ""
 465 echo "$PACKAGE_STRING will be compiled with:"
 466 echo ""
 467 echo "  libkms         $LIBKMS"
 468 echo "  Intel API      $INTEL"
 469 echo "  vmwgfx API     $VMWGFX"
 470 echo "  Radeon API     $RADEON"
 471 echo "  Nouveau API    $NOUVEAU"
 472 echo "  OMAP API       $OMAP"
 473 echo "  EXYNOS API     $EXYNOS"
 474 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 475 echo "  Tegra API      $TEGRA"
 476 echo ""