m4/ax_prog_cxx_for_build.m4

   1 # ===========================================================================
   2 #   http://www.gnu.org/software/autoconf-archive/ax_prog_cxx_for_build.html
   3 # ===========================================================================
   4 #
   5 # SYNOPSIS
   6 #
   7 #   AX_PROG_CXX_FOR_BUILD
   8 #
   9 # DESCRIPTION
  10 #
  11 #   This macro searches for a C++ compiler that generates native executables,
  12 #   that is a C++ compiler that surely is not a cross-compiler. This can be
  13 #   useful if you have to generate source code at compile-time like for
  14 #   example GCC does.
  15 #
  16 #   The macro sets the CXX_FOR_BUILD and CXXCPP_FOR_BUILD macros to anything
  17 #   needed to compile or link (CXX_FOR_BUILD) and preprocess (CXXCPP_FOR_BUILD).
  18 #   The value of these variables can be overridden by the user by specifying
  19 #   a compiler with an environment variable (like you do for standard CXX).
  20 #
  21 # LICENSE
  22 #
  23 #   Copyright (c) 2008 Paolo Bonzini <bonzini@gnu.org>
  24 #   Copyright (c) 2012 Avionic Design GmbH
  25 #
  26 #   Based on the AX_PROG_CC_FOR_BUILD macro by Paolo Bonzini.
  27 #
  28 #   Copying and distribution of this file, with or without modification, are
  29 #   permitted in any medium without royalty provided the copyright notice
  30 #   and this notice are preserved. This file is offered as-is, without any
  31 #   warranty.
  32
  33 #serial 5
  34
  35 AU_ALIAS([AC_PROG_CXX_FOR_BUILD], [AX_PROG_CXX_FOR_BUILD])
  36 AC_DEFUN([AX_PROG_CXX_FOR_BUILD], [dnl
  37 AC_REQUIRE([AX_PROG_CC_FOR_BUILD])dnl
  38 AC_REQUIRE([AC_PROG_CXX])dnl
  39 AC_REQUIRE([AC_PROG_CXXCPP])dnl
  40 AC_REQUIRE([AC_CANONICAL_SYSTEM])dnl
  41
  42 dnl Use the standard macros, but make them use other variable names
  43 dnl
  44 pushdef([ac_cv_prog_CXXCPP], ac_cv_build_prog_CXXCPP)dnl
  45 pushdef([ac_cv_prog_gxx], ac_cv_build_prog_gxx)dnl
  46 pushdef([ac_cv_prog_cxx_works], ac_cv_build_prog_cxx_works)dnl
  47 pushdef([ac_cv_prog_cxx_cross], ac_cv_build_prog_cxx_cross)dnl
  48 pushdef([ac_cv_prog_cxx_g], ac_cv_build_prog_cxx_g)dnl
  49 pushdef([CXX], CXX_FOR_BUILD)dnl
  50 pushdef([CXXCPP], CXXCPP_FOR_BUILD)dnl
  51 pushdef([CXXFLAGS], CXXFLAGS_FOR_BUILD)dnl
  52 pushdef([CPPFLAGS], CPPFLAGS_FOR_BUILD)dnl
  53 pushdef([CXXCPPFLAGS], CXXCPPFLAGS_FOR_BUILD)dnl
  54 pushdef([host], build)dnl
  55 pushdef([host_alias], build_alias)dnl
  56 pushdef([host_cpu], build_cpu)dnl
  57 pushdef([host_vendor], build_vendor)dnl
  58 pushdef([host_os], build_os)dnl
  59 pushdef([ac_cv_host], ac_cv_build)dnl
  60 pushdef([ac_cv_host_alias], ac_cv_build_alias)dnl
  61 pushdef([ac_cv_host_cpu], ac_cv_build_cpu)dnl
  62 pushdef([ac_cv_host_vendor], ac_cv_build_vendor)dnl
  63 pushdef([ac_cv_host_os], ac_cv_build_os)dnl
  64 pushdef([ac_cxxcpp], ac_build_cxxcpp)dnl
  65 pushdef([ac_compile], ac_build_compile)dnl
  66 pushdef([ac_link], ac_build_link)dnl
  67
  68 save_cross_compiling=$cross_compiling
  69 save_ac_tool_prefix=$ac_tool_prefix
  70 cross_compiling=no
  71 ac_tool_prefix=
  72
  73 AC_PROG_CXX
  74 AC_PROG_CXXCPP
  75
  76 ac_tool_prefix=$save_ac_tool_prefix
  77 cross_compiling=$save_cross_compiling
  78
  79 dnl Restore the old definitions
  80 dnl
  81 popdef([ac_link])dnl
  82 popdef([ac_compile])dnl
  83 popdef([ac_cxxcpp])dnl
  84 popdef([ac_cv_host_os])dnl
  85 popdef([ac_cv_host_vendor])dnl
  86 popdef([ac_cv_host_cpu])dnl
  87 popdef([ac_cv_host_alias])dnl
  88 popdef([ac_cv_host])dnl
  89 popdef([host_os])dnl
  90 popdef([host_vendor])dnl
  91 popdef([host_cpu])dnl
  92 popdef([host_alias])dnl
  93 popdef([host])dnl
  94 popdef([CXXCPPFLAGS])dnl
  95 popdef([CPPFLAGS])dnl
  96 popdef([CXXFLAGS])dnl
  97 popdef([CXXCPP])dnl
  98 popdef([CXX])dnl
  99 popdef([ac_cv_prog_cxx_g])dnl
 100 popdef([ac_cv_prog_cxx_cross])dnl
 101 popdef([ac_cv_prog_cxx_works])dnl
 102 popdef([ac_cv_prog_gxx])dnl
 103 popdef([ac_cv_prog_CXXCPP])dnl
 104
 105 dnl Finally, set Makefile variables
 106 dnl
 107 AC_SUBST([CXXFLAGS_FOR_BUILD])dnl
 108 AC_SUBST([CXXCPPFLAGS_FOR_BUILD])dnl
 109 ])