configure.ac

   1 # (C) Copyright IBM Corporation 2006
   2 # All Rights Reserved.
   3 #
   4 # Permission is hereby granted, free of charge, to any person obtaining a
   5 # copy of this software and associated documentation files (the "Software"),
   6 # to deal in the Software without restriction, including without limitation
   7 # on the rights to use, copy, modify, merge, publish, distribute, sub
   8 # license, and/or sell copies of the Software, and to permit persons to whom
   9 # the Software is furnished to do so, subject to the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the next
  12 # paragraph) shall be included in all copies or substantial portions of the
  13 # Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 # IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 # FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  18 # IBM AND/OR THEIR SUPPLIERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 # LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20 # FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  21 # DEALINGS IN THE SOFTWARE.
  22 #
  23
  24 # Initialize Autoconf
  25 AC_PREREQ([2.60])
  26 AC_INIT([libpciaccess],[0.13.4],
  27         [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg&component=libpciaccess],[libpciaccess])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AC_CONFIG_HEADERS([config.h])
  30
  31 # Initialize Automake
  32 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  33 AC_USE_SYSTEM_EXTENSIONS
  34
  35 # Initialize libtool
  36 AC_PROG_LIBTOOL
  37
  38 # Require X.Org macros 1.8 or later
  39 m4_ifndef([XORG_MACROS_VERSION],
  40           [m4_fatal([must install xorg-macros 1.8 or later before running autoconf/autogen])])
  41 XORG_MACROS_VERSION(1.8)
  42 XORG_DEFAULT_OPTIONS
  43
  44 pciids_path=/usr/share/hwdata
  45 AC_ARG_WITH(pciids-path, AS_HELP_STRING([--with-pciids-path=PCIIDS_PATH],
  46         [Path to pci.ids file]), [pciids_path="$withval"])
  47 AX_DEFINE_DIR(PCIIDS_PATH, pciids_path, [Path to pci.ids])
  48
  49 AC_ARG_ENABLE(linux-rom-fallback, AS_HELP_STRING([--enable-linux-rom-fallback],
  50                 [Enable support for falling back to /dev/mem for roms (default: disabled)]),
  51                 [LINUX_ROM=$enableval],[LINUX_ROM=no])
  52
  53 if test "x$LINUX_ROM" = xyes; then
  54         AC_DEFINE(LINUX_ROM, 1, [Linux ROM read fallback])
  55 fi
  56
  57 use_zlib=no
  58 AC_ARG_WITH(zlib, AS_HELP_STRING([--with-zlib],
  59         [Enable zlib support to read gzip compressed pci.ids]),
  60         [use_zlib="$withval"])
  61 if test "x$use_zlib" = xyes; then
  62         AC_CHECK_LIB(z, gzopen,
  63         [PCIACCESS_LIBS="$PCIACCESS_LIBS -lz"],
  64         [AC_MSG_ERROR(Check for zlib library failed)])
  65         AC_CHECK_HEADER([zlib.h],
  66         [AC_DEFINE(HAVE_ZLIB, 1, [Use zlib to read gzip compressed pci.ids])],
  67         [AC_MSG_ERROR(Check for zlib.h header file failed)])
  68 fi
  69
  70 case $host_os in
  71         *freebsd* | *dragonfly*)
  72                 freebsd=yes
  73                 ;;
  74         *linux*)
  75                 linux=yes
  76                 ;;
  77         *netbsd*)
  78                 case $host in
  79                 *i[[3-9]]86*)
  80                         PCIACCESS_LIBS="$PCIACCESS_LIBS -li386"
  81                         ;;
  82                 *x86_64*|*amd64*)
  83                         PCIACCESS_LIBS="$PCIACCESS_LIBS -lx86_64"
  84                         ;;
  85                 *alpha*)
  86                         PCIACCESS_LIBS="$PCIACCESS_LIBS -lalpha"
  87                         ;;
  88                 esac
  89                 PCIACCESS_LIBS="$PCIACCESS_LIBS -lpci"
  90                 netbsd=yes
  91                 ;;
  92         *openbsd*)
  93                 openbsd=yes
  94                 ;;
  95         *solaris*)
  96                 solaris=yes
  97                 PCIACCESS_LIBS="$PCIACCESS_LIBS -ldevinfo"
  98                 ;;
  99         gnu*)
 100                 gnu=yes
 101                 ;;
 102         *cygwin*)
 103                 cygwin=yes
 104                 PCIACCESS_LIBS="$PCIACCESS_LIBS"
 105                 ;;
 106 esac
 107
 108 AM_CONDITIONAL(LINUX, [test "x$linux" = xyes])
 109 AM_CONDITIONAL(FREEBSD, [test "x$freebsd" = xyes])
 110 AM_CONDITIONAL(NETBSD, [test "x$netbsd" = xyes])
 111 AM_CONDITIONAL(OPENBSD, [test "x$openbsd" = xyes])
 112 AM_CONDITIONAL(SOLARIS, [test "x$solaris" = xyes])
 113 AM_CONDITIONAL(GNU, [test "x$gnu" = xyes])
 114 AM_CONDITIONAL(CYGWIN, [test "x$cygwin" = xyes])
 115
 116 AC_SYS_LARGEFILE
 117
 118 AC_CHECK_HEADERS([err.h])
 119
 120 if test "x$netbsd" = xyes; then
 121 AC_CHECK_HEADERS([machine/sysarch.h])
 122 AC_CHECK_HEADERS([machine/mtrr.h], [have_mtrr_h="yes"], [have_mtrr_h="no"],
 123 [#ifdef HAVE_MACHINE_SYSARCH_H
 124 #include <sys/types.h>
 125 #include <machine/sysarch.h>
 126 #endif
 127 ])
 128 else
 129 AC_CHECK_HEADER([asm/mtrr.h], [have_mtrr_h="yes"], [have_mtrr_h="no"])
 130 fi
 131
 132 if test "x$have_mtrr_h" = xyes; then
 133     AC_DEFINE(HAVE_MTRR, 1, [Use MTRRs on mappings])
 134 fi
 135
 136 # check for the pci_io.pi_sel.pc_domain
 137 AC_CHECK_MEMBER([struct pci_io.pi_sel.pc_domain],
 138                [AC_DEFINE(HAVE_PCI_IO_PC_DOMAIN,1,[Have the pci_io.pi_sel.pc_domain member.])],
 139                [],
 140                [ #include <sys/types.h>
 141                  #include <sys/pciio.h>
 142                ])
 143
 144 AC_SUBST(PCIACCESS_CFLAGS)
 145 AC_SUBST(PCIACCESS_LIBS)
 146
 147 AC_CONFIG_FILES([Makefile
 148                 include/Makefile
 149                 man/Makefile
 150                 src/Makefile
 151                 scanpci/Makefile
 152                 pciaccess.pc])
 153 AC_OUTPUT