configure.ac

   1 dnl (C) Copyright IBM Corporation 2006
   2 dnl All Rights Reserved.
   3 dnl
   4 dnl Permission is hereby granted, free of charge, to any person obtaining a
   5 dnl copy of this software and associated documentation files (the "Software"),
   6 dnl to deal in the Software without restriction, including without limitation
   7 dnl on the rights to use, copy, modify, merge, publish, distribute, sub
   8 dnl license, and/or sell copies of the Software, and to permit persons to whom
   9 dnl the Software is furnished to do so, subject to the following conditions:
  10 dnl
  11 dnl The above copyright notice and this permission notice (including the next
  12 dnl paragraph) shall be included in all copies or substantial portions of the
  13 dnl Software.
  14 dnl
  15 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  16 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  17 dnl FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.  IN NO EVENT SHALL
  18 dnl IBM AND/OR THEIR SUPPLIERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  19 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  20 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  21 dnl DEALINGS IN THE SOFTWARE.
  22 dnl
  23 dnl Process this file with autoconf to create configure.
  24
  25 AC_PREREQ([2.60])
  26
  27 AC_INIT(libpciaccess, 0.11.0, [https://bugs.freedesktop.org/enter_bug.cgi?product=xorg&component=libpciaccess], libpciaccess)
  28 AM_INIT_AUTOMAKE([foreign dist-bzip2])
  29 AM_MAINTAINER_MODE
  30
  31 # Require xorg-macros: XORG_DEFAULT_OPTIONS
  32 m4_ifndef([XORG_MACROS_VERSION],
  33           [m4_fatal([must install xorg-macros 1.3 or later before running autoconf/autogen])])
  34 XORG_MACROS_VERSION(1.3)
  35 XORG_DEFAULT_OPTIONS
  36 AM_CONFIG_HEADER(config.h)
  37
  38 # Check for progs
  39 AC_PROG_CC
  40 AC_PROG_LIBTOOL
  41
  42 pciids_path=/usr/share/hwdata
  43 AC_ARG_WITH(pciids-path, AC_HELP_STRING([--with-pciids-path=PCIIDS_PATH],
  44         [Path to pci.ids file]), [pciids_path="$withval"])
  45 AC_DEFINE_DIR(PCIIDS_PATH, pciids_path, [Path to pci.ids])
  46
  47 AC_ARG_ENABLE(linux-rom-fallback, AS_HELP_STRING([--enable-linux-rom-fallback],
  48                 [Enable support for falling back to /dev/mem for roms (default: disabled)]),
  49                 [LINUX_ROM=$enableval],[LINUX_ROM=no])
  50
  51 if test "x$LINUX_ROM" = xyes; then
  52         AC_DEFINE(LINUX_ROM, 1, [Linux ROM read fallback])
  53 fi
  54
  55 use_zlib=no
  56 AC_ARG_WITH(zlib, AC_HELP_STRING([--with-zlib],
  57         [Enable zlib support to read gzip compressed pci.ids]),
  58         [use_zlib="$withval"])
  59 if test "x$use_zlib" = xyes; then
  60         AC_CHECK_LIB(z, gzopen,
  61         [PCIACCESS_LIBS="$PCIACCESS_LIBS -lz"],
  62         [AC_MSG_ERROR(Check for zlib library failed)])
  63         AC_CHECK_HEADER([zlib.h],
  64         [AC_DEFINE(HAVE_ZLIB, 1, [Use zlib to read gzip compressed pci.ids])],
  65         [AC_MSG_ERROR(Check for zlib.h header file failed)])
  66 fi
  67
  68 case $host_os in
  69         *freebsd* | *dragonfly*)
  70                 freebsd=yes
  71                 ;;
  72         *linux*)
  73                 linux=yes
  74                 ;;
  75         *netbsd*)
  76                 case $host in
  77                 *i386*)
  78                         PCIACCESS_LIBS="-li386"
  79                         ;;
  80                 *x86_64*|*amd64*)
  81                         PCIACCESS_LIBS="-lx86_64"
  82                         ;;
  83                 esac
  84                 netbsd=yes
  85                 ;;
  86         *openbsd*)
  87                 openbsd=yes
  88                 ;;
  89         *solaris*)
  90                 solaris=yes
  91                 PCIACCESS_LIBS="$PCIACCESS_LIBS -ldevinfo"
  92                 ;;
  93         gnu*)
  94                 gnu=yes
  95                 ;;
  96 esac
  97
  98 AM_CONDITIONAL(LINUX, [test "x$linux" = xyes])
  99 AM_CONDITIONAL(FREEBSD, [test "x$freebsd" = xyes])
 100 AM_CONDITIONAL(NETBSD, [test "x$netbsd" = xyes])
 101 AM_CONDITIONAL(OPENBSD, [test "x$openbsd" = xyes])
 102 AM_CONDITIONAL(SOLARIS, [test "x$solaris" = xyes])
 103 AM_CONDITIONAL(GNU, [test "x$gnu" = xyes])
 104
 105 AC_SYS_LARGEFILE
 106
 107 AC_CHECK_HEADER([asm/mtrr.h], [have_mtrr_h="yes"], [have_mtrr_h="no"])
 108
 109 if test "x$have_mtrr_h" = xyes; then
 110     AC_DEFINE(HAVE_MTRR, 1, [Use MTRRs on mappings])
 111 fi
 112
 113 dnl check for the pci_io.pi_sel.pc_domain
 114 AC_CHECK_MEMBER([struct pci_io.pi_sel.pc_domain],
 115                [AC_DEFINE(HAVE_PCI_IO_PC_DOMAIN,1,[Have the pci_io.pi_sel.pc_domain member.])],
 116                [],
 117                [ #include <sys/types.h>
 118                  #include <sys/pciio.h>
 119                ])
 120
 121 AC_SUBST(PCIACCESS_CFLAGS)
 122 AC_SUBST(PCIACCESS_LIBS)
 123
 124
 125 AC_OUTPUT([Makefile
 126            src/Makefile
 127            pciaccess.pc])