configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.68],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31
  32 # Require xorg-macros minimum of 1.12 for XORG_WITH_XSLTPROC
  33 m4_ifndef([XORG_MACROS_VERSION],
  34           [m4_fatal([must install xorg-macros 1.12 or later before running autoconf/autogen])])
  35 XORG_MACROS_VERSION(1.12)
  36 XORG_WITH_XSLTPROC
  37 XORG_MANPAGE_SECTIONS
  38
  39 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  40
  41 # Enable quiet compiles on automake 1.11.
  42 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  43
  44 # Check for programs
  45 AC_PROG_CC
  46 AC_PROG_CC_C99
  47
  48 if test "x$ac_cv_prog_cc_c99" = xno; then
  49         AC_MSG_ERROR([Building libdrm requires C99 enabled compiler])
  50 fi
  51
  52 AC_USE_SYSTEM_EXTENSIONS
  53 AC_SYS_LARGEFILE
  54 AC_FUNC_ALLOCA
  55
  56 AC_CHECK_HEADERS([sys/mkdev.h sys/sysctl.h sys/select.h])
  57
  58 # Initialize libtool
  59 LT_PREREQ([2.2])
  60 LT_INIT([disable-static])
  61
  62
  63 PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
  64 AC_SUBST(PTHREADSTUBS_CFLAGS)
  65 AC_SUBST(PTHREADSTUBS_LIBS)
  66
  67 pkgconfigdir=${libdir}/pkgconfig
  68 AC_SUBST(pkgconfigdir)
  69 AC_ARG_ENABLE([udev],
  70               [AS_HELP_STRING([--enable-udev],
  71                               [Enable support for using udev instead of mknod (default: disabled)])],
  72               [UDEV=$enableval], [UDEV=no])
  73
  74 AC_ARG_ENABLE(libkms,
  75               AS_HELP_STRING([--disable-libkms],
  76               [Disable KMS mm abstraction library (default: auto, enabled on supported platforms)]),
  77               [LIBKMS=$enableval], [LIBKMS=auto])
  78
  79 AC_ARG_ENABLE(intel,
  80               AS_HELP_STRING([--disable-intel],
  81               [Enable support for intel's KMS API (default: auto, enabled on x86)]),
  82               [INTEL=$enableval], [INTEL=auto])
  83
  84 AC_ARG_ENABLE(radeon,
  85               AS_HELP_STRING([--disable-radeon],
  86               [Enable support for radeon's KMS API (default: auto)]),
  87               [RADEON=$enableval], [RADEON=auto])
  88
  89 AC_ARG_ENABLE(amdgpu,
  90               AS_HELP_STRING([--disable-amdgpu],
  91               [Enable support for amdgpu's KMS API (default: auto)]),
  92               [AMDGPU=$enableval], [AMDGPU=auto])
  93
  94 AC_ARG_ENABLE(nouveau,
  95               AS_HELP_STRING([--disable-nouveau],
  96               [Enable support for nouveau's KMS API (default: auto)]),
  97               [NOUVEAU=$enableval], [NOUVEAU=auto])
  98
  99 AC_ARG_ENABLE(vmwgfx,
 100               AS_HELP_STRING([--disable-vmwgfx],
 101               [Enable support for vmwgfx's KMS API (default: yes)]),
 102               [VMWGFX=$enableval], [VMWGFX=yes])
 103
 104 AC_ARG_ENABLE(omap-experimental-api,
 105               AS_HELP_STRING([--enable-omap-experimental-api],
 106               [Enable support for OMAP's experimental API (default: disabled)]),
 107               [OMAP=$enableval], [OMAP=no])
 108
 109 AC_ARG_ENABLE(exynos-experimental-api,
 110               AS_HELP_STRING([--enable-exynos-experimental-api],
 111               [Enable support for EXYNOS's experimental API (default: disabled)]),
 112               [EXYNOS=$enableval], [EXYNOS=no])
 113
 114 AC_ARG_ENABLE(freedreno,
 115               AS_HELP_STRING([--disable-freedreno],
 116               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
 117               [FREEDRENO=$enableval], [FREEDRENO=auto])
 118
 119 AC_ARG_ENABLE(freedreno-kgsl,
 120               AS_HELP_STRING([--enable-freedreno-kgsl],
 121               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 122               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 123
 124 AC_ARG_ENABLE(tegra-experimental-api,
 125               AS_HELP_STRING([--enable-tegra-experimental-api],
 126               [Enable support for Tegra's experimental API (default: disabled)]),
 127               [TEGRA=$enableval], [TEGRA=no])
 128
 129 AC_ARG_ENABLE(vc4,
 130               AS_HELP_STRING([--disable-vc4],
 131               [Enable support for vc4's API (default: auto, enabled on arm)]),
 132               [VC4=$enableval], [VC4=auto])
 133
 134 AC_ARG_ENABLE(install-test-programs,
 135                   AS_HELP_STRING([--enable-install-test-programs],
 136                   [Install test programs (default: no)]),
 137                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 138
 139 dnl ===========================================================================
 140 dnl check compiler flags
 141 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 142   AC_MSG_CHECKING([whether $CC supports $1])
 143
 144   libdrm_save_CFLAGS="$CFLAGS"
 145   CFLAGS="$CFLAGS $1"
 146
 147   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 148   CFLAGS="$libdrm_save_CFLAGS"
 149
 150   if test "x$libdrm_cc_flag" = "xyes"; then
 151     ifelse([$2], , :, [$2])
 152   else
 153     ifelse([$3], , :, [$3])
 154   fi
 155   AC_MSG_RESULT([$libdrm_cc_flag])
 156 ])
 157
 158 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 159
 160 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 161                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 162                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 163 AC_SUBST([CLOCK_LIB])
 164
 165 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 166
 167 dnl Use lots of warning flags with with gcc and compatible compilers
 168
 169 dnl Note: if you change the following variable, the cache is automatically
 170 dnl skipped and all flags rechecked.  So there's no need to do anything
 171 dnl else.  If for any reason you need to force a recheck, just change
 172 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 173
 174 MAYBE_WARN="-Wall -Wextra \
 175 -Wsign-compare -Werror-implicit-function-declaration \
 176 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 177 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 178 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 179 -Wstrict-aliasing=2 -Winit-self \
 180 -Wdeclaration-after-statement -Wold-style-definition \
 181 -Wno-unused-parameter \
 182 -Wno-attributes -Wno-long-long -Winline -Wshadow \
 183 -Wno-missing-field-initializers"
 184
 185 # invalidate cached value if MAYBE_WARN has changed
 186 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 187         unset libdrm_cv_warn_cflags
 188 fi
 189 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 190         echo
 191         WARN_CFLAGS=""
 192
 193         # Some warning options are not supported by all versions of
 194         # gcc, so test all desired options against the current
 195         # compiler.
 196         #
 197         # Note that there are some order dependencies
 198         # here. Specifically, an option that disables a warning will
 199         # have no net effect if a later option then enables that
 200         # warnings, (perhaps implicitly). So we put some grouped
 201         # options (-Wall and -Wextra) up front and the -Wno options
 202         # last.
 203
 204         for W in $MAYBE_WARN; do
 205                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 206         done
 207
 208         libdrm_cv_warn_cflags=$WARN_CFLAGS
 209         libdrm_cv_warn_maybe=$MAYBE_WARN
 210
 211         AC_MSG_CHECKING([which warning flags were supported])])
 212 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 213
 214 # Check for atomic intrinsics
 215 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 216         drm_cv_atomic_primitives="none"
 217
 218         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 219         int atomic_add(int *i) { return __sync_add_and_fetch (i, 1); }
 220         int atomic_cmpxchg(int *i, int j, int k) { return __sync_val_compare_and_swap (i, j, k); }
 221                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 222
 223         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 224                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 225         fi
 226
 227         # atomic functions defined in <atomic.h> & libc on Solaris
 228         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 229                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 230         fi
 231 ])
 232
 233 if test "x$drm_cv_atomic_primitives" = xIntel; then
 234         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 235                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 236 fi
 237 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 238         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 239 fi
 240
 241 dnl Print out the approapriate message considering the value set be the
 242 dnl respective in $1.
 243 dnl $1 - value to be evaluated. Eg. $INTEL, $NOUVEAU, ...
 244 dnl $2 - libdrm shortname. Eg. intel, freedreno, ...
 245 dnl $3 - GPU name/brand. Eg. Intel, NVIDIA Tegra, ...
 246 dnl $4 - Configure switch. Eg. intel, omap-experimental-api, ...
 247 AC_DEFUN([LIBDRM_ATOMICS_NOT_FOUND_MSG], [
 248         case "x$1" in
 249                 xyes)   AC_MSG_ERROR([libdrm_$2 depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for $3 GPUs by passing --disable-$4 to ./configure]) ;;
 250                 xauto)  AC_MSG_WARN([Disabling $2. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.]) ;;
 251                 *)      ;;
 252         esac
 253 ])
 254
 255 if test "x$drm_cv_atomic_primitives" = "xnone"; then
 256         LIBDRM_ATOMICS_NOT_FOUND_MSG($INTEL, intel, Intel, intel)
 257         INTEL=no
 258
 259         LIBDRM_ATOMICS_NOT_FOUND_MSG($RADEON, radeon, Radeon, radeon)
 260         RADEON=no
 261
 262         LIBDRM_ATOMICS_NOT_FOUND_MSG($AMDGPU, amdgpu, AMD, amdgpu)
 263         AMDGPU=no
 264
 265         LIBDRM_ATOMICS_NOT_FOUND_MSG($NOUVEAU, nouveau, NVIDIA, nouveau)
 266         NOUVEAU=no
 267
 268         LIBDRM_ATOMICS_NOT_FOUND_MSG($OMAP, omap, OMAP, omap-experimental-api)
 269         OMAP=no
 270
 271         LIBDRM_ATOMICS_NOT_FOUND_MSG($FREEDRENO, freedreno, Qualcomm Adreno, freedreno)
 272         FREEDRENO=no
 273
 274         LIBDRM_ATOMICS_NOT_FOUND_MSG($TEGRA, tegra, NVIDIA Tegra, tegra-experimental-api)
 275         TEGRA=no
 276 else
 277         if test "x$INTEL" = xauto; then
 278                 case $host_cpu in
 279                         i?86|x86_64)    INTEL=yes ;;
 280                         *)              INTEL=no ;;
 281                 esac
 282         fi
 283         if test "x$RADEON" = xauto; then
 284                 RADEON=yes
 285         fi
 286         if test "x$AMDGPU" = xauto; then
 287                 AMDGPU=yes
 288         fi
 289         if test "x$NOUVEAU" = xauto; then
 290                 NOUVEAU=yes
 291         fi
 292         if test "x$FREEDRENO" = xauto; then
 293                 case $host_cpu in
 294                         arm*|aarch64)   FREEDRENO=yes ;;
 295                         *)              FREEDRENO=no ;;
 296                 esac
 297         fi
 298         if test "x$VC4" = xauto; then
 299                 case $host_cpu in
 300                         arm*|aarch64)   VC4=yes ;;
 301                         *)              VC4=no ;;
 302                 esac
 303         fi
 304 fi
 305
 306 if test "x$INTEL" != "xno"; then
 307         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 308 fi
 309 AC_SUBST(PCIACCESS_CFLAGS)
 310 AC_SUBST(PCIACCESS_LIBS)
 311
 312 if test "x$UDEV" = xyes; then
 313         AC_DEFINE(UDEV, 1, [Have UDEV support])
 314 fi
 315
 316 AC_CANONICAL_HOST
 317 if test "x$LIBKMS" = xauto ; then
 318         case $host_os in
 319                 linux*)         LIBKMS="yes" ;;
 320                 freebsd* | kfreebsd*-gnu)
 321                                 LIBKMS="yes" ;;
 322                 dragonfly*)     LIBKMS="yes" ;;
 323                 *)              LIBKMS="no" ;;
 324         esac
 325 fi
 326
 327 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 328
 329 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 330 if test "x$INTEL" = xyes; then
 331         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 332 fi
 333
 334 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 335 if test "x$VMWGFX" = xyes; then
 336         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 337 fi
 338
 339 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 340 if test "x$NOUVEAU" = xyes; then
 341         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 342 fi
 343
 344 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 345 if test "x$OMAP" = xyes; then
 346         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 347 fi
 348
 349 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 350 if test "x$EXYNOS" = xyes; then
 351         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 352 fi
 353
 354 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 355 if test "x$FREEDRENO" = xyes; then
 356         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 357 fi
 358
 359 if test "x$FREEDRENO_KGSL" = xyes; then
 360         if test "x$FREEDRENO" != xyes; then
 361                 AC_MSG_ERROR([Cannot enable freedreno KGSL interface if freedreno is disabled])
 362         fi
 363 fi
 364 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 365 if test "x$FREEDRENO_KGSL" = xyes; then
 366         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 367 fi
 368
 369 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 370 if test "x$RADEON" = xyes; then
 371         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 372 fi
 373
 374 if test "x$AMDGPU" != xno; then
 375         # Detect cunit library
 376         PKG_CHECK_MODULES([CUNIT], [cunit >= 2.1], [have_cunit=yes], [have_cunit=no])
 377         # If pkg-config does not find cunit, check it using AC_CHECK_LIB.  We
 378         # do this because Debian (Ubuntu) lacks pkg-config file for cunit.
 379         # fixed in 2.1-2.dfsg-3: http://anonscm.debian.org/cgit/collab-maint/cunit.git/commit/?h=debian
 380         if test "x${have_cunit}" = "xno"; then
 381                 AC_CHECK_LIB([cunit], [CU_initialize_registry], [have_cunit=yes], [have_cunit=no])
 382                 if test "x${have_cunit}" = "xyes"; then
 383                         CUNIT_LIBS="-lcunit"
 384                         CUNIT_CFLAGS=""
 385                         AC_SUBST([CUNIT_LIBS])
 386                         AC_SUBST([CUNIT_CFLAGS])
 387                 fi
 388         fi
 389 else
 390         have_cunit=no
 391 fi
 392 AM_CONDITIONAL(HAVE_CUNIT, [test "x$have_cunit" != "xno"])
 393
 394 AM_CONDITIONAL(HAVE_AMDGPU, [test "x$AMDGPU" = xyes])
 395 if test "x$AMDGPU" = xyes; then
 396         AC_DEFINE(HAVE_AMDGPU, 1, [Have amdgpu support])
 397
 398         AC_DEFINE(HAVE_CUNIT, [test "x$have_cunit" != "xno"], [Enable CUNIT Have amdgpu support])
 399
 400         if test "x$have_cunit" = "xno"; then
 401                 AC_MSG_WARN([Could not find cunit library. Disabling amdgpu tests])
 402         fi
 403 fi
 404
 405 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 406 if test "x$TEGRA" = xyes; then
 407         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 408 fi
 409
 410 AM_CONDITIONAL(HAVE_VC4, [test "x$VC4" = xyes])
 411 if test "x$VC4" = xyes; then
 412         AC_DEFINE(HAVE_VC4, 1, [Have VC4 support])
 413 fi
 414
 415 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 416 if test "x$INSTALL_TESTS" = xyes; then
 417         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 418 fi
 419
 420 AC_ARG_ENABLE([cairo-tests],
 421               [AS_HELP_STRING([--enable-cairo-tests],
 422                               [Enable support for Cairo rendering in tests (default: auto)])],
 423               [CAIRO=$enableval], [CAIRO=auto])
 424 if test "x$CAIRO" != xno; then
 425         PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 426 fi
 427 AC_MSG_CHECKING([whether to enable Cairo tests])
 428 if test "x$CAIRO" = xauto; then
 429         CAIRO="$HAVE_CAIRO"
 430 fi
 431 if test "x$CAIRO" = xyes; then
 432         if ! test "x$HAVE_CAIRO" = xyes; then
 433                 AC_MSG_ERROR([Cairo support required but not present])
 434         fi
 435         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 436 fi
 437 AC_MSG_RESULT([$CAIRO])
 438 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 439
 440 # For enumerating devices in test case
 441 PKG_CHECK_MODULES(LIBUDEV, libudev, [HAVE_LIBUDEV=yes], [HAVE_LIBUDEV=no])
 442 if test "x$HAVE_LIBUDEV" = xyes; then
 443         AC_DEFINE(HAVE_LIBUDEV, 1, [Have libudev support])
 444 fi
 445 AM_CONDITIONAL(HAVE_LIBUDEV, [test "x$HAVE_LIBUDEV" = xyes])
 446
 447 # xsltproc for docbook manpages
 448 AC_ARG_ENABLE([manpages],
 449               AS_HELP_STRING([--enable-manpages], [enable manpages @<:@default=auto@:>@]),
 450               [MANS=$enableval], [MANS=auto])
 451 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 452
 453 # check for offline man-pages stylesheet
 454 AC_MSG_CHECKING([for docbook manpages stylesheet])
 455 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 456 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 457                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 458                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 459 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 460         AC_SUBST(MANPAGES_STYLESHEET)
 461         AC_MSG_RESULT([yes])
 462 else
 463         AC_MSG_RESULT([no])
 464 fi
 465 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 466
 467 AC_ARG_ENABLE(valgrind,
 468               [AS_HELP_STRING([--enable-valgrind],
 469                              [Build libdrm with  valgrind support (default: auto)])],
 470                              [VALGRIND=$enableval], [VALGRIND=auto])
 471 if test "x$VALGRIND" != xno; then
 472         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 473 fi
 474 AC_MSG_CHECKING([whether to enable Valgrind support])
 475 if test "x$VALGRIND" = xauto; then
 476         VALGRIND="$have_valgrind"
 477 fi
 478
 479 if test "x$VALGRIND" = "xyes"; then
 480         if ! test "x$have_valgrind" = xyes; then
 481                 AC_MSG_ERROR([Valgrind support required but not present])
 482         fi
 483         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 484 fi
 485
 486 AC_MSG_RESULT([$VALGRIND])
 487
 488 AC_ARG_WITH([kernel-source],
 489             [AS_HELP_STRING([--with-kernel-source],
 490               [specify path to linux kernel source])],
 491             [kernel_source="$with_kernel_source"])
 492 AC_SUBST(kernel_source)
 493
 494 AC_MSG_CHECKING([whether $CC supports __attribute__(("hidden"))])
 495 AC_LINK_IFELSE([AC_LANG_PROGRAM([
 496     int foo_hidden( void ) __attribute__((visibility("hidden")));
 497 ])], HAVE_ATTRIBUTE_VISIBILITY="yes"; AC_MSG_RESULT([yes]), AC_MSG_RESULT([no]));
 498
 499 if test "x$HAVE_ATTRIBUTE_VISIBILITY" = xyes; then
 500     AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler supports __attribute__(("hidden"))])
 501 fi
 502
 503 AC_SUBST(WARN_CFLAGS)
 504 AC_CONFIG_FILES([
 505         Makefile
 506         libkms/Makefile
 507         libkms/libkms.pc
 508         intel/Makefile
 509         intel/libdrm_intel.pc
 510         radeon/Makefile
 511         radeon/libdrm_radeon.pc
 512         amdgpu/Makefile
 513         amdgpu/libdrm_amdgpu.pc
 514         nouveau/Makefile
 515         nouveau/libdrm_nouveau.pc
 516         omap/Makefile
 517         omap/libdrm_omap.pc
 518         exynos/Makefile
 519         exynos/libdrm_exynos.pc
 520         freedreno/Makefile
 521         freedreno/libdrm_freedreno.pc
 522         tegra/Makefile
 523         tegra/libdrm_tegra.pc
 524         vc4/Makefile
 525         vc4/libdrm_vc4.pc
 526         tests/Makefile
 527         tests/modeprint/Makefile
 528         tests/modetest/Makefile
 529         tests/kms/Makefile
 530         tests/kmstest/Makefile
 531         tests/proptest/Makefile
 532         tests/radeon/Makefile
 533         tests/amdgpu/Makefile
 534         tests/vbltest/Makefile
 535         tests/exynos/Makefile
 536         tests/tegra/Makefile
 537         tests/nouveau/Makefile
 538         tests/util/Makefile
 539         man/Makefile
 540         libdrm.pc])
 541 AC_OUTPUT
 542
 543 echo ""
 544 echo "$PACKAGE_STRING will be compiled with:"
 545 echo ""
 546 echo "  libkms         $LIBKMS"
 547 echo "  Intel API      $INTEL"
 548 echo "  vmwgfx API     $VMWGFX"
 549 echo "  Radeon API     $RADEON"
 550 echo "  AMDGPU API     $AMDGPU"
 551 echo "  Nouveau API    $NOUVEAU"
 552 echo "  OMAP API       $OMAP"
 553 echo "  EXYNOS API     $EXYNOS"
 554 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 555 echo "  Tegra API      $TEGRA"
 556 echo "  VC4 API        $VC4"
 557 echo ""