CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(SwiftShader C CXX)
   4
   5 if(NOT CMAKE_BUILD_TYPE)
   6     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "The type of build: Debug Release MinSizeRel RelWithDebInfo." FORCE)
   7 endif()
   8 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS Debug Release MinSizeRel RelWithDebInfo)
   9
  10 option(BUILD_EGL "Build the EGL library" 1)
  11 if(WIN32)
  12     option(BUILD_GL32 "Build the OpenGL32 library" 1)
  13 endif()
  14 option(BUILD_GLESv2 "Build the OpenGL ES 2 library" 1)
  15 option(BUILD_GLES_CM "Build the OpenGL ES 1.1 library" 1)
  16
  17 option(USE_GROUP_SOURCES "Group the source files in a folder tree for Visual Studio" 1)
  18
  19 option(BUILD_SAMPLES "Build sample programs" 1)
  20 option(BUILD_TESTS "Build test programs" 1)
  21
  22 set(REACTOR_BACKEND "LLVM" CACHE STRING "JIT compiler back-end used by Reactor")
  23 set_property(CACHE REACTOR_BACKEND PROPERTY STRINGS LLVM Subzero)
  24
  25 # LLVM disallows calling cmake . from the main LLVM dir, the reason is that
  26 # it builds header files that could overwrite the orignal ones. Here we
  27 # want to include LLVM as a subdirectory and even though it wouldn't cause
  28 # the problem, if cmake . is called from the main dir, the condition that
  29 # LLVM checkes, "CMAKE_SOURCE_DIR == CMAKE_BINARY_DIR" will be true. So we
  30 # disallow it ourselves too to. In addition if there are remining CMakeFiles
  31 # and CMakeCache in the directory, cmake .. from a subdirectory will still
  32 # try to build from the main directory so we instruct users to delete these
  33 # files when they get the error.
  34 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
  35     message(FATAL_ERROR "In source builds are not allowed by LLVM, please create a build/ directory and build from there. You may have to delete the CMakeCache.txt file and CMakeFiles directory that are next to the CMakeLists.txt.")
  36 endif()
  37
  38 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  39
  40 ###########################################################
  41 # Detect system
  42 ###########################################################
  43
  44 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  45     set(LINUX ON)
  46 elseif(WIN32)
  47 elseif(APPLE)
  48 else()
  49     message(FATAL_ERROR "Platform is not supported")
  50 endif()
  51
  52 if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm" OR CMAKE_SYSTEM_PROCESSOR MATCHES "aarch")
  53     if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  54         set(ARCH "aarch64")
  55     else()
  56         set(ARCH "arm")
  57     endif()
  58 else()
  59     if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  60         set(ARCH "x86_64")
  61     else()
  62         set(ARCH "x86")
  63     endif()
  64 endif()
  65
  66 set(CMAKE_MACOSX_RPATH ON)
  67
  68 ###########################################################
  69 # Convenience macros
  70 ###########################################################
  71
  72 # Recursively calls source_group on the files of the directory
  73 # so that Visual Studio has the files in a folder tree
  74 macro(group_all_sources directory)
  75     file(GLOB files RELATIVE ${CMAKE_SOURCE_DIR}/${directory} ${CMAKE_SOURCE_DIR}/${directory}/*)
  76     foreach(file ${files})
  77         if(IS_DIRECTORY ${CMAKE_SOURCE_DIR}/${directory}/${file})
  78             group_all_sources(${directory}/${file})
  79         else()
  80             string(REPLACE "/" "\\" groupname ${directory})
  81             source_group(${groupname} FILES ${CMAKE_SOURCE_DIR}/${directory}/${file})
  82         endif()
  83     endforeach()
  84 endmacro()
  85
  86 # Takes target library and a directory where the export map is
  87 # and add the linker options so that only the API symbols are
  88 # exported.
  89 macro(set_target_export_map TARGET DIR)
  90     get_target_property(LINKFLAGS ${TARGET} LINK_FLAGS)
  91     if(LINKFLAGS MATCHES "NOTFOUND")
  92         set(LINKFLAGS "")
  93     endif()
  94     if(MSVC)
  95         set_target_properties(${TARGET} PROPERTIES LINK_FLAGS "/DEF:\"${DIR}/${TARGET}.def\"")
  96     elseif(LINUX)
  97         # Both hash-style are needed, because we want both gold and
  98         # GNU ld to be able to read our libraries (maybe?).
  99         # The version script only exports the API functions and
 100         # hides all the others. Gc sections is used in combination
 101         # with each functions being in its section, to reduce the
 102         # binary size.
 103         set_target_properties(${TARGET} PROPERTIES LINK_FLAGS "${LINKFLAGS} -Wl,--hash-style=both,--version-script=${DIR}/exports.map,--gc-sections,--no-undefined")
 104     endif()
 105 endmacro()
 106
 107 if(USE_GROUP_SOURCES)
 108     group_all_sources(src)
 109 endif()
 110
 111 ###########################################################
 112 # Directories
 113 ###########################################################
 114
 115 set(SOURCE_DIR ${CMAKE_SOURCE_DIR}/src)
 116 set(OPENGL_DIR ${SOURCE_DIR}/OpenGL)
 117 set(OPENGL_COMPILER_DIR ${OPENGL_DIR}/compiler)
 118 set(LLVM_DIR ${CMAKE_SOURCE_DIR}/third_party/LLVM)
 119 set(SUBZERO_DIR ${CMAKE_SOURCE_DIR}/third_party/subzero)
 120 set(SUBZERO_LLVM_DIR ${CMAKE_SOURCE_DIR}/third_party/llvm-subzero)
 121 set(TESTS_DIR ${CMAKE_SOURCE_DIR}/tests)
 122 set(HELLO2_DIR ${CMAKE_SOURCE_DIR}/third_party/PowerVR_SDK/Examples/Beginner/01_HelloAPI/OGLES2)
 123
 124 ###########################################################
 125 # Compile flags
 126 ###########################################################
 127
 128 macro(set_cpp_flag FLAG)
 129     if(${ARGC} GREATER 1)
 130         set(CMAKE_CXX_FLAGS_${ARGV1} "${CMAKE_CXX_FLAGS_${ARGV1}} ${FLAG}")
 131     else()
 132         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${FLAG}")
 133     endif()
 134 endmacro()
 135
 136 if(MSVC)
 137     set_cpp_flag("/MP")
 138     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 139 else()
 140     set_cpp_flag("--std=c++11")
 141     set_cpp_flag("-Wall")
 142     set_cpp_flag("-fno-exceptions")
 143
 144     # Don't allow symbols to be overridden by another module.
 145     # This enables libGLES_CM and libGLESv2 to statically link LLVM.
 146     set_cpp_flag("-fvisibility=protected")
 147
 148     # Remove xor, and, or and friends from the list of keywords, they are used
 149     # by Reactor
 150     set_cpp_flag("-fno-operator-names")
 151
 152     # LLVM headers requires these flags to be set
 153     set_cpp_flag("-D__STDC_CONSTANT_MACROS -D__STDC_LIMIT_MACROS")
 154
 155     if(ARCH EQUAL "x86")
 156         set_cpp_flag("-m32")
 157         set_cpp_flag("-msse2")
 158         set_cpp_flag("-march=i686")
 159     endif()
 160     if(ARCH EQUAL "x86_64")
 161         set_cpp_flag("-m64")
 162         set_cpp_flag("-fPIC")
 163         set_cpp_flag("-march=core2")
 164     endif()
 165
 166     # Use -g3 to have even more debug info
 167     set_cpp_flag("-g -g3" DEBUG)
 168     set_cpp_flag("-g -g3" RELWITHDEBINFO)
 169     set_cpp_flag("-s" RELEASE)
 170
 171     # For distribution it is more important to be slim than super optimized
 172     set_cpp_flag("-Os" RELEASE)
 173     set_cpp_flag("-Os" RELWITHDEBINFO)
 174
 175     set_cpp_flag("-DNDEBUG" RELEASE)
 176     set_cpp_flag("-DNDEBUG" RELWITHDEBINFO)
 177     set_cpp_flag("-DANGLE_DISABLE_TRACE" RELEASE)
 178     set_cpp_flag("-DANGLE_DISABLE_TRACE" RELWITHDEBINFO)
 179
 180     # Put each variable and function in its own section so that when linking
 181     # with -gc-sections unused functions and variables are removed.
 182     set_cpp_flag("-ffunction-sections" RELEASE)
 183     set_cpp_flag("-fdata-sections" RELEASE)
 184     set_cpp_flag("-fomit-frame-pointer" RELEASE)
 185 endif()
 186
 187 if( WIN32 )
 188     add_definitions(-DWINVER=0x501 -DNOMINMAX -DSTRICT)
 189     set(CMAKE_FIND_LIBRARY_PREFIXES ${CMAKE_FIND_LIBRARY_PREFIXES} "" "lib")
 190 endif()
 191
 192
 193 ###########################################################
 194 # LLVM
 195 ###########################################################
 196
 197 set(LLVM_LIST
 198     ${LLVM_DIR}/lib/Analysis/AliasAnalysis.cpp
 199     ${LLVM_DIR}/lib/Analysis/AliasSetTracker.cpp
 200     ${LLVM_DIR}/lib/Analysis/BasicAliasAnalysis.cpp
 201     ${LLVM_DIR}/lib/Analysis/BranchProbabilityInfo.cpp
 202     ${LLVM_DIR}/lib/Analysis/CaptureTracking.cpp
 203     ${LLVM_DIR}/lib/Analysis/ConstantFolding.cpp
 204     ${LLVM_DIR}/lib/Analysis/DIBuilder.cpp
 205     ${LLVM_DIR}/lib/Analysis/DebugInfo.cpp
 206     ${LLVM_DIR}/lib/Analysis/IVUsers.cpp
 207     ${LLVM_DIR}/lib/Analysis/InstructionSimplify.cpp
 208     ${LLVM_DIR}/lib/Analysis/Loads.cpp
 209     ${LLVM_DIR}/lib/Analysis/LoopInfo.cpp
 210     ${LLVM_DIR}/lib/Analysis/LoopPass.cpp
 211     ${LLVM_DIR}/lib/Analysis/MemoryBuiltins.cpp
 212     ${LLVM_DIR}/lib/Analysis/MemoryDependenceAnalysis.cpp
 213     ${LLVM_DIR}/lib/Analysis/NoAliasAnalysis.cpp
 214     ${LLVM_DIR}/lib/Analysis/PHITransAddr.cpp
 215     ${LLVM_DIR}/lib/Analysis/PathNumbering.cpp
 216     ${LLVM_DIR}/lib/Analysis/ProfileInfo.cpp
 217     ${LLVM_DIR}/lib/Analysis/ScalarEvolution.cpp
 218     ${LLVM_DIR}/lib/Analysis/ScalarEvolutionExpander.cpp
 219     ${LLVM_DIR}/lib/Analysis/ScalarEvolutionNormalization.cpp
 220     ${LLVM_DIR}/lib/Analysis/TypeBasedAliasAnalysis.cpp
 221     ${LLVM_DIR}/lib/Analysis/ValueTracking.cpp
 222     ${LLVM_DIR}/lib/CodeGen/AggressiveAntiDepBreaker.cpp
 223     ${LLVM_DIR}/lib/CodeGen/AllocationOrder.cpp
 224     ${LLVM_DIR}/lib/CodeGen/Analysis.cpp
 225     ${LLVM_DIR}/lib/CodeGen/BranchFolding.cpp
 226     ${LLVM_DIR}/lib/CodeGen/CalcSpillWeights.cpp
 227     ${LLVM_DIR}/lib/CodeGen/CallingConvLower.cpp
 228     ${LLVM_DIR}/lib/CodeGen/CodePlacementOpt.cpp
 229     ${LLVM_DIR}/lib/CodeGen/CriticalAntiDepBreaker.cpp
 230     ${LLVM_DIR}/lib/CodeGen/DeadMachineInstructionElim.cpp
 231     ${LLVM_DIR}/lib/CodeGen/DwarfEHPrepare.cpp
 232     ${LLVM_DIR}/lib/CodeGen/ELFCodeEmitter.cpp
 233     ${LLVM_DIR}/lib/CodeGen/ELFWriter.cpp
 234     ${LLVM_DIR}/lib/CodeGen/EdgeBundles.cpp
 235     ${LLVM_DIR}/lib/CodeGen/ExecutionDepsFix.cpp
 236     ${LLVM_DIR}/lib/CodeGen/ExpandISelPseudos.cpp
 237     ${LLVM_DIR}/lib/CodeGen/ExpandPostRAPseudos.cpp
 238     ${LLVM_DIR}/lib/CodeGen/GCMetadata.cpp
 239     ${LLVM_DIR}/lib/CodeGen/GCStrategy.cpp
 240     ${LLVM_DIR}/lib/CodeGen/InlineSpiller.cpp
 241     ${LLVM_DIR}/lib/CodeGen/InterferenceCache.cpp
 242     ${LLVM_DIR}/lib/CodeGen/IntrinsicLowering.cpp
 243     ${LLVM_DIR}/lib/CodeGen/LLVMTargetMachine.cpp
 244     ${LLVM_DIR}/lib/CodeGen/LatencyPriorityQueue.cpp
 245     ${LLVM_DIR}/lib/CodeGen/LexicalScopes.cpp
 246     ${LLVM_DIR}/lib/CodeGen/LiveDebugVariables.cpp
 247     ${LLVM_DIR}/lib/CodeGen/LiveInterval.cpp
 248     ${LLVM_DIR}/lib/CodeGen/LiveIntervalAnalysis.cpp
 249     ${LLVM_DIR}/lib/CodeGen/LiveIntervalUnion.cpp
 250     ${LLVM_DIR}/lib/CodeGen/LiveRangeCalc.cpp
 251     ${LLVM_DIR}/lib/CodeGen/LiveRangeEdit.cpp
 252     ${LLVM_DIR}/lib/CodeGen/LiveStackAnalysis.cpp
 253     ${LLVM_DIR}/lib/CodeGen/LiveVariables.cpp
 254     ${LLVM_DIR}/lib/CodeGen/LocalStackSlotAllocation.cpp
 255     ${LLVM_DIR}/lib/CodeGen/MachineBasicBlock.cpp
 256     ${LLVM_DIR}/lib/CodeGen/MachineCSE.cpp
 257     ${LLVM_DIR}/lib/CodeGen/MachineDominators.cpp
 258     ${LLVM_DIR}/lib/CodeGen/MachineFunction.cpp
 259     ${LLVM_DIR}/lib/CodeGen/MachineFunctionAnalysis.cpp
 260     ${LLVM_DIR}/lib/CodeGen/MachineFunctionPass.cpp
 261     ${LLVM_DIR}/lib/CodeGen/MachineFunctionPrinterPass.cpp
 262     ${LLVM_DIR}/lib/CodeGen/MachineInstr.cpp
 263     ${LLVM_DIR}/lib/CodeGen/MachineLICM.cpp
 264     ${LLVM_DIR}/lib/CodeGen/MachineLoopInfo.cpp
 265     ${LLVM_DIR}/lib/CodeGen/MachineModuleInfo.cpp
 266     ${LLVM_DIR}/lib/CodeGen/MachineModuleInfoImpls.cpp
 267     ${LLVM_DIR}/lib/CodeGen/MachinePassRegistry.cpp
 268     ${LLVM_DIR}/lib/CodeGen/MachineRegisterInfo.cpp
 269     ${LLVM_DIR}/lib/CodeGen/MachineSSAUpdater.cpp
 270     ${LLVM_DIR}/lib/CodeGen/MachineSink.cpp
 271     ${LLVM_DIR}/lib/CodeGen/MachineVerifier.cpp
 272     ${LLVM_DIR}/lib/CodeGen/ObjectCodeEmitter.cpp
 273     ${LLVM_DIR}/lib/CodeGen/OptimizePHIs.cpp
 274     ${LLVM_DIR}/lib/CodeGen/PHIElimination.cpp
 275     ${LLVM_DIR}/lib/CodeGen/PHIEliminationUtils.cpp
 276     ${LLVM_DIR}/lib/CodeGen/Passes.cpp
 277     ${LLVM_DIR}/lib/CodeGen/PeepholeOptimizer.cpp
 278     ${LLVM_DIR}/lib/CodeGen/PostRASchedulerList.cpp
 279     ${LLVM_DIR}/lib/CodeGen/ProcessImplicitDefs.cpp
 280     ${LLVM_DIR}/lib/CodeGen/PrologEpilogInserter.cpp
 281     ${LLVM_DIR}/lib/CodeGen/PseudoSourceValue.cpp
 282     ${LLVM_DIR}/lib/CodeGen/RegAllocBasic.cpp
 283     ${LLVM_DIR}/lib/CodeGen/RegAllocFast.cpp
 284     ${LLVM_DIR}/lib/CodeGen/RegAllocGreedy.cpp
 285     ${LLVM_DIR}/lib/CodeGen/RegAllocLinearScan.cpp
 286     ${LLVM_DIR}/lib/CodeGen/RegisterClassInfo.cpp
 287     ${LLVM_DIR}/lib/CodeGen/RegisterCoalescer.cpp
 288     ${LLVM_DIR}/lib/CodeGen/RegisterScavenging.cpp
 289     ${LLVM_DIR}/lib/CodeGen/RenderMachineFunction.cpp
 290     ${LLVM_DIR}/lib/CodeGen/ScheduleDAG.cpp
 291     ${LLVM_DIR}/lib/CodeGen/ScheduleDAGEmit.cpp
 292     ${LLVM_DIR}/lib/CodeGen/ScheduleDAGInstrs.cpp
 293     ${LLVM_DIR}/lib/CodeGen/ScheduleDAGPrinter.cpp
 294     ${LLVM_DIR}/lib/CodeGen/ScoreboardHazardRecognizer.cpp
 295     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/DAGCombiner.cpp
 296     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/FastISel.cpp
 297     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/FunctionLoweringInfo.cpp
 298     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/InstrEmitter.cpp
 299     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeDAG.cpp
 300     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeFloatTypes.cpp
 301     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeIntegerTypes.cpp
 302     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeTypes.cpp
 303     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeTypesGeneric.cpp
 304     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeVectorOps.cpp
 305     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeVectorTypes.cpp
 306     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGFast.cpp
 307     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGList.cpp
 308     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGRRList.cpp
 309     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGSDNodes.cpp
 310     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAG.cpp
 311     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAGBuilder.cpp
 312     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAGISel.cpp
 313     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAGPrinter.cpp
 314     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/TargetLowering.cpp
 315     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/TargetSelectionDAGInfo.cpp
 316     ${LLVM_DIR}/lib/CodeGen/ShrinkWrapping.cpp
 317     ${LLVM_DIR}/lib/CodeGen/SjLjEHPrepare.cpp
 318     ${LLVM_DIR}/lib/CodeGen/SlotIndexes.cpp
 319     ${LLVM_DIR}/lib/CodeGen/SpillPlacement.cpp
 320     ${LLVM_DIR}/lib/CodeGen/Spiller.cpp
 321     ${LLVM_DIR}/lib/CodeGen/SplitKit.cpp
 322     ${LLVM_DIR}/lib/CodeGen/StackProtector.cpp
 323     ${LLVM_DIR}/lib/CodeGen/StackSlotColoring.cpp
 324     ${LLVM_DIR}/lib/CodeGen/StrongPHIElimination.cpp
 325     ${LLVM_DIR}/lib/CodeGen/TailDuplication.cpp
 326     ${LLVM_DIR}/lib/CodeGen/TargetInstrInfoImpl.cpp
 327     ${LLVM_DIR}/lib/CodeGen/TargetLoweringObjectFileImpl.cpp
 328     ${LLVM_DIR}/lib/CodeGen/TwoAddressInstructionPass.cpp
 329     ${LLVM_DIR}/lib/CodeGen/UnreachableBlockElim.cpp
 330     ${LLVM_DIR}/lib/CodeGen/VirtRegMap.cpp
 331     ${LLVM_DIR}/lib/CodeGen/VirtRegRewriter.cpp
 332     ${LLVM_DIR}/lib/ExecutionEngine/ExecutionEngine.cpp
 333     ${LLVM_DIR}/lib/ExecutionEngine/JIT/Intercept.cpp
 334     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JIT.cpp
 335     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITDebugRegisterer.cpp
 336     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITDwarfEmitter.cpp
 337     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITEmitter.cpp
 338     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITMemoryManager.cpp
 339     ${LLVM_DIR}/lib/ExecutionEngine/JIT/OProfileJITEventListener.cpp
 340     ${LLVM_DIR}/lib/ExecutionEngine/TargetSelect.cpp
 341     ${LLVM_DIR}/lib/MC/ELFObjectWriter.cpp
 342     ${LLVM_DIR}/lib/MC/MCAsmBackend.cpp
 343     ${LLVM_DIR}/lib/MC/MCAsmInfo.cpp
 344     ${LLVM_DIR}/lib/MC/MCAsmInfoCOFF.cpp
 345     ${LLVM_DIR}/lib/MC/MCAsmInfoDarwin.cpp
 346     ${LLVM_DIR}/lib/MC/MCAsmStreamer.cpp
 347     ${LLVM_DIR}/lib/MC/MCAssembler.cpp
 348     ${LLVM_DIR}/lib/MC/MCCodeEmitter.cpp
 349     ${LLVM_DIR}/lib/MC/MCCodeGenInfo.cpp
 350     ${LLVM_DIR}/lib/MC/MCContext.cpp
 351     ${LLVM_DIR}/lib/MC/MCDwarf.cpp
 352     ${LLVM_DIR}/lib/MC/MCELF.cpp
 353     ${LLVM_DIR}/lib/MC/MCELFObjectTargetWriter.cpp
 354     ${LLVM_DIR}/lib/MC/MCELFStreamer.cpp
 355     ${LLVM_DIR}/lib/MC/MCExpr.cpp
 356     ${LLVM_DIR}/lib/MC/MCInst.cpp
 357     ${LLVM_DIR}/lib/MC/MCInstPrinter.cpp
 358     ${LLVM_DIR}/lib/MC/MCInstrAnalysis.cpp
 359     ${LLVM_DIR}/lib/MC/MCLoggingStreamer.cpp
 360     ${LLVM_DIR}/lib/MC/MCMachOStreamer.cpp
 361     ${LLVM_DIR}/lib/MC/MCMachObjectTargetWriter.cpp
 362     ${LLVM_DIR}/lib/MC/MCNullStreamer.cpp
 363     ${LLVM_DIR}/lib/MC/MCObjectFileInfo.cpp
 364     ${LLVM_DIR}/lib/MC/MCObjectStreamer.cpp
 365     ${LLVM_DIR}/lib/MC/MCObjectWriter.cpp
 366     ${LLVM_DIR}/lib/MC/MCSection.cpp
 367     ${LLVM_DIR}/lib/MC/MCSectionCOFF.cpp
 368     ${LLVM_DIR}/lib/MC/MCSectionELF.cpp
 369     ${LLVM_DIR}/lib/MC/MCSectionMachO.cpp
 370     ${LLVM_DIR}/lib/MC/MCStreamer.cpp
 371     ${LLVM_DIR}/lib/MC/MCSubtargetInfo.cpp
 372     ${LLVM_DIR}/lib/MC/MCSymbol.cpp
 373     ${LLVM_DIR}/lib/MC/MCWin64EH.cpp
 374     ${LLVM_DIR}/lib/MC/MachObjectWriter.cpp
 375     ${LLVM_DIR}/lib/MC/SubtargetFeature.cpp
 376     ${LLVM_DIR}/lib/MC/WinCOFFObjectWriter.cpp
 377     ${LLVM_DIR}/lib/MC/WinCOFFStreamer.cpp
 378     ${LLVM_DIR}/lib/Support/APFloat.cpp
 379     ${LLVM_DIR}/lib/Support/APInt.cpp
 380     ${LLVM_DIR}/lib/Support/Allocator.cpp
 381     ${LLVM_DIR}/lib/Support/Atomic.cpp
 382     ${LLVM_DIR}/lib/Support/BlockFrequency.cpp
 383     ${LLVM_DIR}/lib/Support/BranchProbability.cpp
 384     ${LLVM_DIR}/lib/Support/CommandLine.cpp
 385     ${LLVM_DIR}/lib/Support/ConstantRange.cpp
 386     ${LLVM_DIR}/lib/Support/CrashRecoveryContext.cpp
 387     ${LLVM_DIR}/lib/Support/DAGDeltaAlgorithm.cpp
 388     ${LLVM_DIR}/lib/Support/DataExtractor.cpp
 389     ${LLVM_DIR}/lib/Support/Debug.cpp
 390     ${LLVM_DIR}/lib/Support/DeltaAlgorithm.cpp
 391     ${LLVM_DIR}/lib/Support/Disassembler.cpp
 392     ${LLVM_DIR}/lib/Support/Dwarf.cpp
 393     ${LLVM_DIR}/lib/Support/DynamicLibrary.cpp
 394     ${LLVM_DIR}/lib/Support/Errno.cpp
 395     ${LLVM_DIR}/lib/Support/ErrorHandling.cpp
 396     ${LLVM_DIR}/lib/Support/FileUtilities.cpp
 397     ${LLVM_DIR}/lib/Support/FoldingSet.cpp
 398     ${LLVM_DIR}/lib/Support/FormattedStream.cpp
 399     ${LLVM_DIR}/lib/Support/GraphWriter.cpp
 400     ${LLVM_DIR}/lib/Support/Host.cpp
 401     ${LLVM_DIR}/lib/Support/IncludeFile.cpp
 402     ${LLVM_DIR}/lib/Support/IntEqClasses.cpp
 403     ${LLVM_DIR}/lib/Support/IntervalMap.cpp
 404     ${LLVM_DIR}/lib/Support/IsInf.cpp
 405     ${LLVM_DIR}/lib/Support/IsNAN.cpp
 406     ${LLVM_DIR}/lib/Support/ManagedStatic.cpp
 407     ${LLVM_DIR}/lib/Support/Memory.cpp
 408     ${LLVM_DIR}/lib/Support/MemoryBuffer.cpp
 409     ${LLVM_DIR}/lib/Support/MemoryObject.cpp
 410     ${LLVM_DIR}/lib/Support/Mutex.cpp
 411     ${LLVM_DIR}/lib/Support/Path.cpp
 412     ${LLVM_DIR}/lib/Support/PathV2.cpp
 413     ${LLVM_DIR}/lib/Support/PrettyStackTrace.cpp
 414     ${LLVM_DIR}/lib/Support/Process.cpp
 415     ${LLVM_DIR}/lib/Support/Program.cpp
 416     ${LLVM_DIR}/lib/Support/RWMutex.cpp
 417     ${LLVM_DIR}/lib/Support/SearchForAddressOfSpecialSymbol.cpp
 418     ${LLVM_DIR}/lib/Support/Signals.cpp
 419     ${LLVM_DIR}/lib/Support/SmallPtrSet.cpp
 420     ${LLVM_DIR}/lib/Support/SmallVector.cpp
 421     ${LLVM_DIR}/lib/Support/SourceMgr.cpp
 422     ${LLVM_DIR}/lib/Support/Statistic.cpp
 423     ${LLVM_DIR}/lib/Support/StringExtras.cpp
 424     ${LLVM_DIR}/lib/Support/StringMap.cpp
 425     ${LLVM_DIR}/lib/Support/StringPool.cpp
 426     ${LLVM_DIR}/lib/Support/StringRef.cpp
 427     ${LLVM_DIR}/lib/Support/SystemUtils.cpp
 428     ${LLVM_DIR}/lib/Support/TargetRegistry.cpp
 429     ${LLVM_DIR}/lib/Support/ThreadLocal.cpp
 430     ${LLVM_DIR}/lib/Support/Threading.cpp
 431     ${LLVM_DIR}/lib/Support/TimeValue.cpp
 432     ${LLVM_DIR}/lib/Support/Timer.cpp
 433     ${LLVM_DIR}/lib/Support/ToolOutputFile.cpp
 434     ${LLVM_DIR}/lib/Support/Triple.cpp
 435     ${LLVM_DIR}/lib/Support/Twine.cpp
 436     ${LLVM_DIR}/lib/Support/Valgrind.cpp
 437     ${LLVM_DIR}/lib/Support/circular_raw_ostream.cpp
 438     ${LLVM_DIR}/lib/Support/raw_os_ostream.cpp
 439     ${LLVM_DIR}/lib/Support/raw_ostream.cpp
 440     ${LLVM_DIR}/lib/Support/system_error.cpp
 441     ${LLVM_DIR}/lib/Target/Mangler.cpp
 442     ${LLVM_DIR}/lib/Target/TargetData.cpp
 443     ${LLVM_DIR}/lib/Target/TargetELFWriterInfo.cpp
 444     ${LLVM_DIR}/lib/Target/TargetFrameLowering.cpp
 445     ${LLVM_DIR}/lib/Target/TargetInstrInfo.cpp
 446     ${LLVM_DIR}/lib/Target/TargetLibraryInfo.cpp
 447     ${LLVM_DIR}/lib/Target/TargetLoweringObjectFile.cpp
 448     ${LLVM_DIR}/lib/Target/TargetMachine.cpp
 449     ${LLVM_DIR}/lib/Target/TargetRegisterInfo.cpp
 450     ${LLVM_DIR}/lib/Target/TargetSubtargetInfo.cpp
 451     ${LLVM_DIR}/lib/Target/X86/InstPrinter/X86ATTInstPrinter.cpp
 452     ${LLVM_DIR}/lib/Target/X86/InstPrinter/X86InstComments.cpp
 453     ${LLVM_DIR}/lib/Target/X86/InstPrinter/X86IntelInstPrinter.cpp
 454     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86AsmBackend.cpp
 455     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MCAsmInfo.cpp
 456     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MCCodeEmitter.cpp
 457     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MCTargetDesc.cpp
 458     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MachObjectWriter.cpp
 459     ${LLVM_DIR}/lib/Target/X86/TargetInfo/X86TargetInfo.cpp
 460     ${LLVM_DIR}/lib/Target/X86/Utils/X86ShuffleDecode.cpp
 461     ${LLVM_DIR}/lib/Target/X86/X86CodeEmitter.cpp
 462     ${LLVM_DIR}/lib/Target/X86/X86ELFWriterInfo.cpp
 463     ${LLVM_DIR}/lib/Target/X86/X86FastISel.cpp
 464     ${LLVM_DIR}/lib/Target/X86/X86FloatingPoint.cpp
 465     ${LLVM_DIR}/lib/Target/X86/X86FrameLowering.cpp
 466     ${LLVM_DIR}/lib/Target/X86/X86ISelDAGToDAG.cpp
 467     ${LLVM_DIR}/lib/Target/X86/X86ISelLowering.cpp
 468     ${LLVM_DIR}/lib/Target/X86/X86InstrInfo.cpp
 469     ${LLVM_DIR}/lib/Target/X86/X86JITInfo.cpp
 470     ${LLVM_DIR}/lib/Target/X86/X86RegisterInfo.cpp
 471     ${LLVM_DIR}/lib/Target/X86/X86SelectionDAGInfo.cpp
 472     ${LLVM_DIR}/lib/Target/X86/X86Subtarget.cpp
 473     ${LLVM_DIR}/lib/Target/X86/X86TargetMachine.cpp
 474     ${LLVM_DIR}/lib/Target/X86/X86TargetObjectFile.cpp
 475     ${LLVM_DIR}/lib/Target/X86/X86VZeroUpper.cpp
 476     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineAddSub.cpp
 477     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineAndOrXor.cpp
 478     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineCalls.cpp
 479     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineCasts.cpp
 480     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineCompares.cpp
 481     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineLoadStoreAlloca.cpp
 482     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineMulDivRem.cpp
 483     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombinePHI.cpp
 484     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineSelect.cpp
 485     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineShifts.cpp
 486     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineSimplifyDemanded.cpp
 487     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineVectorOps.cpp
 488     ${LLVM_DIR}/lib/Transforms/InstCombine/InstructionCombining.cpp
 489     ${LLVM_DIR}/lib/Transforms/Scalar/ADCE.cpp
 490     ${LLVM_DIR}/lib/Transforms/Scalar/CodeGenPrepare.cpp
 491     ${LLVM_DIR}/lib/Transforms/Scalar/DeadStoreElimination.cpp
 492     ${LLVM_DIR}/lib/Transforms/Scalar/GVN.cpp
 493     ${LLVM_DIR}/lib/Transforms/Scalar/LICM.cpp
 494     ${LLVM_DIR}/lib/Transforms/Scalar/LoopStrengthReduce.cpp
 495     ${LLVM_DIR}/lib/Transforms/Scalar/Reassociate.cpp
 496     ${LLVM_DIR}/lib/Transforms/Scalar/Reg2Mem.cpp
 497     ${LLVM_DIR}/lib/Transforms/Scalar/SCCP.cpp
 498     ${LLVM_DIR}/lib/Transforms/Scalar/ScalarReplAggregates.cpp
 499     ${LLVM_DIR}/lib/Transforms/Scalar/SimplifyCFGPass.cpp
 500     ${LLVM_DIR}/lib/Transforms/Utils/AddrModeMatcher.cpp
 501     ${LLVM_DIR}/lib/Transforms/Utils/BasicBlockUtils.cpp
 502     ${LLVM_DIR}/lib/Transforms/Utils/BreakCriticalEdges.cpp
 503     ${LLVM_DIR}/lib/Transforms/Utils/BuildLibCalls.cpp
 504     ${LLVM_DIR}/lib/Transforms/Utils/DemoteRegToStack.cpp
 505     ${LLVM_DIR}/lib/Transforms/Utils/InstructionNamer.cpp
 506     ${LLVM_DIR}/lib/Transforms/Utils/LCSSA.cpp
 507     ${LLVM_DIR}/lib/Transforms/Utils/Local.cpp
 508     ${LLVM_DIR}/lib/Transforms/Utils/LoopSimplify.cpp
 509     ${LLVM_DIR}/lib/Transforms/Utils/LowerInvoke.cpp
 510     ${LLVM_DIR}/lib/Transforms/Utils/LowerSwitch.cpp
 511     ${LLVM_DIR}/lib/Transforms/Utils/PromoteMemoryToRegister.cpp
 512     ${LLVM_DIR}/lib/Transforms/Utils/SSAUpdater.cpp
 513     ${LLVM_DIR}/lib/Transforms/Utils/SimplifyCFG.cpp
 514     ${LLVM_DIR}/lib/Transforms/Utils/UnifyFunctionExitNodes.cpp
 515     ${LLVM_DIR}/lib/VMCore/AsmWriter.cpp
 516     ${LLVM_DIR}/lib/VMCore/Attributes.cpp
 517     ${LLVM_DIR}/lib/VMCore/BasicBlock.cpp
 518     ${LLVM_DIR}/lib/VMCore/ConstantFold.cpp
 519     ${LLVM_DIR}/lib/VMCore/Constants.cpp
 520     ${LLVM_DIR}/lib/VMCore/DebugInfoProbe.cpp
 521     ${LLVM_DIR}/lib/VMCore/DebugLoc.cpp
 522     ${LLVM_DIR}/lib/VMCore/Dominators.cpp
 523     ${LLVM_DIR}/lib/VMCore/Function.cpp
 524     ${LLVM_DIR}/lib/VMCore/Globals.cpp
 525     ${LLVM_DIR}/lib/VMCore/IRBuilder.cpp
 526     ${LLVM_DIR}/lib/VMCore/InlineAsm.cpp
 527     ${LLVM_DIR}/lib/VMCore/Instruction.cpp
 528     ${LLVM_DIR}/lib/VMCore/Instructions.cpp
 529     ${LLVM_DIR}/lib/VMCore/IntrinsicInst.cpp
 530     ${LLVM_DIR}/lib/VMCore/LLVMContext.cpp
 531     ${LLVM_DIR}/lib/VMCore/LLVMContextImpl.cpp
 532     ${LLVM_DIR}/lib/VMCore/LeakDetector.cpp
 533     ${LLVM_DIR}/lib/VMCore/Metadata.cpp
 534     ${LLVM_DIR}/lib/VMCore/Module.cpp
 535     ${LLVM_DIR}/lib/VMCore/Pass.cpp
 536     ${LLVM_DIR}/lib/VMCore/PassManager.cpp
 537     ${LLVM_DIR}/lib/VMCore/PassRegistry.cpp
 538     ${LLVM_DIR}/lib/VMCore/PrintModulePass.cpp
 539     ${LLVM_DIR}/lib/VMCore/Type.cpp
 540     ${LLVM_DIR}/lib/VMCore/Use.cpp
 541     ${LLVM_DIR}/lib/VMCore/User.cpp
 542     ${LLVM_DIR}/lib/VMCore/Value.cpp
 543     ${LLVM_DIR}/lib/VMCore/ValueSymbolTable.cpp
 544     ${LLVM_DIR}/lib/VMCore/ValueTypes.cpp
 545     ${LLVM_DIR}/lib/VMCore/Verifier.cpp
 546 )
 547
 548 if(WIN32)
 549     set(LLVM_INCLUDE_DIR ${LLVM_DIR}/include)
 550 elseif(LINUX)
 551     set(LLVM_INCLUDE_DIR ${LLVM_DIR}/include-linux)
 552 elseif(APPLE)
 553     set(LLVM_INCLUDE_DIR ${LLVM_DIR}/include-osx)
 554 endif()
 555
 556 list(APPEND LLVM_INCLUDE_DIR
 557     ${LLVM_DIR}/include
 558     ${LLVM_DIR}/lib/Target/X86
 559 )
 560 add_library(llvm STATIC ${LLVM_LIST})
 561 set_target_properties(llvm PROPERTIES
 562     POSITION_INDEPENDENT_CODE 1
 563     INCLUDE_DIRECTORIES "${LLVM_INCLUDE_DIR}"
 564     COMPILE_DEFINITIONS "__STDC_CONSTANT_MACROS; __STDC_LIMIT_MACROS;"
 565     FOLDER "LLVM"
 566 )
 567
 568 ###########################################################
 569 # Subzero
 570 ###########################################################
 571
 572 if(${REACTOR_BACKEND} STREQUAL "Subzero")
 573     set(SUBZERO_LIST
 574         ${SUBZERO_DIR}/src/IceAssembler.cpp
 575         ${SUBZERO_DIR}/src/IceCfg.cpp
 576         ${SUBZERO_DIR}/src/IceCfgNode.cpp
 577         ${SUBZERO_DIR}/src/IceClFlags.cpp
 578         ${SUBZERO_DIR}/src/IceELFObjectWriter.cpp
 579         ${SUBZERO_DIR}/src/IceELFSection.cpp
 580         ${SUBZERO_DIR}/src/IceFixups.cpp
 581         ${SUBZERO_DIR}/src/IceGlobalContext.cpp
 582         ${SUBZERO_DIR}/src/IceGlobalInits.cpp
 583         ${SUBZERO_DIR}/src/IceInst.cpp
 584         ${SUBZERO_DIR}/src/IceInstrumentation.cpp
 585         ${SUBZERO_DIR}/src/IceIntrinsics.cpp
 586         ${SUBZERO_DIR}/src/IceLiveness.cpp
 587         ${SUBZERO_DIR}/src/IceLoopAnalyzer.cpp
 588         ${SUBZERO_DIR}/src/IceMangling.cpp
 589         ${SUBZERO_DIR}/src/IceMemory.cpp
 590         ${SUBZERO_DIR}/src/IceOperand.cpp
 591         ${SUBZERO_DIR}/src/IceRangeSpec.cpp
 592         ${SUBZERO_DIR}/src/IceRegAlloc.cpp
 593         ${SUBZERO_DIR}/src/IceRevision.cpp
 594         ${SUBZERO_DIR}/src/IceRNG.cpp
 595         ${SUBZERO_DIR}/src/IceSwitchLowering.cpp
 596         ${SUBZERO_DIR}/src/IceTargetLowering.cpp
 597         ${SUBZERO_DIR}/src/IceThreading.cpp
 598         ${SUBZERO_DIR}/src/IceTimerTree.cpp
 599         ${SUBZERO_DIR}/src/IceTypes.cpp
 600         ${SUBZERO_DIR}/src/IceVariableSplitting.cpp
 601     )
 602
 603     if(ARCH STREQUAL "x86_64")
 604         list(APPEND SUBZERO_LIST
 605             ${SUBZERO_DIR}/src/IceTargetLoweringX86.cpp
 606             ${SUBZERO_DIR}/src/IceInstX8664.cpp
 607             ${SUBZERO_DIR}/src/IceTargetLoweringX8664.cpp
 608         )
 609         set(SUBZERO_TARGET X8664)
 610     elseif(ARCH STREQUAL "x86")
 611         list(APPEND SUBZERO_LIST
 612             ${SUBZERO_DIR}/src/IceTargetLoweringX86.cpp
 613             ${SUBZERO_DIR}/src/IceInstX8632.cpp
 614             ${SUBZERO_DIR}/src/IceTargetLoweringX8632.cpp
 615         )
 616         set(SUBZERO_TARGET X8632)
 617     elseif(ARCH STREQUAL "arm")
 618         list(APPEND SUBZERO_LIST
 619             ${SUBZERO_DIR}/src/IceAssemblerARM32.cpp
 620             ${SUBZERO_DIR}/src/IceInstARM32.cpp
 621             ${SUBZERO_DIR}/src/IceTargetLoweringARM32.cpp
 622         )
 623         set(SUBZERO_TARGET ARM32)
 624     else()
 625         message(FATAL_ERROR "Architecture '${ARCH}' not supported by Subzero")
 626     endif()
 627
 628     file(GLOB_RECURSE SUBZERO_DEPENDENCIES_LIST
 629         ${SUBZERO_LLVM_DIR}/*.cpp
 630         ${SUBZERO_LLVM_DIR}/*.c
 631         ${SUBZERO_LLVM_DIR}/*.h
 632     )
 633
 634     set(SUBZERO_REACTOR_LIST
 635         ${SOURCE_DIR}/Reactor/SubzeroReactor.cpp
 636         ${SOURCE_DIR}/Reactor/Routine.cpp
 637         ${SOURCE_DIR}/Reactor/Optimizer.cpp
 638         ${SOURCE_DIR}/Reactor/Nucleus.hpp
 639         ${SOURCE_DIR}/Reactor/Routine.hpp
 640     )
 641
 642     set(SUBZERO_INCLUDE_DIR
 643         ${SUBZERO_DIR}/
 644         ${SUBZERO_LLVM_DIR}/include/
 645         ${SUBZERO_DIR}/pnacl-llvm/include/
 646      )
 647
 648     if(WIN32)
 649         list(APPEND SUBZERO_INCLUDE_DIR ${SUBZERO_LLVM_DIR}/build/Windows/include/)
 650     elseif(LINUX)
 651         list(APPEND SUBZERO_INCLUDE_DIR ${SUBZERO_LLVM_DIR}/build/Linux/include/)
 652     elseif(APPLE)
 653         list(APPEND SUBZERO_INCLUDE_DIR ${SUBZERO_LLVM_DIR}/build/MacOS/include/)
 654     endif()
 655
 656     add_library(ReactorSubzero STATIC
 657         ${SUBZERO_LIST}
 658         ${SUBZERO_DEPENDENCIES_LIST}
 659         ${SUBZERO_REACTOR_LIST}
 660     )
 661
 662     set_target_properties(ReactorSubzero PROPERTIES
 663         POSITION_INDEPENDENT_CODE 1
 664         INCLUDE_DIRECTORIES "${SUBZERO_INCLUDE_DIR}"
 665         COMPILE_DEFINITIONS "SZTARGET=${SUBZERO_TARGET}; ALLOW_DUMP=0; ALLOW_TIMERS=0; ALLOW_LLVM_CL=0; ALLOW_LLVM_IR=0; ALLOW_LLVM_IR_AS_INPUT=0; ALLOW_MINIMAL_BUILD=0; ALLOW_WASM=0; ICE_THREAD_LOCAL_HACK=0;"
 666         FOLDER "Subzero"
 667     )
 668
 669     if(WIN32)
 670         target_compile_definitions(ReactorSubzero PRIVATE SUBZERO_USE_MICROSOFT_ABI)
 671     endif()
 672 endif()
 673
 674 ###########################################################
 675 # Include Directories
 676 ###########################################################
 677
 678 set(COMMON_INCLUDE_DIR
 679     ${SOURCE_DIR}
 680     ${SOURCE_DIR}/Common
 681     ${SOURCE_DIR}/Main
 682     ${SOURCE_DIR}/Reactor
 683     ${SOURCE_DIR}/Renderer
 684     ${SOURCE_DIR}/Shader
 685     ${CMAKE_SOURCE_DIR}/include
 686     ${LLVM_INCLUDE_DIR}
 687 )
 688 set(OPENGL_INCLUDE_DIR
 689     ${OPENGL_DIR}
 690     ${COMMON_INCLUDE_DIR}
 691 )
 692
 693 ###########################################################
 694 # File Lists
 695 ###########################################################
 696
 697 file(GLOB_RECURSE SWIFTSHADER_LIST
 698     ${SOURCE_DIR}/Common/*.cpp
 699     ${SOURCE_DIR}/Common/*.h
 700     ${SOURCE_DIR}/Common/*.hpp
 701     ${SOURCE_DIR}/Renderer/*.cpp
 702     ${SOURCE_DIR}/Renderer/*.h
 703     ${SOURCE_DIR}/Renderer/*.hpp
 704     ${SOURCE_DIR}/Shader/*.cpp
 705     ${SOURCE_DIR}/Shader/*.h
 706     ${SOURCE_DIR}/Shader/*.hpp
 707 )
 708 list(APPEND SWIFTSHADER_LIST
 709     ${SOURCE_DIR}/Main/Config.cpp
 710     ${SOURCE_DIR}/Main/Config.hpp
 711     ${SOURCE_DIR}/Main/FrameBuffer.cpp
 712     ${SOURCE_DIR}/Main/FrameBuffer.hpp
 713     ${SOURCE_DIR}/Main/SwiftConfig.cpp
 714     ${SOURCE_DIR}/Main/SwiftConfig.hpp
 715 )
 716 list(REMOVE_ITEM SWIFTSHADER_LIST
 717     ${SOURCE_DIR}/Common/DebugAndroid.cpp
 718     ${SOURCE_DIR}/Common/DebugAndroid.hpp
 719     ${SOURCE_DIR}/Common/GrallocAndroid.cpp
 720     ${SOURCE_DIR}/Common/GrallocAndroid.hpp
 721 )
 722
 723 set(REACTOR_LLVM_LIST
 724     ${SOURCE_DIR}/Reactor/LLVMReactor.cpp
 725     ${SOURCE_DIR}/Reactor/Nucleus.hpp
 726     ${SOURCE_DIR}/Reactor/Routine.cpp
 727     ${SOURCE_DIR}/Reactor/Routine.hpp
 728     ${SOURCE_DIR}/Reactor/LLVMRoutine.cpp
 729     ${SOURCE_DIR}/Reactor/LLVMRoutine.hpp
 730     ${SOURCE_DIR}/Reactor/LLVMRoutineManager.cpp
 731     ${SOURCE_DIR}/Reactor/LLVMRoutineManager.hpp
 732 )
 733
 734 file(GLOB_RECURSE EGL_LIST
 735     ${OPENGL_DIR}/libEGL/*.cpp
 736     ${OPENGL_DIR}/libEGL/*.h
 737     ${OPENGL_DIR}/libEGL/*.hpp
 738     ${OPENGL_DIR}/common/Object.cpp
 739     ${OPENGL_DIR}/common/Object.hpp
 740     ${OPENGL_DIR}/common/debug.cpp
 741     ${OPENGL_DIR}/common/debug.h
 742     ${CMAKE_SOURCE_DIR}/include/*.h
 743 )
 744
 745 file(GLOB_RECURSE GL32_LIST
 746     ${OPENGL_DIR}/libGL/*.cpp
 747     ${OPENGL_DIR}/libGL/*.h
 748     ${OPENGL_DIR}/libGL/*.hpp
 749     ${OPENGL_DIR}/common/*.cpp
 750     ${OPENGL_DIR}/common/*.h
 751     ${OPENGL_DIR}/common/*.hpp
 752     ${CMAKE_SOURCE_DIR}/include/GL/*.h
 753 )
 754
 755 file(GLOB_RECURSE GLES2_LIST
 756     ${OPENGL_DIR}/libGLESv2/*.cpp
 757     ${OPENGL_DIR}/libGLESv2/*.h
 758     ${OPENGL_DIR}/libGLESv2/*.hpp
 759     ${OPENGL_DIR}/common/*.cpp
 760     ${OPENGL_DIR}/common/*.h
 761     ${OPENGL_DIR}/common/*.hpp
 762     ${CMAKE_SOURCE_DIR}/include/KHR/*.h
 763     ${CMAKE_SOURCE_DIR}/include/GLES2/*.h
 764     ${CMAKE_SOURCE_DIR}/include/GLES3/*.h
 765 )
 766
 767 file(GLOB_RECURSE GLES_CM_LIST
 768     ${OPENGL_DIR}/libGLES_CM/*.cpp
 769     ${OPENGL_DIR}/libGLES_CM/*.h
 770     ${OPENGL_DIR}/libGLES_CM/*.hpp
 771     ${OPENGL_DIR}/common/*.cpp
 772     ${OPENGL_DIR}/common/*.h
 773     ${OPENGL_DIR}/common/*.hpp
 774     ${CMAKE_SOURCE_DIR}/include/KHR/*.h
 775     ${CMAKE_SOURCE_DIR}/include/GLES/*.h
 776 )
 777
 778 file(GLOB_RECURSE OPENGL_COMPILER_LIST
 779     ${OPENGL_COMPILER_DIR}/*.cpp
 780     ${OPENGL_COMPILER_DIR}/*.h
 781     ${OPENGL_COMPILER_DIR}/*.hpp
 782 )
 783 file(GLOB_RECURSE OPENGL_COMPILER_OS_SPECIFIC_LIST
 784     ${OPENGL_COMPILER_DIR}/ossource*.cpp
 785     ${OPENGL_COMPILER_DIR}/ossource*.h
 786     ${OPENGL_COMPILER_DIR}/ossource*.hpp
 787 )
 788 list(REMOVE_ITEM OPENGL_COMPILER_LIST ${OPENGL_COMPILER_OS_SPECIFIC_LIST})
 789
 790 ###########################################################
 791 # Append OS specific files to lists
 792 ###########################################################
 793
 794 if(WIN32)
 795     list(APPEND SWIFTSHADER_LIST
 796         ${SOURCE_DIR}/Main/FrameBufferDD.cpp
 797         ${SOURCE_DIR}/Main/FrameBufferDD.hpp
 798         ${SOURCE_DIR}/Main/FrameBufferGDI.cpp
 799         ${SOURCE_DIR}/Main/FrameBufferGDI.hpp
 800         ${SOURCE_DIR}/Main/FrameBufferWin.cpp
 801         ${SOURCE_DIR}/Main/FrameBufferWin.hpp
 802     )
 803     list(APPEND OPENGL_COMPILER_LIST ${OPENGL_COMPILER_DIR}/ossource_win.cpp)
 804     list(APPEND EGL_LIST ${OPENGL_DIR}/libEGL/libEGL.rc)
 805     list(APPEND GL32_LIST ${OPENGL_DIR}/libGL/libGL.rc)
 806     list(APPEND GLES2_LIST ${OPENGL_DIR}/libGLESv2/libGLESv2.rc)
 807     list(APPEND GLES_CM_LIST ${OPENGL_DIR}/libGLES_CM/libGLES_CM.rc)
 808 elseif(LINUX)
 809     list(APPEND SWIFTSHADER_LIST
 810         ${SOURCE_DIR}/Main/FrameBufferX11.cpp
 811         ${SOURCE_DIR}/Main/FrameBufferX11.hpp
 812         ${SOURCE_DIR}/Common/SharedLibrary.hpp
 813         ${SOURCE_DIR}/Main/libX11.cpp
 814         ${SOURCE_DIR}/Main/libX11.hpp
 815     )
 816     list(APPEND EGL_LIST
 817         ${SOURCE_DIR}/Common/SharedLibrary.hpp
 818         ${SOURCE_DIR}/Main/libX11.cpp
 819         ${SOURCE_DIR}/Main/libX11.hpp
 820     )
 821     list(APPEND OPENGL_COMPILER_LIST
 822         ${OPENGL_COMPILER_DIR}/ossource_posix.cpp
 823     )
 824 elseif(APPLE)
 825     list(APPEND SWIFTSHADER_LIST
 826         ${SOURCE_DIR}/Main/FrameBufferOSX.mm
 827         ${SOURCE_DIR}/Main/FrameBufferOSX.hpp
 828     )
 829     list(APPEND EGL_LIST
 830         ${OPENGL_DIR}/libEGL/OSXUtils.mm
 831         ${OPENGL_DIR}/libEGL/OSXUtils.hpp
 832     )
 833     list(APPEND OPENGL_COMPILER_LIST
 834         ${OPENGL_COMPILER_DIR}/ossource_posix.cpp
 835     )
 836 endif()
 837
 838 if(WIN32)
 839     set(OS_LIBS odbc32 odbccp32 WS2_32 dxguid)
 840 elseif(LINUX)
 841     set(OS_LIBS dl pthread)
 842 elseif(APPLE)
 843     find_library(COCOA_FRAMEWORK Cocoa)
 844     find_library(QUARTZ_FRAMEWORK Quartz)
 845     set(OS_LIBS "${COCOA_FRAMEWORK}" "${QUARTZ_FRAMEWORK}")
 846 endif()
 847
 848 ###########################################################
 849 # SwiftShader Targets
 850 ###########################################################
 851
 852 add_library(SwiftShader STATIC ${SWIFTSHADER_LIST})
 853 set_target_properties(SwiftShader PROPERTIES
 854     INCLUDE_DIRECTORIES "${COMMON_INCLUDE_DIR}"
 855     POSITION_INDEPENDENT_CODE 1
 856     FOLDER "Core"
 857     COMPILE_DEFINITIONS "NO_SANITIZE_FUNCTION=;"
 858 )
 859 target_link_libraries(SwiftShader ${OS_LIBS})
 860
 861 add_library(ReactorLLVM STATIC ${REACTOR_LLVM_LIST})
 862 set_target_properties(ReactorLLVM PROPERTIES
 863     INCLUDE_DIRECTORIES "${COMMON_INCLUDE_DIR}"
 864     POSITION_INDEPENDENT_CODE 1
 865     FOLDER "Core"
 866 )
 867 target_link_libraries(ReactorLLVM llvm ${OS_LIBS})
 868
 869 if(${REACTOR_BACKEND} STREQUAL "LLVM")
 870     set(Reactor ReactorLLVM)
 871 elseif(${REACTOR_BACKEND} STREQUAL "Subzero")
 872     set(Reactor ReactorSubzero)
 873 else()
 874     message(FATAL_ERROR "REACTOR_BACKEND must be 'LLVM' or 'Subzero'")
 875 endif()
 876
 877 add_library(GLCompiler STATIC ${OPENGL_COMPILER_LIST})
 878 set_target_properties(GLCompiler PROPERTIES
 879     INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 880     POSITION_INDEPENDENT_CODE 1
 881     FOLDER "OpenGL"
 882 )
 883 target_link_libraries(GLCompiler ${OS_LIBS})
 884
 885 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 886     set(LIB_PREFIX "lib64")
 887 else()
 888     set(LIB_PREFIX "lib")
 889 endif()
 890
 891 if(BUILD_EGL)
 892     add_library(libEGL SHARED ${EGL_LIST})
 893     set_target_properties(libEGL PROPERTIES
 894         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 895         FOLDER "OpenGL"
 896         COMPILE_DEFINITIONS "EGL_EGLEXT_PROTOTYPES; EGLAPI=; NO_SANITIZE_FUNCTION=;"
 897         PREFIX ""
 898     )
 899     set_target_export_map(libEGL ${SOURCE_DIR}/OpenGL/libEGL)
 900     target_link_libraries(libEGL ${OS_LIBS})
 901     add_custom_command(
 902         TARGET libEGL
 903         POST_BUILD
 904         COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:libEGL>/translator
 905         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libEGL> $<TARGET_FILE_DIR:libEGL>/translator/${LIB_PREFIX}EGL_translator${CMAKE_SHARED_LIBRARY_SUFFIX}
 906     )
 907 endif()
 908
 909 if(BUILD_GL32)
 910     add_library(libGL SHARED ${GL32_LIST})
 911     set_target_properties(libGL PROPERTIES
 912         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 913         FOLDER "OpenGL"
 914         COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
 915         PREFIX ""
 916     )
 917     set_target_export_map(libGL ${SOURCE_DIR}/OpenGL/libGL)
 918     target_link_libraries(libGL SwiftShader ${Reactor} GLCompiler ${OS_LIBS})
 919 endif()
 920
 921 if(BUILD_GLESv2)
 922     add_library(libGLESv2 SHARED ${GLES2_LIST})
 923     set_target_properties(libGLESv2 PROPERTIES
 924         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 925         FOLDER "OpenGL"
 926         COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES; GL_API=; GL_APICALL=; NO_SANITIZE_FUNCTION=;"
 927         PREFIX ""
 928     )
 929     set_target_export_map(libGLESv2 ${SOURCE_DIR}/OpenGL/libGLESv2)
 930     target_link_libraries(libGLESv2 SwiftShader ${Reactor} GLCompiler ${OS_LIBS})
 931     add_custom_command(
 932         TARGET libGLESv2
 933         POST_BUILD
 934         COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:libGLESv2>/translator
 935         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libGLESv2> $<TARGET_FILE_DIR:libGLESv2>/translator/${LIB_PREFIX}GLES_V2_translator${CMAKE_SHARED_LIBRARY_SUFFIX}
 936     )
 937 endif()
 938
 939 if(BUILD_GLES_CM)
 940     add_library(libGLES_CM SHARED ${GLES_CM_LIST})
 941     set_target_properties(libGLES_CM PROPERTIES
 942         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 943         FOLDER "OpenGL"
 944         COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES; EGLAPI=; GL_API=; GL_APICALL=;"
 945         PREFIX ""
 946     )
 947     set_target_export_map(libGLES_CM ${SOURCE_DIR}/OpenGL/libGLES_CM)
 948     target_link_libraries(libGLES_CM SwiftShader ${Reactor} GLCompiler ${OS_LIBS})
 949     add_custom_command(
 950         TARGET libGLES_CM
 951         POST_BUILD
 952         COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:libGLES_CM>/translator
 953         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libGLES_CM> $<TARGET_FILE_DIR:libGLES_CM>/translator/${LIB_PREFIX}GLES_CM_translator${CMAKE_SHARED_LIBRARY_SUFFIX}
 954     )
 955 endif()
 956
 957 ###########################################################
 958 # Sample programs
 959 ###########################################################
 960
 961 if(BUILD_SAMPLES)
 962     if(WIN32)
 963         add_executable(OGLES2HelloAPI ${HELLO2_DIR}/OGLES2HelloAPI_Windows.cpp)
 964         set_target_properties(OGLES2HelloAPI PROPERTIES
 965             INCLUDE_DIRECTORIES "${CMAKE_SOURCE_DIR}/include"
 966             COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
 967             FOLDER "Samples"
 968         )
 969         target_link_libraries(OGLES2HelloAPI libEGL libGLESv2)
 970         set_property(TARGET OGLES2HelloAPI APPEND_STRING PROPERTY LINK_FLAGS "/SUBSYSTEM:WINDOWS")
 971         set(CMAKE_DEFAULT_STARTUP_PROJECT OGLES2HelloAPI)
 972     elseif(LINUX)
 973         add_executable(OGLES2HelloAPI ${HELLO2_DIR}/OGLES2HelloAPI_LinuxX11.cpp)
 974         set_target_properties(OGLES2HelloAPI PROPERTIES
 975             INCLUDE_DIRECTORIES "${CMAKE_SOURCE_DIR}/include"
 976             COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
 977         )
 978         target_link_libraries(OGLES2HelloAPI dl X11 libEGL libGLESv2)   # Explicitly link our "lib*" targets, not the platform provided "EGL" and "GLESv2"
 979     elseif(APPLE)
 980         add_executable(OGLES2HelloAPI MACOSX_BUNDLE
 981             ${HELLO2_DIR}/OGLES2HelloAPI_OSX.mm
 982             ${HELLO2_DIR}/Build/OSX/en.lproj/MainMenu.xib
 983         )
 984         set_target_properties(OGLES2HelloAPI PROPERTIES
 985             INCLUDE_DIRECTORIES "${CMAKE_SOURCE_DIR}/include"
 986             COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
 987             MACOSX_BUNDLE_INFO_PLIST "${HELLO2_DIR}/Build/OSX/Info.plist"
 988         )
 989         target_link_libraries(OGLES2HelloAPI libEGL libGLESv2 ${OS_LIBS})
 990         set_source_files_properties(${HELLO2_DIR}/Build/OSX/en.lproj/MainMenu.xib PROPERTIES
 991             MACOSX_PACKAGE_LOCATION "Resources"
 992         )
 993     endif()
 994 endif()
 995
 996 if(BUILD_TESTS AND ${REACTOR_BACKEND} STREQUAL "Subzero")
 997     set(SUBZERO_TEST_LIST
 998         ${SOURCE_DIR}/Reactor/Main.cpp
 999         ${CMAKE_SOURCE_DIR}/third_party/googletest/googletest/src/gtest-all.cc
1000     )
1001
1002     set(SUBZERO_TEST_INCLUDE_DIR
1003         ${CMAKE_SOURCE_DIR}/third_party/googletest/googletest/include
1004         ${CMAKE_SOURCE_DIR}/third_party/googletest/googletest/
1005     )
1006
1007     add_executable(SubzeroTest ${SUBZERO_TEST_LIST})
1008     set_target_properties(SubzeroTest PROPERTIES
1009         INCLUDE_DIRECTORIES "${SUBZERO_TEST_INCLUDE_DIR}"
1010         FOLDER "Tests"
1011     )
1012     if(WIN32)
1013         target_link_libraries(SubzeroTest ReactorSubzero)
1014     else()
1015         target_link_libraries(SubzeroTest ReactorSubzero pthread dl)
1016     endif()
1017 endif()