configure.ac

   1 dnl Process this file with autoconf to create configure.
   2
   3 AC_PREREQ([2.59])
   4
   5 dnl Versioning - scrape the version from configs/default
   6 m4_define([mesa_version],
   7     [m4_esyscmd([${MAKE-make} -s -f bin/version.mk version | tr -d '\n' | tr -d '\r'])])
   8 m4_ifval(mesa_version,,
   9     [m4_fatal([Failed to get the Mesa version from `make -f bin/version.mk version`])])
  10
  11 dnl Tell the user about autoconf.html in the --help output
  12 m4_divert_once([HELP_END], [
  13 See docs/autoconf.html for more details on the options for Mesa.])
  14
  15 AC_INIT([Mesa],[mesa_version],
  16     [https://bugs.freedesktop.org/enter_bug.cgi?product=Mesa])
  17 AC_CONFIG_AUX_DIR([bin])
  18 AC_CANONICAL_HOST
  19
  20 dnl Versions for external dependencies
  21 LIBDRM_REQUIRED=2.4.15
  22 LIBDRM_RADEON_REQUIRED=2.4.17
  23 DRI2PROTO_REQUIRED=2.1
  24 GLPROTO_REQUIRED=1.4.11
  25 LIBDRM_XORG_REQUIRED=2.4.17
  26 LIBKMS_XORG_REQUIRED=1.0.0
  27
  28 dnl Check for progs
  29 AC_PROG_CPP
  30 AC_PROG_CC
  31 AC_PROG_CXX
  32 AC_CHECK_PROGS([MAKE], [gmake make])
  33 AC_CHECK_PROGS([PYTHON2], [python2 python])
  34 AC_PATH_PROG([MKDEP], [makedepend])
  35 AC_PATH_PROG([SED], [sed])
  36
  37 if test "x$MKDEP" = "x"; then
  38     AC_MSG_ERROR([makedepend is required to build Mesa])
  39 fi
  40
  41 dnl Our fallback install-sh is a symlink to minstall. Use the existing
  42 dnl configuration in that case.
  43 AC_PROG_INSTALL
  44 test "x$INSTALL" = "x$ac_install_sh" && INSTALL='$(MINSTALL)'
  45
  46 dnl We need a POSIX shell for parts of the build. Assume we have one
  47 dnl in most cases.
  48 case "$host_os" in
  49 solaris*)
  50     # Solaris /bin/sh is too old/non-POSIX compliant
  51     AC_PATH_PROGS(POSIX_SHELL, [ksh93 ksh sh])
  52     SHELL="$POSIX_SHELL"
  53     ;;
  54 esac
  55
  56 dnl clang is mostly GCC-compatible, but its version is much lower,
  57 dnl so we have to check for it.
  58 AC_MSG_CHECKING([if compiling with clang])
  59
  60 AC_COMPILE_IFELSE(
  61 [AC_LANG_PROGRAM([], [[
  62 #ifndef __clang__
  63        not clang
  64 #endif
  65 ]])],
  66 [CLANG=yes], [CLANG=no])
  67
  68 AC_MSG_RESULT([$CLANG])
  69
  70 dnl If we're using GCC, make sure that it is at least version 3.3.0.  Older
  71 dnl versions are explictly not supported.
  72 if test "x$GCC" = xyes -a "x$CLANG" = xno; then
  73     AC_MSG_CHECKING([whether gcc version is sufficient])
  74     major=0
  75     minor=0
  76
  77     GCC_VERSION=`$CC -dumpversion`
  78     if test $? -eq 0; then
  79         major=`echo $GCC_VERSION | cut -d. -f1`
  80         minor=`echo $GCC_VERSION | cut -d. -f1`
  81     fi
  82
  83     if test $major -lt 3 -o $major -eq 3 -a $minor -lt 3 ; then
  84         AC_MSG_RESULT([no])
  85         AC_MSG_ERROR([If using GCC, version 3.3.0 or later is required.])
  86     else
  87         AC_MSG_RESULT([yes])
  88     fi
  89 fi
  90
  91
  92 MKDEP_OPTIONS=-fdepend
  93 dnl Ask gcc where it's keeping its secret headers
  94 if test "x$GCC" = xyes; then
  95     for dir in include include-fixed; do
  96         GCC_INCLUDES=`$CC -print-file-name=$dir`
  97         if test "x$GCC_INCLUDES" != x && \
  98            test "$GCC_INCLUDES" != "$dir" && \
  99            test -d "$GCC_INCLUDES"; then
 100             MKDEP_OPTIONS="$MKDEP_OPTIONS -I$GCC_INCLUDES"
 101         fi
 102     done
 103 fi
 104 AC_SUBST([MKDEP_OPTIONS])
 105
 106 dnl Make sure the pkg-config macros are defined
 107 m4_ifndef([PKG_PROG_PKG_CONFIG],
 108     [m4_fatal([Could not locate the pkg-config autoconf macros.
 109   These are usually located in /usr/share/aclocal/pkg.m4. If your macros
 110   are in a different location, try setting the environment variable
 111   ACLOCAL="aclocal -I/other/macro/dir" before running autoreconf.])])
 112 PKG_PROG_PKG_CONFIG()
 113
 114 dnl LIB_DIR - library basename
 115 LIB_DIR=`echo $libdir | $SED 's%.*/%%'`
 116 AC_SUBST([LIB_DIR])
 117
 118 dnl Cache LDFLAGS so we can add EXTRA_LIB_PATH and restore it later
 119 _SAVE_LDFLAGS="$LDFLAGS"
 120 AC_ARG_VAR([EXTRA_LIB_PATH],[Extra -L paths for the linker])
 121 AC_SUBST([EXTRA_LIB_PATH])
 122
 123 dnl Cache CPPFLAGS so we can add *_INCLUDES and restore it later
 124 _SAVE_CPPFLAGS="$CPPFLAGS"
 125 AC_ARG_VAR([X11_INCLUDES],[Extra -I paths for X11 headers])
 126 AC_SUBST([X11_INCLUDES])
 127
 128 dnl Compiler macros
 129 DEFINES=""
 130 AC_SUBST([DEFINES])
 131 case "$host_os" in
 132 linux*|*-gnu*|gnu*)
 133     DEFINES="$DEFINES -D_GNU_SOURCE -DPTHREADS"
 134     ;;
 135 solaris*)
 136     DEFINES="$DEFINES -DPTHREADS -DSVR4"
 137     ;;
 138 cygwin*)
 139     DEFINES="$DEFINES -DPTHREADS"
 140     ;;
 141 esac
 142
 143 dnl Add flags for gcc and g++
 144 if test "x$GCC" = xyes; then
 145     CFLAGS="$CFLAGS -Wall -Wmissing-prototypes -std=c99"
 146     if test "x$CLANG" = "xno"; then
 147        CFLAGS="$CFLAGS -ffast-math"
 148     fi
 149
 150     # Enable -fvisibility=hidden if using a gcc that supports it
 151     save_CFLAGS="$CFLAGS"
 152     AC_MSG_CHECKING([whether $CC supports -fvisibility=hidden])
 153     CFLAGS="$CFLAGS -fvisibility=hidden"
 154     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 155                    [CFLAGS="$save_CFLAGS" ; AC_MSG_RESULT([no])]);
 156
 157     # Work around aliasing bugs - developers should comment this out
 158     CFLAGS="$CFLAGS -fno-strict-aliasing"
 159 fi
 160 if test "x$GXX" = xyes; then
 161     CXXFLAGS="$CXXFLAGS -Wall"
 162
 163     # Enable -fvisibility=hidden if using a gcc that supports it
 164     save_CXXFLAGS="$CXXFLAGS"
 165     AC_MSG_CHECKING([whether $CXX supports -fvisibility=hidden])
 166     CXXFLAGS="$CXXFLAGS -fvisibility=hidden"
 167     AC_LINK_IFELSE([AC_LANG_PROGRAM()], AC_MSG_RESULT([yes]),
 168                    [CXXFLAGS="$save_CXXFLAGS" ; AC_MSG_RESULT([no])]);
 169
 170     # Work around aliasing bugs - developers should comment this out
 171     CXXFLAGS="$CXXFLAGS -fno-strict-aliasing"
 172 fi
 173
 174 dnl These should be unnecessary, but let the user set them if they want
 175 AC_ARG_VAR([OPT_FLAGS], [Additional optimization flags for the compiler.
 176     Default is to use CFLAGS.])
 177 AC_ARG_VAR([ARCH_FLAGS], [Additional architecture specific flags for the
 178     compiler. Default is to use CFLAGS.])
 179 AC_SUBST([OPT_FLAGS])
 180 AC_SUBST([ARCH_FLAGS])
 181
 182 dnl
 183 dnl Hacks to enable 32 or 64 bit build
 184 dnl
 185 AC_ARG_ENABLE([32-bit],
 186     [AS_HELP_STRING([--enable-32-bit],
 187         [build 32-bit libraries @<:@default=auto@:>@])],
 188     [enable_32bit="$enableval"],
 189     [enable_32bit=auto]
 190 )
 191 if test "x$enable_32bit" = xyes; then
 192     if test "x$GCC" = xyes; then
 193         CFLAGS="$CFLAGS -m32"
 194         ARCH_FLAGS="$ARCH_FLAGS -m32"
 195     fi
 196     if test "x$GXX" = xyes; then
 197         CXXFLAGS="$CXXFLAGS -m32"
 198     fi
 199 fi
 200 AC_ARG_ENABLE([64-bit],
 201     [AS_HELP_STRING([--enable-64-bit],
 202         [build 64-bit libraries @<:@default=auto@:>@])],
 203     [enable_64bit="$enableval"],
 204     [enable_64bit=auto]
 205 )
 206 if test "x$enable_64bit" = xyes; then
 207     if test "x$GCC" = xyes; then
 208         CFLAGS="$CFLAGS -m64"
 209     fi
 210     if test "x$GXX" = xyes; then
 211         CXXFLAGS="$CXXFLAGS -m64"
 212     fi
 213 fi
 214
 215 dnl
 216 dnl shared/static libraries, mimic libtool options
 217 dnl
 218 AC_ARG_ENABLE([static],
 219     [AS_HELP_STRING([--enable-static],
 220         [build static libraries @<:@default=disabled@:>@])],
 221     [enable_static="$enableval"],
 222     [enable_static=no]
 223 )
 224 case "x$enable_static" in
 225 xyes|xno ) ;;
 226 x ) enable_static=no ;;
 227 * )
 228     AC_MSG_ERROR([Static library option '$enable_static' is not a valid])
 229     ;;
 230 esac
 231 AC_ARG_ENABLE([shared],
 232     [AS_HELP_STRING([--disable-shared],
 233         [build shared libraries @<:@default=enabled@:>@])],
 234     [enable_shared="$enableval"],
 235     [enable_shared=yes]
 236 )
 237 case "x$enable_shared" in
 238 xyes|xno ) ;;
 239 x ) enable_shared=yes ;;
 240 * )
 241     AC_MSG_ERROR([Shared library option '$enable_shared' is not a valid])
 242     ;;
 243 esac
 244
 245 dnl Can't have static and shared libraries, default to static if user
 246 dnl explicitly requested. If both disabled, set to static since shared
 247 dnl was explicitly requirested.
 248 case "x$enable_static$enable_shared" in
 249 xyesyes )
 250     AC_MSG_WARN([Can't build static and shared libraries, disabling shared])
 251     enable_shared=no
 252     ;;
 253 xnono )
 254     AC_MSG_WARN([Can't disable both static and shared libraries, enabling static])
 255     enable_static=yes
 256     ;;
 257 esac
 258
 259 dnl
 260 dnl mklib options
 261 dnl
 262 AC_ARG_VAR([MKLIB_OPTIONS],[Options for the Mesa library script, mklib])
 263 if test "$enable_static" = yes; then
 264     MKLIB_OPTIONS="$MKLIB_OPTIONS -static"
 265 fi
 266 AC_SUBST([MKLIB_OPTIONS])
 267
 268 dnl
 269 dnl other compiler options
 270 dnl
 271 AC_ARG_ENABLE([debug],
 272     [AS_HELP_STRING([--enable-debug],
 273         [use debug compiler flags and macros @<:@default=disabled@:>@])],
 274     [enable_debug="$enableval"],
 275     [enable_debug=no]
 276 )
 277 if test "x$enable_debug" = xyes; then
 278     DEFINES="$DEFINES -DDEBUG"
 279     if test "x$GCC" = xyes; then
 280         CFLAGS="$CFLAGS -g"
 281     fi
 282     if test "x$GXX" = xyes; then
 283         CXXFLAGS="$CXXFLAGS -g"
 284     fi
 285 fi
 286
 287 dnl
 288 dnl library names
 289 dnl
 290 LIB_PREFIX_GLOB='lib'
 291 LIB_VERSION_SEPARATOR='.'
 292 if test "$enable_static" = yes; then
 293     LIB_EXTENSION='a'
 294 else
 295     case "$host_os" in
 296     darwin* )
 297         LIB_EXTENSION='dylib' ;;
 298     cygwin* )
 299         dnl prefix can be 'cyg' or 'lib'
 300         LIB_PREFIX_GLOB='???'
 301         LIB_VERSION_SEPARATOR='-'
 302         LIB_EXTENSION='dll' ;;
 303     aix* )
 304         LIB_EXTENSION='a' ;;
 305     * )
 306         LIB_EXTENSION='so' ;;
 307     esac
 308 fi
 309
 310 GL_LIB_NAME='lib$(GL_LIB).'${LIB_EXTENSION}
 311 GLU_LIB_NAME='lib$(GLU_LIB).'${LIB_EXTENSION}
 312 GLUT_LIB_NAME='lib$(GLUT_LIB).'${LIB_EXTENSION}
 313 GLW_LIB_NAME='lib$(GLW_LIB).'${LIB_EXTENSION}
 314 OSMESA_LIB_NAME='lib$(OSMESA_LIB).'${LIB_EXTENSION}
 315 EGL_LIB_NAME='lib$(EGL_LIB).'${LIB_EXTENSION}
 316 GLESv1_CM_LIB_NAME='lib$(GLESv1_CM_LIB).'${LIB_EXTENSION}
 317 GLESv2_LIB_NAME='lib$(GLESv2_LIB).'${LIB_EXTENSION}
 318 VG_LIB_NAME='lib$(VG_LIB).'${LIB_EXTENSION}
 319
 320 GL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 321 GLU_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLU_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 322 GLUT_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLUT_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 323 GLW_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLW_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 324 OSMESA_LIB_GLOB=${LIB_PREFIX_GLOB}'$(OSMESA_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 325 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 326 EGL_LIB_GLOB=${LIB_PREFIX_GLOB}'$(EGL_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 327 GLESv1_CM_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv1_CM_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 328 GLESv2_LIB_GLOB=${LIB_PREFIX_GLOB}'$(GLESv2_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 329 VG_LIB_GLOB=${LIB_PREFIX_GLOB}'$(VG_LIB)'${LIB_VERSION_SEPARATOR}'*'${LIB_EXTENSION}'*'
 330
 331 AC_SUBST([GL_LIB_NAME])
 332 AC_SUBST([GLU_LIB_NAME])
 333 AC_SUBST([GLUT_LIB_NAME])
 334 AC_SUBST([GLW_LIB_NAME])
 335 AC_SUBST([OSMESA_LIB_NAME])
 336 AC_SUBST([EGL_LIB_NAME])
 337 AC_SUBST([GLESv1_CM_LIB_NAME])
 338 AC_SUBST([GLESv2_LIB_NAME])
 339 AC_SUBST([VG_LIB_NAME])
 340
 341 AC_SUBST([GL_LIB_GLOB])
 342 AC_SUBST([GLU_LIB_GLOB])
 343 AC_SUBST([GLUT_LIB_GLOB])
 344 AC_SUBST([GLW_LIB_GLOB])
 345 AC_SUBST([OSMESA_LIB_GLOB])
 346 AC_SUBST([EGL_LIB_GLOB])
 347 AC_SUBST([GLESv1_CM_LIB_GLOB])
 348 AC_SUBST([GLESv2_LIB_GLOB])
 349 AC_SUBST([VG_LIB_GLOB])
 350
 351 dnl
 352 dnl Arch/platform-specific settings
 353 dnl
 354 AC_ARG_ENABLE([asm],
 355     [AS_HELP_STRING([--disable-asm],
 356         [disable assembly usage @<:@default=enabled on supported plaforms@:>@])],
 357     [enable_asm="$enableval"],
 358     [enable_asm=yes]
 359 )
 360 asm_arch=""
 361 ASM_FLAGS=""
 362 MESA_ASM_SOURCES=""
 363 GLAPI_ASM_SOURCES=""
 364 AC_MSG_CHECKING([whether to enable assembly])
 365 test "x$enable_asm" = xno && AC_MSG_RESULT([no])
 366 # disable if cross compiling on x86/x86_64 since we must run gen_matypes
 367 if test "x$enable_asm" = xyes && test "x$cross_compiling" = xyes; then
 368     case "$host_cpu" in
 369     i?86 | x86_64)
 370         enable_asm=no
 371         AC_MSG_RESULT([no, cross compiling])
 372         ;;
 373     esac
 374 fi
 375 # check for supported arches
 376 if test "x$enable_asm" = xyes; then
 377     case "$host_cpu" in
 378     i?86)
 379         case "$host_os" in
 380         linux* | *freebsd* | dragonfly*)
 381             test "x$enable_64bit" = xyes && asm_arch=x86_64 || asm_arch=x86
 382             ;;
 383         esac
 384         ;;
 385     x86_64)
 386         case "$host_os" in
 387         linux* | *freebsd* | dragonfly*)
 388             test "x$enable_32bit" = xyes && asm_arch=x86 || asm_arch=x86_64
 389             ;;
 390         esac
 391         ;;
 392     powerpc)
 393         case "$host_os" in
 394         linux*)
 395             asm_arch=ppc
 396             ;;
 397         esac
 398         ;;
 399     sparc*)
 400         case "$host_os" in
 401         linux*)
 402             asm_arch=sparc
 403             ;;
 404         esac
 405         ;;
 406     esac
 407
 408     case "$asm_arch" in
 409     x86)
 410         ASM_FLAGS="-DUSE_X86_ASM -DUSE_MMX_ASM -DUSE_3DNOW_ASM -DUSE_SSE_ASM"
 411         MESA_ASM_SOURCES='$(X86_SOURCES)'
 412         GLAPI_ASM_SOURCES='$(X86_API)'
 413         AC_MSG_RESULT([yes, x86])
 414         ;;
 415     x86_64)
 416         ASM_FLAGS="-DUSE_X86_64_ASM"
 417         MESA_ASM_SOURCES='$(X86-64_SOURCES)'
 418         GLAPI_ASM_SOURCES='$(X86-64_API)'
 419         AC_MSG_RESULT([yes, x86_64])
 420         ;;
 421     ppc)
 422         ASM_FLAGS="-DUSE_PPC_ASM -DUSE_VMX_ASM"
 423         MESA_ASM_SOURCES='$(PPC_SOURCES)'
 424         AC_MSG_RESULT([yes, ppc])
 425         ;;
 426     sparc)
 427         ASM_FLAGS="-DUSE_SPARC_ASM"
 428         MESA_ASM_SOURCES='$(SPARC_SOURCES)'
 429         GLAPI_ASM_SOURCES='$(SPARC_API)'
 430         AC_MSG_RESULT([yes, sparc])
 431         ;;
 432     *)
 433         AC_MSG_RESULT([no, platform not supported])
 434         ;;
 435     esac
 436 fi
 437 AC_SUBST([ASM_FLAGS])
 438 AC_SUBST([MESA_ASM_SOURCES])
 439 AC_SUBST([GLAPI_ASM_SOURCES])
 440
 441 dnl PIC code macro
 442 MESA_PIC_FLAGS
 443
 444 dnl Check to see if dlopen is in default libraries (like Solaris, which
 445 dnl has it in libc), or if libdl is needed to get it.
 446 AC_CHECK_FUNC([dlopen], [],
 447     [AC_CHECK_LIB([dl], [dlopen], [DLOPEN_LIBS="-ldl"])])
 448 AC_SUBST([DLOPEN_LIBS])
 449
 450 dnl See if posix_memalign is available
 451 AC_CHECK_FUNC([posix_memalign], [DEFINES="$DEFINES -DHAVE_POSIX_MEMALIGN"])
 452
 453 dnl SELinux awareness.
 454 AC_ARG_ENABLE([selinux],
 455     [AS_HELP_STRING([--enable-selinux],
 456         [Build SELinux-aware Mesa @<:@default=disabled@:>@])],
 457     [MESA_SELINUX="$enableval"],
 458     [MESA_SELINUX=no])
 459 if test "x$enable_selinux" = "xyes"; then
 460     AC_CHECK_HEADER([selinux/selinux.h],[],
 461                     [AC_MSG_ERROR([SELinux headers not found])])
 462     AC_CHECK_LIB([selinux],[is_selinux_enabled],[],
 463                  [AC_MSG_ERROR([SELinux library not found])])
 464     SELINUX_LIBS="-lselinux"
 465     DEFINES="$DEFINES -DMESA_SELINUX"
 466 fi
 467
 468 dnl Determine which APIs to support
 469 AC_ARG_ENABLE([opengl],
 470     [AS_HELP_STRING([--disable-opengl],
 471         [disable support for standard OpenGL API @<:@default=no@:>@])],
 472     [enable_opengl="$enableval"],
 473     [enable_opengl=yes])
 474 AC_ARG_ENABLE([gles1],
 475     [AS_HELP_STRING([--enable-gles1],
 476         [enable support for OpenGL ES 1.x API @<:@default=no@:>@])],
 477     [enable_gles1="$enableval"],
 478     [enable_gles1=no])
 479 AC_ARG_ENABLE([gles2],
 480     [AS_HELP_STRING([--enable-gles2],
 481         [enable support for OpenGL ES 2.x API @<:@default=no@:>@])],
 482     [enable_gles2="$enableval"],
 483     [enable_gles2=no])
 484 AC_ARG_ENABLE([gles-overlay],
 485     [AS_HELP_STRING([--enable-gles-overlay],
 486         [build separate OpenGL ES only libraries @<:@default=no@:>@])],
 487     [enable_gles_overlay="$enableval"],
 488     [enable_gles_overlay=no])
 489
 490 AC_ARG_ENABLE([openvg],
 491     [AS_HELP_STRING([--enable-openvg],
 492         [enable support for OpenVG API @<:@default=no@:>@])],
 493     [enable_openvg="$enableval"],
 494     [enable_openvg=no])
 495
 496 dnl smooth the transition; should be removed eventually
 497 if test "x$enable_openvg" = xno; then
 498     case "x$with_state_trackers" in
 499     x*vega*)
 500         AC_MSG_WARN([vega state tracker is enabled without --enable-openvg])
 501         enable_openvg=yes
 502         ;;
 503     esac
 504 fi
 505
 506 if test "x$enable_opengl" = xno -a \
 507         "x$enable_gles1" = xno -a \
 508         "x$enable_gles2" = xno -a \
 509         "x$enable_gles_overlay" = xno -a \
 510         "x$enable_openvg" = xno; then
 511     AC_MSG_ERROR([at least one API should be enabled])
 512 fi
 513
 514 API_DEFINES=""
 515 GLES_OVERLAY=0
 516 if test "x$enable_opengl" = xno; then
 517     API_DEFINES="$API_DEFINES -DFEATURE_GL=0"
 518 else
 519     API_DEFINES="$API_DEFINES -DFEATURE_GL=1"
 520 fi
 521 if test "x$enable_gles1" = xyes; then
 522     API_DEFINES="$API_DEFINES -DFEATURE_ES1=1"
 523 fi
 524 if test "x$enable_gles2" = xyes; then
 525     API_DEFINES="$API_DEFINES -DFEATURE_ES2=1"
 526 fi
 527 if test "x$enable_gles_overlay" = xyes; then
 528     GLES_OVERLAY=1
 529 fi
 530 AC_SUBST([API_DEFINES])
 531 AC_SUBST([GLES_OVERLAY])
 532
 533 dnl
 534 dnl Driver configuration. Options are xlib, dri and osmesa right now.
 535 dnl More later: fbdev, ...
 536 dnl
 537 default_driver="xlib"
 538
 539 case "$host_os" in
 540 linux*)
 541     case "$host_cpu" in
 542     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 543     esac
 544     ;;
 545 *freebsd* | dragonfly*)
 546     case "$host_cpu" in
 547     i*86|x86_64|powerpc*|sparc*) default_driver="dri";;
 548     esac
 549     ;;
 550 esac
 551
 552 if test "x$enable_opengl" = xno; then
 553     default_driver="no"
 554 fi
 555
 556 AC_ARG_WITH([driver],
 557     [AS_HELP_STRING([--with-driver=DRIVER],
 558         [driver for Mesa: xlib,dri,osmesa @<:@default=dri when available, or xlib@:>@])],
 559     [mesa_driver="$withval"],
 560     [mesa_driver="$default_driver"])
 561 dnl Check for valid option
 562 case "x$mesa_driver" in
 563 xxlib|xdri|xosmesa)
 564     if test "x$enable_opengl" = xno; then
 565         AC_MSG_ERROR([Driver '$mesa_driver' requires OpenGL enabled])
 566     fi
 567     ;;
 568 xno)
 569     ;;
 570 *)
 571     AC_MSG_ERROR([Driver '$mesa_driver' is not a valid option])
 572     ;;
 573 esac
 574
 575 PKG_CHECK_MODULES([TALLOC], [talloc])
 576 AC_SUBST([TALLOC_LIBS])
 577 AC_SUBST([TALLOC_CFLAGS])
 578
 579 dnl
 580 dnl Driver specific build directories
 581 dnl
 582
 583 dnl this variable will be prepended to SRC_DIRS and is not exported
 584 CORE_DIRS=""
 585
 586 SRC_DIRS=""
 587 GLU_DIRS="sgi"
 588 GALLIUM_DIRS="auxiliary drivers state_trackers"
 589 GALLIUM_TARGET_DIRS=""
 590 GALLIUM_WINSYS_DIRS="sw"
 591 GALLIUM_DRIVERS_DIRS="softpipe failover galahad trace rbug identity"
 592 GALLIUM_STATE_TRACKERS_DIRS=""
 593
 594 # build glapi if OpenGL is enabled
 595 if test "x$enable_opengl" = xyes; then
 596     CORE_DIRS="$CORE_DIRS mapi/glapi"
 597 fi
 598
 599 # build es1api and es2api if OpenGL ES is enabled
 600 case "x$enable_gles1$enable_gles2$enable_gles_overlay" in
 601 x*yes*)
 602     CORE_DIRS="$CORE_DIRS mapi/es1api mapi/es2api"
 603     ;;
 604 esac
 605
 606 # build vgapi if OpenVG is enabled
 607 if test "x$enable_openvg" = xyes; then
 608     CORE_DIRS="$CORE_DIRS mapi/vgapi"
 609 fi
 610
 611 # build glsl and mesa if OpenGL or OpenGL ES is enabled
 612 case "x$enable_opengl$enable_gles1$enable_gles2$enable_gles_overlay" in
 613 x*yes*)
 614     CORE_DIRS="$CORE_DIRS glsl mesa"
 615     ;;
 616 esac
 617
 618 case "$mesa_driver" in
 619 xlib)
 620     DRIVER_DIRS="x11"
 621     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib"
 622     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS libgl-xlib"
 623     ;;
 624 dri)
 625     SRC_DIRS="$SRC_DIRS glx"
 626     DRIVER_DIRS="dri"
 627     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/xlib sw/dri"
 628     ;;
 629 osmesa)
 630     DRIVER_DIRS="osmesa"
 631     ;;
 632 no)
 633     DRIVER_DRIS=""
 634     ;;
 635 esac
 636 AC_SUBST([SRC_DIRS])
 637 AC_SUBST([GLU_DIRS])
 638 AC_SUBST([DRIVER_DIRS])
 639 AC_SUBST([GALLIUM_DIRS])
 640 AC_SUBST([GALLIUM_TARGET_DIRS])
 641 AC_SUBST([GALLIUM_WINSYS_DIRS])
 642 AC_SUBST([GALLIUM_DRIVERS_DIRS])
 643 AC_SUBST([GALLIUM_STATE_TRACKERS_DIRS])
 644 AC_SUBST([MESA_LLVM])
 645
 646 dnl
 647 dnl Find out if X is available. The variable have_x is set if libX11 is
 648 dnl found to mimic AC_PATH_XTRA.
 649 dnl
 650 if test -n "$PKG_CONFIG"; then
 651     AC_MSG_CHECKING([pkg-config files for X11 are available])
 652     PKG_CHECK_EXISTS([x11],[
 653         x11_pkgconfig=yes
 654         have_x=yes
 655         ],[
 656         x11_pkgconfig=no
 657     ])
 658     AC_MSG_RESULT([$x11_pkgconfig])
 659 else
 660     x11_pkgconfig=no
 661 fi
 662 dnl Use the autoconf macro if no pkg-config files
 663 if test "$x11_pkgconfig" = yes; then
 664     PKG_CHECK_MODULES([X11], [x11])
 665 else
 666     AC_PATH_XTRA
 667     test -z "$X11_CFLAGS" && X11_CFLAGS="$X_CFLAGS"
 668     test -z "$X11_LIBS" && X11_LIBS="$X_LIBS -lX11"
 669     AC_SUBST([X11_CFLAGS])
 670     AC_SUBST([X11_LIBS])
 671 fi
 672
 673 dnl Try to tell the user that the --x-* options are only used when
 674 dnl pkg-config is not available. This must be right after AC_PATH_XTRA.
 675 m4_divert_once([HELP_BEGIN],
 676 [These options are only used when the X libraries cannot be found by the
 677 pkg-config utility.])
 678
 679 dnl We need X for xlib and dri, so bomb now if it's not found
 680 case "$mesa_driver" in
 681 xlib|dri)
 682     if test "$no_x" = yes; then
 683         AC_MSG_ERROR([X11 development libraries needed for $mesa_driver driver])
 684     fi
 685     ;;
 686 esac
 687
 688 dnl XCB - this is only used for GLX right now
 689 AC_ARG_ENABLE([xcb],
 690     [AS_HELP_STRING([--enable-xcb],
 691         [use XCB for GLX @<:@default=disabled@:>@])],
 692     [enable_xcb="$enableval"],
 693     [enable_xcb=no])
 694 if test "x$enable_xcb" = xyes; then
 695     DEFINES="$DEFINES -DUSE_XCB"
 696 else
 697     enable_xcb=no
 698 fi
 699
 700 dnl
 701 dnl libGL configuration per driver
 702 dnl
 703 case "$mesa_driver" in
 704 xlib)
 705     if test "$x11_pkgconfig" = yes; then
 706         PKG_CHECK_MODULES([XLIBGL], [x11 xext])
 707         GL_PC_REQ_PRIV="x11 xext"
 708         X11_INCLUDES="$X11_INCLUDES $XLIBGL_CFLAGS"
 709         GL_LIB_DEPS="$XLIBGL_LIBS"
 710     else
 711         # should check these...
 712         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 713         GL_LIB_DEPS="$X_LIBS -lX11 -lXext"
 714         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 715         GL_PC_CFLAGS="$X11_INCLUDES"
 716     fi
 717     GL_LIB_DEPS="$GL_LIB_DEPS $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 718     GL_PC_LIB_PRIV="$GL_PC_LIB_PRIV $SELINUX_LIBS -lm -lpthread $TALLOC_LIBS"
 719
 720     # if static, move the external libraries to the programs
 721     # and empty the libraries for libGL
 722     if test "$enable_static" = yes; then
 723         APP_LIB_DEPS="$APP_LIB_DEPS $GL_LIB_DEPS"
 724         GL_LIB_DEPS=""
 725     fi
 726     ;;
 727 dri|no) # these checks are still desired when there is no mesa_driver
 728     # DRI must be shared, I think
 729     if test "$enable_static" = yes; then
 730         AC_MSG_ERROR([Can't use static libraries for DRI drivers])
 731     fi
 732
 733     # Check for libdrm
 734     PKG_CHECK_MODULES([LIBDRM], [libdrm >= $LIBDRM_REQUIRED])
 735     PKG_CHECK_MODULES([DRI2PROTO], [dri2proto >= $DRI2PROTO_REQUIRED])
 736     PKG_CHECK_MODULES([GLPROTO], [glproto >= $GLPROTO_REQUIRED])
 737     GL_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED dri2proto >= $DRI2PROTO_REQUIRED glproto >= $GLPROTO_REQUIRED"
 738     DRI_PC_REQ_PRIV="libdrm >= $LIBDRM_REQUIRED"
 739
 740     # find the DRI deps for libGL
 741     if test "$x11_pkgconfig" = yes; then
 742         dri_modules="x11 xext xdamage xfixes"
 743
 744         # add xf86vidmode if available
 745         PKG_CHECK_MODULES([XF86VIDMODE], [xxf86vm], HAVE_XF86VIDMODE=yes, HAVE_XF86VIDMODE=no)
 746         if test "$HAVE_XF86VIDMODE" = yes ; then
 747             dri_modules="$dri_modules xxf86vm"
 748         fi
 749
 750         # add xcb modules if necessary
 751         if test "$enable_xcb" = yes; then
 752             dri_modules="$dri_modules x11-xcb xcb-glx"
 753         fi
 754
 755         PKG_CHECK_MODULES([DRIGL], [$dri_modules])
 756         GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV $dri_modules"
 757         X11_INCLUDES="$X11_INCLUDES $DRIGL_CFLAGS"
 758         GL_LIB_DEPS="$DRIGL_LIBS"
 759     else
 760         # should check these...
 761         X11_INCLUDES="$X11_INCLUDES $X_CFLAGS"
 762         GL_LIB_DEPS="$X_LIBS -lX11 -lXext -lXxf86vm -lXdamage -lXfixes"
 763         GL_PC_LIB_PRIV="$GL_LIB_DEPS"
 764         GL_PC_CFLAGS="$X11_INCLUDES"
 765
 766         # XCB can only be used from pkg-config
 767         if test "$enable_xcb" = yes; then
 768             PKG_CHECK_MODULES([XCB],[x11-xcb xcb-glx])
 769             GL_PC_REQ_PRIV="$GL_PC_REQ_PRIV x11-xcb xcb-glx"
 770             X11_INCLUDES="$X11_INCLUDES $XCB_CFLAGS"
 771             GL_LIB_DEPS="$GL_LIB_DEPS $XCB_LIBS"
 772         fi
 773     fi
 774
 775     # need DRM libs, -lpthread, etc.
 776     GL_LIB_DEPS="$GL_LIB_DEPS $LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 777     GL_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 778     GLESv1_CM_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 779     GLESv1_CM_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 780     GLESv2_LIB_DEPS="$LIBDRM_LIBS -lm -lpthread $DLOPEN_LIBS"
 781     GLESv2_PC_LIB_PRIV="-lm -lpthread $DLOPEN_LIBS"
 782     ;;
 783 osmesa)
 784     # No libGL for osmesa
 785     GL_LIB_DEPS=""
 786     ;;
 787 esac
 788 AC_SUBST([GL_LIB_DEPS])
 789 AC_SUBST([GL_PC_REQ_PRIV])
 790 AC_SUBST([GL_PC_LIB_PRIV])
 791 AC_SUBST([GL_PC_CFLAGS])
 792 AC_SUBST([DRI_PC_REQ_PRIV])
 793 AC_SUBST([GLESv1_CM_LIB_DEPS])
 794 AC_SUBST([GLESv1_CM_PC_LIB_PRIV])
 795 AC_SUBST([GLESv2_LIB_DEPS])
 796 AC_SUBST([GLESv2_PC_LIB_PRIV])
 797
 798
 799 AC_SUBST([HAVE_XF86VIDMODE])
 800
 801 PKG_CHECK_MODULES([LIBDRM_RADEON],
 802                   [libdrm_radeon libdrm >= $LIBDRM_RADEON_REQUIRED],
 803                   HAVE_LIBDRM_RADEON=yes,
 804                   HAVE_LIBDRM_RADEON=no)
 805
 806 dnl
 807 dnl More X11 setup
 808 dnl
 809 if test "$mesa_driver" = xlib; then
 810     DEFINES="$DEFINES -DUSE_XSHM"
 811 fi
 812
 813 dnl
 814 dnl More DRI setup
 815 dnl
 816 AC_ARG_ENABLE([glx-tls],
 817     [AS_HELP_STRING([--enable-glx-tls],
 818         [enable TLS support in GLX @<:@default=disabled@:>@])],
 819     [GLX_USE_TLS="$enableval"],
 820     [GLX_USE_TLS=no])
 821 dnl Directory for DRI drivers
 822 AC_ARG_WITH([dri-driverdir],
 823     [AS_HELP_STRING([--with-dri-driverdir=DIR],
 824         [directory for the DRI drivers @<:@${libdir}/dri@:>@])],
 825     [DRI_DRIVER_INSTALL_DIR="$withval"],
 826     [DRI_DRIVER_INSTALL_DIR='${libdir}/dri'])
 827 AC_SUBST([DRI_DRIVER_INSTALL_DIR])
 828 dnl Extra search path for DRI drivers
 829 AC_ARG_WITH([dri-searchpath],
 830     [AS_HELP_STRING([--with-dri-searchpath=DIRS...],
 831         [semicolon delimited DRI driver search directories @<:@${libdir}/dri@:>@])],
 832     [DRI_DRIVER_SEARCH_DIR="$withval"],
 833     [DRI_DRIVER_SEARCH_DIR='${DRI_DRIVER_INSTALL_DIR}'])
 834 AC_SUBST([DRI_DRIVER_SEARCH_DIR])
 835 dnl Direct rendering or just indirect rendering
 836 AC_ARG_ENABLE([driglx-direct],
 837     [AS_HELP_STRING([--disable-driglx-direct],
 838         [enable direct rendering in GLX and EGL for DRI @<:@default=enabled@:>@])],
 839     [driglx_direct="$enableval"],
 840     [driglx_direct="yes"])
 841 dnl Which drivers to build - default is chosen by platform
 842 AC_ARG_WITH([dri-drivers],
 843     [AS_HELP_STRING([--with-dri-drivers@<:@=DIRS...@:>@],
 844         [comma delimited DRI drivers list, e.g.
 845         "swrast,i965,radeon" @<:@default=auto@:>@])],
 846     [with_dri_drivers="$withval"],
 847     [with_dri_drivers=yes])
 848 if test "x$with_dri_drivers" = x; then
 849     with_dri_drivers=no
 850 fi
 851
 852 dnl If $with_dri_drivers is yes, directories will be added through
 853 dnl platform checks
 854 DRI_DIRS=""
 855 case "$with_dri_drivers" in
 856 no) ;;
 857 yes)
 858     DRI_DIRS="yes"
 859     ;;
 860 *)
 861     # verify the requested driver directories exist
 862     dri_drivers=`IFS=', '; echo $with_dri_drivers`
 863     for driver in $dri_drivers; do
 864         test -d "$srcdir/src/mesa/drivers/dri/$driver" || \
 865             AC_MSG_ERROR([DRI driver directory '$driver' doesn't exist])
 866     done
 867     DRI_DIRS="$dri_drivers"
 868     ;;
 869 esac
 870
 871 dnl Set DRI_DIRS, DEFINES and LIB_DEPS
 872 if test "$mesa_driver" = dri -o "$mesa_driver" = no; then
 873     # Use TLS in GLX?
 874     if test "x$GLX_USE_TLS" = xyes; then
 875         DEFINES="$DEFINES -DGLX_USE_TLS -DPTHREADS"
 876     fi
 877
 878     # Platform specific settings and drivers to build
 879     case "$host_os" in
 880     linux*)
 881         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 882         if test "x$driglx_direct" = xyes; then
 883             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 884         fi
 885         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 886
 887         case "$host_cpu" in
 888         x86_64)
 889             # sis is missing because they have not be converted to use
 890             # the new interface.  i810 are missing because there is no
 891             # x86-64 system where they could *ever* be used.
 892             if test "x$DRI_DIRS" = "xyes"; then
 893                 DRI_DIRS="i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 894                     savage tdfx unichrome swrast"
 895             fi
 896             ;;
 897         powerpc*)
 898             # Build only the drivers for cards that exist on PowerPC.
 899             # At some point MGA will be added, but not yet.
 900             if test "x$DRI_DIRS" = "xyes"; then
 901                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon tdfx swrast"
 902             fi
 903             ;;
 904         sparc*)
 905             # Build only the drivers for cards that exist on sparc`
 906             if test "x$DRI_DIRS" = "xyes"; then
 907                 DRI_DIRS="mach64 r128 r200 r300 r600 radeon swrast"
 908             fi
 909             ;;
 910         esac
 911         ;;
 912     freebsd* | dragonfly*)
 913         DEFINES="$DEFINES -DPTHREADS -DUSE_EXTERNAL_DXTN_LIB=1"
 914         DEFINES="$DEFINES -DIN_DRI_DRIVER -DHAVE_ALIAS"
 915         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 916         if test "x$driglx_direct" = xyes; then
 917             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 918         fi
 919         if test "x$GXX" = xyes; then
 920             CXXFLAGS="$CXXFLAGS -ansi -pedantic"
 921         fi
 922
 923         if test "x$DRI_DIRS" = "xyes"; then
 924             DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon tdfx \
 925                 unichrome savage sis swrast"
 926         fi
 927         ;;
 928     gnu*)
 929         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 930         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING -DHAVE_ALIAS"
 931         ;;
 932     solaris*)
 933         DEFINES="$DEFINES -DUSE_EXTERNAL_DXTN_LIB=1 -DIN_DRI_DRIVER"
 934         DEFINES="$DEFINES -DGLX_INDIRECT_RENDERING"
 935         if test "x$driglx_direct" = xyes; then
 936             DEFINES="$DEFINES -DGLX_DIRECT_RENDERING"
 937         fi
 938         ;;
 939     esac
 940
 941     # default drivers
 942     if test "x$DRI_DIRS" = "xyes"; then
 943         DRI_DIRS="i810 i915 i965 mach64 mga r128 r200 r300 r600 radeon \
 944             savage sis tdfx unichrome swrast"
 945     fi
 946
 947     DRI_DIRS=`echo "$DRI_DIRS" | $SED 's/  */ /g'`
 948
 949     # Check for expat
 950     if test "$mesa_driver" = dri; then
 951         EXPAT_INCLUDES=""
 952         EXPAT_LIB=-lexpat
 953         AC_ARG_WITH([expat],
 954             [AS_HELP_STRING([--with-expat=DIR],
 955                 [expat install directory])],[
 956             EXPAT_INCLUDES="-I$withval/include"
 957             CPPFLAGS="$CPPFLAGS $EXPAT_INCLUDES"
 958             LDFLAGS="$LDFLAGS -L$withval/$LIB_DIR"
 959             EXPAT_LIB="-L$withval/$LIB_DIR -lexpat"
 960             ])
 961         AC_CHECK_HEADER([expat.h],[],[AC_MSG_ERROR([Expat required for DRI.])])
 962         AC_CHECK_LIB([expat],[XML_ParserCreate],[],
 963             [AC_MSG_ERROR([Expat required for DRI.])])
 964     fi
 965
 966     # put all the necessary libs together
 967     DRI_LIB_DEPS="$SELINUX_LIBS $LIBDRM_LIBS $EXPAT_LIB -lm -lpthread $DLOPEN_LIBS $TALLOC_LIBS"
 968 fi
 969 AC_SUBST([DRI_DIRS])
 970 AC_SUBST([EXPAT_INCLUDES])
 971 AC_SUBST([DRI_LIB_DEPS])
 972
 973 case $DRI_DIRS in
 974 *i915*|*i965*)
 975     PKG_CHECK_MODULES([INTEL], [libdrm_intel >= 2.4.23])
 976     ;;
 977 esac
 978
 979 case $DRI_DIRS in
 980 *radeon*|*r200*|*r300*|*r600*)
 981     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
 982         RADEON_CFLAGS="-DHAVE_LIBDRM_RADEON=1 $LIBDRM_RADEON_CFLAGS"
 983         RADEON_LDFLAGS=$LIBDRM_RADEON_LIBS
 984     fi
 985     ;;
 986 esac
 987 AC_SUBST([RADEON_CFLAGS])
 988 AC_SUBST([RADEON_LDFLAGS])
 989
 990
 991 dnl
 992 dnl OSMesa configuration
 993 dnl
 994 if test "$mesa_driver" = xlib; then
 995     default_gl_osmesa=yes
 996 else
 997     default_gl_osmesa=no
 998 fi
 999 AC_ARG_ENABLE([gl-osmesa],
1000     [AS_HELP_STRING([--enable-gl-osmesa],
1001         [enable OSMesa with libGL @<:@default=enabled for xlib driver@:>@])],
1002     [gl_osmesa="$enableval"],
1003     [gl_osmesa="$default_gl_osmesa"])
1004 if test "x$gl_osmesa" = xyes; then
1005     if test "x$enable_opengl" = xno; then
1006         AC_MSG_ERROR([OpenGL is not available for OSMesa driver])
1007     fi
1008     if test "$mesa_driver" = osmesa; then
1009         AC_MSG_ERROR([libGL is not available for OSMesa driver])
1010     else
1011         DRIVER_DIRS="$DRIVER_DIRS osmesa"
1012     fi
1013 fi
1014
1015 dnl Configure the channel bits for OSMesa (libOSMesa, libOSMesa16, ...)
1016 AC_ARG_WITH([osmesa-bits],
1017     [AS_HELP_STRING([--with-osmesa-bits=BITS],
1018         [OSMesa channel bits and library name: 8, 16, 32 @<:@default=8@:>@])],
1019     [osmesa_bits="$withval"],
1020     [osmesa_bits=8])
1021 if test "$mesa_driver" != osmesa && test "x$osmesa_bits" != x8; then
1022     AC_MSG_WARN([Ignoring OSMesa channel bits for non-OSMesa driver])
1023     osmesa_bits=8
1024 fi
1025 case "x$osmesa_bits" in
1026 x8)
1027     OSMESA_LIB=OSMesa
1028     ;;
1029 x16|x32)
1030     OSMESA_LIB="OSMesa$osmesa_bits"
1031     DEFINES="$DEFINES -DCHAN_BITS=$osmesa_bits -DDEFAULT_SOFTWARE_DEPTH_BITS=31"
1032     ;;
1033 *)
1034     AC_MSG_ERROR([OSMesa bits '$osmesa_bits' is not a valid option])
1035     ;;
1036 esac
1037 AC_SUBST([OSMESA_LIB])
1038
1039 case "$DRIVER_DIRS" in
1040 *osmesa*)
1041     # only link libraries with osmesa if shared
1042     if test "$enable_static" = no; then
1043         OSMESA_LIB_DEPS="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1044     else
1045         OSMESA_LIB_DEPS=""
1046     fi
1047     OSMESA_MESA_DEPS=""
1048     OSMESA_PC_LIB_PRIV="-lm -lpthread $SELINUX_LIBS $DLOPEN_LIBS $TALLOC_LIBS"
1049     ;;
1050 esac
1051 AC_SUBST([OSMESA_LIB_DEPS])
1052 AC_SUBST([OSMESA_MESA_DEPS])
1053 AC_SUBST([OSMESA_PC_REQ])
1054 AC_SUBST([OSMESA_PC_LIB_PRIV])
1055
1056 dnl
1057 dnl EGL configuration
1058 dnl
1059 AC_ARG_ENABLE([egl],
1060     [AS_HELP_STRING([--disable-egl],
1061         [disable EGL library @<:@default=enabled@:>@])],
1062     [enable_egl="$enableval"],
1063     [enable_egl=yes])
1064 if test "x$enable_egl" = xno; then
1065     if test "x$mesa_driver" = xno; then
1066         AC_MSG_ERROR([cannot disable EGL when there is no mesa driver])
1067     fi
1068     if test "x$enable_openvg" = xyes; then
1069         AC_MSG_ERROR([cannot enable OpenVG without EGL])
1070     fi
1071 fi
1072 if test "x$enable_egl" = xyes; then
1073     SRC_DIRS="$SRC_DIRS egl"
1074     EGL_LIB_DEPS="$DLOPEN_LIBS -lpthread"
1075     EGL_DRIVERS_DIRS=""
1076     if test "$enable_static" != yes; then
1077         # build egl_glx when libGL is built
1078         if test "$mesa_driver" = xlib -o "$mesa_driver" = dri; then
1079             EGL_DRIVERS_DIRS="glx"
1080         fi
1081
1082         if test "$mesa_driver" = dri; then
1083             # build egl_dri2 when xcb-dri2 is available
1084             PKG_CHECK_MODULES([XCB_DRI2], [x11-xcb xcb-dri2 xcb-xfixes],
1085                           [have_xcb_dri2=yes],[have_xcb_dri2=no])
1086             PKG_CHECK_MODULES([LIBUDEV], [libudev > 150],
1087                           [have_libudev=yes],[have_libudev=no])
1088
1089             if test "$have_xcb_dri2" = yes; then
1090                 EGL_DRIVER_DRI2=dri2
1091                 DEFINES="$DEFINES -DHAVE_XCB_DRI2"
1092                 if test "$have_libudev" = yes; then
1093                     DEFINES="$DEFINES -DHAVE_LIBUDEV"
1094                 fi
1095             fi
1096         fi
1097
1098         EGL_DRIVERS_DIRS="$EGL_DRIVERS_DIRS $EGL_DRIVER_DRI2"
1099     fi
1100 fi
1101 AC_SUBST([EGL_LIB_DEPS])
1102 AC_SUBST([EGL_DRIVERS_DIRS])
1103
1104 dnl
1105 dnl GLU configuration
1106 dnl
1107 AC_ARG_ENABLE([glu],
1108     [AS_HELP_STRING([--disable-glu],
1109         [enable OpenGL Utility library @<:@default=enabled@:>@])],
1110     [enable_glu="$enableval"],
1111     [enable_glu=yes])
1112
1113 if test "x$enable_glu" = xyes -a "x$mesa_driver" = xno; then
1114     AC_MSG_NOTICE([Disabling GLU since there is no OpenGL driver])
1115     enable_glu=no
1116 fi
1117
1118 if test "x$enable_glu" = xyes; then
1119     SRC_DIRS="$SRC_DIRS glu"
1120
1121     case "$mesa_driver" in
1122     osmesa)
1123         # Link libGLU to libOSMesa instead of libGL
1124         GLU_LIB_DEPS=""
1125         GLU_PC_REQ="osmesa"
1126         if test "$enable_static" = no; then
1127             GLU_MESA_DEPS='-l$(OSMESA_LIB)'
1128         else
1129             GLU_MESA_DEPS=""
1130         fi
1131         ;;
1132     *)
1133         # If static, empty GLU_LIB_DEPS and add libs for programs to link
1134         GLU_PC_REQ="gl"
1135         GLU_PC_LIB_PRIV="-lm"
1136         if test "$enable_static" = no; then
1137             GLU_LIB_DEPS="-lm"
1138             GLU_MESA_DEPS='-l$(GL_LIB)'
1139         else
1140             GLU_LIB_DEPS=""
1141             GLU_MESA_DEPS=""
1142             APP_LIB_DEPS="$APP_LIB_DEPS -lstdc++"
1143         fi
1144         ;;
1145     esac
1146 fi
1147 if test "$enable_static" = no; then
1148     GLU_LIB_DEPS="$GLU_LIB_DEPS $OS_CPLUSPLUS_LIBS"
1149 fi
1150 GLU_PC_LIB_PRIV="$GLU_PC_LIB_PRIV $OS_CPLUSPLUS_LIBS"
1151 AC_SUBST([GLU_LIB_DEPS])
1152 AC_SUBST([GLU_MESA_DEPS])
1153 AC_SUBST([GLU_PC_REQ])
1154 AC_SUBST([GLU_PC_REQ_PRIV])
1155 AC_SUBST([GLU_PC_LIB_PRIV])
1156 AC_SUBST([GLU_PC_CFLAGS])
1157
1158 dnl
1159 dnl GLw configuration
1160 dnl
1161 AC_ARG_ENABLE([glw],
1162     [AS_HELP_STRING([--disable-glw],
1163         [enable Xt/Motif widget library @<:@default=enabled@:>@])],
1164     [enable_glw="$enableval"],
1165     [enable_glw=yes])
1166 dnl Don't build GLw on osmesa
1167 if test "x$enable_glw" = xyes; then
1168     case "$mesa_driver" in
1169     osmesa|no)
1170         AC_MSG_NOTICE([Disabling GLw since there is no OpenGL driver])
1171         enable_glw=no
1172         ;;
1173     esac
1174 fi
1175 AC_ARG_ENABLE([motif],
1176     [AS_HELP_STRING([--enable-motif],
1177         [use Motif widgets in GLw @<:@default=disabled@:>@])],
1178     [enable_motif="$enableval"],
1179     [enable_motif=no])
1180
1181 if test "x$enable_glw" = xyes; then
1182     SRC_DIRS="$SRC_DIRS glw"
1183     if test "$x11_pkgconfig" = yes; then
1184         PKG_CHECK_MODULES([GLW],[x11 xt])
1185         GLW_PC_REQ_PRIV="x11 xt"
1186         GLW_LIB_DEPS="$GLW_LIBS"
1187     else
1188         # should check these...
1189         GLW_LIB_DEPS="$X_LIBS -lXt -lX11"
1190         GLW_PC_LIB_PRIV="$GLW_LIB_DEPS"
1191         GLW_PC_CFLAGS="$X11_INCLUDES"
1192     fi
1193
1194     GLW_SOURCES="GLwDrawA.c"
1195     MOTIF_CFLAGS=
1196     if test "x$enable_motif" = xyes; then
1197         GLW_SOURCES="$GLW_SOURCES GLwMDrawA.c"
1198         AC_PATH_PROG([MOTIF_CONFIG], [motif-config], [no])
1199         if test "x$MOTIF_CONFIG" != xno; then
1200             MOTIF_CFLAGS=`$MOTIF_CONFIG --cflags`
1201             MOTIF_LIBS=`$MOTIF_CONFIG --libs`
1202         else
1203             AC_CHECK_HEADER([Xm/PrimitiveP.h], [],
1204                 [AC_MSG_ERROR([Can't locate Motif headers])])
1205             AC_CHECK_LIB([Xm], [XmGetPixmap], [MOTIF_LIBS="-lXm"],
1206                 [AC_MSG_ERROR([Can't locate Motif Xm library])])
1207         fi
1208         # MOTIF_LIBS is prepended to GLW_LIB_DEPS since Xm needs Xt/X11
1209         GLW_LIB_DEPS="$MOTIF_LIBS $GLW_LIB_DEPS"
1210         GLW_PC_LIB_PRIV="$MOTIF_LIBS $GLW_PC_LIB_PRIV"
1211         GLW_PC_CFLAGS="$MOTIF_CFLAGS $GLW_PC_CFLAGS"
1212     fi
1213
1214     # If static, empty GLW_LIB_DEPS and add libs for programs to link
1215     GLW_PC_LIB_PRIV="$GLW_PC_LIB_PRIV"
1216     if test "$enable_static" = no; then
1217         GLW_MESA_DEPS='-l$(GL_LIB)'
1218         GLW_LIB_DEPS="$GLW_LIB_DEPS"
1219     else
1220         APP_LIB_DEPS="$APP_LIB_DEPS $GLW_LIB_DEPS"
1221         GLW_LIB_DEPS=""
1222         GLW_MESA_DEPS=""
1223     fi
1224 fi
1225 AC_SUBST([GLW_LIB_DEPS])
1226 AC_SUBST([GLW_MESA_DEPS])
1227 AC_SUBST([GLW_SOURCES])
1228 AC_SUBST([MOTIF_CFLAGS])
1229 AC_SUBST([GLW_PC_REQ_PRIV])
1230 AC_SUBST([GLW_PC_LIB_PRIV])
1231 AC_SUBST([GLW_PC_CFLAGS])
1232
1233 dnl
1234 dnl GLUT configuration
1235 dnl
1236 if test -f "$srcdir/include/GL/glut.h"; then
1237     default_glut=yes
1238 else
1239     default_glut=no
1240 fi
1241 AC_ARG_ENABLE([glut],
1242     [AS_HELP_STRING([--disable-glut],
1243         [enable GLUT library @<:@default=enabled if source available@:>@])],
1244     [enable_glut="$enableval"],
1245     [enable_glut="$default_glut"])
1246
1247 dnl Don't build glut on osmesa
1248 if test "x$enable_glut" = xyes; then
1249     case "$mesa_driver" in
1250     osmesa|no)
1251         AC_MSG_NOTICE([Disabling glut since there is no OpenGL driver])
1252         enable_glut=no
1253         ;;
1254     esac
1255 fi
1256 dnl Can't build glut if GLU not available
1257 if test "x$enable_glu$enable_glut" = xnoyes; then
1258     AC_MSG_WARN([Disabling glut since GLU is disabled])
1259     enable_glut=no
1260 fi
1261
1262 if test "x$enable_glut" = xyes; then
1263     SRC_DIRS="$SRC_DIRS glut/glx"
1264     if test "$x11_pkgconfig" = yes; then
1265         PKG_CHECK_MODULES([GLUT],[x11 xmu xi])
1266         GLUT_PC_REQ_PRIV="x11 xmu xi"
1267         GLUT_LIB_DEPS="$GLUT_LIBS"
1268     else
1269         # should check these...
1270         GLUT_LIB_DEPS="$X_LIBS -lX11 -lXmu -lXi"
1271         GLUT_PC_LIB_PRIV="$GLUT_LIB_DEPS"
1272         GLUT_PC_CFLAGS="$X11_INCLUDES"
1273     fi
1274     if test "x$GCC" = xyes; then
1275         GLUT_CFLAGS="$GLUT_CFLAGS -fexceptions"
1276     fi
1277     GLUT_LIB_DEPS="$GLUT_LIB_DEPS -lm"
1278     GLUT_PC_LIB_PRIV="$GLUT_PC_LIB_PRIV -lm"
1279
1280     # If static, empty GLUT_LIB_DEPS and add libs for programs to link
1281     if test "$enable_static" = no; then
1282         GLUT_MESA_DEPS='-l$(GLU_LIB) -l$(GL_LIB)'
1283     else
1284         APP_LIB_DEPS="$APP_LIB_DEPS $GLUT_LIB_DEPS"
1285         GLUT_LIB_DEPS=""
1286         GLUT_MESA_DEPS=""
1287     fi
1288 fi
1289 AC_SUBST([GLUT_LIB_DEPS])
1290 AC_SUBST([GLUT_MESA_DEPS])
1291 AC_SUBST([GLUT_CFLAGS])
1292 AC_SUBST([GLUT_PC_REQ_PRIV])
1293 AC_SUBST([GLUT_PC_LIB_PRIV])
1294 AC_SUBST([GLUT_PC_CFLAGS])
1295
1296 dnl
1297 dnl Program library dependencies
1298 dnl    Only libm is added here if necessary as the libraries should
1299 dnl    be pulled in by the linker
1300 dnl
1301 if test "x$APP_LIB_DEPS" = x; then
1302     case "$host_os" in
1303     solaris*)
1304         APP_LIB_DEPS="-lX11 -lsocket -lnsl -lm"
1305         ;;
1306     cygwin*)
1307         APP_LIB_DEPS="-lX11"
1308         ;;
1309     *)
1310         APP_LIB_DEPS="-lm"
1311         ;;
1312     esac
1313 fi
1314 AC_SUBST([APP_LIB_DEPS])
1315 AC_SUBST([PROGRAM_DIRS])
1316
1317 dnl
1318 dnl Gallium configuration
1319 dnl
1320 AC_ARG_ENABLE([gallium],
1321     [AS_HELP_STRING([--disable-gallium],
1322         [build gallium @<:@default=enabled@:>@])],
1323     [enable_gallium="$enableval"],
1324     [enable_gallium=yes])
1325 if test "x$enable_gallium" = xno -a "x$enable_openvg" = xyes; then
1326     AC_MSG_ERROR([cannot enable OpenVG without Gallium])
1327 fi
1328 if test "x$enable_gallium" = xyes; then
1329     SRC_DIRS="$SRC_DIRS gallium gallium/winsys gallium/targets"
1330     AC_CHECK_HEADER([udis86.h], [HAS_UDIS86="yes"],
1331                 [HAS_UDIS86="no"])
1332     AC_PATH_PROG([LLVM_CONFIG], [llvm-config], [no])
1333 fi
1334
1335 AC_SUBST([LLVM_CFLAGS])
1336 AC_SUBST([LLVM_LIBS])
1337 AC_SUBST([LLVM_LDFLAGS])
1338 AC_SUBST([LLVM_VERSION])
1339
1340 dnl
1341 dnl Gallium state trackers configuration
1342 dnl
1343
1344 AC_ARG_ENABLE([gallium-egl],
1345     [AS_HELP_STRING([--enable-gallium-egl],
1346         [enable gallium EGL state tracker @<:@default=auto@:>@])],
1347     [enable_gallium_egl="$enableval"],
1348     [enable_gallium_egl=auto])
1349 if test "x$enable_gallium_egl" = xauto; then
1350     case "$mesa_driver" in
1351     dri|no)
1352         enable_gallium_egl=$enable_egl
1353         ;;
1354     *)
1355         enable_gallium_egl=$enable_openvg
1356         ;;
1357     esac
1358 fi
1359 case "x$enable_egl$enable_gallium_egl" in
1360 xnoyes)
1361     AC_MSG_ERROR([cannot build Gallium EGL state tracker without EGL])
1362 esac
1363
1364 AC_ARG_WITH([state-trackers],
1365     [AS_HELP_STRING([--with-state-trackers@<:@=DIRS...@:>@],
1366         [comma delimited state_trackers list, e.g.
1367         "egl,glx" @<:@default=auto@:>@])],
1368     [with_state_trackers="$withval"],
1369     [with_state_trackers=yes])
1370
1371 case "$with_state_trackers" in
1372 no)
1373     GALLIUM_STATE_TRACKERS_DIRS=""
1374     ;;
1375 yes)
1376     # look at what else is built
1377     case "$mesa_driver" in
1378     xlib)
1379         GALLIUM_STATE_TRACKERS_DIRS=glx
1380         ;;
1381     dri)
1382         GALLIUM_STATE_TRACKERS_DIRS="dri"
1383         HAVE_ST_DRI="yes"
1384         # Have only tested st/xorg on 1.6.0 servers
1385         PKG_CHECK_MODULES(XORG, [xorg-server >= 1.6.0 libdrm >= $LIBDRM_XORG_REQUIRED libkms >= $LIBKMS_XORG_REQUIRED],
1386             HAVE_ST_XORG="yes"; GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS xorg",
1387             HAVE_ST_XORG="no")
1388         ;;
1389     esac
1390
1391     if test "x$enable_egl" = xyes; then
1392         if test "$enable_openvg" = yes; then
1393             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS vega"
1394             st_egl="yes"
1395         fi
1396
1397         if test "$enable_gallium_egl" = yes; then
1398             GALLIUM_STATE_TRACKERS_DIRS="$GALLIUM_STATE_TRACKERS_DIRS egl"
1399             HAVE_ST_EGL="yes"
1400         fi
1401     fi
1402     ;;
1403 *)
1404     # verify the requested state tracker exist
1405     state_trackers=""
1406     _state_trackers=`IFS=', '; echo $with_state_trackers`
1407     for tracker in $_state_trackers; do
1408         case "$tracker" in
1409         dri)
1410             if test "x$mesa_driver" != xdri; then
1411                 AC_MSG_ERROR([cannot build dri state tracker without mesa driver set to dri])
1412             fi
1413             HAVE_ST_DRI="yes"
1414             ;;
1415         egl)
1416             if test "x$enable_egl" != xyes; then
1417                 AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1418             fi
1419             HAVE_ST_EGL="yes"
1420             ;;
1421         xorg)
1422             PKG_CHECK_MODULES([XORG], [xorg-server >= 1.6.0])
1423             PKG_CHECK_MODULES([LIBDRM_XORG], [libdrm >= $LIBDRM_XORG_REQUIRED])
1424             PKG_CHECK_MODULES([LIBKMS_XORG], [libkms >= $LIBKMS_XORG_REQUIRED])
1425             HAVE_ST_XORG="yes"
1426             ;;
1427         vega)
1428             if test "x$enable_openvg" != xyes; then
1429                 AC_MSG_ERROR([cannot build vega state tracker without --enable-openvg])
1430             fi
1431             ;;
1432         esac
1433
1434         if test -n "$tracker"; then
1435             test -d "$srcdir/src/gallium/state_trackers/$tracker" || \
1436                 AC_MSG_ERROR([state tracker '$tracker' doesn't exist])
1437             if test -n "$state_trackers"; then
1438                 state_trackers="$state_trackers $tracker"
1439             else
1440                 state_trackers="$tracker"
1441             fi
1442         fi
1443     done
1444     GALLIUM_STATE_TRACKERS_DIRS="$state_trackers"
1445     ;;
1446 esac
1447
1448
1449 EGL_CLIENT_APIS=""
1450 VG_LIB_DEPS=""
1451
1452 case "x$enable_opengl$enable_gles1$enable_gles2" in
1453 x*yes*)
1454     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GL_LIB)'
1455     ;;
1456 esac
1457 if test "x$enable_gles_overlay" = xyes; then
1458     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(GLESv1_CM_LIB) $(GLESv2_LIB)'
1459 fi
1460 if test "x$enable_openvg" = xyes; then
1461     EGL_CLIENT_APIS="$EGL_CLIENT_APIS "'$(VG_LIB)'
1462     VG_LIB_DEPS="$VG_LIB_DEPS -lpthread"
1463 fi
1464
1465 AC_SUBST([VG_LIB_DEPS])
1466 AC_SUBST([EGL_CLIENT_APIS])
1467
1468 if test "x$HAVE_ST_EGL" = xyes; then
1469         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS egl"
1470 fi
1471
1472 if test "x$HAVE_ST_XORG" = xyes; then
1473     PKG_CHECK_MODULES(XEXT, [xextproto >= 7.0.99.1],
1474         HAVE_XEXTPROTO_71="yes"; DEFINES="$DEFINES -DHAVE_XEXTPROTO_71",
1475         HAVE_XEXTPROTO_71="no")
1476 fi
1477
1478 AC_ARG_WITH([egl-platforms],
1479     [AS_HELP_STRING([--with-egl-platforms@<:@=DIRS...@:>@],
1480         [comma delimited native platforms libEGL supports, e.g.
1481         "x11,drm" @<:@default=auto@:>@])],
1482     [with_egl_platforms="$withval"],
1483     [with_egl_platforms=yes])
1484 AC_ARG_WITH([egl-displays],
1485     [AS_HELP_STRING([--with-egl-displays@<:@=DIRS...@:>@],
1486         [DEPRECATED.  Use --with-egl-platforms instead])],
1487     [with_egl_platforms="$withval"])
1488
1489 EGL_PLATFORMS=""
1490 case "$with_egl_platforms" in
1491 yes)
1492     if test "x$enable_egl" = xyes && test "x$mesa_driver" != xosmesa; then
1493         EGL_PLATFORMS="x11"
1494         if test "$mesa_driver" = dri; then
1495             EGL_PLATFORMS="$EGL_PLATFORMS drm"
1496         fi
1497     fi
1498     ;;
1499 *)
1500     if test "x$enable_egl" != xyes; then
1501         AC_MSG_ERROR([cannot build egl state tracker without EGL library])
1502     fi
1503     # verify the requested driver directories exist
1504     egl_platforms=`IFS=', '; echo $with_egl_platforms`
1505     for plat in $egl_platforms; do
1506         test -d "$srcdir/src/gallium/state_trackers/egl/$plat" || \
1507             AC_MSG_ERROR([EGL platform '$plat' does't exist])
1508         if test "$plat" = "fbdev"; then
1509                 GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS sw/fbdev"
1510         fi
1511     done
1512     EGL_PLATFORMS="$egl_platforms"
1513     ;;
1514 esac
1515 AC_SUBST([EGL_PLATFORMS])
1516
1517 AC_ARG_WITH([egl-driver-dir],
1518     [AS_HELP_STRING([--with-egl-driver-dir=DIR],
1519                     [directory for EGL drivers [[default=${libdir}/egl]]])],
1520     [EGL_DRIVER_INSTALL_DIR="$withval"],
1521     [EGL_DRIVER_INSTALL_DIR='${libdir}/egl'])
1522 AC_SUBST([EGL_DRIVER_INSTALL_DIR])
1523
1524 AC_ARG_WITH([xorg-driver-dir],
1525     [AS_HELP_STRING([--with-xorg-driver-dir=DIR],
1526                     [Default xorg driver directory[[default=${libdir}/xorg/modules/drivers]]])],
1527     [XORG_DRIVER_INSTALL_DIR="$withval"],
1528     [XORG_DRIVER_INSTALL_DIR="${libdir}/xorg/modules/drivers"])
1529 AC_SUBST([XORG_DRIVER_INSTALL_DIR])
1530
1531 AC_ARG_WITH([max-width],
1532     [AS_HELP_STRING([--with-max-width=N],
1533                     [Maximum framebuffer width (4096)])],
1534     [DEFINES="${DEFINES} -DMAX_WIDTH=${withval}";
1535      AS_IF([test "${withval}" -gt "4096"],
1536            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1537 )
1538 AC_ARG_WITH([max-height],
1539     [AS_HELP_STRING([--with-max-height=N],
1540                     [Maximum framebuffer height (4096)])],
1541     [DEFINES="${DEFINES} -DMAX_HEIGHT=${withval}";
1542      AS_IF([test "${withval}" -gt "4096"],
1543            [AC_MSG_WARN([Large framebuffer: see s_tritemp.h comments.])])]
1544 )
1545
1546 dnl
1547 dnl Gallium LLVM
1548 dnl
1549 AC_ARG_ENABLE([gallium-llvm],
1550     [AS_HELP_STRING([--enable-gallium-llvm],
1551         [build gallium LLVM support @<:@default=disabled@:>@])],
1552     [enable_gallium_llvm="$enableval"],
1553     [enable_gallium_llvm=auto])
1554 if test "x$enable_gallium_llvm" = xyes; then
1555     if test "x$LLVM_CONFIG" != xno; then
1556         LLVM_VERSION=`$LLVM_CONFIG --version`
1557         LLVM_CFLAGS=`$LLVM_CONFIG --cppflags`
1558         LLVM_LIBS="`$LLVM_CONFIG --libs jit interpreter nativecodegen bitwriter` -lstdc++"
1559
1560         if test "x$HAS_UDIS86" != xno; then
1561             LLVM_LIBS="$LLVM_LIBS -ludis86"
1562             DEFINES="$DEFINES -DHAVE_UDIS86"
1563         fi
1564         LLVM_LDFLAGS=`$LLVM_CONFIG --ldflags`
1565         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS llvmpipe"
1566         DEFINES="$DEFINES -DGALLIUM_LLVMPIPE -D__STDC_CONSTANT_MACROS"
1567         MESA_LLVM=1
1568     else
1569         MESA_LLVM=0
1570     fi
1571 else
1572     MESA_LLVM=0
1573 fi
1574
1575 dnl
1576 dnl Gallium helper functions
1577 dnl
1578 gallium_check_st() {
1579     if test "x$HAVE_ST_DRI" = xyes || test "x$HAVE_ST_XORG" = xyes; then
1580          GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS $1"
1581     fi
1582     if test "x$HAVE_ST_DRI" = xyes && test "x$2" != x; then
1583          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $2"
1584     fi
1585     if test "x$HAVE_ST_XORG" = xyes && test "x$3" != x; then
1586          GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS $3"
1587     fi
1588 }
1589
1590
1591 dnl
1592 dnl Gallium SVGA configuration
1593 dnl
1594 AC_ARG_ENABLE([gallium-svga],
1595     [AS_HELP_STRING([--enable-gallium-svga],
1596         [build gallium SVGA @<:@default=disabled@:>@])],
1597     [enable_gallium_svga="$enableval"],
1598     [enable_gallium_svga=auto])
1599 if test "x$enable_gallium_svga" = xyes; then
1600     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1601     gallium_check_st "svga/drm" "dri-vmwgfx" "xorg-vmwgfx"
1602 elif test "x$enable_gallium_svga" = xauto; then
1603     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS svga"
1604 fi
1605
1606 dnl
1607 dnl Gallium i915 configuration
1608 dnl
1609 AC_ARG_ENABLE([gallium-i915],
1610     [AS_HELP_STRING([--enable-gallium-i915],
1611         [build gallium i915 @<:@default=disabled@:>@])],
1612     [enable_gallium_i915="$enableval"],
1613     [enable_gallium_i915=auto])
1614 if test "x$enable_gallium_i915" = xyes; then
1615     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1616     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1617     gallium_check_st "i915/drm" "dri-i915" "xorg-i915"
1618 elif test "x$enable_gallium_i915" = xauto; then
1619     GALLIUM_WINSYS_DIRS="$GALLIUM_WINSYS_DIRS i915/sw"
1620     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i915"
1621 fi
1622
1623 dnl
1624 dnl Gallium i965 configuration
1625 dnl
1626 AC_ARG_ENABLE([gallium-i965],
1627     [AS_HELP_STRING([--enable-gallium-i965],
1628         [build gallium i965 @<:@default=disabled@:>@])],
1629     [enable_gallium_i965="$enableval"],
1630     [enable_gallium_i965=auto])
1631 if test "x$enable_gallium_i965" = xyes; then
1632     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1633     gallium_check_st "i965/drm" "dri-i965" "xorg-i965"
1634 elif test "x$enable_gallium_i965" = xauto; then
1635     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS i965"
1636 fi
1637
1638 dnl
1639 dnl Gallium Radeon r300g configuration
1640 dnl
1641 AC_ARG_ENABLE([gallium-radeon],
1642     [AS_HELP_STRING([--enable-gallium-radeon],
1643         [build gallium radeon @<:@default=disabled@:>@])],
1644     [enable_gallium_radeon="$enableval"],
1645     [enable_gallium_radeon=auto])
1646 if test "x$enable_gallium_radeon" = xauto; then
1647     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1648         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1649         gallium_check_st "radeon/drm" "dri-r300"
1650     else
1651         AC_MSG_WARN([libdrm_radeon is missing, not building gallium-radeon (r300)])
1652     fi
1653 fi
1654 if test "x$enable_gallium_radeon" = xyes; then
1655     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1656         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r300"
1657         gallium_check_st "radeon/drm" "dri-r300" "xorg-radeon"
1658     else
1659         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-radeon (r300)])
1660     fi
1661 fi
1662
1663 dnl
1664 dnl Gallium Radeon r600g configuration
1665 dnl
1666 AC_ARG_ENABLE([gallium-r600],
1667     [AS_HELP_STRING([--enable-gallium-r600],
1668         [build gallium radeon @<:@default=disabled@:>@])],
1669     [enable_gallium_r600="$enableval"],
1670     [enable_gallium_r600=auto])
1671 if test "x$enable_gallium_r600" = xyes; then
1672     if test "x$HAVE_LIBDRM_RADEON" = xyes; then
1673         GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS r600"
1674         gallium_check_st "r600/drm" "dri-r600"
1675     else
1676         AC_MSG_ERROR([libdrm_radeon is missing, cannot build gallium-r600])
1677     fi
1678 fi
1679
1680 dnl
1681 dnl Gallium Nouveau configuration
1682 dnl
1683 AC_ARG_ENABLE([gallium-nouveau],
1684     [AS_HELP_STRING([--enable-gallium-nouveau],
1685         [build gallium nouveau @<:@default=disabled@:>@])],
1686     [enable_gallium_nouveau="$enableval"],
1687     [enable_gallium_nouveau=no])
1688 if test "x$enable_gallium_nouveau" = xyes; then
1689     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS nouveau nvfx nv50"
1690     gallium_check_st "nouveau/drm" "dri-nouveau" "xorg-nouveau"
1691 fi
1692
1693 dnl
1694 dnl Gallium swrast configuration
1695 dnl
1696 AC_ARG_ENABLE([gallium-swrast],
1697     [AS_HELP_STRING([--enable-gallium-swrast],
1698         [build gallium swrast @<:@default=auto@:>@])],
1699     [enable_gallium_swrast="$enableval"],
1700     [enable_gallium_swrast=auto])
1701 if test "x$enable_gallium_swrast" = xyes || test "x$enable_gallium_swrast" = xauto; then
1702     if test "x$HAVE_ST_DRI" = xyes; then
1703         GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-swrast"
1704     fi
1705 fi
1706
1707 dnl
1708 dnl Gallium noop configuration
1709 dnl
1710 AC_ARG_ENABLE([gallium-noop],
1711     [AS_HELP_STRING([--enable-gallium-noop],
1712         [build gallium radeon @<:@default=disabled@:>@])],
1713     [enable_gallium_noop="$enableval"],
1714     [enable_gallium_noop=auto])
1715 if test "x$enable_gallium_noop" = xyes; then
1716     GALLIUM_DRIVERS_DIRS="$GALLIUM_DRIVERS_DIRS noop"
1717     GALLIUM_TARGET_DIRS="$GALLIUM_TARGET_DIRS dri-noop"
1718 fi
1719
1720 dnl prepend CORE_DIRS to SRC_DIRS
1721 SRC_DIRS="$CORE_DIRS $SRC_DIRS"
1722
1723 dnl Restore LDFLAGS and CPPFLAGS
1724 LDFLAGS="$_SAVE_LDFLAGS"
1725 CPPFLAGS="$_SAVE_CPPFLAGS"
1726
1727 dnl Substitute the config
1728 AC_CONFIG_FILES([configs/autoconf])
1729
1730 dnl Replace the configs/current symlink
1731 AC_CONFIG_COMMANDS([configs],[
1732 if test -f configs/current || test -L configs/current; then
1733     rm -f configs/current
1734 fi
1735 ln -s autoconf configs/current
1736 ])
1737
1738 AC_OUTPUT
1739
1740 dnl
1741 dnl Output some configuration info for the user
1742 dnl
1743 echo ""
1744 echo "        prefix:          $prefix"
1745 echo "        exec_prefix:     $exec_prefix"
1746 echo "        libdir:          $libdir"
1747 echo "        includedir:      $includedir"
1748
1749 dnl API info
1750 echo ""
1751 echo "        OpenGL:          $enable_opengl (ES1: $enable_gles1 ES2: $enable_gles2)"
1752 echo "        GLES overlay:    $enable_gles_overlay"
1753 echo "        OpenVG:          $enable_openvg"
1754
1755 dnl Driver info
1756 echo ""
1757 echo "        Driver:          $mesa_driver"
1758 if test "$mesa_driver" != no; then
1759     if echo "$DRIVER_DIRS" | grep 'osmesa' >/dev/null 2>&1; then
1760         echo "        OSMesa:          lib$OSMESA_LIB"
1761     else
1762         echo "        OSMesa:          no"
1763     fi
1764     if test "$mesa_driver" = dri; then
1765         # cleanup the drivers var
1766         dri_dirs=`echo $DRI_DIRS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1767         if test "x$DRI_DIRS" = x; then
1768             echo "        DRI drivers:     no"
1769         else
1770             echo "        DRI drivers:     $dri_dirs"
1771         fi
1772         echo "        DRI driver dir:  $DRI_DRIVER_INSTALL_DIR"
1773         echo "        Use XCB:         $enable_xcb"
1774     fi
1775 fi
1776 echo ""
1777 echo "        GLU:             $enable_glu"
1778 echo "        GLw:             $enable_glw (Motif: $enable_motif)"
1779 echo "        glut:            $enable_glut"
1780
1781 dnl EGL
1782 echo ""
1783 echo "        EGL:             $enable_egl"
1784 if test "$enable_egl" = yes; then
1785     echo "        EGL platforms:   $EGL_PLATFORMS"
1786
1787     egl_drivers=""
1788     for d in $EGL_DRIVERS_DIRS; do
1789         egl_drivers="$egl_drivers egl_$d"
1790     done
1791
1792     if test "$enable_gallium" = yes -a "$HAVE_ST_EGL" = yes; then
1793         echo "        EGL drivers:    ${egl_drivers} egl_gallium"
1794         echo "        EGL Gallium STs:$EGL_CLIENT_APIS"
1795     else
1796         echo "        EGL drivers:    $egl_drivers"
1797     fi
1798 fi
1799
1800 echo ""
1801 if test "x$MESA_LLVM" = x1; then
1802     echo "        llvm:            yes"
1803     echo "        llvm-config:     $LLVM_CONFIG"
1804     echo "        llvm-version:    $LLVM_VERSION"
1805 else
1806     echo "        llvm:            no"
1807 fi
1808
1809 echo ""
1810 if echo "$SRC_DIRS" | grep 'gallium' >/dev/null 2>&1; then
1811     echo "        Gallium:         yes"
1812     echo "        Gallium dirs:    $GALLIUM_DIRS"
1813     echo "        Target dirs:     $GALLIUM_TARGET_DIRS"
1814     echo "        Winsys dirs:     $GALLIUM_WINSYS_DIRS"
1815     echo "        Driver dirs:     $GALLIUM_DRIVERS_DIRS"
1816     echo "        Trackers dirs:   $GALLIUM_STATE_TRACKERS_DIRS"
1817 else
1818     echo "        Gallium:         no"
1819 fi
1820
1821 dnl Libraries
1822 echo ""
1823 echo "        Shared libs:     $enable_shared"
1824 echo "        Static libs:     $enable_static"
1825
1826 dnl Compiler options
1827 # cleanup the CFLAGS/CXXFLAGS/DEFINES vars
1828 cflags=`echo $CFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1829     $SED 's/^ *//;s/  */ /;s/ *$//'`
1830 cxxflags=`echo $CXXFLAGS $OPT_FLAGS $PIC_FLAGS $ARCH_FLAGS | \
1831     $SED 's/^ *//;s/  */ /;s/ *$//'`
1832 defines=`echo $DEFINES $ASM_FLAGS | $SED 's/^ *//;s/  */ /;s/ *$//'`
1833 echo ""
1834 echo "        CFLAGS:          $cflags"
1835 echo "        CXXFLAGS:        $cxxflags"
1836 echo "        Macros:          $defines"
1837 echo ""
1838 echo "        PYTHON2:         $PYTHON2"
1839
1840 echo ""
1841 echo "        Run '${MAKE-make}' to build Mesa"
1842 echo ""