configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.73],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Require xorg-macros minimum of 1.12 for XORG_WITH_XSLTPROC
  33 m4_ifndef([XORG_MACROS_VERSION],
  34           [m4_fatal([must install xorg-macros 1.12 or later before running autoconf/autogen])])
  35 XORG_MACROS_VERSION(1.12)
  36 XORG_WITH_XSLTPROC
  37 XORG_MANPAGE_SECTIONS
  38
  39 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  40
  41 # Enable quiet compiles on automake 1.11.
  42 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  43
  44 # Check for programs
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47
  48 if test "x$ac_cv_prog_cc_c99" = xno; then
  49         AC_MSG_ERROR([Building libdrm requires C99 enabled compiler])
  50 fi
  51
  52 AC_USE_SYSTEM_EXTENSIONS
  53 AC_SYS_LARGEFILE
  54 AC_FUNC_ALLOCA
  55
  56 AC_HEADER_MAJOR
  57 AC_CHECK_HEADERS([sys/sysctl.h sys/select.h])
  58
  59 # Initialize libtool
  60 LT_PREREQ([2.2])
  61 LT_INIT([disable-static])
  62
  63
  64 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  65 AC_SUBST(PTHREADSTUBS_CFLAGS)
  66 AC_SUBST(PTHREADSTUBS_LIBS)
  67
  68 pkgconfigdir=${libdir}/pkgconfig
  69 AC_SUBST(pkgconfigdir)
  70 AC_ARG_ENABLE([udev],
  71               [AS_HELP_STRING([--enable-udev],
  72                               [Enable support for using udev instead of mknod (default: disabled)])],
  73               [UDEV=$enableval], [UDEV=no])
  74
  75 AC_ARG_ENABLE(libkms,
  76               AS_HELP_STRING([--disable-libkms],
  77               [Disable KMS mm abstraction library (default: auto, enabled on supported platforms)]),
  78               [LIBKMS=$enableval], [LIBKMS=auto])
  79
  80 AC_ARG_ENABLE(intel,
  81               AS_HELP_STRING([--disable-intel],
  82               [Enable support for intel's KMS API (default: auto, enabled on x86)]),
  83               [INTEL=$enableval], [INTEL=auto])
  84
  85 AC_ARG_ENABLE(radeon,
  86               AS_HELP_STRING([--disable-radeon],
  87               [Enable support for radeon's KMS API (default: auto)]),
  88               [RADEON=$enableval], [RADEON=auto])
  89
  90 AC_ARG_ENABLE(amdgpu,
  91               AS_HELP_STRING([--disable-amdgpu],
  92               [Enable support for amdgpu's KMS API (default: auto)]),
  93               [AMDGPU=$enableval], [AMDGPU=auto])
  94
  95 AC_ARG_ENABLE(nouveau,
  96               AS_HELP_STRING([--disable-nouveau],
  97               [Enable support for nouveau's KMS API (default: auto)]),
  98               [NOUVEAU=$enableval], [NOUVEAU=auto])
  99
 100 AC_ARG_ENABLE(vmwgfx,
 101               AS_HELP_STRING([--disable-vmwgfx],
 102               [Enable support for vmwgfx's KMS API (default: yes)]),
 103               [VMWGFX=$enableval], [VMWGFX=yes])
 104
 105 AC_ARG_ENABLE(omap-experimental-api,
 106               AS_HELP_STRING([--enable-omap-experimental-api],
 107               [Enable support for OMAP's experimental API (default: disabled)]),
 108               [OMAP=$enableval], [OMAP=no])
 109
 110 AC_ARG_ENABLE(exynos-experimental-api,
 111               AS_HELP_STRING([--enable-exynos-experimental-api],
 112               [Enable support for EXYNOS's experimental API (default: disabled)]),
 113               [EXYNOS=$enableval], [EXYNOS=no])
 114
 115 AC_ARG_ENABLE(freedreno,
 116               AS_HELP_STRING([--disable-freedreno],
 117               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
 118               [FREEDRENO=$enableval], [FREEDRENO=auto])
 119
 120 AC_ARG_ENABLE(freedreno-kgsl,
 121               AS_HELP_STRING([--enable-freedreno-kgsl],
 122               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 123               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 124
 125 AC_ARG_ENABLE(tegra-experimental-api,
 126               AS_HELP_STRING([--enable-tegra-experimental-api],
 127               [Enable support for Tegra's experimental API (default: disabled)]),
 128               [TEGRA=$enableval], [TEGRA=no])
 129
 130 AC_ARG_ENABLE(vc4,
 131               AS_HELP_STRING([--disable-vc4],
 132               [Enable support for vc4's API (default: auto, enabled on arm)]),
 133               [VC4=$enableval], [VC4=auto])
 134
 135 AC_ARG_ENABLE(etnaviv-experimental-api,
 136               AS_HELP_STRING([--enable-etnaviv-experimental-api],
 137               [Enable support for etnaviv's experimental API (default: disabled)]),
 138               [ETNAVIV=$enableval], [ETNAVIV=no])
 139
 140 AC_ARG_ENABLE(install-test-programs,
 141                   AS_HELP_STRING([--enable-install-test-programs],
 142                   [Install test programs (default: no)]),
 143                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 144
 145 dnl ===========================================================================
 146 dnl check compiler flags
 147 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 148   AC_MSG_CHECKING([whether $CC supports $1])
 149
 150   libdrm_save_CFLAGS="$CFLAGS"
 151   CFLAGS="$CFLAGS $1"
 152
 153   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 154   CFLAGS="$libdrm_save_CFLAGS"
 155
 156   if test "x$libdrm_cc_flag" = "xyes"; then
 157     ifelse([$2], , :, [$2])
 158   else
 159     ifelse([$3], , :, [$3])
 160   fi
 161   AC_MSG_RESULT([$libdrm_cc_flag])
 162 ])
 163
 164 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 165
 166 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 167                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 168                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 169 AC_SUBST([CLOCK_LIB])
 170
 171 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 172
 173 dnl Use lots of warning flags with with gcc and compatible compilers
 174
 175 dnl Note: if you change the following variable, the cache is automatically
 176 dnl skipped and all flags rechecked.  So there's no need to do anything
 177 dnl else.  If for any reason you need to force a recheck, just change
 178 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 179
 180 MAYBE_WARN="-Wall -Wextra \
 181 -Wsign-compare -Werror-implicit-function-declaration \
 182 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 183 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 184 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 185 -Wstrict-aliasing=2 -Winit-self \
 186 -Wdeclaration-after-statement -Wold-style-definition \
 187 -Wno-unused-parameter \
 188 -Wno-attributes -Wno-long-long -Winline -Wshadow \
 189 -Wno-missing-field-initializers"
 190
 191 # invalidate cached value if MAYBE_WARN has changed
 192 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 193         unset libdrm_cv_warn_cflags
 194 fi
 195 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 196         echo
 197         WARN_CFLAGS=""
 198
 199         # Some warning options are not supported by all versions of
 200         # gcc, so test all desired options against the current
 201         # compiler.
 202         #
 203         # Note that there are some order dependencies
 204         # here. Specifically, an option that disables a warning will
 205         # have no net effect if a later option then enables that
 206         # warnings, (perhaps implicitly). So we put some grouped
 207         # options (-Wall and -Wextra) up front and the -Wno options
 208         # last.
 209
 210         for W in $MAYBE_WARN; do
 211                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 212         done
 213
 214         libdrm_cv_warn_cflags=$WARN_CFLAGS
 215         libdrm_cv_warn_maybe=$MAYBE_WARN
 216
 217         AC_MSG_CHECKING([which warning flags were supported])])
 218 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 219
 220 # Check for atomic intrinsics
 221 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 222         drm_cv_atomic_primitives="none"
 223
 224         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 225         int atomic_add(int *i) { return __sync_add_and_fetch (i, 1); }
 226         int atomic_cmpxchg(int *i, int j, int k) { return __sync_val_compare_and_swap (i, j, k); }
 227                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 228
 229         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 230                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 231         fi
 232
 233         # atomic functions defined in <atomic.h> & libc on Solaris
 234         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 235                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 236         fi
 237 ])
 238
 239 if test "x$drm_cv_atomic_primitives" = xIntel; then
 240         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 241                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 242 fi
 243 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 244         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 245 fi
 246
 247 dnl Print out the approapriate message considering the value set be the
 248 dnl respective in $1.
 249 dnl $1 - value to be evaluated. Eg. $INTEL, $NOUVEAU, ...
 250 dnl $2 - libdrm shortname. Eg. intel, freedreno, ...
 251 dnl $3 - GPU name/brand. Eg. Intel, NVIDIA Tegra, ...
 252 dnl $4 - Configure switch. Eg. intel, omap-experimental-api, ...
 253 AC_DEFUN([LIBDRM_ATOMICS_NOT_FOUND_MSG], [
 254         case "x$1" in
 255                 xyes)   AC_MSG_ERROR([libdrm_$2 depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for $3 GPUs by passing --disable-$4 to ./configure]) ;;
 256                 xauto)  AC_MSG_WARN([Disabling $2. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.]) ;;
 257                 *)      ;;
 258         esac
 259 ])
 260
 261 if test "x$drm_cv_atomic_primitives" = "xnone"; then
 262         LIBDRM_ATOMICS_NOT_FOUND_MSG($INTEL, intel, Intel, intel)
 263         INTEL=no
 264
 265         LIBDRM_ATOMICS_NOT_FOUND_MSG($RADEON, radeon, Radeon, radeon)
 266         RADEON=no
 267
 268         LIBDRM_ATOMICS_NOT_FOUND_MSG($AMDGPU, amdgpu, AMD, amdgpu)
 269         AMDGPU=no
 270
 271         LIBDRM_ATOMICS_NOT_FOUND_MSG($NOUVEAU, nouveau, NVIDIA, nouveau)
 272         NOUVEAU=no
 273
 274         LIBDRM_ATOMICS_NOT_FOUND_MSG($OMAP, omap, OMAP, omap-experimental-api)
 275         OMAP=no
 276
 277         LIBDRM_ATOMICS_NOT_FOUND_MSG($FREEDRENO, freedreno, Qualcomm Adreno, freedreno)
 278         FREEDRENO=no
 279
 280         LIBDRM_ATOMICS_NOT_FOUND_MSG($TEGRA, tegra, NVIDIA Tegra, tegra-experimental-api)
 281         TEGRA=no
 282
 283         LIBDRM_ATOMICS_NOT_FOUND_MSG($ETNAVIV, etnaviv, Vivante, etnaviv-experimental-api)
 284         ETNAVIV=no
 285 else
 286         if test "x$INTEL" = xauto; then
 287                 case $host_cpu in
 288                         i?86|x86_64)    INTEL=yes ;;
 289                         *)              INTEL=no ;;
 290                 esac
 291         fi
 292         if test "x$RADEON" = xauto; then
 293                 RADEON=yes
 294         fi
 295         if test "x$AMDGPU" = xauto; then
 296                 AMDGPU=yes
 297         fi
 298         if test "x$NOUVEAU" = xauto; then
 299                 NOUVEAU=yes
 300         fi
 301         if test "x$FREEDRENO" = xauto; then
 302                 case $host_cpu in
 303                         arm*|aarch64)   FREEDRENO=yes ;;
 304                         *)              FREEDRENO=no ;;
 305                 esac
 306         fi
 307         if test "x$VC4" = xauto; then
 308                 case $host_cpu in
 309                         arm*|aarch64)   VC4=yes ;;
 310                         *)              VC4=no ;;
 311                 esac
 312         fi
 313 fi
 314
 315 if test "x$INTEL" != "xno"; then
 316         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 317 fi
 318 AC_SUBST(PCIACCESS_CFLAGS)
 319 AC_SUBST(PCIACCESS_LIBS)
 320
 321 if test "x$UDEV" = xyes; then
 322         AC_DEFINE(UDEV, 1, [Have UDEV support])
 323 fi
 324
 325 AC_CANONICAL_HOST
 326 if test "x$LIBKMS" = xauto ; then
 327         case $host_os in
 328                 linux*)         LIBKMS="yes" ;;
 329                 freebsd* | kfreebsd*-gnu)
 330                                 LIBKMS="yes" ;;
 331                 dragonfly*)     LIBKMS="yes" ;;
 332                 *)              LIBKMS="no" ;;
 333         esac
 334 fi
 335
 336 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 337
 338 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 339 if test "x$INTEL" = xyes; then
 340         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 341 fi
 342
 343 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 344 if test "x$VMWGFX" = xyes; then
 345         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 346 fi
 347
 348 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 349 if test "x$NOUVEAU" = xyes; then
 350         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 351 fi
 352
 353 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 354 if test "x$OMAP" = xyes; then
 355         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 356 fi
 357
 358 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 359 if test "x$EXYNOS" = xyes; then
 360         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 361 fi
 362
 363 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 364 if test "x$FREEDRENO" = xyes; then
 365         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 366 fi
 367
 368 if test "x$FREEDRENO_KGSL" = xyes; then
 369         if test "x$FREEDRENO" != xyes; then
 370                 AC_MSG_ERROR([Cannot enable freedreno KGSL interface if freedreno is disabled])
 371         fi
 372 fi
 373 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 374 if test "x$FREEDRENO_KGSL" = xyes; then
 375         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 376 fi
 377
 378 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 379 if test "x$RADEON" = xyes; then
 380         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 381 fi
 382
 383 if test "x$AMDGPU" != xno; then
 384         # Detect cunit library
 385         PKG_CHECK_MODULES([CUNIT], [cunit >= 2.1], [have_cunit=yes], [have_cunit=no])
 386         # If pkg-config does not find cunit, check it using AC_CHECK_LIB.  We
 387         # do this because Debian (Ubuntu) lacks pkg-config file for cunit.
 388         # fixed in 2.1-2.dfsg-3: http://anonscm.debian.org/cgit/collab-maint/cunit.git/commit/?h=debian
 389         if test "x${have_cunit}" = "xno"; then
 390                 AC_CHECK_LIB([cunit], [CU_initialize_registry], [have_cunit=yes], [have_cunit=no])
 391                 if test "x${have_cunit}" = "xyes"; then
 392                         CUNIT_LIBS="-lcunit"
 393                         CUNIT_CFLAGS=""
 394                         AC_SUBST([CUNIT_LIBS])
 395                         AC_SUBST([CUNIT_CFLAGS])
 396                 fi
 397         fi
 398 else
 399         have_cunit=no
 400 fi
 401 AM_CONDITIONAL(HAVE_CUNIT, [test "x$have_cunit" != "xno"])
 402
 403 AM_CONDITIONAL(HAVE_AMDGPU, [test "x$AMDGPU" = xyes])
 404 if test "x$AMDGPU" = xyes; then
 405         AC_DEFINE(HAVE_AMDGPU, 1, [Have amdgpu support])
 406
 407         AC_DEFINE(HAVE_CUNIT, [test "x$have_cunit" != "xno"], [Enable CUNIT Have amdgpu support])
 408
 409         if test "x$have_cunit" = "xno"; then
 410                 AC_MSG_WARN([Could not find cunit library. Disabling amdgpu tests])
 411         fi
 412 fi
 413
 414 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 415 if test "x$TEGRA" = xyes; then
 416         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 417 fi
 418
 419 AM_CONDITIONAL(HAVE_VC4, [test "x$VC4" = xyes])
 420 if test "x$VC4" = xyes; then
 421         AC_DEFINE(HAVE_VC4, 1, [Have VC4 support])
 422 fi
 423
 424 AM_CONDITIONAL(HAVE_ETNAVIV, [test "x$ETNAVIV" = xyes])
 425 if test "x$ETNAVIV" = xyes; then
 426         AC_DEFINE(HAVE_ETNAVIV, 1, [Have etnaviv support])
 427 fi
 428
 429 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 430 if test "x$INSTALL_TESTS" = xyes; then
 431         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 432 fi
 433
 434 AC_ARG_ENABLE([cairo-tests],
 435               [AS_HELP_STRING([--enable-cairo-tests],
 436                               [Enable support for Cairo rendering in tests (default: auto)])],
 437               [CAIRO=$enableval], [CAIRO=auto])
 438 if test "x$CAIRO" != xno; then
 439         PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 440 fi
 441 AC_MSG_CHECKING([whether to enable Cairo tests])
 442 if test "x$CAIRO" = xauto; then
 443         CAIRO="$HAVE_CAIRO"
 444 fi
 445 if test "x$CAIRO" = xyes; then
 446         if ! test "x$HAVE_CAIRO" = xyes; then
 447                 AC_MSG_ERROR([Cairo support required but not present])
 448         fi
 449         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 450 fi
 451 AC_MSG_RESULT([$CAIRO])
 452 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 453
 454 # For enumerating devices in test case
 455 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 456 if test "x$HAVE_LIBUDEV" = xyes; then
 457         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 458 fi
 459 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 460
 461 # xsltproc for docbook manpages
 462 AC_ARG_ENABLE([manpages],
 463               AS_HELP_STRING([--enable-manpages], [enable manpages @<:@default=auto@:>@]),
 464               [MANS=$enableval], [MANS=auto])
 465 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 466
 467 # check for offline man-pages stylesheet
 468 AC_MSG_CHECKING([for docbook manpages stylesheet])
 469 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 470 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 471                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 472                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 473 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 474         AC_SUBST(MANPAGES_STYLESHEET)
 475         AC_MSG_RESULT([yes])
 476 else
 477         AC_MSG_RESULT([no])
 478 fi
 479 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 480
 481 AC_ARG_ENABLE(valgrind,
 482               [AS_HELP_STRING([--enable-valgrind],
 483                              [Build libdrm with  valgrind support (default: auto)])],
 484                              [VALGRIND=$enableval], [VALGRIND=auto])
 485 if test "x$VALGRIND" != xno; then
 486         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 487 fi
 488 AC_MSG_CHECKING([whether to enable Valgrind support])
 489 if test "x$VALGRIND" = xauto; then
 490         VALGRIND="$have_valgrind"
 491 fi
 492
 493 if test "x$VALGRIND" = "xyes"; then
 494         if ! test "x$have_valgrind" = xyes; then
 495                 AC_MSG_ERROR([Valgrind support required but not present])
 496         fi
 497         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 498 fi
 499
 500 AC_MSG_RESULT([$VALGRIND])
 501
 502 AC_ARG_WITH([kernel-source],
 503             [AS_HELP_STRING([--with-kernel-source],
 504               [specify path to linux kernel source])],
 505             [kernel_source="$with_kernel_source"])
 506 AC_SUBST(kernel_source)
 507
 508 AC_MSG_CHECKING([whether $CC supports __attribute__(("hidden"))])
 509 AC_LINK_IFELSE([AC_LANG_PROGRAM([
 510     int foo_hidden( void ) __attribute__((visibility("hidden")));
 511 ])], HAVE_ATTRIBUTE_VISIBILITY="yes"; AC_MSG_RESULT([yes]), AC_MSG_RESULT([no]));
 512
 513 if test "x$HAVE_ATTRIBUTE_VISIBILITY" = xyes; then
 514     AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler supports __attribute__(("hidden"))])
 515 fi
 516
 517 AC_SUBST(WARN_CFLAGS)
 518 AC_CONFIG_FILES([
 519         Makefile
 520         libkms/Makefile
 521         libkms/libkms.pc
 522         intel/Makefile
 523         intel/libdrm_intel.pc
 524         radeon/Makefile
 525         radeon/libdrm_radeon.pc
 526         amdgpu/Makefile
 527         amdgpu/libdrm_amdgpu.pc
 528         nouveau/Makefile
 529         nouveau/libdrm_nouveau.pc
 530         omap/Makefile
 531         omap/libdrm_omap.pc
 532         exynos/Makefile
 533         exynos/libdrm_exynos.pc
 534         freedreno/Makefile
 535         freedreno/libdrm_freedreno.pc
 536         tegra/Makefile
 537         tegra/libdrm_tegra.pc
 538         vc4/Makefile
 539         vc4/libdrm_vc4.pc
 540         etnaviv/Makefile
 541         etnaviv/libdrm_etnaviv.pc
 542         tests/Makefile
 543         tests/modeprint/Makefile
 544         tests/modetest/Makefile
 545         tests/kms/Makefile
 546         tests/kmstest/Makefile
 547         tests/proptest/Makefile
 548         tests/radeon/Makefile
 549         tests/amdgpu/Makefile
 550         tests/vbltest/Makefile
 551         tests/exynos/Makefile
 552         tests/tegra/Makefile
 553         tests/nouveau/Makefile
 554         tests/etnaviv/Makefile
 555         tests/util/Makefile
 556         man/Makefile
 557         libdrm.pc])
 558 AC_OUTPUT
 559
 560 echo ""
 561 echo "$PACKAGE_STRING will be compiled with:"
 562 echo ""
 563 echo "  libkms         $LIBKMS"
 564 echo "  Intel API      $INTEL"
 565 echo "  vmwgfx API     $VMWGFX"
 566 echo "  Radeon API     $RADEON"
 567 echo "  AMDGPU API     $AMDGPU"
 568 echo "  Nouveau API    $NOUVEAU"
 569 echo "  OMAP API       $OMAP"
 570 echo "  EXYNOS API     $EXYNOS"
 571 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 572 echo "  Tegra API      $TEGRA"
 573 echo "  VC4 API        $VC4"
 574 echo "  Etnaviv API    $ETNAVIV"
 575 echo ""