configure.ac

   1 #  Copyright 2005 Adam Jackson.
   2 #
   3 #  Permission is hereby granted, free of charge, to any person obtaining a
   4 #  copy of this software and associated documentation files (the "Software"),
   5 #  to deal in the Software without restriction, including without limitation
   6 #  on the rights to use, copy, modify, merge, publish, distribute, sub
   7 #  license, and/or sell copies of the Software, and to permit persons to whom
   8 #  the Software is furnished to do so, subject to the following conditions:
   9 #
  10 #  The above copyright notice and this permission notice (including the next
  11 #  paragraph) shall be included in all copies or substantial portions of the
  12 #  Software.
  13 #
  14 #  THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  15 #  IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  16 #  FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  17 #  ADAM JACKSON BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER
  18 #  IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN
  19 #  CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  20
  21 AC_PREREQ([2.63])
  22 AC_INIT([libdrm],
  23         [2.4.81],
  24         [https://bugs.freedesktop.org/enter_bug.cgi?product=DRI],
  25         [libdrm])
  26
  27 AC_CONFIG_HEADERS([config.h])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_MACRO_DIR([m4])
  30 AC_CONFIG_AUX_DIR([build-aux])
  31 PKG_PROG_PKG_CONFIG
  32
  33 # Require xorg-macros minimum of 1.12 for XORG_WITH_XSLTPROC
  34 m4_ifndef([XORG_MACROS_VERSION],
  35           [m4_fatal([must install xorg-macros 1.12 or later before running autoconf/autogen])])
  36 XORG_MACROS_VERSION(1.12)
  37 XORG_WITH_XSLTPROC
  38 XORG_MANPAGE_SECTIONS
  39
  40 AM_INIT_AUTOMAKE([1.10 foreign dist-bzip2])
  41
  42 # Enable quiet compiles on automake 1.11.
  43 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  44
  45 # Check for programs
  46 AC_PROG_CC
  47 AC_PROG_CC_C99
  48
  49 if test "x$ac_cv_prog_cc_c99" = xno; then
  50         AC_MSG_ERROR([Building libdrm requires C99 enabled compiler])
  51 fi
  52
  53 AC_USE_SYSTEM_EXTENSIONS
  54 AC_SYS_LARGEFILE
  55 AC_FUNC_ALLOCA
  56
  57 save_CFLAGS="$CFLAGS"
  58 export CFLAGS="$CFLAGS -Werror"
  59 AC_HEADER_MAJOR
  60 CFLAGS="$save_CFLAGS"
  61
  62 AC_CHECK_HEADERS([sys/sysctl.h sys/select.h])
  63
  64 # Initialize libtool
  65 LT_PREREQ([2.2])
  66 LT_INIT([disable-static])
  67
  68 dnl pthread-stubs is mandatory on BSD platforms, due to the nature of the
  69 dnl project. Even then there's a notable issue as described in the project README
  70 case "$host_os" in
  71 linux* | cygwin* | darwin* | solaris* | *-gnu* | gnu*)
  72     pthread_stubs_possible="no"
  73     ;;
  74 * )
  75     pthread_stubs_possible="yes"
  76     ;;
  77 esac
  78
  79 if test "x$pthread_stubs_possible" = xyes; then
  80     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs >= 0.4)
  81     AC_SUBST(PTHREADSTUBS_CFLAGS)
  82     AC_SUBST(PTHREADSTUBS_LIBS)
  83 fi
  84
  85 pkgconfigdir=${libdir}/pkgconfig
  86 AC_SUBST(pkgconfigdir)
  87 libdrmdatadir=${datadir}/libdrm
  88 AC_SUBST(libdrmdatadir)
  89
  90 AC_ARG_ENABLE([udev],
  91               [AS_HELP_STRING([--enable-udev],
  92                               [Enable support for using udev instead of mknod (default: disabled)])],
  93               [UDEV=$enableval], [UDEV=no])
  94
  95 AC_ARG_ENABLE(libkms,
  96               AS_HELP_STRING([--disable-libkms],
  97               [Disable KMS mm abstraction library (default: auto, enabled on supported platforms)]),
  98               [LIBKMS=$enableval], [LIBKMS=auto])
  99
 100 AC_ARG_ENABLE(intel,
 101               AS_HELP_STRING([--disable-intel],
 102               [Enable support for intel's KMS API (default: auto, enabled on x86)]),
 103               [INTEL=$enableval], [INTEL=auto])
 104
 105 AC_ARG_ENABLE(radeon,
 106               AS_HELP_STRING([--disable-radeon],
 107               [Enable support for radeon's KMS API (default: auto)]),
 108               [RADEON=$enableval], [RADEON=auto])
 109
 110 AC_ARG_ENABLE(amdgpu,
 111               AS_HELP_STRING([--disable-amdgpu],
 112               [Enable support for amdgpu's KMS API (default: auto)]),
 113               [AMDGPU=$enableval], [AMDGPU=auto])
 114
 115 AC_ARG_ENABLE(nouveau,
 116               AS_HELP_STRING([--disable-nouveau],
 117               [Enable support for nouveau's KMS API (default: auto)]),
 118               [NOUVEAU=$enableval], [NOUVEAU=auto])
 119
 120 AC_ARG_ENABLE(vmwgfx,
 121               AS_HELP_STRING([--disable-vmwgfx],
 122               [Enable support for vmwgfx's KMS API (default: yes)]),
 123               [VMWGFX=$enableval], [VMWGFX=yes])
 124
 125 AC_ARG_ENABLE(omap-experimental-api,
 126               AS_HELP_STRING([--enable-omap-experimental-api],
 127               [Enable support for OMAP's experimental API (default: disabled)]),
 128               [OMAP=$enableval], [OMAP=no])
 129
 130 AC_ARG_ENABLE(exynos-experimental-api,
 131               AS_HELP_STRING([--enable-exynos-experimental-api],
 132               [Enable support for EXYNOS's experimental API (default: disabled)]),
 133               [EXYNOS=$enableval], [EXYNOS=no])
 134
 135 AC_ARG_ENABLE(freedreno,
 136               AS_HELP_STRING([--disable-freedreno],
 137               [Enable support for freedreno's KMS API (default: auto, enabled on arm)]),
 138               [FREEDRENO=$enableval], [FREEDRENO=auto])
 139
 140 AC_ARG_ENABLE(freedreno-kgsl,
 141               AS_HELP_STRING([--enable-freedreno-kgsl],
 142               [Enable support for freedreno's to use downstream android kernel API (default: disabled)]),
 143               [FREEDRENO_KGSL=$enableval], [FREEDRENO_KGSL=no])
 144
 145 AC_ARG_ENABLE(tegra-experimental-api,
 146               AS_HELP_STRING([--enable-tegra-experimental-api],
 147               [Enable support for Tegra's experimental API (default: disabled)]),
 148               [TEGRA=$enableval], [TEGRA=no])
 149
 150 AC_ARG_ENABLE(vc4,
 151               AS_HELP_STRING([--disable-vc4],
 152               [Enable support for vc4's API (default: auto, enabled on arm)]),
 153               [VC4=$enableval], [VC4=auto])
 154
 155 AC_ARG_ENABLE(etnaviv-experimental-api,
 156               AS_HELP_STRING([--enable-etnaviv-experimental-api],
 157               [Enable support for etnaviv's experimental API (default: disabled)]),
 158               [ETNAVIV=$enableval], [ETNAVIV=no])
 159
 160 AC_ARG_ENABLE(install-test-programs,
 161                   AS_HELP_STRING([--enable-install-test-programs],
 162                   [Install test programs (default: no)]),
 163                   [INSTALL_TESTS=$enableval], [INSTALL_TESTS=no])
 164
 165 dnl ===========================================================================
 166 dnl check compiler flags
 167 AC_DEFUN([LIBDRM_CC_TRY_FLAG], [
 168   AC_MSG_CHECKING([whether $CC supports $1])
 169
 170   libdrm_save_CFLAGS="$CFLAGS"
 171   CFLAGS="$CFLAGS $1"
 172
 173   AC_COMPILE_IFELSE([AC_LANG_SOURCE([ ])], [libdrm_cc_flag=yes], [libdrm_cc_flag=no])
 174   CFLAGS="$libdrm_save_CFLAGS"
 175
 176   if test "x$libdrm_cc_flag" = "xyes"; then
 177     ifelse([$2], , :, [$2])
 178   else
 179     ifelse([$3], , :, [$3])
 180   fi
 181   AC_MSG_RESULT([$libdrm_cc_flag])
 182 ])
 183
 184 dnl We use clock_gettime to check for timeouts in drmWaitVBlank
 185
 186 AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 187                [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 188                              [AC_MSG_ERROR([Couldn't find clock_gettime])])])
 189 AC_SUBST([CLOCK_LIB])
 190
 191 AC_CHECK_FUNCS([open_memstream], [HAVE_OPEN_MEMSTREAM=yes])
 192
 193 dnl Use lots of warning flags with with gcc and compatible compilers
 194
 195 dnl Note: if you change the following variable, the cache is automatically
 196 dnl skipped and all flags rechecked.  So there's no need to do anything
 197 dnl else.  If for any reason you need to force a recheck, just change
 198 dnl MAYBE_WARN in an ignorable way (like adding whitespace)
 199
 200 MAYBE_WARN="-Wall -Wextra \
 201 -Wsign-compare -Werror-implicit-function-declaration \
 202 -Wpointer-arith -Wwrite-strings -Wstrict-prototypes \
 203 -Wmissing-prototypes -Wmissing-declarations -Wnested-externs \
 204 -Wpacked -Wswitch-enum -Wmissing-format-attribute \
 205 -Wstrict-aliasing=2 -Winit-self \
 206 -Wdeclaration-after-statement -Wold-style-definition \
 207 -Wno-unused-parameter \
 208 -Wno-attributes -Wno-long-long -Winline -Wshadow \
 209 -Wno-missing-field-initializers"
 210
 211 # invalidate cached value if MAYBE_WARN has changed
 212 if test "x$libdrm_cv_warn_maybe" != "x$MAYBE_WARN"; then
 213         unset libdrm_cv_warn_cflags
 214 fi
 215 AC_CACHE_CHECK([for supported warning flags], libdrm_cv_warn_cflags, [
 216         echo
 217         WARN_CFLAGS=""
 218
 219         # Some warning options are not supported by all versions of
 220         # gcc, so test all desired options against the current
 221         # compiler.
 222         #
 223         # Note that there are some order dependencies
 224         # here. Specifically, an option that disables a warning will
 225         # have no net effect if a later option then enables that
 226         # warnings, (perhaps implicitly). So we put some grouped
 227         # options (-Wall and -Wextra) up front and the -Wno options
 228         # last.
 229
 230         for W in $MAYBE_WARN; do
 231                 LIBDRM_CC_TRY_FLAG([$W], [WARN_CFLAGS="$WARN_CFLAGS $W"])
 232         done
 233
 234         libdrm_cv_warn_cflags=$WARN_CFLAGS
 235         libdrm_cv_warn_maybe=$MAYBE_WARN
 236
 237         AC_MSG_CHECKING([which warning flags were supported])])
 238 WARN_CFLAGS="$libdrm_cv_warn_cflags"
 239
 240 # Check for atomic intrinsics
 241 AC_CACHE_CHECK([for native atomic primitives], drm_cv_atomic_primitives, [
 242         drm_cv_atomic_primitives="none"
 243
 244         AC_LINK_IFELSE([AC_LANG_PROGRAM([[
 245         int atomic_add(int *i) { return __sync_add_and_fetch (i, 1); }
 246         int atomic_cmpxchg(int *i, int j, int k) { return __sync_val_compare_and_swap (i, j, k); }
 247                                           ]],[[]])], [drm_cv_atomic_primitives="Intel"],[])
 248
 249         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 250                 AC_CHECK_HEADER([atomic_ops.h], drm_cv_atomic_primitives="libatomic-ops")
 251         fi
 252
 253         # atomic functions defined in <atomic.h> & libc on Solaris
 254         if test "x$drm_cv_atomic_primitives" = "xnone"; then
 255                 AC_CHECK_FUNC([atomic_cas_uint], drm_cv_atomic_primitives="Solaris")
 256         fi
 257 ])
 258
 259 if test "x$drm_cv_atomic_primitives" = xIntel; then
 260         AC_DEFINE(HAVE_LIBDRM_ATOMIC_PRIMITIVES, 1,
 261                 [Enable if your compiler supports the Intel __sync_* atomic primitives])
 262 fi
 263 if test "x$drm_cv_atomic_primitives" = "xlibatomic-ops"; then
 264         AC_DEFINE(HAVE_LIB_ATOMIC_OPS, 1, [Enable if you have libatomic-ops-dev installed])
 265 fi
 266
 267 dnl Print out the approapriate message considering the value set be the
 268 dnl respective in $1.
 269 dnl $1 - value to be evaluated. Eg. $INTEL, $NOUVEAU, ...
 270 dnl $2 - libdrm shortname. Eg. intel, freedreno, ...
 271 dnl $3 - GPU name/brand. Eg. Intel, NVIDIA Tegra, ...
 272 dnl $4 - Configure switch. Eg. intel, omap-experimental-api, ...
 273 AC_DEFUN([LIBDRM_ATOMICS_NOT_FOUND_MSG], [
 274         case "x$1" in
 275                 xyes)   AC_MSG_ERROR([libdrm_$2 depends upon atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package, or, failing both of those, disable support for $3 GPUs by passing --disable-$4 to ./configure]) ;;
 276                 xauto)  AC_MSG_WARN([Disabling $2. It depends on atomic operations, which were not found for your compiler/cpu. Try compiling with -march=native, or install the libatomics-op-dev package.]) ;;
 277                 *)      ;;
 278         esac
 279 ])
 280
 281 if test "x$drm_cv_atomic_primitives" = "xnone"; then
 282         LIBDRM_ATOMICS_NOT_FOUND_MSG($INTEL, intel, Intel, intel)
 283         INTEL=no
 284
 285         LIBDRM_ATOMICS_NOT_FOUND_MSG($RADEON, radeon, Radeon, radeon)
 286         RADEON=no
 287
 288         LIBDRM_ATOMICS_NOT_FOUND_MSG($AMDGPU, amdgpu, AMD, amdgpu)
 289         AMDGPU=no
 290
 291         LIBDRM_ATOMICS_NOT_FOUND_MSG($NOUVEAU, nouveau, NVIDIA, nouveau)
 292         NOUVEAU=no
 293
 294         LIBDRM_ATOMICS_NOT_FOUND_MSG($OMAP, omap, OMAP, omap-experimental-api)
 295         OMAP=no
 296
 297         LIBDRM_ATOMICS_NOT_FOUND_MSG($FREEDRENO, freedreno, Qualcomm Adreno, freedreno)
 298         FREEDRENO=no
 299
 300         LIBDRM_ATOMICS_NOT_FOUND_MSG($TEGRA, tegra, NVIDIA Tegra, tegra-experimental-api)
 301         TEGRA=no
 302
 303         LIBDRM_ATOMICS_NOT_FOUND_MSG($ETNAVIV, etnaviv, Vivante, etnaviv-experimental-api)
 304         ETNAVIV=no
 305 else
 306         if test "x$INTEL" = xauto; then
 307                 case $host_cpu in
 308                         i?86|x86_64)    INTEL=yes ;;
 309                         *)              INTEL=no ;;
 310                 esac
 311         fi
 312         if test "x$RADEON" = xauto; then
 313                 RADEON=yes
 314         fi
 315         if test "x$AMDGPU" = xauto; then
 316                 AMDGPU=yes
 317         fi
 318         if test "x$NOUVEAU" = xauto; then
 319                 NOUVEAU=yes
 320         fi
 321         if test "x$FREEDRENO" = xauto; then
 322                 case $host_cpu in
 323                         arm*|aarch64)   FREEDRENO=yes ;;
 324                         *)              FREEDRENO=no ;;
 325                 esac
 326         fi
 327         if test "x$VC4" = xauto; then
 328                 case $host_cpu in
 329                         arm*|aarch64)   VC4=yes ;;
 330                         *)              VC4=no ;;
 331                 esac
 332         fi
 333 fi
 334
 335 if test "x$INTEL" != "xno"; then
 336         PKG_CHECK_MODULES(PCIACCESS, [pciaccess >= 0.10])
 337 fi
 338 AC_SUBST(PCIACCESS_CFLAGS)
 339 AC_SUBST(PCIACCESS_LIBS)
 340
 341 if test "x$UDEV" = xyes; then
 342         AC_DEFINE(UDEV, 1, [Have UDEV support])
 343 fi
 344
 345 AC_CANONICAL_HOST
 346 if test "x$LIBKMS" = xauto ; then
 347         case $host_os in
 348                 linux*)         LIBKMS="yes" ;;
 349                 freebsd* | kfreebsd*-gnu)
 350                                 LIBKMS="yes" ;;
 351                 dragonfly*)     LIBKMS="yes" ;;
 352                 *)              LIBKMS="no" ;;
 353         esac
 354 fi
 355
 356 AM_CONDITIONAL(HAVE_LIBKMS, [test "x$LIBKMS" = xyes])
 357
 358 AM_CONDITIONAL(HAVE_INTEL, [test "x$INTEL" = xyes])
 359 if test "x$INTEL" = xyes; then
 360         AC_DEFINE(HAVE_INTEL, 1, [Have intel support])
 361 fi
 362
 363 AM_CONDITIONAL(HAVE_VMWGFX, [test "x$VMWGFX" = xyes])
 364 if test "x$VMWGFX" = xyes; then
 365         AC_DEFINE(HAVE_VMWGFX, 1, [Have vmwgfx kernel headers])
 366 fi
 367
 368 AM_CONDITIONAL(HAVE_NOUVEAU, [test "x$NOUVEAU" = xyes])
 369 if test "x$NOUVEAU" = xyes; then
 370         AC_DEFINE(HAVE_NOUVEAU, 1, [Have nouveau (nvidia) support])
 371 fi
 372
 373 AM_CONDITIONAL(HAVE_OMAP, [test "x$OMAP" = xyes])
 374 if test "x$OMAP" = xyes; then
 375         AC_DEFINE(HAVE_OMAP, 1, [Have OMAP support])
 376 fi
 377
 378 AM_CONDITIONAL(HAVE_EXYNOS, [test "x$EXYNOS" = xyes])
 379 if test "x$EXYNOS" = xyes; then
 380         AC_DEFINE(HAVE_EXYNOS, 1, [Have EXYNOS support])
 381 fi
 382
 383 AM_CONDITIONAL(HAVE_FREEDRENO, [test "x$FREEDRENO" = xyes])
 384 if test "x$FREEDRENO" = xyes; then
 385         AC_DEFINE(HAVE_FREEDRENO, 1, [Have freedreno support])
 386 fi
 387
 388 if test "x$FREEDRENO_KGSL" = xyes; then
 389         if test "x$FREEDRENO" != xyes; then
 390                 AC_MSG_ERROR([Cannot enable freedreno KGSL interface if freedreno is disabled])
 391         fi
 392 fi
 393 AM_CONDITIONAL(HAVE_FREEDRENO_KGSL, [test "x$FREEDRENO_KGSL" = xyes])
 394 if test "x$FREEDRENO_KGSL" = xyes; then
 395         AC_DEFINE(HAVE_FREEDRENO_KGSL, 1, [Have freedreno support for KGSL kernel interface])
 396 fi
 397
 398 AM_CONDITIONAL(HAVE_RADEON, [test "x$RADEON" = xyes])
 399 if test "x$RADEON" = xyes; then
 400         AC_DEFINE(HAVE_RADEON, 1, [Have radeon support])
 401 fi
 402
 403 if test "x$AMDGPU" != xno; then
 404         # Detect cunit library
 405         PKG_CHECK_MODULES([CUNIT], [cunit >= 2.1], [have_cunit=yes], [have_cunit=no])
 406         # If pkg-config does not find cunit, check it using AC_CHECK_LIB.  We
 407         # do this because Debian (Ubuntu) lacks pkg-config file for cunit.
 408         # fixed in 2.1-2.dfsg-3: http://anonscm.debian.org/cgit/collab-maint/cunit.git/commit/?h=debian
 409         if test "x${have_cunit}" = "xno"; then
 410                 AC_CHECK_LIB([cunit], [CU_initialize_registry], [have_cunit=yes], [have_cunit=no])
 411                 if test "x${have_cunit}" = "xyes"; then
 412                         CUNIT_LIBS="-lcunit"
 413                         CUNIT_CFLAGS=""
 414                         AC_SUBST([CUNIT_LIBS])
 415                         AC_SUBST([CUNIT_CFLAGS])
 416                 fi
 417         fi
 418 else
 419         have_cunit=no
 420 fi
 421 AM_CONDITIONAL(HAVE_CUNIT, [test "x$have_cunit" != "xno"])
 422
 423 AM_CONDITIONAL(HAVE_AMDGPU, [test "x$AMDGPU" = xyes])
 424 if test "x$AMDGPU" = xyes; then
 425         AC_DEFINE(HAVE_AMDGPU, 1, [Have amdgpu support])
 426
 427         AC_DEFINE(HAVE_CUNIT, [test "x$have_cunit" != "xno"], [Enable CUNIT Have amdgpu support])
 428
 429         if test "x$have_cunit" = "xno"; then
 430                 AC_MSG_WARN([Could not find cunit library. Disabling amdgpu tests])
 431         fi
 432 fi
 433
 434 AM_CONDITIONAL(HAVE_TEGRA, [test "x$TEGRA" = xyes])
 435 if test "x$TEGRA" = xyes; then
 436         AC_DEFINE(HAVE_TEGRA, 1, [Have Tegra support])
 437 fi
 438
 439 AM_CONDITIONAL(HAVE_VC4, [test "x$VC4" = xyes])
 440 if test "x$VC4" = xyes; then
 441         AC_DEFINE(HAVE_VC4, 1, [Have VC4 support])
 442 fi
 443
 444 AM_CONDITIONAL(HAVE_ETNAVIV, [test "x$ETNAVIV" = xyes])
 445 if test "x$ETNAVIV" = xyes; then
 446         AC_DEFINE(HAVE_ETNAVIV, 1, [Have etnaviv support])
 447 fi
 448
 449 AM_CONDITIONAL(HAVE_INSTALL_TESTS, [test "x$INSTALL_TESTS" = xyes])
 450 if test "x$INSTALL_TESTS" = xyes; then
 451         AC_DEFINE(HAVE_INSTALL_TESTS, 1, [Install test programs])
 452 fi
 453
 454 AC_ARG_ENABLE([cairo-tests],
 455               [AS_HELP_STRING([--enable-cairo-tests],
 456                               [Enable support for Cairo rendering in tests (default: auto)])],
 457               [CAIRO=$enableval], [CAIRO=auto])
 458 if test "x$CAIRO" != xno; then
 459         PKG_CHECK_MODULES(CAIRO, cairo, [HAVE_CAIRO=yes], [HAVE_CAIRO=no])
 460 fi
 461 AC_MSG_CHECKING([whether to enable Cairo tests])
 462 if test "x$CAIRO" = xauto; then
 463         CAIRO="$HAVE_CAIRO"
 464 fi
 465 if test "x$CAIRO" = xyes; then
 466         if ! test "x$HAVE_CAIRO" = xyes; then
 467                 AC_MSG_ERROR([Cairo support required but not present])
 468         fi
 469         AC_DEFINE(HAVE_CAIRO, 1, [Have Cairo support])
 470 fi
 471 AC_MSG_RESULT([$CAIRO])
 472 AM_CONDITIONAL(HAVE_CAIRO, [test "x$CAIRO" = xyes])
 473
 474 # xsltproc for docbook manpages
 475 AC_ARG_ENABLE([manpages],
 476               AS_HELP_STRING([--enable-manpages], [enable manpages @<:@default=auto@:>@]),
 477               [MANS=$enableval], [MANS=auto])
 478 AM_CONDITIONAL([BUILD_MANPAGES], [test "x$XSLTPROC" != "x" -a "x$MANS" != "xno"])
 479
 480 # check for offline man-pages stylesheet
 481 AC_MSG_CHECKING([for docbook manpages stylesheet])
 482 MANPAGES_STYLESHEET="http://docbook.sourceforge.net/release/xsl/current/manpages/docbook.xsl"
 483 AC_PATH_PROGS_FEATURE_CHECK([XSLTPROC_TMP], [xsltproc],
 484                             AS_IF([`"$ac_path_XSLTPROC_TMP" --nonet "$MANPAGES_STYLESHEET" > /dev/null 2>&1`],
 485                                   [HAVE_MANPAGES_STYLESHEET=yes]))
 486 if test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"; then
 487         AC_SUBST(MANPAGES_STYLESHEET)
 488         AC_MSG_RESULT([yes])
 489 else
 490         AC_MSG_RESULT([no])
 491 fi
 492 AM_CONDITIONAL([HAVE_MANPAGES_STYLESHEET], [test "x$HAVE_MANPAGES_STYLESHEET" = "xyes"])
 493
 494 AC_ARG_ENABLE(valgrind,
 495               [AS_HELP_STRING([--enable-valgrind],
 496                              [Build libdrm with  valgrind support (default: auto)])],
 497                              [VALGRIND=$enableval], [VALGRIND=auto])
 498 if test "x$VALGRIND" != xno; then
 499         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
 500 fi
 501 AC_MSG_CHECKING([whether to enable Valgrind support])
 502 if test "x$VALGRIND" = xauto; then
 503         VALGRIND="$have_valgrind"
 504 fi
 505
 506 if test "x$VALGRIND" = "xyes"; then
 507         if ! test "x$have_valgrind" = xyes; then
 508                 AC_MSG_ERROR([Valgrind support required but not present])
 509         fi
 510         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
 511 fi
 512
 513 AC_MSG_RESULT([$VALGRIND])
 514
 515 AC_ARG_WITH([kernel-source],
 516             [AS_HELP_STRING([--with-kernel-source],
 517               [specify path to linux kernel source])],
 518             [kernel_source="$with_kernel_source"])
 519 AC_SUBST(kernel_source)
 520
 521 AC_MSG_CHECKING([whether $CC supports __attribute__(("hidden"))])
 522 AC_LINK_IFELSE([AC_LANG_PROGRAM([
 523     int foo_hidden( void ) __attribute__((visibility("hidden")));
 524 ])], HAVE_ATTRIBUTE_VISIBILITY="yes"; AC_MSG_RESULT([yes]), AC_MSG_RESULT([no]));
 525
 526 if test "x$HAVE_ATTRIBUTE_VISIBILITY" = xyes; then
 527     AC_DEFINE(HAVE_VISIBILITY, 1, [Compiler supports __attribute__(("hidden"))])
 528 fi
 529
 530 AC_SUBST(WARN_CFLAGS)
 531 AC_CONFIG_FILES([
 532         Makefile
 533         data/Makefile
 534         libkms/Makefile
 535         libkms/libkms.pc
 536         intel/Makefile
 537         intel/libdrm_intel.pc
 538         radeon/Makefile
 539         radeon/libdrm_radeon.pc
 540         amdgpu/Makefile
 541         amdgpu/libdrm_amdgpu.pc
 542         nouveau/Makefile
 543         nouveau/libdrm_nouveau.pc
 544         omap/Makefile
 545         omap/libdrm_omap.pc
 546         exynos/Makefile
 547         exynos/libdrm_exynos.pc
 548         freedreno/Makefile
 549         freedreno/libdrm_freedreno.pc
 550         tegra/Makefile
 551         tegra/libdrm_tegra.pc
 552         vc4/Makefile
 553         vc4/libdrm_vc4.pc
 554         etnaviv/Makefile
 555         etnaviv/libdrm_etnaviv.pc
 556         tests/Makefile
 557         tests/modeprint/Makefile
 558         tests/modetest/Makefile
 559         tests/kms/Makefile
 560         tests/kmstest/Makefile
 561         tests/proptest/Makefile
 562         tests/radeon/Makefile
 563         tests/amdgpu/Makefile
 564         tests/vbltest/Makefile
 565         tests/exynos/Makefile
 566         tests/tegra/Makefile
 567         tests/nouveau/Makefile
 568         tests/etnaviv/Makefile
 569         tests/util/Makefile
 570         man/Makefile
 571         libdrm.pc])
 572 AC_OUTPUT
 573
 574 echo ""
 575 echo "$PACKAGE_STRING will be compiled with:"
 576 echo ""
 577 echo "  libkms         $LIBKMS"
 578 echo "  Intel API      $INTEL"
 579 echo "  vmwgfx API     $VMWGFX"
 580 echo "  Radeon API     $RADEON"
 581 echo "  AMDGPU API     $AMDGPU"
 582 echo "  Nouveau API    $NOUVEAU"
 583 echo "  OMAP API       $OMAP"
 584 echo "  EXYNOS API     $EXYNOS"
 585 echo "  Freedreno API  $FREEDRENO (kgsl: $FREEDRENO_KGSL)"
 586 echo "  Tegra API      $TEGRA"
 587 echo "  VC4 API        $VC4"
 588 echo "  Etnaviv API    $ETNAVIV"
 589 echo ""