configure.ac

   1 dnl Copyright © 2011-2014 Intel Corporation
   2 dnl Copyright © 2011-2014 Emil Velikov <emil.l.velikov@gmail.com>
   3 dnl Copyright © 2007-2010 Dan Nicholson
   4 dnl Copyright © 2010-2014 Marek Olšák <maraeo@gmail.com>
   5 dnl Copyright © 2010-2014 Christian König
   6 dnl Copyright © 2012-2014 Tom Stellard <tstellar@gmail.com>
   7 dnl Copyright © 2009-2012 Jakob Bornecrantz
   8 dnl Copyright © 2009-2014 Jon TURNEY
   9 dnl Copyright © 2011-2012 Benjamin Franzke
  10 dnl Copyright © 2008-2014 David Airlie
  11 dnl Copyright © 2009-2013 Brian Paul
  12 dnl Copyright © 2003-2007 Keith Packard, Daniel Stone
  13 dnl
  14 dnl Permission is hereby granted, free of charge, to any person obtaining a
  15 dnl copy of this software and associated documentation files (the "Software"),
  16 dnl to deal in the Software without restriction, including without limitation
  17 dnl the rights to use, copy, modify, merge, publish, distribute, sublicense,
  18 dnl and/or sell copies of the Software, and to permit persons to whom the
  19 dnl Software is furnished to do so, subject to the following conditions:
  20 dnl
  21 dnl The above copyright notice and this permission notice (including the next
  22 dnl paragraph) shall be included in all copies or substantial portions of the
  23 dnl Software.
  24 dnl
  25 dnl THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS OR
  26 dnl IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF MERCHANTABILITY,
  27 dnl FITNESS FOR A PARTICULAR PURPOSE AND NONINFRINGEMENT.  IN NO EVENT SHALL
  28 dnl THE AUTHORS OR COPYRIGHT HOLDERS BE LIABLE FOR ANY CLAIM, DAMAGES OR OTHER
  29 dnl LIABILITY, WHETHER IN AN ACTION OF CONTRACT, TORT OR OTHERWISE, ARISING
  30 dnl FROM, OUT OF OR IN CONNECTION WITH THE SOFTWARE OR THE USE OR OTHER
  31 dnl DEALINGS IN THE SOFTWARE.
  32 dnl
  33 dnl Process this file with autoconf to create configure.
  34
  35 AC_PREREQ([2.60])
  36
  37 dnl Tell the user about autoconf.html in the --help output
  38 m4_divert_once([HELP_END], [
  39 See docs/autoconf.html for more details on the options for Mesa.])
  40
  41 m4_define(MESA_VERSION, m4_normalize(m4_include(VERSION)))
  42 AC_INIT([Mesa], [MESA_VERSION],
  43     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  44 AC_CONFIG_AUX_DIR([bin])
  45 AC_CONFIG_MACRO_DIR([m4])
  46 AC_CANONICAL_SYSTEM
  47 AM_INIT_AUTOMAKE([foreign tar-ustar dist-xz subdir-objects])
  48
  49 dnl We only support native Windows builds (MinGW/MSVC) through SCons.
  50 case "$host_os" in
  51 mingw*)
  52     AC_MSG_ERROR([MinGW build not supported through autoconf/automake, use SCons instead])
  53     ;;
  54 esac
  55
  56 # Support silent build rules, requires at least automake-1.11. Disable
  57 # by either passing --disable-silent-rules to configure or passing V=1
  58 # to make
  59 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])],
  60     [AC_SUBST([AM_DEFAULT_VERBOSITY], [1])])
  61
  62 m4_ifdef([AM_PROG_AR], [AM_PROG_AR])
  63
  64 dnl Set internal versions
  65 OSMESA_VERSION=8
  66 AC_SUBST([OSMESA_VERSION])
  67 OPENCL_VERSION=1
  68 AC_SUBST([OPENCL_VERSION])
  69
  70 dnl Versions for external dependencies
  71 LIBDRM_REQUIRED=2.4.66
  72 LIBDRM_RADEON_REQUIRED=2.4.56
  73 LIBDRM_AMDGPU_REQUIRED=2.4.63
  74 LIBDRM_INTEL_REQUIRED=2.4.61
  75 LIBDRM_NVVIEUX_REQUIRED=2.4.66
  76 LIBDRM_NOUVEAU_REQUIRED=2.4.66
  77 LIBDRM_FREEDRENO_REQUIRED=2.4.68
  78 LIBDRM_VC4_REQUIRED=2.4.69
  79 DRI2PROTO_REQUIRED=2.6
  80 DRI3PROTO_REQUIRED=1.0
  81 PRESENTPROTO_REQUIRED=1.0
  82 GLPROTO_REQUIRED=1.4.14
  83 LIBOMXIL_BELLAGIO_REQUIRED=0.0
  84 LIBVA_REQUIRED=0.38.0
  85 VDPAU_REQUIRED=1.1
  86 WAYLAND_REQUIRED=1.2.0
  87 XCB_REQUIRED=1.9.3
  88 XCBDRI2_REQUIRED=1.8
  89 XCBGLX_REQUIRED=1.8.1
  90 XSHMFENCE_REQUIRED=1.1
  91 XVMC_REQUIRED=1.0.6
  92 PYTHON_MAKO_REQUIRED=0.8.0
  93 LIBSENSORS_REQUIRED=4.0.0
  94
  95 dnl Check for progs
  96 AC_PROG_CPP
  97 AC_PROG_CC
  98 AC_PROG_CXX
  99 AM_PROG_CC_C_O
 100 AM_PROG_AS
 101 AX_CHECK_GNU_MAKE
 102 AC_CHECK_PROGS([PYTHON2], [python2.7 python2 python])
 103 AC_PROG_SED
 104 AC_PROG_MKDIR_P
 105
 106 AC_SYS_LARGEFILE
 107
 108 LT_PREREQ([2.2])
 109 LT_INIT([disable-static])
 110
 111 AC_CHECK_PROG(RM, rm, [rm -f])
 112 AC_CHECK_PROG(XXD, xxd, [xxd])
 113
 114 AX_PROG_BISON([],
 115               AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-parse.c"],
 116                     [AC_MSG_ERROR([bison not found - unable to compile glcpp-parse.y])]))
 117 AX_PROG_FLEX([],
 118              AS_IF([test ! -f "$srcdir/src/compiler/glsl/glcpp/glcpp-lex.c"],
 119                    [AC_MSG_ERROR([flex not found - unable to compile glcpp-lex.l])]))
 120
 121 AC_CHECK_PROG(INDENT, indent, indent, cat)
 122 if test "x$INDENT" != "xcat"; then
 123     # Only GNU indent is supported
 124     INDENT_VERSION=`indent --version | grep GNU`
 125     if test $? -eq 0; then
 126        AC_SUBST(INDENT_FLAGS, '-i4 -nut -br -brs -npcs -ce -TGLubyte -TGLbyte -TBool')
 127     else
 128        INDENT="cat"
 129     fi
 130 fi
 131
 132 AX_CHECK_PYTHON_MAKO_MODULE($PYTHON_MAKO_REQUIRED)
 133
 134 if test -z "$PYTHON2"; then
 135     if test ! -f "$srcdir/src/util/format_srgb.c"; then
 136         AC_MSG_ERROR([Python not found - unable to generate sources])
 137     fi
 138 else
 139     if test "x$acv_mako_found" = xno; then
 140         if test ! -f "$srcdir/src/mesa/main/format_unpack.c"; then
 141             AC_MSG_ERROR([Python mako module v$PYTHON_MAKO_REQUIRED or higher not found])
 142         fi
 143     fi
 144 fi
 145
 146 AC_PROG_INSTALL
 147
 148 dnl We need a POSIX shell for parts of the build. Assume we have one
 149 dnl in most cases.
 150 case "$host_os" in
 151 solaris*)
 152     # Solaris /bin/sh is too old/non-POSIX compliant
 153     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
 154     SHELL="$POSIX_SHELL"
 155     ;;
 156 esac
 157
 158 dnl clang is mostly GCC-compatible, but its version is much lower,
 159 dnl so we have to check for it.
 160 AC_MSG_CHECKING([if compiling with clang])
 161
 162 AC_COMPILE_IFELSE(
 163 [AC_LANG_PROGRAM([], [[
 164 #ifndef __clang__
 165        not clang
 166 #endif
 167 ]])],
 168 [acv_mesa_CLANG=yes], [acv_mesa_CLANG=no])
 169
 170 AC_MSG_RESULT([$acv_mesa_CLANG])
 171
 172 dnl If we're using GCC, make sure that it is at least version 4.2.0.  Older
 173 dnl versions are explictly not supported.
 174 GEN_ASM_OFFSETS=no
 175 USE_GNU99=no
 176 if test "x$GCC" = xyes -a "x$acv_mesa_CLANG" = xno; then
 177     AC_MSG_CHECKING([whether gcc version is sufficient])
 178     major=0
 179     minor=0
 180
 181     GCC_VERSION=`$CC -dumpversion`
 182     if test $? -eq 0; then
 183         GCC_VERSION_MAJOR=`echo $GCC_VERSION | cut -d. -f1`
 184         GCC_VERSION_MINOR=`echo $GCC_VERSION | cut -d. -f2`
 185     fi
 186
 187     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 2 ; then
 188         AC_MSG_RESULT([no])
 189         AC_MSG_ERROR([If using GCC, version 4.2.0 or later is required.])
 190     else
 191         AC_MSG_RESULT([yes])
 192     fi
 193
 194     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6 ; then
 195         USE_GNU99=yes
 196     fi
 197     if test "x$cross_compiling" = xyes; then
 198         GEN_ASM_OFFSETS=yes
 199     fi
 200 fi
 201
 202 dnl We don't support building Mesa with Sun C compiler
 203 dnl https://bugs.freedesktop.org/show_bug.cgi?id=93189
 204 AC_CHECK_DECL([__SUNPRO_C], [SUNCC=yes], [SUNCC=no])
 205 if test "x$SUNCC" = xyes; then
 206     AC_MSG_ERROR([Building with Sun C compiler is not supported, use GCC instead.])
 207 fi
 208
 209 dnl Check for compiler builtins
 210 AX_GCC_BUILTIN([__builtin_bswap32])
 211 AX_GCC_BUILTIN([__builtin_bswap64])
 212 AX_GCC_BUILTIN([__builtin_clz])
 213 AX_GCC_BUILTIN([__builtin_clzll])
 214 AX_GCC_BUILTIN([__builtin_ctz])
 215 AX_GCC_BUILTIN([__builtin_expect])
 216 AX_GCC_BUILTIN([__builtin_ffs])
 217 AX_GCC_BUILTIN([__builtin_ffsll])
 218 AX_GCC_BUILTIN([__builtin_popcount])
 219 AX_GCC_BUILTIN([__builtin_popcountll])
 220 AX_GCC_BUILTIN([__builtin_unreachable])
 221
 222 AX_GCC_FUNC_ATTRIBUTE([const])
 223 AX_GCC_FUNC_ATTRIBUTE([flatten])
 224 AX_GCC_FUNC_ATTRIBUTE([format])
 225 AX_GCC_FUNC_ATTRIBUTE([malloc])
 226 AX_GCC_FUNC_ATTRIBUTE([packed])
 227 AX_GCC_FUNC_ATTRIBUTE([pure])
 228 AX_GCC_FUNC_ATTRIBUTE([returns_nonnull])
 229 AX_GCC_FUNC_ATTRIBUTE([unused])
 230 AX_GCC_FUNC_ATTRIBUTE([visibility])
 231 AX_GCC_FUNC_ATTRIBUTE([warn_unused_result])
 232 AX_GCC_FUNC_ATTRIBUTE([weak])
 233
 234 AM_CONDITIONAL([GEN_ASM_OFFSETS], test "x$GEN_ASM_OFFSETS" = xyes)
 235
 236 dnl Make sure the pkg-config macros are defined
 237 m4_ifndef([PKG_PROG_PKG_CONFIG],
 238     [m4_fatal([Could not locate the pkg-config autoconf macros.
 239   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 240   are in a different location, try setting the environment variable
 241   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 242 PKG_PROG_PKG_CONFIG()
 243
 244 dnl LIB_DIR - library basename
 245 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 246 AC_SUBST([LIB_DIR])
 247
 248 dnl Cache LDFLAGS and CPPFLAGS so we can add to them and restore later
 249 _SAVE_LDFLAGS="$LDFLAGS"
 250 _SAVE_CPPFLAGS="$CPPFLAGS"
 251
 252 dnl Compiler macros
 253 DEFINES="-D__STDC_LIMIT_MACROS -D__STDC_CONSTANT_MACROS"
 254 AC_SUBST([DEFINES])
 255 android=no
 256 case "$host_os" in
 257 *-android)
 258     android=yes
 259     ;;
 260 linux*|*-gnu*|gnu*|cygwin*)
 261     DEFINES="$DEFINES -D_GNU_SOURCE"
 262     ;;
 263 solaris*)
 264     DEFINES="$DEFINES -DSVR4"
 265     ;;
 266 esac
 267
 268 AM_CONDITIONAL(HAVE_ANDROID, test "x$android" = xyes)
 269
 270 dnl Add flags for gcc and g++
 271 if test "x$GCC" = xyes; then
 272     CFLAGS="$CFLAGS -Wall"
 273
 274     if test "x$USE_GNU99" = xyes; then
 275         CFLAGS="$CFLAGS -std=gnu99"
 276     else
 277         CFLAGS="$CFLAGS -std=c99"
 278     fi
 279
 280     # Enable -Werror=implicit-function-declaration and
 281     # -Werror=missing-prototypes, if available, or otherwise, just
 282     # -Wmissing-prototypes.  This is particularly useful to avoid
 283     # generating a loadable driver module that has undefined symbols.
 284     save_CFLAGS="$CFLAGS"
 285     AC_MSG_CHECKING([whether $CC supports -Werror=missing-prototypes])
 286     CFLAGS="$CFLAGS -Werror=implicit-function-declaration"
 287     CFLAGS="$CFLAGS -Werror=missing-prototypes"
 288     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 289                    AC_MSG_RESULT([yes]),
 290                    [CFLAGS="$save_CFLAGS -Wmissing-prototypes";
 291                     AC_MSG_RESULT([no])]);
 292
 293     # Enable -fvisibility=hidden if using a gcc that supports it
 294     save_CFLAGS="$CFLAGS"
 295     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 296     VISIBILITY_CFLAGS="-fvisibility=hidden"
 297     CFLAGS="$CFLAGS $VISIBILITY_CFLAGS"
 298     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 299                    [VISIBILITY_CFLAGS=""; AC_MSG_RESULT([no])]);
 300
 301     # Restore CFLAGS; VISIBILITY_CFLAGS are added to it where needed.
 302     CFLAGS=$save_CFLAGS
 303
 304     # We don't want floating-point math functions to set errno or trap
 305     CFLAGS="$CFLAGS -fno-math-errno -fno-trapping-math"
 306
 307     # Flags to help ensure that certain portions of the code -- and only those
 308     # portions -- can be built with MSVC:
 309     # - src/util, src/gallium/auxiliary, rc/gallium/drivers/llvmpipe, and
 310     # - non-Linux/Posix OpenGL portions needs to build on MSVC 2013 (which
 311     #   supports most of C99)
 312     # - the rest has no compiler compiler restrictions
 313     MSVC2013_COMPAT_CFLAGS="-Werror=pointer-arith"
 314     MSVC2013_COMPAT_CXXFLAGS="-Werror=pointer-arith"
 315
 316     # Enable -Werror=vla if compiler supports it
 317     save_CFLAGS="$CFLAGS"
 318     AC_MSG_CHECKING([whether $CC supports -Werror=vla])
 319     CFLAGS="$CFLAGS -Werror=vla"
 320     AC_LINK_IFELSE([AC_LANG_PROGRAM()],
 321                    [MSVC2013_COMPAT_CFLAGS="$MSVC2013_COMPAT_CFLAGS -Werror=vla";
 322                     MSVC2013_COMPAT_CXXFLAGS="$MSVC2013_COMPAT_CXXFLAGS -Werror=vla";
 323                     AC_MSG_RESULT([yes])],
 324                     AC_MSG_RESULT([no]));
 325     CFLAGS="$save_CFLAGS"
 326 fi
 327 if test "x$GXX" = xyes; then
 328     CXXFLAGS="$CXXFLAGS -Wall"
 329
 330     # Enable -fvisibility=hidden if using a gcc that supports it
 331     save_CXXFLAGS="$CXXFLAGS"
 332     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 333     VISIBILITY_CXXFLAGS="-fvisibility=hidden"
 334     CXXFLAGS="$CXXFLAGS $VISIBILITY_CXXFLAGS"
 335     AC_LANG_PUSH([C++])
 336     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 337                    [VISIBILITY_CXXFLAGS="" ; AC_MSG_RESULT([no])]);
 338     AC_LANG_POP([C++])
 339
 340     # Restore CXXFLAGS; VISIBILITY_CXXFLAGS are added to it where needed.
 341     CXXFLAGS=$save_CXXFLAGS
 342
 343     # We don't want floating-point math functions to set errno or trap
 344     CXXFLAGS="$CXXFLAGS -fno-math-errno -fno-trapping-math"
 345 fi
 346
 347 AC_SUBST([MSVC2013_COMPAT_CFLAGS])
 348 AC_SUBST([MSVC2013_COMPAT_CXXFLAGS])
 349
 350 dnl even if the compiler appears to support it, using visibility attributes isn't
 351 dnl going to do anything useful currently on cygwin apart from emit lots of warnings
 352 case "$host_os" in
 353 cygwin*)
 354     VISIBILITY_CFLAGS=""
 355     VISIBILITY_CXXFLAGS=""
 356     ;;
 357 esac
 358
 359 AC_SUBST([VISIBILITY_CFLAGS])
 360 AC_SUBST([VISIBILITY_CXXFLAGS])
 361
 362 dnl
 363 dnl Optional flags, check for compiler support
 364 dnl
 365 SSE41_CFLAGS="-msse4.1"
 366 dnl Code compiled by GCC with -msse* assumes a 16 byte aligned
 367 dnl stack, but on x86-32 such alignment is not guaranteed.
 368 case "$target_cpu" in
 369 i?86)
 370     SSE41_CFLAGS="$SSE41_CFLAGS -mstackrealign"
 371     ;;
 372 esac
 373 save_CFLAGS="$CFLAGS"
 374 CFLAGS="$SSE41_CFLAGS $CFLAGS"
 375 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 376 #include <smmintrin.h>
 377 int param;
 378 int main () {
 379     __m128i a = _mm_set1_epi32 (param), b = _mm_set1_epi32 (param + 1), c;
 380     c = _mm_max_epu32(a, b);
 381     return _mm_cvtsi128_si32(c);
 382 }]])], SSE41_SUPPORTED=1)
 383 CFLAGS="$save_CFLAGS"
 384 if test "x$SSE41_SUPPORTED" = x1; then
 385     DEFINES="$DEFINES -DUSE_SSE41"
 386 fi
 387 AM_CONDITIONAL([SSE41_SUPPORTED], [test x$SSE41_SUPPORTED = x1])
 388 AC_SUBST([SSE41_CFLAGS], $SSE41_CFLAGS)
 389
 390 dnl Check for new-style atomic builtins
 391 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 392 int main() {
 393     int n;
 394     return __atomic_load_n(&n, __ATOMIC_ACQUIRE);
 395 }]])], GCC_ATOMIC_BUILTINS_SUPPORTED=1)
 396 if test "x$GCC_ATOMIC_BUILTINS_SUPPORTED" = x1; then
 397     DEFINES="$DEFINES -DUSE_GCC_ATOMIC_BUILTINS"
 398 fi
 399 AM_CONDITIONAL([GCC_ATOMIC_BUILTINS_SUPPORTED], [test x$GCC_ATOMIC_BUILTINS_SUPPORTED = x1])
 400
 401 dnl Check for Endianness
 402 AC_C_BIGENDIAN(
 403    little_endian=no,
 404    little_endian=yes,
 405    little_endian=no,
 406    little_endian=no
 407 )
 408
 409 dnl Check for POWER8 Architecture
 410 PWR8_CFLAGS="-mpower8-vector"
 411 have_pwr8_intrinsics=no
 412 AC_MSG_CHECKING(whether gcc supports -mpower8-vector)
 413 save_CFLAGS=$CFLAGS
 414 CFLAGS="$PWR8_CFLAGS $CFLAGS"
 415 AC_COMPILE_IFELSE([AC_LANG_SOURCE([[
 416 #if defined(__GNUC__) && (__GNUC__ < 4 || (__GNUC__ == 4 && __GNUC_MINOR__ < 8))
 417 #error "Need GCC >= 4.8 for sane POWER8 support"
 418 #endif
 419 #include <altivec.h>
 420 int main () {
 421     vector unsigned char r;
 422     vector unsigned int v = vec_splat_u32 (1);
 423     r = __builtin_vec_vgbbd ((vector unsigned char) v);
 424     return 0;
 425 }]])], have_pwr8_intrinsics=yes)
 426 CFLAGS=$save_CFLAGS
 427
 428 AC_ARG_ENABLE(pwr8,
 429    [AC_HELP_STRING([--disable-pwr8-inst],
 430                    [disable POWER8-specific instructions])],
 431    [enable_pwr8=$enableval], [enable_pwr8=auto])
 432
 433 if test "x$enable_pwr8" = xno ; then
 434    have_pwr8_intrinsics=disabled
 435 fi
 436
 437 if test $have_pwr8_intrinsics = yes && test $little_endian = yes ; then
 438    DEFINES="$DEFINES -D_ARCH_PWR8"
 439    CXXFLAGS="$CXXFLAGS $PWR8_CFLAGS"
 440    CFLAGS="$CFLAGS $PWR8_CFLAGS"
 441 else
 442    PWR8_CFLAGS=
 443 fi
 444
 445 AC_MSG_RESULT($have_pwr8_intrinsics)
 446 if test "x$enable_pwr8" = xyes && test $have_pwr8_intrinsics = no ; then
 447    AC_MSG_ERROR([POWER8 compiler support not detected])
 448 fi
 449
 450 if test $have_pwr8_intrinsics = yes && test $little_endian = no ; then
 451    AC_MSG_WARN([POWER8 optimization is enabled only on POWER8 Little-Endian])
 452 fi
 453
 454 AC_SUBST([PWR8_CFLAGS], $PWR8_CFLAGS)
 455
 456 dnl Can't have static and shared libraries, default to static if user
 457 dnl explicitly requested. If both disabled, set to static since shared
 458 dnl was explicitly requested.
 459 case "x$enable_static$enable_shared" in
 460 xyesyes)
 461     AC_MSG_WARN([Cannot build static and shared libraries, disabling shared])
 462     enable_shared=no
 463     ;;
 464 xnono)
 465     AC_MSG_WARN([Cannot disable both static and shared libraries, enabling shared])
 466     enable_shared=yes
 467     ;;
 468 esac
 469
 470 AM_CONDITIONAL(BUILD_SHARED, test "x$enable_shared" = xyes)
 471
 472 dnl
 473 dnl other compiler options
 474 dnl
 475 AC_ARG_ENABLE([debug],
 476     [AS_HELP_STRING([--enable-debug],
 477         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 478     [enable_debug="$enableval"],
 479     [enable_debug=no]
 480 )
 481
 482 AC_ARG_ENABLE([profile],
 483     [AS_HELP_STRING([--enable-profile],
 484         [enable profiling of code @<:@default=disabled@:>@])],
 485     [enable_profile="$enableval"],
 486     [enable_profile=no]
 487 )
 488
 489 if test "x$enable_profile" = xyes; then
 490     DEFINES="$DEFINES -DPROFILE"
 491     if test "x$GCC" = xyes; then
 492         CFLAGS="$CFLAGS -fno-omit-frame-pointer"
 493     fi
 494     if test "x$GXX" = xyes; then
 495         CXXFLAGS="$CXXFLAGS -fno-omit-frame-pointer"
 496     fi
 497 fi
 498
 499 if test "x$enable_debug" = xyes; then
 500     DEFINES="$DEFINES -DDEBUG"
 501     if test "x$enable_profile" = xyes; then
 502         AC_MSG_WARN([Debug and Profile are enabled at the same time])
 503     fi
 504     if test "x$GCC" = xyes; then
 505         if ! echo "$CFLAGS" | grep -q -e '-g'; then
 506             CFLAGS="$CFLAGS -g"
 507         fi
 508         if ! echo "$CFLAGS" | grep -q -e '-O'; then
 509             CFLAGS="$CFLAGS -O0"
 510         fi
 511     fi
 512     if test "x$GXX" = xyes; then
 513         if ! echo "$CXXFLAGS" | grep -q -e '-g'; then
 514             CXXFLAGS="$CXXFLAGS -g"
 515         fi
 516         if ! echo "$CXXFLAGS" | grep -q -e '-O'; then
 517             CXXFLAGS="$CXXFLAGS -O0"
 518         fi
 519     fi
 520 else
 521    DEFINES="$DEFINES -DNDEBUG"
 522 fi
 523
 524 DEFAULT_GL_LIB_NAME=GL
 525
 526 dnl
 527 dnl Check if linker supports -Bsymbolic
 528 dnl
 529 save_LDFLAGS=$LDFLAGS
 530 LDFLAGS="$LDFLAGS -Wl,-Bsymbolic"
 531 AC_MSG_CHECKING([if ld supports -Bsymbolic])
 532 AC_LINK_IFELSE(
 533     [AC_LANG_SOURCE([int main() { return 0;}])],
 534     [AC_MSG_RESULT([yes])
 535         BSYMBOLIC="-Wl,-Bsymbolic";],
 536     [AC_MSG_RESULT([no])
 537         BSYMBOLIC="";])
 538 LDFLAGS=$save_LDFLAGS
 539
 540 AC_SUBST([BSYMBOLIC])
 541
 542 dnl
 543 dnl Check if linker supports garbage collection
 544 dnl
 545 save_LDFLAGS=$LDFLAGS
 546 LDFLAGS="$LDFLAGS -Wl,--gc-sections"
 547 AC_MSG_CHECKING([whether ld supports --gc-sections])
 548 AC_LINK_IFELSE(
 549     [AC_LANG_SOURCE([static char UnusedFunc() { return 5; } int main() { return 0;}])],
 550     [AC_MSG_RESULT([yes])
 551         GC_SECTIONS="-Wl,--gc-sections";],
 552     [AC_MSG_RESULT([no])
 553         GC_SECTIONS="";])
 554 LDFLAGS=$save_LDFLAGS
 555
 556 AC_SUBST([GC_SECTIONS])
 557
 558 dnl
 559 dnl OpenBSD does not have DT_NEEDED entries for libc by design
 560 dnl so when these flags are passed to ld via libtool the checks will fail
 561 dnl
 562 case "$host_os" in
 563 openbsd* | darwin* )
 564     LD_NO_UNDEFINED="" ;;
 565 *)
 566     LD_NO_UNDEFINED="-Wl,--no-undefined" ;;
 567 esac
 568
 569 AC_SUBST([LD_NO_UNDEFINED])
 570
 571 dnl
 572 dnl Check if linker supports version scripts
 573 dnl
 574 AC_MSG_CHECKING([if the linker supports version-scripts])
 575 save_LDFLAGS=$LDFLAGS
 576 LDFLAGS="$LDFLAGS -Wl,--version-script=conftest.map"
 577 cat > conftest.map <<EOF
 578 VERSION_1 {
 579      global:
 580          main;
 581
 582      local:
 583          *;
 584 };
 585 EOF
 586 AC_LINK_IFELSE(
 587     [AC_LANG_SOURCE([int main() { return 0;}])],
 588     [have_ld_version_script=yes;AC_MSG_RESULT(yes)],
 589     [have_ld_version_script=no; AC_MSG_RESULT(no)])
 590 LDFLAGS=$save_LDFLAGS
 591 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 592
 593 dnl
 594 dnl Check if linker supports dynamic list files
 595 dnl
 596 AC_MSG_CHECKING([if the linker supports --dynamic-list])
 597 save_LDFLAGS=$LDFLAGS
 598 LDFLAGS="$LDFLAGS -Wl,--dynamic-list=conftest.dyn"
 599 cat > conftest.dyn <<EOF
 600 {
 601         radeon_drm_winsys_create;
 602 };
 603 EOF
 604 AC_LINK_IFELSE(
 605     [AC_LANG_SOURCE([int main() { return 0;}])],
 606     [have_ld_dynamic_list=yes;AC_MSG_RESULT(yes)],
 607     [have_ld_dynamic_list=no; AC_MSG_RESULT(no)])
 608 LDFLAGS=$save_LDFLAGS
 609 AM_CONDITIONAL(HAVE_LD_DYNAMIC_LIST, test "$have_ld_dynamic_list" = "yes")
 610
 611 dnl
 612 dnl compatibility symlinks
 613 dnl
 614 case "$host_os" in
 615 linux* )
 616     HAVE_COMPAT_SYMLINKS=yes ;;
 617 * )
 618     HAVE_COMPAT_SYMLINKS=no ;;
 619 esac
 620
 621 AM_CONDITIONAL(HAVE_COMPAT_SYMLINKS, test "x$HAVE_COMPAT_SYMLINKS" = xyes)
 622
 623 DEFAULT_GL_LIB_NAME=GL
 624
 625 dnl
 626 dnl Libglvnd configuration
 627 dnl
 628 AC_ARG_ENABLE([libglvnd],
 629     [AS_HELP_STRING([--enable-libglvnd],
 630         [Build for libglvnd @<:@default=disabled@:>@])],
 631     [enable_libglvnd="$enableval"],
 632     [enable_libglvnd=no])
 633 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
 634 #AM_COND_IF([USE_LIBGLVND_GLX], [DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"])
 635 if test "x$enable_libglvnd" = xyes ; then
 636     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
 637     DEFAULT_GL_LIB_NAME=GLX_mesa
 638 fi
 639
 640 dnl
 641 dnl library names
 642 dnl
 643 dnl Unfortunately we need to do a few things that libtool can't help us with,
 644 dnl so we need some knowledge of shared library filenames:
 645 dnl
 646 dnl LIB_EXT is the extension used when creating symlinks for alternate
 647 dnl filenames for a shared library which will be dynamically loaded
 648 dnl
 649 dnl IMP_LIB_EXT is the extension used when checking for the presence of a
 650 dnl the file for a shared library we wish to link with
 651 dnl
 652 case "$host_os" in
 653 darwin* )
 654     LIB_EXT='dylib'
 655     IMP_LIB_EXT=$LIB_EXT
 656     ;;
 657 cygwin* )
 658     LIB_EXT='dll'
 659     IMP_LIB_EXT='dll.a'
 660     ;;
 661 aix* )
 662     LIB_EXT='a'
 663     IMP_LIB_EXT=$LIB_EXT
 664     ;;
 665 * )
 666     LIB_EXT='so'
 667     IMP_LIB_EXT=$LIB_EXT
 668     ;;
 669 esac
 670
 671 AC_SUBST([LIB_EXT])
 672
 673 AC_ARG_WITH([gl-lib-name],
 674   [AS_HELP_STRING([--with-gl-lib-name@<:@=NAME@:>@],
 675     [specify GL library name @<:@default=GL@:>@])],
 676   [GL_LIB=$withval],
 677   [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 678 AC_ARG_WITH([osmesa-lib-name],
 679   [AS_HELP_STRING([--with-osmesa-lib-name@<:@=NAME@:>@],
 680     [specify OSMesa library name @<:@default=OSMesa@:>@])],
 681   [OSMESA_LIB=$withval],
 682   [OSMESA_LIB=OSMesa])
 683 AS_IF([test "x$GL_LIB" = xyes], [GL_LIB="$DEFAULT_GL_LIB_NAME"])
 684 AS_IF([test "x$OSMESA_LIB" = xyes], [OSMESA_LIB=OSMesa])
 685
 686 dnl
 687 dnl Mangled Mesa support
 688 dnl
 689 AC_ARG_ENABLE([mangling],
 690   [AS_HELP_STRING([--enable-mangling],
 691     [enable mangled symbols and library name @<:@default=disabled@:>@])],
 692   [enable_mangling="${enableval}"],
 693   [enable_mangling=no]
 694 )
 695 if test "x${enable_mangling}" = "xyes" ; then
 696   DEFINES="${DEFINES} -DUSE_MGL_NAMESPACE"
 697   GL_LIB="Mangled${GL_LIB}"
 698   OSMESA_LIB="Mangled${OSMESA_LIB}"
 699 fi
 700 AC_SUBST([GL_LIB])
 701 AC_SUBST([OSMESA_LIB])
 702
 703 dnl
 704 dnl potentially-infringing-but-nobody-knows-for-sure stuff
 705 dnl
 706 AC_ARG_ENABLE([texture-float],
 707     [AS_HELP_STRING([--enable-texture-float],
 708         [enable floating-point textures and renderbuffers @<:@default=disabled@:>@])],
 709     [enable_texture_float="$enableval"],
 710     [enable_texture_float=no]
 711 )
 712 if test "x$enable_texture_float" = xyes; then
 713     AC_MSG_WARN([Floating-point textures enabled.])
 714     AC_MSG_WARN([Please consult docs/patents.txt with your lawyer before building Mesa.])
 715     DEFINES="$DEFINES -DTEXTURE_FLOAT_ENABLED"
 716 fi
 717
 718 dnl
 719 dnl Arch/platform-specific settings
 720 dnl
 721 AC_ARG_ENABLE([asm],
 722     [AS_HELP_STRING([--disable-asm],
 723         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 724     [enable_asm="$enableval"],
 725     [enable_asm=yes]
 726 )
 727 asm_arch=""
 728 AC_MSG_CHECKING([whether to enable assembly])
 729 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 730 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 731 if test "x$enable_asm" = xyes -a "x$cross_compiling" = xyes; then
 732     case "$host_cpu" in
 733     i?86 | x86_64 | amd64)
 734         if test "x$host_cpu" != "x$target_cpu"; then
 735             enable_asm=no
 736             AC_MSG_RESULT([no, cross compiling])
 737         fi
 738         ;;
 739     esac
 740 fi
 741 # check for supported arches
 742 if test "x$enable_asm" = xyes; then
 743     case "$host_cpu" in
 744     i?86)
 745         case "$host_os" in
 746         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd* | gnu*)
 747             asm_arch=x86
 748             ;;
 749         esac
 750         ;;
 751     x86_64|amd64)
 752         case "$host_os" in
 753         linux* | *freebsd* | dragonfly* | *netbsd* | openbsd*)
 754             asm_arch=x86_64
 755             ;;
 756         esac
 757         ;;
 758     sparc*)
 759         case "$host_os" in
 760         linux*)
 761             asm_arch=sparc
 762             ;;
 763         esac
 764         ;;
 765     esac
 766
 767     case "$asm_arch" in
 768     x86)
 769         DEFINES="$DEFINES -DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 770         AC_MSG_RESULT([yes, x86])
 771         ;;
 772     x86_64|amd64)
 773         DEFINES="$DEFINES -DUSE_X86_64_ASM"
 774         AC_MSG_RESULT([yes, x86_64])
 775         ;;
 776     sparc)
 777         DEFINES="$DEFINES -DUSE_SPARC_ASM"
 778         AC_MSG_RESULT([yes, sparc])
 779         ;;
 780     *)
 781         AC_MSG_RESULT([no, platform not supported])
 782         ;;
 783     esac
 784 fi
 785
 786 AC_HEADER_MAJOR
 787 AC_CHECK_HEADER([xlocale.h], [DEFINES="$DEFINES -DHAVE_XLOCALE_H"])
 788 AC_CHECK_HEADER([sys/sysctl.h], [DEFINES="$DEFINES -DHAVE_SYS_SYSCTL_H"])
 789 AC_CHECK_FUNC([strtof], [DEFINES="$DEFINES -DHAVE_STRTOF"])
 790 AC_CHECK_FUNC([mkostemp], [DEFINES="$DEFINES -DHAVE_MKOSTEMP"])
 791
 792 dnl Check to see if dlopen is in default libraries (like Solaris, which
 793 dnl has it in libc), or if libdl is needed to get it.
 794 AC_CHECK_FUNC([dlopen], [DEFINES="$DEFINES -DHAVE_DLOPEN"],
 795     [AC_CHECK_LIB([dl], [dlopen],
 796        [DEFINES="$DEFINES -DHAVE_DLOPEN"; DLOPEN_LIBS="-ldl"])])
 797 AC_SUBST([DLOPEN_LIBS])
 798
 799 dnl Check if that library also has dladdr
 800 save_LIBS="$LIBS"
 801 LIBS="$LIBS $DLOPEN_LIBS"
 802 AC_CHECK_FUNCS([dladdr])
 803 LIBS="$save_LIBS"
 804
 805 case "$host_os" in
 806 darwin*)
 807     ;;
 808 *)
 809     AC_CHECK_FUNCS([clock_gettime], [CLOCK_LIB=],
 810                    [AC_CHECK_LIB([rt], [clock_gettime], [CLOCK_LIB=-lrt],
 811                                  [AC_MSG_ERROR([Could not find clock_gettime])])])
 812     AC_SUBST([CLOCK_LIB])
 813     ;;
 814 esac
 815
 816 dnl See if posix_memalign is available
 817 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 818
 819 dnl Check for pthreads
 820 AX_PTHREAD
 821 if test "x$ax_pthread_ok" = xno; then
 822     AC_MSG_ERROR([Building mesa on this platform requires pthreads])
 823 fi
 824 dnl AX_PTHREADS leaves PTHREAD_LIBS empty for gcc and sets PTHREAD_CFLAGS
 825 dnl to -pthread, which causes problems if we need -lpthread to appear in
 826 dnl pkgconfig files.
 827 test -z "$PTHREAD_LIBS" && PTHREAD_LIBS="-lpthread"
 828
 829 dnl pthread-stubs is mandatory on targets where it exists
 830 case "$host_os" in
 831 cygwin* )
 832     pthread_stubs_possible="no"
 833     ;;
 834 * )
 835     pthread_stubs_possible="yes"
 836     ;;
 837 esac
 838
 839 if test "x$pthread_stubs_possible" = xyes; then
 840     PKG_CHECK_MODULES(PTHREADSTUBS, pthread-stubs)
 841     AC_SUBST(PTHREADSTUBS_CFLAGS)
 842     AC_SUBST(PTHREADSTUBS_LIBS)
 843 fi
 844
 845 dnl SELinux awareness.
 846 AC_ARG_ENABLE([selinux],
 847     [AS_HELP_STRING([--enable-selinux],
 848         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 849     [MESA_SELINUX="$enableval"],
 850     [MESA_SELINUX=no])
 851 if test "x$enable_selinux" = "xyes"; then
 852     PKG_CHECK_MODULES([SELINUX], [libselinux], [],
 853         [AC_CHECK_HEADER([selinux/selinux.h],[],
 854                          [AC_MSG_ERROR([SELinux headers not found])])
 855          AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 856                       [AC_MSG_ERROR([SELinux library not found])])
 857          SELINUX_LIBS="-lselinux"])
 858     DEFINES="$DEFINES -DMESA_SELINUX"
 859 fi
 860 AC_SUBST([SELINUX_CFLAGS])
 861 AC_SUBST([SELINUX_LIBS])
 862
 863 dnl Options for APIs
 864 AC_ARG_ENABLE([opengl],
 865     [AS_HELP_STRING([--disable-opengl],
 866         [disable support for standard OpenGL API @<:@default=enabled@:>@])],
 867     [enable_opengl="$enableval"],
 868     [enable_opengl=yes])
 869 AC_ARG_ENABLE([gles1],
 870     [AS_HELP_STRING([--disable-gles1],
 871         [disable support for OpenGL ES 1.x API @<:@default=enabled@:>@])],
 872     [enable_gles1="$enableval"],
 873     [enable_gles1=yes])
 874 AC_ARG_ENABLE([gles2],
 875     [AS_HELP_STRING([--disable-gles2],
 876         [disable support for OpenGL ES 2.x API @<:@default=enabled@:>@])],
 877     [enable_gles2="$enableval"],
 878     [enable_gles2=yes])
 879
 880 AC_ARG_ENABLE([dri],
 881     [AS_HELP_STRING([--enable-dri],
 882         [enable DRI modules @<:@default=enabled@:>@])],
 883     [enable_dri="$enableval"],
 884     [enable_dri=yes])
 885
 886 AC_ARG_ENABLE([gallium-extra-hud],
 887     [AS_HELP_STRING([--enable-gallium-extra-hud],
 888         [enable HUD block/NIC I/O HUD stats support @<:@default=disabled@:>@])],
 889     [enable_gallium_extra_hud="$enableval"],
 890     [enable_gallium_extra_hud=no])
 891 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes)
 892 if test "x$enable_gallium_extra_hud" = xyes ; then
 893     DEFINES="${DEFINES} -DHAVE_GALLIUM_EXTRA_HUD=1"
 894 fi
 895
 896 #TODO: no pkgconfig .pc available for libsensors.
 897 #PKG_CHECK_MODULES([LIBSENSORS], [libsensors >= $LIBSENSORS_REQUIRED], [enable_lmsensors=yes], [enable_lmsensors=no])
 898 AC_ARG_ENABLE([lmsensors],
 899     [AS_HELP_STRING([--enable-lmsensors],
 900         [enable HUD lmsensor support @<:@default=disabled@:>@])],
 901     [enable_lmsensors="$enableval"],
 902     [enable_lmsensors=no])
 903 AM_CONDITIONAL(HAVE_LIBSENSORS, test "x$enable_lmsensors" = xyes)
 904 if test "x$enable_lmsensors" = xyes ; then
 905     DEFINES="${DEFINES} -DHAVE_LIBSENSORS=1"
 906     LIBSENSORS_LDFLAGS="-lsensors"
 907 else
 908     LIBSENSORS_LDFLAGS=""
 909 fi
 910 AC_SUBST(LIBSENSORS_LDFLAGS)
 911
 912 case "$host_os" in
 913 linux*)
 914     dri3_default=yes
 915     ;;
 916 *)
 917     dri3_default=no
 918     ;;
 919 esac
 920
 921 if test "x$enable_dri" = xno; then
 922     dri3_default=no
 923 fi
 924
 925 AC_ARG_ENABLE([dri3],
 926     [AS_HELP_STRING([--enable-dri3],
 927         [enable DRI3 @<:@default=auto@:>@])],
 928     [enable_dri3="$enableval"],
 929     [enable_dri3="$dri3_default"])
 930 AC_ARG_ENABLE([glx],
 931     [AS_HELP_STRING([--enable-glx@<:@=dri|xlib|gallium-xlib@:>@],
 932         [enable the GLX library and choose an implementation @<:@default=auto@:>@])],
 933     [enable_glx="$enableval"],
 934     [enable_glx=yes])
 935 AC_ARG_ENABLE([osmesa],
 936     [AS_HELP_STRING([--enable-osmesa],
 937         [enable OSMesa library @<:@default=disabled@:>@])],
 938     [enable_osmesa="$enableval"],
 939     [enable_osmesa=no])
 940 AC_ARG_ENABLE([gallium-osmesa],
 941     [AS_HELP_STRING([--enable-gallium-osmesa],
 942         [enable Gallium implementation of the OSMesa library @<:@default=disabled@:>@])],
 943     [enable_gallium_osmesa="$enableval"],
 944     [enable_gallium_osmesa=no])
 945 AC_ARG_ENABLE([egl],
 946     [AS_HELP_STRING([--disable-egl],
 947         [disable EGL library @<:@default=enabled@:>@])],
 948     [enable_egl="$enableval"],
 949     [enable_egl=yes])
 950
 951 AC_ARG_ENABLE([xa],
 952     [AS_HELP_STRING([--enable-xa],
 953         [enable build of the XA X Acceleration API @<:@default=disabled@:>@])],
 954     [enable_xa="$enableval"],
 955     [enable_xa=no])
 956 AC_ARG_ENABLE([gbm],
 957    [AS_HELP_STRING([--enable-gbm],
 958          [enable gbm library @<:@default=auto@:>@])],
 959    [enable_gbm="$enableval"],
 960    [enable_gbm=auto])
 961 AC_ARG_ENABLE([nine],
 962     [AS_HELP_STRING([--enable-nine],
 963         [enable build of the nine Direct3D9 API @<:@default=no@:>@])],
 964     [enable_nine="$enableval"],
 965     [enable_nine=no])
 966
 967 AC_ARG_ENABLE([xvmc],
 968    [AS_HELP_STRING([--enable-xvmc],
 969          [enable xvmc library @<:@default=auto@:>@])],
 970    [enable_xvmc="$enableval"],
 971    [enable_xvmc=auto])
 972 AC_ARG_ENABLE([vdpau],
 973    [AS_HELP_STRING([--enable-vdpau],
 974          [enable vdpau library @<:@default=auto@:>@])],
 975    [enable_vdpau="$enableval"],
 976    [enable_vdpau=auto])
 977 AC_ARG_ENABLE([omx],
 978    [AS_HELP_STRING([--enable-omx],
 979          [enable OpenMAX library @<:@default=disabled@:>@])],
 980    [enable_omx="$enableval"],
 981    [enable_omx=no])
 982 AC_ARG_ENABLE([va],
 983    [AS_HELP_STRING([--enable-va],
 984          [enable va library @<:@default=auto@:>@])],
 985    [enable_va="$enableval"],
 986    [enable_va=auto])
 987 AC_ARG_ENABLE([opencl],
 988    [AS_HELP_STRING([--enable-opencl],
 989          [enable OpenCL library @<:@default=disabled@:>@])],
 990    [enable_opencl="$enableval"],
 991    [enable_opencl=no])
 992 AC_ARG_ENABLE([opencl_icd],
 993    [AS_HELP_STRING([--enable-opencl-icd],
 994           [Build an OpenCL ICD library to be loaded by an ICD implementation
 995            @<:@default=disabled@:>@])],
 996     [enable_opencl_icd="$enableval"],
 997     [enable_opencl_icd=no])
 998
 999 AC_ARG_ENABLE([gallium-tests],
1000     [AS_HELP_STRING([--enable-gallium-tests],
1001         [Enable optional Gallium tests) @<:@default=disabled@:>@])],
1002     [enable_gallium_tests="$enableval"],
1003     [enable_gallium_tests=no])
1004
1005 # Option for Gallium drivers
1006
1007 # Keep this in sync with the --with-gallium-drivers help string default value
1008 GALLIUM_DRIVERS_DEFAULT="r300,r600,svga,swrast"
1009
1010 AC_ARG_WITH([gallium-drivers],
1011     [AS_HELP_STRING([--with-gallium-drivers@<:@=DIRS...@:>@],
1012         [comma delimited Gallium drivers list, e.g.
1013         "i915,ilo,nouveau,r300,r600,radeonsi,freedreno,svga,swrast,vc4,virgl"
1014         @<:@default=r300,r600,svga,swrast@:>@])],
1015     [with_gallium_drivers="$withval"],
1016     [with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT"])
1017
1018 # Doing '--without-gallium-drivers' will set this variable to 'no'.  Clear it
1019 # here so that the script doesn't choke on an unknown driver name later.
1020 case "$with_gallium_drivers" in
1021     yes) with_gallium_drivers="$GALLIUM_DRIVERS_DEFAULT" ;;
1022     no) with_gallium_drivers='' ;;
1023 esac
1024
1025 if test "x$enable_opengl" = xno -a \
1026         "x$enable_gles1" = xno -a \
1027         "x$enable_gles2" = xno -a \
1028         "x$enable_nine" = xno -a \
1029         "x$enable_xa" = xno -a \
1030         "x$enable_xvmc" = xno -a \
1031         "x$enable_vdpau" = xno -a \
1032         "x$enable_omx" = xno -a \
1033         "x$enable_va" = xno -a \
1034         "x$enable_opencl" = xno; then
1035     AC_MSG_ERROR([at least one API should be enabled])
1036 fi
1037
1038 # Building OpenGL ES1 and/or ES2 without OpenGL is not supported on mesa 9.0.x
1039 if test "x$enable_opengl" = xno -a \
1040         "x$enable_gles1" = xyes; then
1041     AC_MSG_ERROR([Building OpenGL ES1 without OpenGL is not supported])
1042 fi
1043
1044 if test "x$enable_opengl" = xno -a \
1045         "x$enable_gles2" = xyes; then
1046     AC_MSG_ERROR([Building OpenGL ES2 without OpenGL is not supported])
1047 fi
1048
1049 AM_CONDITIONAL(HAVE_OPENGL, test "x$enable_opengl" = xyes)
1050 AM_CONDITIONAL(HAVE_OPENGL_ES1, test "x$enable_gles1" = xyes)
1051 AM_CONDITIONAL(HAVE_OPENGL_ES2, test "x$enable_gles2" = xyes)
1052 AM_CONDITIONAL(NEED_OPENGL_COMMON, test "x$enable_opengl" = xyes -o \
1053                                         "x$enable_gles1" = xyes -o \
1054                                         "x$enable_gles2" = xyes)
1055
1056 # Validate GLX options
1057 if test "x$enable_glx" = xyes; then
1058     if test "x$enable_dri" = xyes; then
1059         enable_glx=dri
1060     elif test -n "$with_gallium_drivers"; then
1061         enable_glx=gallium-xlib
1062     else
1063         enable_glx=xlib
1064     fi
1065 fi
1066 case "x$enable_glx" in
1067 xdri | xxlib | xgallium-xlib)
1068     # GLX requires OpenGL
1069     if test "x$enable_opengl" = xno; then
1070         AC_MSG_ERROR([GLX cannot be built without OpenGL])
1071     fi
1072
1073     # Check individual dependencies
1074     case "x$enable_glx" in
1075     xdri)
1076         if test "x$enable_dri" = xno; then
1077             AC_MSG_ERROR([DRI-based GLX requires DRI to be enabled])
1078         fi
1079         ;;
1080     xxlib)
1081         if test "x$enable_dri" = xyes; then
1082             AC_MSG_ERROR([Xlib-based GLX cannot be built with DRI enabled])
1083         fi
1084         ;;
1085     xgallium-xlib )
1086         if test "x$enable_dri" = xyes; then
1087             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built with DRI enabled])
1088         fi
1089         if test -z "$with_gallium_drivers"; then
1090             AC_MSG_ERROR([Xlib-based (Gallium) GLX cannot be built without Gallium enabled])
1091         fi
1092         ;;
1093     esac
1094     ;;
1095 xno)
1096     ;;
1097 *)
1098     AC_MSG_ERROR([Illegal value for --enable-glx: $enable_glx])
1099     ;;
1100 esac
1101
1102 AM_CONDITIONAL(HAVE_GLX, test "x$enable_glx" != xno)
1103 AM_CONDITIONAL(HAVE_DRI_GLX, test "x$enable_glx" = xdri)
1104 AM_CONDITIONAL(HAVE_XLIB_GLX, test "x$enable_glx" = xxlib)
1105 AM_CONDITIONAL(HAVE_GALLIUM_XLIB_GLX, test "x$enable_glx" = xgallium-xlib)
1106
1107 dnl
1108 dnl Libglvnd configuration
1109 dnl
1110 AC_ARG_ENABLE([libglvnd],
1111     [AS_HELP_STRING([--enable-libglvnd],
1112         [Build for libglvnd @<:@default=disabled@:>@])],
1113     [enable_libglvnd="$enableval"],
1114     [enable_libglvnd=no])
1115 AM_CONDITIONAL(USE_LIBGLVND_GLX, test "x$enable_libglvnd" = xyes)
1116 if test "x$enable_libglvnd" = xyes ; then
1117     dnl XXX: update once we can handle more than libGL/glx.
1118     dnl Namely: we should error out if neither of the glvnd enabled libraries
1119     dnl are built
1120     case "x$enable_glx" in
1121     xno)
1122         AC_MSG_ERROR([cannot build libglvnd without GLX])
1123         ;;
1124     xxlib | xgallium-xlib )
1125         AC_MSG_ERROR([cannot build libgvnd when Xlib-GLX or Gallium-Xlib-GLX is enabled])
1126         ;;
1127     xdri)
1128         ;;
1129     esac
1130
1131     PKG_CHECK_MODULES([GLVND], libglvnd >= 0.1.0)
1132     DEFINES="${DEFINES} -DUSE_LIBGLVND_GLX=1"
1133     DEFAULT_GL_LIB_NAME=GLX_mesa
1134 fi
1135
1136 # Check for libdrm
1137 PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED],
1138                   [have_libdrm=yes], [have_libdrm=no])
1139 if test "x$have_libdrm" = xyes; then
1140         DEFINES="$DEFINES -DHAVE_LIBDRM"
1141 fi
1142
1143 require_libdrm() {
1144     if test "x$have_libdrm" != xyes; then
1145        AC_MSG_ERROR([$1 requires libdrm >= $LIBDRM_REQUIRED])
1146     fi
1147 }
1148
1149
1150 # Select which platform-dependent DRI code gets built
1151 case "$host_os" in
1152 darwin*)
1153     dri_platform='apple' ;;
1154 cygwin*)
1155     dri_platform='windows' ;;
1156 gnu*)
1157     dri_platform='none' ;;
1158 *)
1159     dri_platform='drm' ;;
1160 esac
1161
1162 if test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes; then
1163     have_drisw_kms='yes'
1164 fi
1165
1166 AM_CONDITIONAL(HAVE_DRICOMMON, test "x$enable_dri" = xyes )
1167 AM_CONDITIONAL(HAVE_DRISW, test "x$enable_dri" = xyes )
1168 AM_CONDITIONAL(HAVE_DRISW_KMS, test "x$have_drisw_kms" = xyes )
1169 AM_CONDITIONAL(HAVE_DRI2, test "x$enable_dri" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1170 AM_CONDITIONAL(HAVE_DRI3, test "x$enable_dri3" = xyes -a "x$dri_platform" = xdrm -a "x$have_libdrm" = xyes )
1171 AM_CONDITIONAL(HAVE_APPLEDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xapple )
1172 AM_CONDITIONAL(HAVE_LMSENSORS, test "x$enable_lmsensors" = xyes )
1173 AM_CONDITIONAL(HAVE_GALLIUM_EXTRA_HUD, test "x$enable_gallium_extra_hud" = xyes )
1174 AM_CONDITIONAL(HAVE_WINDOWSDRI, test "x$enable_dri" = xyes -a "x$dri_platform" = xwindows )
1175
1176 AC_ARG_ENABLE([shared-glapi],
1177     [AS_HELP_STRING([--enable-shared-glapi],
1178         [Enable shared glapi for OpenGL @<:@default=enabled@:>@])],
1179     [enable_shared_glapi="$enableval"],
1180     [enable_shared_glapi=yes])
1181
1182 case "x$enable_opengl$enable_gles1$enable_gles2" in
1183 x*yes*yes*)
1184     if test "x$enable_shared_glapi" = xno; then
1185         AC_MSG_ERROR([shared GLAPI required when building two or more of
1186                       the following APIs - opengl, gles1 gles2])
1187     fi
1188     ;;
1189 esac
1190
1191 AM_CONDITIONAL(HAVE_SHARED_GLAPI, test "x$enable_shared_glapi" = xyes)
1192
1193 # Build the pipe-drivers as separate libraries/modules.
1194 # Do not touch this unless you know what you are doing.
1195 # XXX: Expose via configure option ?
1196 enable_shared_pipe_drivers=no
1197
1198 dnl
1199 dnl Driver specific build directories
1200 dnl
1201
1202 if test "x$enable_gallium_osmesa" = xyes; then
1203     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1204         AC_MSG_ERROR([gallium_osmesa requires the gallium swrast driver])
1205     fi
1206     if test "x$enable_osmesa" = xyes; then
1207         AC_MSG_ERROR([Cannot enable both classic and Gallium OSMesa implementations])
1208     fi
1209 fi
1210
1211 AC_SUBST([MESA_LLVM])
1212
1213 # SHA1 hashing
1214 AC_ARG_WITH([sha1],
1215         [AS_HELP_STRING([--with-sha1=libc|libmd|libnettle|libgcrypt|libcrypto|libsha1|CommonCrypto|CryptoAPI],
1216         [choose SHA1 implementation])])
1217 case "x$with_sha1" in
1218 x | xlibc | xlibmd | xlibnettle | xlibgcrypt | xlibcrypto | xlibsha1 | xCommonCrypto | xCryptoAPI)
1219   ;;
1220 *)
1221         AC_MSG_ERROR([Illegal value for --with-sha1: $with_sha1])
1222 esac
1223
1224 AC_CHECK_FUNC([SHA1Init], [HAVE_SHA1_IN_LIBC=yes])
1225 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_LIBC" = xyes; then
1226         with_sha1=libc
1227 fi
1228 if test "x$with_sha1" = xlibc && test "x$HAVE_SHA1_IN_LIBC" != xyes; then
1229         AC_MSG_ERROR([sha1 in libc requested but not found])
1230 fi
1231 if test "x$with_sha1" = xlibc; then
1232         AC_DEFINE([HAVE_SHA1_IN_LIBC], [1],
1233                 [Use libc SHA1 functions])
1234         SHA1_LIBS=""
1235 fi
1236 AC_CHECK_FUNC([CC_SHA1_Init], [HAVE_SHA1_IN_COMMONCRYPTO=yes])
1237 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_COMMONCRYPTO" = xyes; then
1238         with_sha1=CommonCrypto
1239 fi
1240 if test "x$with_sha1" = xCommonCrypto && test "x$HAVE_SHA1_IN_COMMONCRYPTO" != xyes; then
1241         AC_MSG_ERROR([CommonCrypto requested but not found])
1242 fi
1243 if test "x$with_sha1" = xCommonCrypto; then
1244         AC_DEFINE([HAVE_SHA1_IN_COMMONCRYPTO], [1],
1245                 [Use CommonCrypto SHA1 functions])
1246         SHA1_LIBS=""
1247 fi
1248 dnl stdcall functions cannot be tested with AC_CHECK_LIB
1249 AC_CHECK_HEADER([wincrypt.h], [HAVE_SHA1_IN_CRYPTOAPI=yes], [], [#include <windows.h>])
1250 if test "x$with_sha1" = x && test "x$HAVE_SHA1_IN_CRYPTOAPI" = xyes; then
1251         with_sha1=CryptoAPI
1252 fi
1253 if test "x$with_sha1" = xCryptoAPI && test "x$HAVE_SHA1_IN_CRYPTOAPI" != xyes; then
1254         AC_MSG_ERROR([CryptoAPI requested but not found])
1255 fi
1256 if test "x$with_sha1" = xCryptoAPI; then
1257         AC_DEFINE([HAVE_SHA1_IN_CRYPTOAPI], [1],
1258                 [Use CryptoAPI SHA1 functions])
1259         SHA1_LIBS=""
1260 fi
1261 AC_CHECK_LIB([md], [SHA1Init], [HAVE_LIBMD=yes])
1262 if test "x$with_sha1" = x && test "x$HAVE_LIBMD" = xyes; then
1263         with_sha1=libmd
1264 fi
1265 if test "x$with_sha1" = xlibmd && test "x$HAVE_LIBMD" != xyes; then
1266         AC_MSG_ERROR([libmd requested but not found])
1267 fi
1268 if test "x$with_sha1" = xlibmd; then
1269         AC_DEFINE([HAVE_SHA1_IN_LIBMD], [1],
1270                   [Use libmd SHA1 functions])
1271         SHA1_LIBS=-lmd
1272 fi
1273 PKG_CHECK_MODULES([LIBSHA1], [libsha1], [HAVE_LIBSHA1=yes], [HAVE_LIBSHA1=no])
1274 if test "x$with_sha1" = x && test "x$HAVE_LIBSHA1" = xyes; then
1275    with_sha1=libsha1
1276 fi
1277 if test "x$with_sha1" = xlibsha1 && test "x$HAVE_LIBSHA1" != xyes; then
1278         AC_MSG_ERROR([libsha1 requested but not found])
1279 fi
1280 if test "x$with_sha1" = xlibsha1; then
1281         AC_DEFINE([HAVE_SHA1_IN_LIBSHA1], [1],
1282                   [Use libsha1 for SHA1])
1283         SHA1_LIBS=-lsha1
1284 fi
1285 AC_CHECK_LIB([nettle], [nettle_sha1_init], [HAVE_LIBNETTLE=yes])
1286 if test "x$with_sha1" = x && test "x$HAVE_LIBNETTLE" = xyes; then
1287         with_sha1=libnettle
1288 fi
1289 if test "x$with_sha1" = xlibnettle && test "x$HAVE_LIBNETTLE" != xyes; then
1290         AC_MSG_ERROR([libnettle requested but not found])
1291 fi
1292 if test "x$with_sha1" = xlibnettle; then
1293         AC_DEFINE([HAVE_SHA1_IN_LIBNETTLE], [1],
1294                   [Use libnettle SHA1 functions])
1295         SHA1_LIBS=-lnettle
1296 fi
1297 AC_CHECK_LIB([gcrypt], [gcry_md_open], [HAVE_LIBGCRYPT=yes])
1298 if test "x$with_sha1" = x && test "x$HAVE_LIBGCRYPT" = xyes; then
1299         with_sha1=libgcrypt
1300 fi
1301 if test "x$with_sha1" = xlibgcrypt && test "x$HAVE_LIBGCRYPT" != xyes; then
1302         AC_MSG_ERROR([libgcrypt requested but not found])
1303 fi
1304 if test "x$with_sha1" = xlibgcrypt; then
1305         AC_DEFINE([HAVE_SHA1_IN_LIBGCRYPT], [1],
1306                   [Use libgcrypt SHA1 functions])
1307         SHA1_LIBS=-lgcrypt
1308 fi
1309 # We don't need all of the OpenSSL libraries, just libcrypto
1310 AC_CHECK_LIB([crypto], [SHA1_Init], [HAVE_LIBCRYPTO=yes])
1311 PKG_CHECK_MODULES([OPENSSL], [openssl], [HAVE_OPENSSL_PKC=yes],
1312                   [HAVE_OPENSSL_PKC=no])
1313 if test "x$HAVE_LIBCRYPTO" = xyes || test "x$HAVE_OPENSSL_PKC" = xyes; then
1314         if test "x$with_sha1" = x; then
1315                 with_sha1=libcrypto
1316         fi
1317 else
1318         if test "x$with_sha1" = xlibcrypto; then
1319                 AC_MSG_ERROR([OpenSSL libcrypto requested but not found])
1320         fi
1321 fi
1322 if test "x$with_sha1" = xlibcrypto; then
1323         if test "x$HAVE_LIBCRYPTO" = xyes; then
1324                 SHA1_LIBS=-lcrypto
1325         else
1326                 SHA1_LIBS="$OPENSSL_LIBS"
1327                 SHA1_CFLAGS="$OPENSSL_CFLAGS"
1328         fi
1329 fi
1330 AC_MSG_CHECKING([for SHA1 implementation])
1331 AC_MSG_RESULT([$with_sha1])
1332 AC_SUBST(SHA1_LIBS)
1333 AC_SUBST(SHA1_CFLAGS)
1334
1335 # Enable a define for SHA1
1336 if test "x$with_sha1" != "x"; then
1337         DEFINES="$DEFINES -DHAVE_SHA1"
1338 fi
1339
1340 # Allow user to configure out the shader-cache feature
1341 AC_ARG_ENABLE([shader-cache],
1342     AS_HELP_STRING([--disable-shader-cache], [Disable binary shader cache]),
1343     [enable_shader_cache="$enableval"],
1344     [if test "x$with_sha1" != "x"; then
1345         enable_shader_cache=yes
1346      else
1347         enable_shader_cache=no
1348      fi])
1349 if test "x$with_sha1" = "x"; then
1350     if test "x$enable_shader_cache" = "xyes"; then
1351         AC_MSG_ERROR([Cannot enable shader cache (no SHA-1 implementation found)])
1352     fi
1353 fi
1354 AM_CONDITIONAL([ENABLE_SHADER_CACHE], [test x$enable_shader_cache = xyes])
1355 if test "x$enable_shader_cache" = "xyes"; then
1356    AC_DEFINE([ENABLE_SHADER_CACHE], [1], [Enable shader cache])
1357 fi
1358
1359 if test "x$enable_dri" = xyes; then
1360     if test "$enable_static" = yes; then
1361         AC_MSG_ERROR([Cannot use static libraries for DRI drivers])
1362     fi
1363
1364     # not a hard requirement as swrast does not depend on it
1365     if test "x$have_libdrm" = xyes; then
1366         DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
1367     fi
1368 fi
1369
1370 AC_ARG_ENABLE([driglx-direct],
1371     [AS_HELP_STRING([--disable-driglx-direct],
1372         [disable direct rendering in GLX and EGL for DRI \
1373             @<:@default=auto@:>@])],
1374     [driglx_direct="$enableval"],
1375     [driglx_direct="yes"])
1376
1377 dnl
1378 dnl libGL configuration per driver
1379 dnl
1380 case "x$enable_glx" in
1381 xxlib | xgallium-xlib)
1382     # Xlib-based GLX
1383     dri_modules="x11 xext xcb"
1384     PKG_CHECK_MODULES([XLIBGL], [$dri_modules])
1385     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1386     X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
1387     GL_LIB_DEPS="$XLIBGL_LIBS"
1388     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1389     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm $PTHREAD_LIBS"
1390     ;;
1391 xdri)
1392     # DRI-based GLX
1393     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
1394
1395     # find the DRI deps for libGL
1396     dri_modules="x11 xext xdamage xfixes x11-xcb xcb xcb-glx >= $XCBGLX_REQUIRED"
1397
1398     if test x"$driglx_direct" = xyes; then
1399         if test x"$dri_platform" = xdrm ; then
1400             DEFINES="$DEFINES -DGLX_USE_DRM"
1401             require_libdrm "Direct rendering"
1402
1403             PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
1404             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV libdrm >= $LIBDRM_REQUIRED"
1405             if test x"$enable_dri3" = xyes; then
1406                PKG_CHECK_MODULES([DRI3PROTO], [dri3proto >= $DRI3PROTO_REQUIRED])
1407                PKG_CHECK_MODULES([PRESENTPROTO], [presentproto >= $PRESENTPROTO_REQUIRED])
1408             fi
1409
1410             if test x"$enable_dri" = xyes; then
1411                dri_modules="$dri_modules xcb-dri2 >= $XCBDRI2_REQUIRED"
1412             fi
1413
1414             if test x"$enable_dri3" = xyes; then
1415                PKG_CHECK_EXISTS([xcb >= $XCB_REQUIRED], [], AC_MSG_ERROR([DRI3 requires xcb >= $XCB_REQUIRED]))
1416                dri3_modules="xcb xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED"
1417                PKG_CHECK_MODULES([XCB_DRI3], [$dri3_modules])
1418             fi
1419         fi
1420         if test x"$dri_platform" = xapple ; then
1421             DEFINES="$DEFINES -DGLX_USE_APPLEGL"
1422         fi
1423         if test x"$dri_platform" = xwindows ; then
1424             DEFINES="$DEFINES -DGLX_USE_WINDOWSGL"
1425         fi
1426     fi
1427
1428     # add xf86vidmode if available
1429     PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
1430     if test "$HAVE_XF86VIDMODE" = yes ; then
1431         dri_modules="$dri_modules xxf86vm"
1432     fi
1433
1434     PKG_CHECK_MODULES([DRIGL], [$dri_modules])
1435     GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
1436     X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
1437     GL_LIB_DEPS="$DRIGL_LIBS"
1438
1439     # need DRM libs, $PTHREAD_LIBS, etc.
1440     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1441     GL_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1442     ;;
1443 esac
1444
1445 # This is outside the case (above) so that it is invoked even for non-GLX
1446 # builds.
1447 AM_CONDITIONAL(HAVE_XF86VIDMODE, test "x$HAVE_XF86VIDMODE" = xyes)
1448
1449 GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1450 GLESv1_CM_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1451 GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1452 GLESv2_PC_LIB_PRIV="-lm $PTHREAD_LIBS $DLOPEN_LIBS"
1453
1454 AC_SUBST([X11_INCLUDES])
1455 AC_SUBST([GL_LIB_DEPS])
1456 AC_SUBST([GL_PC_REQ_PRIV])
1457 AC_SUBST([GL_PC_LIB_PRIV])
1458 AC_SUBST([GL_PC_CFLAGS])
1459 AC_SUBST([DRI_PC_REQ_PRIV])
1460 AC_SUBST([GLESv1_CM_LIB_DEPS])
1461 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
1462 AC_SUBST([GLESv2_LIB_DEPS])
1463 AC_SUBST([GLESv2_PC_LIB_PRIV])
1464
1465 AC_SUBST([HAVE_XF86VIDMODE])
1466
1467 dnl
1468 dnl More GLX setup
1469 dnl
1470 case "x$enable_glx" in
1471 xxlib | xgallium-xlib)
1472     DEFINES="$DEFINES -DUSE_XSHM"
1473     ;;
1474 xdri)
1475     DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
1476     if test "x$driglx_direct" = xyes; then
1477         DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
1478     fi
1479     ;;
1480 esac
1481
1482 dnl
1483 dnl TLS detection
1484 dnl
1485
1486 AC_ARG_ENABLE([glx-tls],
1487     [AS_HELP_STRING([--enable-glx-tls],
1488         [enable TLS support in GLX @<:@default=disabled@:>@])],
1489     [GLX_USE_TLS="$enableval"],
1490     [GLX_USE_TLS=no])
1491 AC_SUBST(GLX_TLS, ${GLX_USE_TLS})
1492
1493 AS_IF([test "x$GLX_USE_TLS" = xyes -a "x$ax_pthread_ok" = xyes],
1494       [DEFINES="${DEFINES} -DGLX_USE_TLS"])
1495
1496 dnl Read-only text section on x86 hardened platforms
1497 AC_ARG_ENABLE([glx-read-only-text],
1498     [AS_HELP_STRING([--enable-glx-read-only-text],
1499         [Disable writable .text section on x86 (decreases performance) @<:@default=disabled@:>@])],
1500     [enable_glx_read_only_text="$enableval"],
1501     [enable_glx_read_only_text=no])
1502 if test "x$enable_glx_read_only_text" = xyes; then
1503     DEFINES="$DEFINES -DGLX_X86_READONLY_TEXT"
1504 fi
1505
1506 dnl
1507 dnl More DRI setup
1508 dnl
1509 dnl Directory for DRI drivers
1510 AC_ARG_WITH([dri-driverdir],
1511     [AS_HELP_STRING([--with-dri-driverdir=DIR],
1512         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
1513     [DRI_DRIVER_INSTALL_DIR="$withval"],
1514     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
1515 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
1516 dnl Extra search path for DRI drivers
1517 AC_ARG_WITH([dri-searchpath],
1518     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
1519         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
1520     [DRI_DRIVER_SEARCH_DIR="$withval"],
1521     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
1522 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
1523 dnl Which drivers to build - default is chosen by platform
1524 AC_ARG_WITH([dri-drivers],
1525     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
1526         [comma delimited classic DRI drivers list, e.g.
1527         "swrast,i965,radeon" @<:@default=auto@:>@])],
1528     [with_dri_drivers="$withval"],
1529     [with_dri_drivers=auto])
1530
1531 if test "x$with_dri_drivers" = xauto; then
1532     if test "x$enable_opengl" = xyes -a "x$enable_dri" = xyes; then
1533         with_dri_drivers="yes"
1534     else
1535         with_dri_drivers="no"
1536     fi
1537 fi
1538 if test "x$with_dri_drivers" = xno; then
1539     with_dri_drivers=''
1540 fi
1541
1542 dnl If $with_dri_drivers is yes, drivers will be added through
1543 dnl platform checks. Set DEFINES and LIB_DEPS
1544 if test "x$enable_dri" = xyes; then
1545     # Platform specific settings and drivers to build
1546     case "$host_os" in
1547     linux*)
1548         DEFINES="$DEFINES -DHAVE_ALIAS"
1549         if test "x$enable_dri3" = xyes; then
1550             DEFINES="$DEFINES -DHAVE_DRI3"
1551         fi
1552
1553         case "$host_cpu" in
1554         powerpc* | sparc*)
1555             # Build only the drivers for cards that exist on PowerPC/sparc
1556             if test "x$with_dri_drivers" = "xyes"; then
1557                 with_dri_drivers="r200 radeon swrast"
1558             fi
1559             ;;
1560         esac
1561         ;;
1562     *freebsd* | dragonfly* | *netbsd* | openbsd*)
1563         DEFINES="$DEFINES -DHAVE_ALIAS"
1564         ;;
1565     gnu*)
1566         DEFINES="$DEFINES -DHAVE_ALIAS"
1567         ;;
1568     cygwin*)
1569         if test "x$with_dri_drivers" = "xyes"; then
1570             with_dri_drivers="swrast"
1571         fi
1572         ;;
1573     darwin*)
1574         DEFINES="$DEFINES -DGLX_ALIAS_UNSUPPORTED -DBUILDING_MESA"
1575         if test "x$with_dri_drivers" = "xyes"; then
1576             with_dri_drivers="swrast"
1577         fi
1578         ;;
1579     esac
1580
1581     # default drivers
1582     if test "x$with_dri_drivers" = "xyes"; then
1583         with_dri_drivers="i915 i965 nouveau r200 radeon swrast"
1584     fi
1585
1586     # Check for expat
1587     PKG_CHECK_MODULES([EXPAT], [expat], [],
1588         # expat version 2.0 and earlier do not provide expat.pc
1589         [AC_CHECK_HEADER([expat.h],[],
1590                          [AC_MSG_ERROR([Expat headers required for DRI not found])])
1591          AC_CHECK_LIB([expat],[XML_ParserCreate],[],
1592                      [AC_MSG_ERROR([Expat library required for DRI not found])])
1593          EXPAT_LIBS="-lexpat"])
1594
1595     # put all the necessary libs together
1596     DRI_LIB_DEPS="$DRI_LIB_DEPS $SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIBS -lm $PTHREAD_LIBS $DLOPEN_LIBS"
1597 fi
1598
1599 AC_SUBST([DRI_LIB_DEPS])
1600
1601 DRI_DIRS=''
1602 dnl Duplicates in DRI_DIRS are removed by sorting it at the end of this block
1603 if test -n "$with_dri_drivers"; then
1604     if test "x$enable_opengl" != xyes; then
1605         AC_MSG_ERROR([--with-dri-drivers requires OpenGL])
1606     fi
1607
1608     dri_drivers=`IFS=', '; echo $with_dri_drivers`
1609     for driver in $dri_drivers; do
1610         DRI_DIRS="$DRI_DIRS $driver"
1611         case "x$driver" in
1612         xi915)
1613             HAVE_I915_DRI=yes;
1614             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1615             ;;
1616         xi965)
1617             HAVE_I965_DRI=yes;
1618             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
1619             ;;
1620         xnouveau)
1621             HAVE_NOUVEAU_DRI=yes;
1622             PKG_CHECK_MODULES([NVVIEUX], [libdrm_nouveau >= $LIBDRM_NVVIEUX_REQUIRED])
1623             ;;
1624         xradeon)
1625             HAVE_RADEON_DRI=yes;
1626             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1627             ;;
1628         xr200)
1629             HAVE_R200_DRI=yes;
1630             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
1631             ;;
1632         xswrast)
1633             HAVE_SWRAST_DRI=yes;
1634             ;;
1635         *)
1636             AC_MSG_ERROR([classic DRI driver '$driver' does not exist])
1637             ;;
1638         esac
1639     done
1640     DRI_DIRS=`echo $DRI_DIRS|tr " " "\n"|sort -u|tr "\n" " "`
1641 fi
1642
1643
1644 #
1645 # Vulkan driver configuration
1646 #
1647
1648 AC_ARG_WITH([vulkan-drivers],
1649     [AS_HELP_STRING([--with-vulkan-drivers@<:@=DIRS...@:>@],
1650         [comma delimited Vulkan drivers list, e.g.
1651         "intel"
1652         @<:@default=no@:>@])],
1653     [with_vulkan_drivers="$withval"],
1654     [with_vulkan_drivers="no"])
1655
1656 # Doing '--without-vulkan-drivers' will set this variable to 'no'.  Clear it
1657 # here so that the script doesn't choke on an unknown driver name later.
1658 case "x$with_vulkan_drivers" in
1659     xyes) with_vulkan_drivers="$VULKAN_DRIVERS_DEFAULT" ;;
1660     xno) with_vulkan_drivers='' ;;
1661 esac
1662
1663 AC_ARG_WITH([vulkan-icddir],
1664     [AS_HELP_STRING([--with-vulkan-icddir=DIR],
1665         [directory for the Vulkan driver icd files @<:@${datarootdir}/vulkan/icd.d@:>@])],
1666     [VULKAN_ICD_INSTALL_DIR="$withval"],
1667     [VULKAN_ICD_INSTALL_DIR='${datarootdir}/vulkan/icd.d'])
1668 AC_SUBST([VULKAN_ICD_INSTALL_DIR])
1669
1670 if test -n "$with_vulkan_drivers"; then
1671     VULKAN_DRIVERS=`IFS=', '; echo $with_vulkan_drivers`
1672     for driver in $VULKAN_DRIVERS; do
1673         case "x$driver" in
1674         xintel)
1675             if test "x$HAVE_I965_DRI" != xyes; then
1676                 AC_MSG_ERROR([Intel Vulkan driver requires the i965 dri driver])
1677             fi
1678             if test "x$with_sha1" == "x"; then
1679                 AC_MSG_ERROR([Intel Vulkan driver requires SHA1])
1680             fi
1681             HAVE_INTEL_VULKAN=yes;
1682
1683             ;;
1684         xradeon)
1685             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
1686             HAVE_RADEON_VULKAN=yes;
1687             if test "x$with_sha1" == "x"; then
1688                 AC_MSG_ERROR([radv vulkan driver requires SHA1])
1689             fi
1690             ;;
1691         *)
1692             AC_MSG_ERROR([Vulkan driver '$driver' does not exist])
1693             ;;
1694         esac
1695     done
1696     VULKAN_DRIVERS=`echo $VULKAN_DRIVERS|tr " " "\n"|sort -u|tr "\n" " "`
1697 fi
1698
1699
1700 AM_CONDITIONAL(NEED_MEGADRIVER, test -n "$DRI_DIRS")
1701 AM_CONDITIONAL(NEED_LIBMESA, test "x$enable_glx" = xxlib -o \
1702                                   "x$enable_osmesa" = xyes -o \
1703                                   -n "$DRI_DIRS")
1704
1705 dnl
1706 dnl OSMesa configuration
1707 dnl
1708
1709 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1710 AC_ARG_WITH([osmesa-bits],
1711     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1712         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1713     [osmesa_bits="$withval"],
1714     [osmesa_bits=8])
1715 if test "x$osmesa_bits" != x8; then
1716     if test "x$enable_dri" = xyes -o "x$enable_glx" != xno; then
1717         AC_MSG_WARN([Ignoring OSMesa channel bits because of non-OSMesa driver])
1718         osmesa_bits=8
1719     fi
1720 fi
1721 case "x$osmesa_bits" in
1722 x8)
1723     OSMESA_LIB="${OSMESA_LIB}"
1724     ;;
1725 x16|x32)
1726     OSMESA_LIB="${OSMESA_LIB}$osmesa_bits"
1727     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1728     ;;
1729 *)
1730     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1731     ;;
1732 esac
1733
1734 if test "x$enable_osmesa" = xyes -o "x$enable_gallium_osmesa" = xyes; then
1735     # only link libraries with osmesa if shared
1736     if test "$enable_static" = no; then
1737         OSMESA_LIB_DEPS="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1738     else
1739         OSMESA_LIB_DEPS=""
1740     fi
1741     OSMESA_PC_LIB_PRIV="-lm $PTHREAD_LIBS $SELINUX_LIBS $DLOPEN_LIBS"
1742 fi
1743
1744 AC_SUBST([OSMESA_LIB_DEPS])
1745 AC_SUBST([OSMESA_PC_REQ])
1746 AC_SUBST([OSMESA_PC_LIB_PRIV])
1747
1748 dnl
1749 dnl gbm configuration
1750 dnl
1751 if test "x$enable_gbm" = xauto; then
1752     case "$with_egl_platforms" in
1753         *drm*)
1754             enable_gbm=yes ;;
1755          *)
1756             enable_gbm=no ;;
1757     esac
1758 fi
1759 if test "x$enable_gbm" = xyes; then
1760     if test "x$enable_dri" = xyes; then
1761         if test "x$enable_shared_glapi" = xno; then
1762             AC_MSG_ERROR([gbm_dri requires --enable-shared-glapi])
1763         fi
1764     else
1765         # Strictly speaking libgbm does not require --enable-dri, although
1766         # both of its backends do. Thus one can build libgbm without any
1767         # backends if --disable-dri is set.
1768         # To avoid unnecessary complexity of checking if at least one backend
1769         # is available when building, just mandate --enable-dri.
1770         AC_MSG_ERROR([gbm requires --enable-dri])
1771     fi
1772 fi
1773 AM_CONDITIONAL(HAVE_GBM, test "x$enable_gbm" = xyes)
1774 # FINISHME: GBM has a number of dependencies which we should add below
1775 GBM_PC_REQ_PRIV=""
1776 GBM_PC_LIB_PRIV="$DLOPEN_LIBS"
1777 AC_SUBST([GBM_PC_REQ_PRIV])
1778 AC_SUBST([GBM_PC_LIB_PRIV])
1779
1780 dnl
1781 dnl EGL configuration
1782 dnl
1783 EGL_CLIENT_APIS=""
1784
1785 if test "x$enable_egl" = xyes; then
1786     EGL_LIB_DEPS="$DLOPEN_LIBS $SELINUX_LIBS $PTHREAD_LIBS"
1787
1788     AC_CHECK_FUNC(mincore, [DEFINES="$DEFINES -DHAVE_MINCORE"])
1789
1790     if test "$enable_static" != yes; then
1791         if test "x$enable_dri" = xyes; then
1792             HAVE_EGL_DRIVER_DRI2=1
1793             if test "x$enable_shared_glapi" = xno; then
1794                 AC_MSG_ERROR([egl_dri2 requires --enable-shared-glapi])
1795             fi
1796             if test "x$enable_dri3" = xyes; then
1797                 HAVE_EGL_DRIVER_DRI3=1
1798                 if test "x$enable_shared_glapi" = xno; then
1799                     AC_MSG_ERROR([egl_dri3 requires --enable-shared-glapi])
1800                 fi
1801             fi
1802         else
1803             # Avoid building an "empty" libEGL. Drop/update this
1804             # when other backends (haiku?) come along.
1805             AC_MSG_ERROR([egl requires --enable-dri])
1806         fi
1807
1808     fi
1809 fi
1810 AM_CONDITIONAL(HAVE_EGL, test "x$enable_egl" = xyes)
1811 AC_SUBST([EGL_LIB_DEPS])
1812
1813 gallium_st="mesa"
1814
1815 dnl
1816 dnl XA configuration
1817 dnl
1818 if test "x$enable_xa" = xyes; then
1819     if test "x$with_gallium_drivers" = xswrast; then
1820        AC_MSG_ERROR([
1821           Building xa requires at least one non swrast gallium driver.
1822           If you are looking to use libxatracker.so with the VMware driver,
1823           make sure to include svga in the gallium drivers list, apart from
1824           enabling XA.
1825           Example: ./configure --enable-xa --with-gallium-drivers=svga...])
1826     fi
1827     gallium_st="$gallium_st xa"
1828 fi
1829 AM_CONDITIONAL(HAVE_ST_XA, test "x$enable_xa" = xyes)
1830
1831 dnl
1832 dnl Gallium G3DVL configuration
1833 dnl
1834 if test -n "$with_gallium_drivers" -a "x$with_gallium_drivers" != xswrast; then
1835     if test "x$enable_xvmc" = xauto; then
1836         PKG_CHECK_EXISTS([xvmc >= $XVMC_REQUIRED], [enable_xvmc=yes], [enable_xvmc=no])
1837     fi
1838
1839     if test "x$enable_vdpau" = xauto; then
1840         PKG_CHECK_EXISTS([vdpau >= $VDPAU_REQUIRED], [enable_vdpau=yes], [enable_vdpau=no])
1841     fi
1842
1843     if test "x$enable_omx" = xauto; then
1844         PKG_CHECK_EXISTS([libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED], [enable_omx=yes], [enable_omx=no])
1845     fi
1846
1847     if test "x$enable_va" = xauto; then
1848         PKG_CHECK_EXISTS([libva >= $LIBVA_REQUIRED], [enable_va=yes], [enable_va=no])
1849     fi
1850 fi
1851
1852 if test "x$enable_dri" = xyes -o \
1853         "x$enable_xvmc" = xyes -o \
1854         "x$enable_vdpau" = xyes -o \
1855         "x$enable_omx" = xyes -o \
1856         "x$enable_va" = xyes; then
1857     need_gallium_vl=yes
1858 fi
1859 AM_CONDITIONAL(NEED_GALLIUM_VL, test "x$need_gallium_vl" = xyes)
1860
1861 if test "x$enable_xvmc" = xyes -o \
1862         "x$enable_vdpau" = xyes -o \
1863         "x$enable_omx" = xyes -o \
1864         "x$enable_va" = xyes; then
1865     if test x"$enable_dri3" = xyes; then
1866         PKG_CHECK_MODULES([VL], [xcb-dri3 xcb-present xcb-sync xshmfence >= $XSHMFENCE_REQUIRED
1867                                  x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1868     else
1869         PKG_CHECK_MODULES([VL], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED])
1870     fi
1871     need_gallium_vl_winsys=yes
1872 fi
1873 AM_CONDITIONAL(NEED_GALLIUM_VL_WINSYS, test "x$need_gallium_vl_winsys" = xyes)
1874
1875 if test "x$enable_xvmc" = xyes; then
1876     PKG_CHECK_MODULES([XVMC], [xvmc >= $XVMC_REQUIRED])
1877     gallium_st="$gallium_st xvmc"
1878 fi
1879 AM_CONDITIONAL(HAVE_ST_XVMC, test "x$enable_xvmc" = xyes)
1880
1881 if test "x$enable_vdpau" = xyes; then
1882     PKG_CHECK_MODULES([VDPAU], [vdpau >= $VDPAU_REQUIRED])
1883     gallium_st="$gallium_st vdpau"
1884     DEFINES="$DEFINES -DHAVE_ST_VDPAU"
1885 fi
1886 AM_CONDITIONAL(HAVE_ST_VDPAU, test "x$enable_vdpau" = xyes)
1887
1888 if test "x$enable_omx" = xyes; then
1889     PKG_CHECK_MODULES([OMX], [libomxil-bellagio >= $LIBOMXIL_BELLAGIO_REQUIRED])
1890     gallium_st="$gallium_st omx"
1891 fi
1892 AM_CONDITIONAL(HAVE_ST_OMX, test "x$enable_omx" = xyes)
1893
1894 if test "x$enable_va" = xyes; then
1895     PKG_CHECK_MODULES([VA], [libva >= $LIBVA_REQUIRED])
1896     gallium_st="$gallium_st va"
1897 fi
1898 AM_CONDITIONAL(HAVE_ST_VA, test "x$enable_va" = xyes)
1899
1900 dnl
1901 dnl Nine Direct3D9 configuration
1902 dnl
1903 if test "x$enable_nine" = xyes; then
1904     if ! echo "$with_gallium_drivers" | grep -q 'swrast'; then
1905         AC_MSG_ERROR([nine requires the gallium swrast driver])
1906     fi
1907     if test "x$with_gallium_drivers" = xswrast; then
1908         AC_MSG_ERROR([nine requires at least one non-swrast gallium driver])
1909     fi
1910     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 6; then
1911         AC_MSG_ERROR([gcc >= 4.6 is required to build nine])
1912     fi
1913
1914     if test "x$enable_dri3" = xno; then
1915         AC_MSG_WARN([using nine together with wine requires DRI3 enabled system])
1916     fi
1917
1918     gallium_st="$gallium_st nine"
1919 fi
1920 AM_CONDITIONAL(HAVE_ST_NINE, test "x$enable_nine" = xyes)
1921
1922 dnl
1923 dnl OpenCL configuration
1924 dnl
1925
1926 AC_ARG_WITH([clang-libdir],
1927    [AS_HELP_STRING([--with-clang-libdir],
1928          [Path to Clang libraries @<:@default=llvm-config --libdir@:>@])],
1929    [CLANG_LIBDIR="$withval"],
1930    [CLANG_LIBDIR=''])
1931
1932 PKG_CHECK_EXISTS([libclc], [have_libclc=yes], [have_libclc=no])
1933 PKG_CHECK_MODULES([LIBELF], [libelf], [have_libelf=yes], [have_libelf=no])
1934
1935 if test "x$have_libelf" = xno; then
1936    LIBELF_LIBS=''
1937    LIBELF_CFLAGS=''
1938    AC_CHECK_LIB([elf], [elf_memory], [have_libelf=yes;LIBELF_LIBS=-lelf], [have_libelf=no])
1939    AC_SUBST([LIBELF_LIBS])
1940    AC_SUBST([LIBELF_CFLAGS])
1941 fi
1942
1943 if test "x$enable_opencl" = xyes; then
1944     if test -z "$with_gallium_drivers"; then
1945         AC_MSG_ERROR([cannot enable OpenCL without Gallium])
1946     fi
1947
1948     if test $GCC_VERSION_MAJOR -lt 4 -o $GCC_VERSION_MAJOR -eq 4 -a $GCC_VERSION_MINOR -lt 7; then
1949         AC_MSG_ERROR([gcc >= 4.7 is required to build clover])
1950     fi
1951
1952     if test "x$have_libclc" = xno; then
1953         AC_MSG_ERROR([pkg-config cannot find libclc.pc which is required to build clover.
1954                     Make sure the directory containing libclc.pc is specified in your
1955                     PKG_CONFIG_PATH environment variable.
1956                     By default libclc.pc is installed to /usr/local/share/pkgconfig/])
1957     else
1958         LIBCLC_INCLUDEDIR=`$PKG_CONFIG --variable=includedir libclc`
1959         LIBCLC_LIBEXECDIR=`$PKG_CONFIG --variable=libexecdir libclc`
1960         AC_SUBST([LIBCLC_INCLUDEDIR])
1961         AC_SUBST([LIBCLC_LIBEXECDIR])
1962     fi
1963
1964     gallium_st="$gallium_st clover"
1965
1966     if test "x$enable_opencl_icd" = xyes; then
1967         OPENCL_LIBNAME="MesaOpenCL"
1968     else
1969         OPENCL_LIBNAME="OpenCL"
1970     fi
1971
1972     if test "x$have_libelf" != xyes; then
1973        AC_MSG_ERROR([Clover requires libelf])
1974     fi
1975 fi
1976 AM_CONDITIONAL(HAVE_CLOVER, test "x$enable_opencl" = xyes)
1977 AM_CONDITIONAL(HAVE_CLOVER_ICD, test "x$enable_opencl_icd" = xyes)
1978 AC_SUBST([OPENCL_LIBNAME])
1979
1980 dnl
1981 dnl Gallium configuration
1982 dnl
1983 AM_CONDITIONAL(HAVE_GALLIUM, test -n "$with_gallium_drivers")
1984
1985 AC_SUBST([LLVM_BINDIR])
1986 AC_SUBST([LLVM_CFLAGS])
1987 AC_SUBST([LLVM_CPPFLAGS])
1988 AC_SUBST([LLVM_CXXFLAGS])
1989 AC_SUBST([LLVM_LIBDIR])
1990 AC_SUBST([LLVM_LIBS])
1991 AC_SUBST([LLVM_LDFLAGS])
1992 AC_SUBST([LLVM_INCLUDEDIR])
1993 AC_SUBST([LLVM_VERSION])
1994 AC_SUBST([CLANG_RESOURCE_DIR])
1995
1996 case "x$enable_opengl$enable_gles1$enable_gles2" in
1997 x*yes*)
1998     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1999     ;;
2000 esac
2001
2002 AC_SUBST([VG_LIB_DEPS])
2003 AC_SUBST([EGL_CLIENT_APIS])
2004
2005 dnl
2006 dnl EGL Platforms configuration
2007 dnl
2008 AC_ARG_WITH([egl-platforms],
2009     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
2010         [comma delimited native platforms libEGL supports, e.g.
2011         "x11,drm" @<:@default=auto@:>@])],
2012     [with_egl_platforms="$withval"],
2013     [if test "x$enable_egl" = xyes; then
2014         with_egl_platforms="x11"
2015     else
2016         with_egl_platforms=""
2017     fi])
2018
2019 if test "x$with_egl_platforms" != "x" -a "x$enable_egl" != xyes; then
2020     AC_MSG_ERROR([cannot build egl state tracker without EGL library])
2021 fi
2022
2023 PKG_CHECK_MODULES([WAYLAND_SCANNER], [wayland-scanner],
2024         WAYLAND_SCANNER=`$PKG_CONFIG --variable=wayland_scanner wayland-scanner`,
2025         WAYLAND_SCANNER='')
2026 if test "x$WAYLAND_SCANNER" = x; then
2027     AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner])
2028 fi
2029
2030 # Do per-EGL platform setups and checks
2031 egl_platforms=`IFS=', '; echo $with_egl_platforms`
2032 for plat in $egl_platforms; do
2033         case "$plat" in
2034         wayland)
2035
2036                 PKG_CHECK_MODULES([WAYLAND], [wayland-client >= $WAYLAND_REQUIRED wayland-server >= $WAYLAND_REQUIRED])
2037
2038                 if test "x$WAYLAND_SCANNER" = x; then
2039                         AC_MSG_ERROR([wayland-scanner is needed to compile the wayland egl platform])
2040                 fi
2041                 ;;
2042
2043         x11)
2044                 PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb xcb-dri2 >= $XCBDRI2_REQUIRED xcb-xfixes])
2045                 ;;
2046
2047         drm)
2048                 test "x$enable_gbm" = "xno" &&
2049                         AC_MSG_ERROR([EGL platform drm needs gbm])
2050                 ;;
2051
2052         surfaceless)
2053                 ;;
2054
2055         android)
2056                 ;;
2057
2058         *)
2059                 AC_MSG_ERROR([EGL platform '$plat' does not exist])
2060                 ;;
2061         esac
2062
2063         case "$plat" in
2064         wayland|drm|surfaceless)
2065                 require_libdrm "Platform $plat"
2066                 ;;
2067         esac
2068 done
2069
2070 # libEGL wants to default to the first platform specified in
2071 # ./configure.  parse that here.
2072 if test "x$egl_platforms" != "x"; then
2073     FIRST_PLATFORM_CAPS=`echo $egl_platforms | sed 's| .*||' | tr '[[a-z]]' '[[A-Z]]'`
2074     EGL_NATIVE_PLATFORM="_EGL_PLATFORM_$FIRST_PLATFORM_CAPS"
2075 else
2076     EGL_NATIVE_PLATFORM="_EGL_INVALID_PLATFORM"
2077 fi
2078
2079 AM_CONDITIONAL(HAVE_PLATFORM_X11, echo "$egl_platforms" | grep -q 'x11')
2080 AM_CONDITIONAL(HAVE_PLATFORM_WAYLAND, echo "$egl_platforms" | grep -q 'wayland')
2081 AM_CONDITIONAL(HAVE_EGL_PLATFORM_DRM, echo "$egl_platforms" | grep -q 'drm')
2082 AM_CONDITIONAL(HAVE_EGL_PLATFORM_SURFACELESS, echo "$egl_platforms" | grep -q 'surfaceless')
2083 AM_CONDITIONAL(HAVE_EGL_PLATFORM_ANDROID, echo "$egl_platforms" | grep -q 'android')
2084
2085 AM_CONDITIONAL(HAVE_EGL_DRIVER_DRI2, test "x$HAVE_EGL_DRIVER_DRI2" != "x")
2086
2087 AC_SUBST([EGL_NATIVE_PLATFORM])
2088 AC_SUBST([EGL_CFLAGS])
2089
2090 # If we don't have the X11 platform, set this define so we don't try to include
2091 # the X11 headers.
2092 if ! echo "$egl_platforms" | grep -q 'x11'; then
2093     DEFINES="$DEFINES -DMESA_EGL_NO_X11_HEADERS"
2094     GL_PC_CFLAGS="$GL_PC_CFLAGS -DMESA_EGL_NO_X11_HEADERS"
2095 fi
2096
2097 dnl
2098 dnl Gallium LLVM
2099 dnl
2100 AC_ARG_ENABLE([gallium-llvm],
2101     [AS_HELP_STRING([--enable-gallium-llvm],
2102         [build gallium LLVM support @<:@default=enabled on x86/x86_64@:>@])],
2103     [enable_gallium_llvm="$enableval"],
2104     [enable_gallium_llvm=auto])
2105
2106 AC_ARG_ENABLE([llvm-shared-libs],
2107     [AS_HELP_STRING([--enable-llvm-shared-libs],
2108         [link with LLVM shared libraries @<:@default=enabled@:>@])],
2109     [enable_llvm_shared_libs="$enableval"],
2110     [enable_llvm_shared_libs=yes])
2111
2112 AC_ARG_WITH([llvm-prefix],
2113     [AS_HELP_STRING([--with-llvm-prefix],
2114         [Prefix for LLVM installations in non-standard locations])],
2115     [llvm_prefix="$withval"],
2116     [llvm_prefix=''])
2117
2118
2119 # Call this inside ` ` to get the return value.
2120 # $1 is the llvm-config command with arguments.
2121 strip_unwanted_llvm_flags() {
2122     # Use \> (marks the end of the word)
2123     echo `$1` | sed \
2124         -e 's/-march=\S*//g' \
2125         -e 's/-mtune=\S*//g' \
2126         -e 's/-mcpu=\S*//g' \
2127         -e 's/-DNDEBUG\>//g' \
2128         -e 's/-D_GNU_SOURCE\>//g' \
2129         -e 's/-pedantic\>//g' \
2130         -e 's/-Wcovered-switch-default\>//g' \
2131         -e 's/-O.\>//g' \
2132         -e 's/-g\>//g' \
2133         -e 's/-Wall\>//g' \
2134         -e 's/-Wcast-qual\>//g' \
2135         -e 's/-Woverloaded-virtual\>//g' \
2136         -e 's/-fcolor-diagnostics\>//g' \
2137         -e 's/-fdata-sections\>//g' \
2138         -e 's/-ffunction-sections\>//g' \
2139         -e 's/-fno-exceptions\>//g' \
2140         -e 's/-fomit-frame-pointer\>//g' \
2141         -e 's/-fvisibility-inlines-hidden\>//g' \
2142         -e 's/-fPIC\>//g' \
2143         -e 's/-fstack-protector-strong\>//g'
2144 }
2145
2146 llvm_check_version_for() {
2147     if test "${LLVM_VERSION_INT}${LLVM_VERSION_PATCH}" -lt "${1}0${2}${3}"; then
2148         AC_MSG_ERROR([LLVM $1.$2.$3 or newer is required for $4])
2149     fi
2150 }
2151
2152
2153
2154 if test -z "$with_gallium_drivers"; then
2155     enable_gallium_llvm=no
2156 fi
2157 if test "x$enable_gallium_llvm" = xauto; then
2158     case "$host_cpu" in
2159     i*86|x86_64|amd64) enable_gallium_llvm=yes;;
2160     esac
2161 fi
2162 if test "x$enable_gallium_llvm" = xyes || test "x$HAVE_RADEON_VULKAN" = xyes; then
2163     if test -n "$llvm_prefix"; then
2164         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no], ["$llvm_prefix/bin"])
2165     else
2166         AC_PATH_TOOL([LLVM_CONFIG], [llvm-config], [no])
2167     fi
2168
2169     if test "x$LLVM_CONFIG" != xno; then
2170         LLVM_VERSION=`$LLVM_CONFIG --version | egrep -o '^[[0-9.]]+'`
2171         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
2172         LLVM_BINDIR=`$LLVM_CONFIG --bindir`
2173         LLVM_CPPFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cppflags"`
2174         LLVM_CFLAGS=$LLVM_CPPFLAGS   # CPPFLAGS seem to be sufficient
2175         LLVM_CXXFLAGS=`strip_unwanted_llvm_flags "$LLVM_CONFIG --cxxflags"`
2176         LLVM_INCLUDEDIR=`$LLVM_CONFIG --includedir`
2177         LLVM_LIBDIR=`$LLVM_CONFIG --libdir`
2178
2179         AC_COMPUTE_INT([LLVM_VERSION_MAJOR], [LLVM_VERSION_MAJOR],
2180             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2181         AC_COMPUTE_INT([LLVM_VERSION_MINOR], [LLVM_VERSION_MINOR],
2182             [#include "${LLVM_INCLUDEDIR}/llvm/Config/llvm-config.h"])
2183
2184         LLVM_VERSION_PATCH=`echo $LLVM_VERSION | cut -d. -f3 | egrep -o '^[[0-9]]+'`
2185         if test -z "$LLVM_VERSION_PATCH"; then
2186             LLVM_VERSION_PATCH=0
2187         fi
2188
2189         if test -n "${LLVM_VERSION_MAJOR}"; then
2190             LLVM_VERSION_INT="${LLVM_VERSION_MAJOR}0${LLVM_VERSION_MINOR}"
2191         else
2192             LLVM_VERSION_INT=`echo $LLVM_VERSION | sed -e 's/\([[0-9]]\)\.\([[0-9]]\)/\10\2/g'`
2193         fi
2194
2195         LLVM_REQUIRED_VERSION_MAJOR="3"
2196         LLVM_REQUIRED_VERSION_MINOR="3"
2197         if test "$LLVM_VERSION_INT" -lt "${LLVM_REQUIRED_VERSION_MAJOR}0${LLVM_REQUIRED_VERSION_MINOR}"; then
2198             AC_MSG_ERROR([LLVM $LLVM_REQUIRED_VERSION_MAJOR.$LLVM_REQUIRED_VERSION_MINOR or newer is required])
2199         fi
2200
2201         LLVM_COMPONENTS="engine bitwriter mcjit mcdisassembler"
2202
2203         if $LLVM_CONFIG --components | grep -q inteljitevents ; then
2204             LLVM_COMPONENTS="${LLVM_COMPONENTS} inteljitevents"
2205         fi
2206
2207         if test "x$enable_opencl" = xyes; then
2208             llvm_check_version_for "3" "6" "0" "opencl"
2209
2210             LLVM_COMPONENTS="${LLVM_COMPONENTS} all-targets ipo linker instrumentation"
2211             LLVM_COMPONENTS="${LLVM_COMPONENTS} irreader option objcarcopts profiledata"
2212         fi
2213         DEFINES="${DEFINES} -DHAVE_LLVM=0x0$LLVM_VERSION_INT -DMESA_LLVM_VERSION_PATCH=$LLVM_VERSION_PATCH"
2214         MESA_LLVM=1
2215
2216         dnl Check for Clang internal headers
2217         if test "x$enable_opencl" = xyes; then
2218             if test -z "$CLANG_LIBDIR"; then
2219                 CLANG_LIBDIR=${LLVM_LIBDIR}
2220             fi
2221             CLANG_RESOURCE_DIR=$CLANG_LIBDIR/clang/${LLVM_VERSION}
2222             AS_IF([test ! -f "$CLANG_RESOURCE_DIR/include/stddef.h"],
2223                 [AC_MSG_ERROR([Could not find clang internal header stddef.h in $CLANG_RESOURCE_DIR Use --with-clang-libdir to specify the correct path to the clang libraries.])])
2224         fi
2225     else
2226         MESA_LLVM=0
2227         LLVM_VERSION_INT=0
2228     fi
2229 else
2230     MESA_LLVM=0
2231     LLVM_VERSION_INT=0
2232
2233     if test "x$enable_opencl" = xyes; then
2234         AC_MSG_ERROR([cannot enable OpenCL without LLVM])
2235     fi
2236 fi
2237
2238 dnl Directory for XVMC libs
2239 AC_ARG_WITH([xvmc-libdir],
2240     [AS_HELP_STRING([--with-xvmc-libdir=DIR],
2241         [directory for the XVMC libraries @<:@default=${libdir}@:>@])],
2242     [XVMC_LIB_INSTALL_DIR="$withval"],
2243     [XVMC_LIB_INSTALL_DIR='${libdir}'])
2244 AC_SUBST([XVMC_LIB_INSTALL_DIR])
2245
2246 dnl
2247 dnl Gallium Tests
2248 dnl
2249 AM_CONDITIONAL(HAVE_GALLIUM_TESTS, test "x$enable_gallium_tests" = xyes)
2250
2251 dnl Directory for VDPAU libs
2252 AC_ARG_WITH([vdpau-libdir],
2253     [AS_HELP_STRING([--with-vdpau-libdir=DIR],
2254         [directory for the VDPAU libraries @<:@default=${libdir}/vdpau@:>@])],
2255     [VDPAU_LIB_INSTALL_DIR="$withval"],
2256     [VDPAU_LIB_INSTALL_DIR='${libdir}/vdpau'])
2257 AC_SUBST([VDPAU_LIB_INSTALL_DIR])
2258
2259 dnl Directory for OMX libs
2260
2261 AC_ARG_WITH([omx-libdir],
2262     [AS_HELP_STRING([--with-omx-libdir=DIR],
2263         [directory for the OMX libraries])],
2264     [OMX_LIB_INSTALL_DIR="$withval"],
2265     [OMX_LIB_INSTALL_DIR=`$PKG_CONFIG --define-variable=libdir=\$libdir --variable=pluginsdir libomxil-bellagio`])
2266 AC_SUBST([OMX_LIB_INSTALL_DIR])
2267
2268 dnl Directory for VA libs
2269
2270 AC_ARG_WITH([va-libdir],
2271     [AS_HELP_STRING([--with-va-libdir=DIR],
2272         [directory for the VA libraries @<:@${libdir}/dri@:>@])],
2273     [VA_LIB_INSTALL_DIR="$withval"],
2274     [VA_LIB_INSTALL_DIR="${libdir}/dri"])
2275 AC_SUBST([VA_LIB_INSTALL_DIR])
2276
2277 AC_ARG_WITH([d3d-libdir],
2278     [AS_HELP_STRING([--with-d3d-libdir=DIR],
2279         [directory for the D3D modules @<:@${libdir}/d3d@:>@])],
2280     [D3D_DRIVER_INSTALL_DIR="$withval"],
2281     [D3D_DRIVER_INSTALL_DIR="${libdir}/d3d"])
2282 AC_SUBST([D3D_DRIVER_INSTALL_DIR])
2283
2284 dnl
2285 dnl Gallium helper functions
2286 dnl
2287 gallium_require_llvm() {
2288     if test "x$MESA_LLVM" = x0; then
2289         case "$host" in *gnux32) return;; esac
2290         case "$host_cpu" in
2291         i*86|x86_64|amd64) AC_MSG_ERROR([LLVM is required to build $1 on x86 and x86_64]);;
2292         esac
2293     fi
2294 }
2295
2296 dnl This is for Glamor. Skip this if OpenGL is disabled.
2297 require_egl_drm() {
2298     if test "x$enable_opengl" = xno; then
2299         return 0
2300     fi
2301
2302     case "$with_egl_platforms" in
2303         *drm*)
2304             ;;
2305          *)
2306             AC_MSG_ERROR([--with-egl-platforms=drm is required to build the $1 driver.])
2307             ;;
2308     esac
2309     if test "x$enable_gbm" != xyes; then
2310             AC_MSG_ERROR([--enable-gbm is required to build the $1 driver.])
2311     fi
2312 }
2313
2314 radeon_llvm_check() {
2315     if test ${LLVM_VERSION_INT} -lt 307; then
2316         amdgpu_llvm_target_name='r600'
2317     else
2318         amdgpu_llvm_target_name='amdgpu'
2319     fi
2320     llvm_check_version_for $2 $3 $4 $1
2321     if test true && $LLVM_CONFIG --targets-built | grep -iqvw $amdgpu_llvm_target_name ; then
2322         AC_MSG_ERROR([LLVM $amdgpu_llvm_target_name not enabled in your LLVM build.])
2323     fi
2324     LLVM_COMPONENTS="${LLVM_COMPONENTS} $amdgpu_llvm_target_name bitreader ipo"
2325     NEED_RADEON_LLVM=yes
2326     if test "x$have_libelf" != xyes; then
2327        AC_MSG_ERROR([$1 requires libelf when using llvm])
2328     fi
2329 }
2330
2331 radeon_gallium_llvm_check() {
2332     if test "x$enable_gallium_llvm" != "xyes"; then
2333         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2334     fi
2335     radeon_llvm_check $*
2336 }
2337
2338 swr_llvm_check() {
2339     gallium_require_llvm $1
2340     if test ${LLVM_VERSION_INT} -lt 306; then
2341         AC_MSG_ERROR([LLVM version 3.6 or later required when building $1])
2342     fi
2343     if test "x$enable_gallium_llvm" != "xyes"; then
2344         AC_MSG_ERROR([--enable-gallium-llvm is required when building $1])
2345     fi
2346 }
2347
2348 swr_require_cxx_feature_flags() {
2349     feature_name="$1"
2350     preprocessor_test="$2"
2351     option_list="$3"
2352     output_var="$4"
2353
2354     AC_MSG_CHECKING([whether $CXX supports $feature_name])
2355     AC_LANG_PUSH([C++])
2356     save_CXXFLAGS="$CXXFLAGS"
2357     save_IFS="$IFS"
2358     IFS=","
2359     found=0
2360     for opts in $option_list
2361     do
2362         unset IFS
2363         CXXFLAGS="$opts $save_CXXFLAGS"
2364         AC_COMPILE_IFELSE(
2365             [AC_LANG_PROGRAM(
2366                 [   #if !($preprocessor_test)
2367                     #error
2368                     #endif
2369                 ])],
2370             [found=1; break],
2371             [])
2372         IFS=","
2373     done
2374     IFS="$save_IFS"
2375     CXXFLAGS="$save_CXXFLAGS"
2376     AC_LANG_POP([C++])
2377     if test $found -eq 1; then
2378         AC_MSG_RESULT([$opts])
2379         eval "$output_var=\$opts"
2380         return 0
2381     fi
2382     AC_MSG_RESULT([no])
2383     AC_MSG_ERROR([swr requires $feature_name support])
2384     return 1
2385 }
2386
2387 dnl Duplicates in GALLIUM_DRIVERS_DIRS are removed by sorting it after this block
2388 if test -n "$with_gallium_drivers"; then
2389     gallium_drivers=`IFS=', '; echo $with_gallium_drivers`
2390     for driver in $gallium_drivers; do
2391         case "x$driver" in
2392         xsvga)
2393             HAVE_GALLIUM_SVGA=yes
2394             require_libdrm "svga"
2395             ;;
2396         xi915)
2397             HAVE_GALLIUM_I915=yes
2398             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2399             require_libdrm "Gallium i915"
2400             ;;
2401         xilo)
2402             HAVE_GALLIUM_ILO=yes
2403             PKG_CHECK_MODULES([INTEL], [libdrm_intel >= $LIBDRM_INTEL_REQUIRED])
2404             require_libdrm "Gallium i965/ilo"
2405             ;;
2406         xr300)
2407             HAVE_GALLIUM_R300=yes
2408             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2409             require_libdrm "Gallium R300"
2410             gallium_require_llvm "Gallium R300"
2411             ;;
2412         xr600)
2413             HAVE_GALLIUM_R600=yes
2414             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2415             require_libdrm "Gallium R600"
2416             if test "x$enable_opencl" = xyes; then
2417                 radeon_gallium_llvm_check "r600g" "3" "6" "0"
2418                 LLVM_COMPONENTS="${LLVM_COMPONENTS} bitreader asmparser"
2419             fi
2420             ;;
2421         xradeonsi)
2422             HAVE_GALLIUM_RADEONSI=yes
2423             PKG_CHECK_MODULES([RADEON], [libdrm_radeon >= $LIBDRM_RADEON_REQUIRED])
2424             PKG_CHECK_MODULES([AMDGPU], [libdrm_amdgpu >= $LIBDRM_AMDGPU_REQUIRED])
2425             require_libdrm "radeonsi"
2426             radeon_gallium_llvm_check "radeonsi" "3" "6" "0"
2427             require_egl_drm "radeonsi"
2428             ;;
2429         xnouveau)
2430             HAVE_GALLIUM_NOUVEAU=yes
2431             PKG_CHECK_MODULES([NOUVEAU], [libdrm_nouveau >= $LIBDRM_NOUVEAU_REQUIRED])
2432             require_libdrm "nouveau"
2433             ;;
2434         xfreedreno)
2435             HAVE_GALLIUM_FREEDRENO=yes
2436             PKG_CHECK_MODULES([FREEDRENO], [libdrm_freedreno >= $LIBDRM_FREEDRENO_REQUIRED])
2437             require_libdrm "freedreno"
2438             ;;
2439         xswrast)
2440             HAVE_GALLIUM_SOFTPIPE=yes
2441             if test "x$MESA_LLVM" = x1; then
2442                 HAVE_GALLIUM_LLVMPIPE=yes
2443             fi
2444             ;;
2445         xswr)
2446             swr_llvm_check "swr"
2447
2448             swr_require_cxx_feature_flags "C++11" "__cplusplus >= 201103L" \
2449                 ",-std=c++11" \
2450                 SWR_CXX11_CXXFLAGS
2451             AC_SUBST([SWR_CXX11_CXXFLAGS])
2452
2453             swr_require_cxx_feature_flags "AVX" "defined(__AVX__)" \
2454                 ",-mavx,-march=core-avx" \
2455                 SWR_AVX_CXXFLAGS
2456             AC_SUBST([SWR_AVX_CXXFLAGS])
2457
2458             swr_require_cxx_feature_flags "AVX2" "defined(__AVX2__)" \
2459                 ",-mavx2 -mfma -mbmi2 -mf16c,-march=core-avx2" \
2460                 SWR_AVX2_CXXFLAGS
2461             AC_SUBST([SWR_AVX2_CXXFLAGS])
2462
2463             HAVE_GALLIUM_SWR=yes
2464             ;;
2465         xvc4)
2466             HAVE_GALLIUM_VC4=yes
2467             PKG_CHECK_MODULES([VC4], [libdrm_vc4 >= $LIBDRM_VC4_REQUIRED])
2468             require_libdrm "vc4"
2469
2470             PKG_CHECK_MODULES([SIMPENROSE], [simpenrose],
2471                               [USE_VC4_SIMULATOR=yes;
2472                                DEFINES="$DEFINES -DUSE_VC4_SIMULATOR"],
2473                               [USE_VC4_SIMULATOR=no])
2474             ;;
2475         xvirgl)
2476             HAVE_GALLIUM_VIRGL=yes
2477             require_libdrm "virgl"
2478             require_egl_drm "virgl"
2479             ;;
2480         *)
2481             AC_MSG_ERROR([Unknown Gallium driver: $driver])
2482             ;;
2483         esac
2484     done
2485 fi
2486
2487 if test "x$HAVE_RADEON_VULKAN" = "xyes"; then
2488     radeon_llvm_check "radv" "3" "9" "0"
2489 fi
2490
2491 dnl Set LLVM_LIBS - This is done after the driver configuration so
2492 dnl that drivers can add additional components to LLVM_COMPONENTS.
2493 dnl Previously, gallium drivers were updating LLVM_LIBS directly
2494 dnl by calling llvm-config --libs ${DRIVER_LLVM_COMPONENTS}, but
2495 dnl this was causing the same libraries to be appear multiple times
2496 dnl in LLVM_LIBS.
2497
2498 if test "x$MESA_LLVM" != x0; then
2499
2500     if ! $LLVM_CONFIG --libs ${LLVM_COMPONENTS} >/dev/null; then
2501        AC_MSG_ERROR([Calling ${LLVM_CONFIG} failed])
2502     fi
2503     LLVM_LIBS="`$LLVM_CONFIG --libs ${LLVM_COMPONENTS}`"
2504
2505     dnl llvm-config may not give the right answer when llvm is a built as a
2506     dnl single shared library, so we must work the library name out for
2507     dnl ourselves.
2508     dnl (See https://llvm.org/bugs/show_bug.cgi?id=6823)
2509     if test "x$enable_llvm_shared_libs" = xyes; then
2510         dnl We can't use $LLVM_VERSION because it has 'svn' stripped out,
2511         LLVM_SO_NAME=LLVM-`$LLVM_CONFIG --version`
2512         AS_IF([test -f "$LLVM_LIBDIR/lib$LLVM_SO_NAME.$IMP_LIB_EXT"], [llvm_have_one_so=yes])
2513
2514         if test "x$llvm_have_one_so" = xyes; then
2515             dnl LLVM was built using auto*, so there is only one shared object.
2516             LLVM_LIBS="-l$LLVM_SO_NAME"
2517         else
2518             dnl If LLVM was built with CMake, there will be one shared object per
2519             dnl component.
2520             AS_IF([test ! -f "$LLVM_LIBDIR/libLLVMTarget.$IMP_LIB_EXT"],
2521                     [AC_MSG_ERROR([Could not find llvm shared libraries:
2522         Please make sure you have built llvm with the --enable-shared option
2523         and that your llvm libraries are installed in $LLVM_LIBDIR
2524         If you have installed your llvm libraries to a different directory you
2525         can use the --with-llvm-prefix= configure flag to specify this directory.
2526         NOTE: Mesa is attempting to use llvm shared libraries by default.
2527         If you do not want to build with llvm shared libraries and instead want to
2528         use llvm static libraries then add --disable-llvm-shared-libs to your configure
2529         invocation and rebuild.])])
2530
2531            dnl We don't need to update LLVM_LIBS in this case because the LLVM
2532            dnl install uses a shared object for each component and we have
2533            dnl already added all of these objects to LLVM_LIBS.
2534         fi
2535     else
2536         AC_MSG_WARN([Building mesa with statically linked LLVM may cause compilation issues])
2537         dnl We need to link to llvm system libs when using static libs
2538         dnl However, only llvm 3.5+ provides --system-libs
2539         if test $LLVM_VERSION_MAJOR -ge 4 -o $LLVM_VERSION_MAJOR -eq 3 -a $LLVM_VERSION_MINOR -ge 5; then
2540             LLVM_LIBS="$LLVM_LIBS `$LLVM_CONFIG --system-libs`"
2541         fi
2542     fi
2543 fi
2544
2545 AM_CONDITIONAL(HAVE_GALLIUM_SVGA, test "x$HAVE_GALLIUM_SVGA" = xyes)
2546 AM_CONDITIONAL(HAVE_GALLIUM_I915, test "x$HAVE_GALLIUM_I915" = xyes)
2547 AM_CONDITIONAL(HAVE_GALLIUM_ILO, test "x$HAVE_GALLIUM_ILO" = xyes)
2548 AM_CONDITIONAL(HAVE_GALLIUM_R300, test "x$HAVE_GALLIUM_R300" = xyes)
2549 AM_CONDITIONAL(HAVE_GALLIUM_R600, test "x$HAVE_GALLIUM_R600" = xyes)
2550 AM_CONDITIONAL(HAVE_GALLIUM_RADEONSI, test "x$HAVE_GALLIUM_RADEONSI" = xyes)
2551 AM_CONDITIONAL(HAVE_GALLIUM_RADEON_COMMON, test "x$HAVE_GALLIUM_R600" = xyes -o \
2552                                                 "x$HAVE_GALLIUM_RADEONSI" = xyes)
2553 AM_CONDITIONAL(HAVE_GALLIUM_NOUVEAU, test "x$HAVE_GALLIUM_NOUVEAU" = xyes)
2554 AM_CONDITIONAL(HAVE_GALLIUM_FREEDRENO, test "x$HAVE_GALLIUM_FREEDRENO" = xyes)
2555 AM_CONDITIONAL(HAVE_GALLIUM_SOFTPIPE, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes)
2556 AM_CONDITIONAL(HAVE_GALLIUM_LLVMPIPE, test "x$HAVE_GALLIUM_LLVMPIPE" = xyes)
2557 AM_CONDITIONAL(HAVE_GALLIUM_SWR, test "x$HAVE_GALLIUM_SWR" = xyes)
2558 AM_CONDITIONAL(HAVE_GALLIUM_SWRAST, test "x$HAVE_GALLIUM_SOFTPIPE" = xyes -o \
2559                                          "x$HAVE_GALLIUM_LLVMPIPE" = xyes -o \
2560                                          "x$HAVE_GALLIUM_SWR" = xyes)
2561 AM_CONDITIONAL(HAVE_GALLIUM_VC4, test "x$HAVE_GALLIUM_VC4" = xyes)
2562 AM_CONDITIONAL(HAVE_GALLIUM_VIRGL, test "x$HAVE_GALLIUM_VIRGL" = xyes)
2563
2564 AM_CONDITIONAL(HAVE_GALLIUM_STATIC_TARGETS, test "x$enable_shared_pipe_drivers" = xno)
2565
2566 if test "x$enable_dri" = xyes; then
2567     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_DRI"
2568 fi
2569
2570 if test "x$have_drisw_kms" = xyes; then
2571     GALLIUM_PIPE_LOADER_DEFINES="$GALLIUM_PIPE_LOADER_DEFINES -DHAVE_PIPE_LOADER_KMS"
2572 fi
2573 AC_SUBST([GALLIUM_PIPE_LOADER_DEFINES])
2574
2575 AM_CONDITIONAL(HAVE_I915_DRI, test x$HAVE_I915_DRI = xyes)
2576 AM_CONDITIONAL(HAVE_I965_DRI, test x$HAVE_I965_DRI = xyes)
2577 AM_CONDITIONAL(HAVE_NOUVEAU_DRI, test x$HAVE_NOUVEAU_DRI = xyes)
2578 AM_CONDITIONAL(HAVE_R200_DRI, test x$HAVE_R200_DRI = xyes)
2579 AM_CONDITIONAL(HAVE_RADEON_DRI, test x$HAVE_RADEON_DRI = xyes)
2580 AM_CONDITIONAL(HAVE_SWRAST_DRI, test x$HAVE_SWRAST_DRI = xyes)
2581
2582 AM_CONDITIONAL(HAVE_RADEON_VULKAN, test "x$HAVE_RADEON_VULKAN" = xyes)
2583 AM_CONDITIONAL(HAVE_INTEL_VULKAN, test "x$HAVE_INTEL_VULKAN" = xyes)
2584
2585 AM_CONDITIONAL(HAVE_AMD_DRIVERS, test "x$HAVE_GALLIUM_R600" = xyes -o \
2586                                       "x$HAVE_GALLIUM_RADEONSI" = xyes -o \
2587                                       "x$HAVE_RADEON_VULKAN" = xyes)
2588
2589 AM_CONDITIONAL(HAVE_INTEL_DRIVERS, test "x$HAVE_INTEL_VULKAN" = xyes -o \
2590                                         "x$HAVE_I965_DRI" = xyes)
2591
2592 AM_CONDITIONAL(NEED_RADEON_DRM_WINSYS, test "x$HAVE_GALLIUM_R300" = xyes -o \
2593                                             "x$HAVE_GALLIUM_R600" = xyes -o \
2594                                             "x$HAVE_GALLIUM_RADEONSI" = xyes)
2595 AM_CONDITIONAL(NEED_WINSYS_XLIB, test "x$enable_glx" = xgallium-xlib)
2596 AM_CONDITIONAL(NEED_RADEON_LLVM, test x$NEED_RADEON_LLVM = xyes)
2597 AM_CONDITIONAL(HAVE_GALLIUM_COMPUTE, test x$enable_opencl = xyes)
2598 AM_CONDITIONAL(HAVE_MESA_LLVM, test x$MESA_LLVM = x1)
2599 AM_CONDITIONAL(USE_VC4_SIMULATOR, test x$USE_VC4_SIMULATOR = xyes)
2600 if test "x$USE_VC4_SIMULATOR" = xyes -a "x$HAVE_GALLIUM_ILO" = xyes; then
2601     AC_MSG_ERROR([VC4 simulator on x86 replaces i965 driver build, so ilo must be disabled.])
2602 fi
2603
2604 AM_CONDITIONAL(HAVE_LIBDRM, test "x$have_libdrm" = xyes)
2605 AM_CONDITIONAL(HAVE_OSMESA, test "x$enable_osmesa" = xyes)
2606 AM_CONDITIONAL(HAVE_GALLIUM_OSMESA, test "x$enable_gallium_osmesa" = xyes)
2607 AM_CONDITIONAL(HAVE_COMMON_OSMESA, test "x$enable_osmesa" = xyes -o \
2608                                         "x$enable_gallium_osmesa" = xyes)
2609
2610 AM_CONDITIONAL(HAVE_X86_ASM, test "x$asm_arch" = xx86 -o "x$asm_arch" = xx86_64)
2611 AM_CONDITIONAL(HAVE_X86_64_ASM, test "x$asm_arch" = xx86_64)
2612 AM_CONDITIONAL(HAVE_SPARC_ASM, test "x$asm_arch" = xsparc)
2613
2614 AC_SUBST([NINE_MAJOR], 1)
2615 AC_SUBST([NINE_MINOR], 0)
2616 AC_SUBST([NINE_TINY], 0)
2617 AC_SUBST([NINE_VERSION], "$NINE_MAJOR.$NINE_MINOR.$NINE_TINY")
2618
2619 AC_SUBST([VDPAU_MAJOR], 1)
2620 AC_SUBST([VDPAU_MINOR], 0)
2621
2622 VA_MAJOR=`$PKG_CONFIG --modversion libva | $SED -n 's/\([[^\.]]*\)\..*$/\1/p'`
2623 VA_MINOR=`$PKG_CONFIG --modversion libva | $SED -n 's/.*\.\(.*\)\..*$/\1/p'`
2624 AC_SUBST([VA_MAJOR], $VA_MAJOR)
2625 AC_SUBST([VA_MINOR], $VA_MINOR)
2626
2627 AM_CONDITIONAL(HAVE_VULKAN_COMMON, test "x$VULKAN_DRIVERS" != "x")
2628
2629 AC_SUBST([XVMC_MAJOR], 1)
2630 AC_SUBST([XVMC_MINOR], 0)
2631
2632 XA_HEADER="$srcdir/src/gallium/state_trackers/xa/xa_tracker.h"
2633 XA_MAJOR=`grep "#define XA_TRACKER_VERSION_MAJOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MAJOR //'`
2634 XA_MINOR=`grep "#define XA_TRACKER_VERSION_MINOR" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_MINOR //'`
2635 XA_TINY=`grep "#define XA_TRACKER_VERSION_PATCH" $XA_HEADER | $SED 's/^#define XA_TRACKER_VERSION_PATCH //'`
2636
2637 AC_SUBST([XA_MAJOR], $XA_MAJOR)
2638 AC_SUBST([XA_MINOR], $XA_MINOR)
2639 AC_SUBST([XA_TINY], $XA_TINY)
2640 AC_SUBST([XA_VERSION], "$XA_MAJOR.$XA_MINOR.$XA_TINY")
2641
2642 AC_SUBST([TIMESTAMP_CMD], '`test $(SOURCE_DATE_EPOCH) && echo $(SOURCE_DATE_EPOCH) || date +%s`')
2643
2644 AC_ARG_ENABLE(valgrind,
2645               [AS_HELP_STRING([--enable-valgrind],
2646                              [Build mesa with valgrind support (default: auto)])],
2647                              [VALGRIND=$enableval], [VALGRIND=auto])
2648 if test "x$VALGRIND" != xno; then
2649         PKG_CHECK_MODULES(VALGRIND, [valgrind], [have_valgrind=yes], [have_valgrind=no])
2650 fi
2651 AC_MSG_CHECKING([whether to enable Valgrind support])
2652 if test "x$VALGRIND" = xauto; then
2653         VALGRIND="$have_valgrind"
2654 fi
2655
2656 if test "x$VALGRIND" = "xyes"; then
2657         if ! test "x$have_valgrind" = xyes; then
2658                 AC_MSG_ERROR([Valgrind support required but not present])
2659         fi
2660         AC_DEFINE([HAVE_VALGRIND], 1, [Use valgrind intrinsics to suppress false warnings])
2661 fi
2662
2663 AC_MSG_RESULT([$VALGRIND])
2664
2665 dnl Restore LDFLAGS and CPPFLAGS
2666 LDFLAGS="$_SAVE_LDFLAGS"
2667 CPPFLAGS="$_SAVE_CPPFLAGS"
2668
2669 dnl Suppress clang's warnings about unused CFLAGS and CXXFLAGS
2670 if test "x$acv_mesa_CLANG" = xyes; then
2671     CFLAGS="$CFLAGS -Qunused-arguments"
2672     CXXFLAGS="$CXXFLAGS -Qunused-arguments"
2673 fi
2674
2675 dnl Add user CFLAGS and CXXFLAGS
2676 CFLAGS="$CFLAGS $USER_CFLAGS"
2677 CXXFLAGS="$CXXFLAGS $USER_CXXFLAGS"
2678
2679 dnl Substitute the config
2680 AC_CONFIG_FILES([Makefile
2681                 src/Makefile
2682                 src/amd/Makefile
2683                 src/amd/common/Makefile
2684                 src/amd/vulkan/Makefile
2685                 src/compiler/Makefile
2686                 src/egl/Makefile
2687                 src/egl/main/egl.pc
2688                 src/egl/wayland/wayland-drm/Makefile
2689                 src/egl/wayland/wayland-egl/Makefile
2690                 src/egl/wayland/wayland-egl/wayland-egl.pc
2691                 src/gallium/Makefile
2692                 src/gallium/auxiliary/Makefile
2693                 src/gallium/auxiliary/pipe-loader/Makefile
2694                 src/gallium/drivers/freedreno/Makefile
2695                 src/gallium/drivers/ddebug/Makefile
2696                 src/gallium/drivers/i915/Makefile
2697                 src/gallium/drivers/ilo/Makefile
2698                 src/gallium/drivers/llvmpipe/Makefile
2699                 src/gallium/drivers/noop/Makefile
2700                 src/gallium/drivers/nouveau/Makefile
2701                 src/gallium/drivers/r300/Makefile
2702                 src/gallium/drivers/r600/Makefile
2703                 src/gallium/drivers/radeon/Makefile
2704                 src/gallium/drivers/radeonsi/Makefile
2705                 src/gallium/drivers/rbug/Makefile
2706                 src/gallium/drivers/softpipe/Makefile
2707                 src/gallium/drivers/svga/Makefile
2708                 src/gallium/drivers/swr/Makefile
2709                 src/gallium/drivers/trace/Makefile
2710                 src/gallium/drivers/vc4/Makefile
2711                 src/gallium/drivers/virgl/Makefile
2712                 src/gallium/state_trackers/clover/Makefile
2713                 src/gallium/state_trackers/dri/Makefile
2714                 src/gallium/state_trackers/glx/xlib/Makefile
2715                 src/gallium/state_trackers/nine/Makefile
2716                 src/gallium/state_trackers/omx/Makefile
2717                 src/gallium/state_trackers/osmesa/Makefile
2718                 src/gallium/state_trackers/va/Makefile
2719                 src/gallium/state_trackers/vdpau/Makefile
2720                 src/gallium/state_trackers/xa/Makefile
2721                 src/gallium/state_trackers/xvmc/Makefile
2722                 src/gallium/targets/d3dadapter9/Makefile
2723                 src/gallium/targets/d3dadapter9/d3d.pc
2724                 src/gallium/targets/dri/Makefile
2725                 src/gallium/targets/libgl-xlib/Makefile
2726                 src/gallium/targets/omx/Makefile
2727                 src/gallium/targets/opencl/Makefile
2728                 src/gallium/targets/opencl/mesa.icd
2729                 src/gallium/targets/osmesa/Makefile
2730                 src/gallium/targets/osmesa/osmesa.pc
2731                 src/gallium/targets/pipe-loader/Makefile
2732                 src/gallium/targets/va/Makefile
2733                 src/gallium/targets/vdpau/Makefile
2734                 src/gallium/targets/xa/Makefile
2735                 src/gallium/targets/xa/xatracker.pc
2736                 src/gallium/targets/xvmc/Makefile
2737                 src/gallium/tests/trivial/Makefile
2738                 src/gallium/tests/unit/Makefile
2739                 src/gallium/winsys/freedreno/drm/Makefile
2740                 src/gallium/winsys/i915/drm/Makefile
2741                 src/gallium/winsys/intel/drm/Makefile
2742                 src/gallium/winsys/nouveau/drm/Makefile
2743                 src/gallium/winsys/radeon/drm/Makefile
2744                 src/gallium/winsys/amdgpu/drm/Makefile
2745                 src/gallium/winsys/svga/drm/Makefile
2746                 src/gallium/winsys/sw/dri/Makefile
2747                 src/gallium/winsys/sw/kms-dri/Makefile
2748                 src/gallium/winsys/sw/null/Makefile
2749                 src/gallium/winsys/sw/wrapper/Makefile
2750                 src/gallium/winsys/sw/xlib/Makefile
2751                 src/gallium/winsys/vc4/drm/Makefile
2752                 src/gallium/winsys/virgl/drm/Makefile
2753                 src/gallium/winsys/virgl/vtest/Makefile
2754                 src/gbm/Makefile
2755                 src/gbm/main/gbm.pc
2756                 src/glx/Makefile
2757                 src/glx/apple/Makefile
2758                 src/glx/tests/Makefile
2759                 src/glx/windows/Makefile
2760                 src/glx/windows/windowsdriproto.pc
2761                 src/gtest/Makefile
2762                 src/intel/Makefile
2763                 src/intel/tools/Makefile
2764                 src/intel/vulkan/Makefile
2765                 src/loader/Makefile
2766                 src/mapi/Makefile
2767                 src/mapi/es1api/glesv1_cm.pc
2768                 src/mapi/es2api/glesv2.pc
2769                 src/mapi/glapi/gen/Makefile
2770                 src/mesa/Makefile
2771                 src/mesa/gl.pc
2772                 src/mesa/drivers/dri/dri.pc
2773                 src/mesa/drivers/dri/common/Makefile
2774                 src/mesa/drivers/dri/common/xmlpool/Makefile
2775                 src/mesa/drivers/dri/i915/Makefile
2776                 src/mesa/drivers/dri/i965/Makefile
2777                 src/mesa/drivers/dri/Makefile
2778                 src/mesa/drivers/dri/nouveau/Makefile
2779                 src/mesa/drivers/dri/r200/Makefile
2780                 src/mesa/drivers/dri/radeon/Makefile
2781                 src/mesa/drivers/dri/swrast/Makefile
2782                 src/mesa/drivers/osmesa/Makefile
2783                 src/mesa/drivers/osmesa/osmesa.pc
2784                 src/mesa/drivers/x11/Makefile
2785                 src/mesa/main/tests/Makefile
2786                 src/util/Makefile
2787                 src/util/tests/hash_table/Makefile
2788                 src/vulkan/wsi/Makefile])
2789
2790 AC_OUTPUT
2791
2792 # Fix up dependencies in *.Plo files, where we changed the extension of a
2793 # source file
2794 $SED -i -e 's/brw_blorp.cpp/brw_blorp.c/' src/mesa/drivers/dri/i965/.deps/brw_blorp.Plo
2795
2796
2797 dnl
2798 dnl Output some configuration info for the user
2799 dnl
2800 echo ""
2801 echo "        prefix:          $prefix"
2802 echo "        exec_prefix:     $exec_prefix"
2803 echo "        libdir:          $libdir"
2804 echo "        includedir:      $includedir"
2805
2806 dnl API info
2807 echo ""
2808 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
2809
2810 dnl Driver info
2811 echo ""
2812 case "x$enable_osmesa$enable_gallium_osmesa" in
2813 xnoyes)
2814         echo "        OSMesa:          lib$OSMESA_LIB (Gallium)"
2815         ;;
2816 xyesno)
2817         echo "        OSMesa:          lib$OSMESA_LIB"
2818         ;;
2819 xnono)
2820         echo "        OSMesa:          no"
2821         ;;
2822 esac
2823
2824 echo ""
2825 if test "x$enable_dri" != xno; then
2826         echo "        DRI platform:    $dri_platform"
2827         if test -z "$DRI_DIRS"; then
2828             echo "        DRI drivers:     no"
2829         else
2830             echo "        DRI drivers:     $DRI_DIRS"
2831         fi
2832         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
2833 fi
2834
2835 case "x$enable_glx" in
2836 xdri)
2837     echo "        GLX:             DRI-based"
2838     ;;
2839 xxlib)
2840     echo "        GLX:             Xlib-based"
2841     ;;
2842 xgallium-xlib)
2843     echo "        GLX:             Xlib-based (Gallium)"
2844     ;;
2845 *)
2846     echo "        GLX:             $enable_glx"
2847     ;;
2848 esac
2849
2850 dnl EGL
2851 echo ""
2852 echo "        EGL:             $enable_egl"
2853 if test "$enable_egl" = yes; then
2854     echo "        EGL platforms:   $egl_platforms"
2855
2856     egl_drivers=""
2857     if test "x$HAVE_EGL_DRIVER_DRI2" != "x"; then
2858         egl_drivers="$egl_drivers builtin:egl_dri2"
2859     fi
2860     if test "x$HAVE_EGL_DRIVER_DRI3" != "x"; then
2861         egl_drivers="$egl_drivers builtin:egl_dri3"
2862     fi
2863
2864     echo "        EGL drivers:    $egl_drivers"
2865 fi
2866
2867 # Vulkan
2868 echo ""
2869 if test "x$VULKAN_DRIVERS" != x; then
2870     echo "        Vulkan drivers:  $VULKAN_DRIVERS"
2871     echo "        Vulkan ICD dir:  $VULKAN_ICD_INSTALL_DIR"
2872 else
2873     echo "        Vulkan drivers:  no"
2874 fi
2875
2876 echo ""
2877 if test "x$MESA_LLVM" = x1; then
2878     echo "        llvm:            yes"
2879     echo "        llvm-config:     $LLVM_CONFIG"
2880     echo "        llvm-version:    $LLVM_VERSION"
2881 else
2882     echo "        llvm:            no"
2883 fi
2884
2885 echo ""
2886 if test -n "$with_gallium_drivers"; then
2887     echo "        Gallium drivers: $gallium_drivers"
2888     echo "        Gallium st:      $gallium_st"
2889 else
2890     echo "        Gallium:         no"
2891 fi
2892
2893 echo ""
2894 if test "x$enable_gallium_extra_hud" != xyes; then
2895     echo "        HUD extra stats: no"
2896 else
2897     echo "        HUD extra stats: yes"
2898 fi
2899
2900 if test "x$enable_lmsensors" != xyes; then
2901     echo "        HUD lmsensors:   no"
2902 else
2903     echo "        HUD lmsensors:   yes"
2904 fi
2905
2906 dnl Shader cache
2907 echo ""
2908 echo "        Shader cache:    $enable_shader_cache"
2909 if test "x$enable_shader_cache" = "xyes"; then
2910     echo "        With SHA1 from:  $with_sha1"
2911 fi
2912
2913 dnl Libraries
2914 echo ""
2915 echo "        Shared libs:     $enable_shared"
2916 echo "        Static libs:     $enable_static"
2917 echo "        Shared-glapi:    $enable_shared_glapi"
2918
2919 dnl Compiler options
2920 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
2921 cflags=`echo $CFLAGS | \
2922     $SED 's/^ *//;s/  */ /;s/ *$//'`
2923 cxxflags=`echo $CXXFLAGS | \
2924     $SED 's/^ *//;s/  */ /;s/ *$//'`
2925 defines=`echo $DEFINES | $SED 's/^ *//;s/  */ /;s/ *$//'`
2926 echo ""
2927 echo "        CFLAGS:          $cflags"
2928 echo "        CXXFLAGS:        $cxxflags"
2929 echo "        Macros:          $defines"
2930 echo ""
2931 if test "x$MESA_LLVM" = x1; then
2932     echo "        LLVM_CFLAGS:     $LLVM_CFLAGS"
2933     echo "        LLVM_CXXFLAGS:   $LLVM_CXXFLAGS"
2934     echo "        LLVM_CPPFLAGS:   $LLVM_CPPFLAGS"
2935     echo "        LLVM_LDFLAGS:    $LLVM_LDFLAGS"
2936     echo ""
2937 fi
2938 echo "        PYTHON2:         $PYTHON2"
2939
2940 echo ""
2941 echo "        Run '${MAKE-make}' to build Mesa"
2942 echo ""