CMakeLists.txt

   1 cmake_minimum_required(VERSION 2.8)
   2
   3 project(SwiftShader C CXX)
   4
   5 ###########################################################
   6 # Detect system
   7 ###########################################################
   8
   9 if(CMAKE_SYSTEM_NAME MATCHES "Linux")
  10     set(LINUX ON)
  11 elseif(WIN32)
  12 elseif(APPLE)
  13 else()
  14     message(FATAL_ERROR "Platform is not supported")
  15 endif()
  16
  17 if(CMAKE_SYSTEM_PROCESSOR MATCHES "arm" OR CMAKE_SYSTEM_PROCESSOR MATCHES "aarch")
  18     if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  19         set(ARCH "aarch64")
  20     else()
  21         set(ARCH "arm")
  22     endif()
  23 else()
  24     if(CMAKE_SIZEOF_VOID_P EQUAL 8)
  25         set(ARCH "x86_64")
  26     else()
  27         set(ARCH "x86")
  28     endif()
  29 endif()
  30
  31 set(CMAKE_MACOSX_RPATH ON)
  32
  33 ###########################################################
  34 # Options
  35 ###########################################################
  36
  37 if(NOT CMAKE_BUILD_TYPE)
  38     set(CMAKE_BUILD_TYPE "Release" CACHE STRING "The type of build: Debug Release MinSizeRel RelWithDebInfo." FORCE)
  39 endif()
  40 set_property(CACHE CMAKE_BUILD_TYPE PROPERTY STRINGS Debug Release MinSizeRel RelWithDebInfo)
  41
  42 option(BUILD_EGL "Build the EGL library" 1)
  43 if(WIN32)
  44     option(BUILD_GL32 "Build the OpenGL32 library" 1)
  45 endif()
  46 option(BUILD_GLESv2 "Build the OpenGL ES 2 library" 1)
  47 option(BUILD_GLES_CM "Build the OpenGL ES 1.1 library" 1)
  48
  49 option(USE_GROUP_SOURCES "Group the source files in a folder tree for Visual Studio" 1)
  50
  51 option(BUILD_SAMPLES "Build sample programs" 1)
  52 option(BUILD_TESTS "Build test programs" 1)
  53
  54 if(ARCH STREQUAL "arm")
  55     set(DEFAULT_REACTOR_BACKEND "Subzero")
  56 else()
  57     set(DEFAULT_REACTOR_BACKEND "LLVM")
  58 endif()
  59
  60 set(REACTOR_BACKEND DEFAULT_REACTOR_BACKEND CACHE STRING "JIT compiler back-end used by Reactor")
  61 set_property(CACHE REACTOR_BACKEND PROPERTY STRINGS LLVM Subzero)
  62
  63 # LLVM disallows calling cmake . from the main LLVM dir, the reason is that
  64 # it builds header files that could overwrite the orignal ones. Here we
  65 # want to include LLVM as a subdirectory and even though it wouldn't cause
  66 # the problem, if cmake . is called from the main dir, the condition that
  67 # LLVM checkes, "CMAKE_SOURCE_DIR == CMAKE_BINARY_DIR" will be true. So we
  68 # disallow it ourselves too to. In addition if there are remining CMakeFiles
  69 # and CMakeCache in the directory, cmake .. from a subdirectory will still
  70 # try to build from the main directory so we instruct users to delete these
  71 # files when they get the error.
  72 if(CMAKE_SOURCE_DIR STREQUAL CMAKE_BINARY_DIR)
  73     message(FATAL_ERROR "In source builds are not allowed by LLVM, please create a build/ directory and build from there. You may have to delete the CMakeCache.txt file and CMakeFiles directory that are next to the CMakeLists.txt.")
  74 endif()
  75
  76 set_property(GLOBAL PROPERTY USE_FOLDERS ON)
  77
  78 ###########################################################
  79 # Convenience macros
  80 ###########################################################
  81
  82 # Recursively calls source_group on the files of the directory
  83 # so that Visual Studio has the files in a folder tree
  84 macro(group_all_sources directory)
  85     file(GLOB files RELATIVE ${CMAKE_SOURCE_DIR}/${directory} ${CMAKE_SOURCE_DIR}/${directory}/*)
  86     foreach(file ${files})
  87         if(IS_DIRECTORY ${CMAKE_SOURCE_DIR}/${directory}/${file})
  88             group_all_sources(${directory}/${file})
  89         else()
  90             string(REPLACE "/" "\\" groupname ${directory})
  91             source_group(${groupname} FILES ${CMAKE_SOURCE_DIR}/${directory}/${file})
  92         endif()
  93     endforeach()
  94 endmacro()
  95
  96 # Takes target library and a directory where the export map is
  97 # and add the linker options so that only the API symbols are
  98 # exported.
  99 macro(set_target_export_map TARGET DIR)
 100     get_target_property(LINKFLAGS ${TARGET} LINK_FLAGS)
 101     if(LINKFLAGS MATCHES "NOTFOUND")
 102         set(LINKFLAGS "")
 103     endif()
 104     if(MSVC)
 105         set_target_properties(${TARGET} PROPERTIES LINK_FLAGS "/DEF:\"${DIR}/${TARGET}.def\"")
 106     elseif(LINUX)
 107         # Both hash-style are needed, because we want both gold and
 108         # GNU ld to be able to read our libraries (maybe?).
 109         # The version script only exports the API functions and
 110         # hides all the others. Gc sections is used in combination
 111         # with each functions being in its section, to reduce the
 112         # binary size.
 113         set_target_properties(${TARGET} PROPERTIES LINK_FLAGS "${LINKFLAGS} -Wl,--hash-style=both,--version-script=${DIR}/${TARGET}.lds,--gc-sections,--no-undefined")
 114         set_target_properties(${TARGET} PROPERTIES LINK_DEPENDS "${DIR}/${TARGET}.lds")
 115     endif()
 116 endmacro()
 117
 118 if(USE_GROUP_SOURCES)
 119     group_all_sources(src)
 120 endif()
 121
 122 ###########################################################
 123 # Directories
 124 ###########################################################
 125
 126 set(SOURCE_DIR ${CMAKE_SOURCE_DIR}/src)
 127 set(OPENGL_DIR ${SOURCE_DIR}/OpenGL)
 128 set(OPENGL_COMPILER_DIR ${OPENGL_DIR}/compiler)
 129 set(LLVM_DIR ${CMAKE_SOURCE_DIR}/third_party/LLVM)
 130 set(SUBZERO_DIR ${CMAKE_SOURCE_DIR}/third_party/subzero)
 131 set(SUBZERO_LLVM_DIR ${CMAKE_SOURCE_DIR}/third_party/llvm-subzero)
 132 set(TESTS_DIR ${CMAKE_SOURCE_DIR}/tests)
 133 set(HELLO2_DIR ${CMAKE_SOURCE_DIR}/third_party/PowerVR_SDK/Examples/Beginner/01_HelloAPI/OGLES2)
 134
 135 ###########################################################
 136 # Compile flags
 137 ###########################################################
 138
 139 macro(set_cpp_flag FLAG)
 140     if(${ARGC} GREATER 1)
 141         set(CMAKE_CXX_FLAGS_${ARGV1} "${CMAKE_CXX_FLAGS_${ARGV1}} ${FLAG}")
 142     else()
 143         set(CMAKE_CXX_FLAGS "${CMAKE_CXX_FLAGS} ${FLAG}")
 144     endif()
 145 endmacro()
 146
 147 if(MSVC)
 148     set_cpp_flag("/MP")
 149     add_definitions(-D_CRT_SECURE_NO_WARNINGS)
 150 else()
 151     set_cpp_flag("--std=c++11")
 152     set_cpp_flag("-Wall")
 153     set_cpp_flag("-Werror=reorder")
 154     set_cpp_flag("-Werror=sign-compare")
 155     set_cpp_flag("-fno-exceptions")
 156
 157     # Don't allow symbols to be overridden by another module.
 158     # This enables libGLES_CM and libGLESv2 to statically link LLVM.
 159     set_cpp_flag("-fvisibility=protected")
 160
 161     # Remove xor, and, or and friends from the list of keywords, they are used
 162     # by Reactor
 163     set_cpp_flag("-fno-operator-names")
 164
 165     # LLVM headers requires these flags to be set
 166     set_cpp_flag("-D__STDC_CONSTANT_MACROS -D__STDC_LIMIT_MACROS")
 167
 168     if(ARCH EQUAL "x86")
 169         set_cpp_flag("-m32")
 170         set_cpp_flag("-msse2")
 171         set_cpp_flag("-mfpmath=sse")
 172         set_cpp_flag("-march=pentium4")
 173         set_cpp_flag("-mtune=generic")
 174     endif()
 175     if(ARCH EQUAL "x86_64")
 176         set_cpp_flag("-m64")
 177         set_cpp_flag("-fPIC")
 178         set_cpp_flag("-march=x86-64")
 179         set_cpp_flag("-mtune=generic")
 180     endif()
 181
 182     # Use -g3 to have even more debug info
 183     set_cpp_flag("-g -g3" DEBUG)
 184     set_cpp_flag("-g -g3" RELWITHDEBINFO)
 185     set_cpp_flag("-s" RELEASE)
 186
 187     # For distribution it is more important to be slim than super optimized
 188     set_cpp_flag("-Os" RELEASE)
 189     set_cpp_flag("-Os" RELWITHDEBINFO)
 190
 191     set_cpp_flag("-DNDEBUG" RELEASE)
 192     set_cpp_flag("-DNDEBUG" RELWITHDEBINFO)
 193     set_cpp_flag("-DANGLE_DISABLE_TRACE" RELEASE)
 194     set_cpp_flag("-DANGLE_DISABLE_TRACE" RELWITHDEBINFO)
 195
 196     # Put each variable and function in its own section so that when linking
 197     # with -gc-sections unused functions and variables are removed.
 198     set_cpp_flag("-ffunction-sections" RELEASE)
 199     set_cpp_flag("-fdata-sections" RELEASE)
 200     set_cpp_flag("-fomit-frame-pointer" RELEASE)
 201 endif()
 202
 203 if( WIN32 )
 204     add_definitions(-DWINVER=0x501 -DNOMINMAX -DSTRICT)
 205     set(CMAKE_FIND_LIBRARY_PREFIXES ${CMAKE_FIND_LIBRARY_PREFIXES} "" "lib")
 206 endif()
 207
 208
 209 ###########################################################
 210 # LLVM
 211 ###########################################################
 212
 213 set(LLVM_LIST
 214     ${LLVM_DIR}/lib/Analysis/AliasAnalysis.cpp
 215     ${LLVM_DIR}/lib/Analysis/AliasSetTracker.cpp
 216     ${LLVM_DIR}/lib/Analysis/BasicAliasAnalysis.cpp
 217     ${LLVM_DIR}/lib/Analysis/BranchProbabilityInfo.cpp
 218     ${LLVM_DIR}/lib/Analysis/CaptureTracking.cpp
 219     ${LLVM_DIR}/lib/Analysis/ConstantFolding.cpp
 220     ${LLVM_DIR}/lib/Analysis/DIBuilder.cpp
 221     ${LLVM_DIR}/lib/Analysis/DebugInfo.cpp
 222     ${LLVM_DIR}/lib/Analysis/IVUsers.cpp
 223     ${LLVM_DIR}/lib/Analysis/InstructionSimplify.cpp
 224     ${LLVM_DIR}/lib/Analysis/Loads.cpp
 225     ${LLVM_DIR}/lib/Analysis/LoopInfo.cpp
 226     ${LLVM_DIR}/lib/Analysis/LoopPass.cpp
 227     ${LLVM_DIR}/lib/Analysis/MemoryBuiltins.cpp
 228     ${LLVM_DIR}/lib/Analysis/MemoryDependenceAnalysis.cpp
 229     ${LLVM_DIR}/lib/Analysis/NoAliasAnalysis.cpp
 230     ${LLVM_DIR}/lib/Analysis/PHITransAddr.cpp
 231     ${LLVM_DIR}/lib/Analysis/PathNumbering.cpp
 232     ${LLVM_DIR}/lib/Analysis/ProfileInfo.cpp
 233     ${LLVM_DIR}/lib/Analysis/ScalarEvolution.cpp
 234     ${LLVM_DIR}/lib/Analysis/ScalarEvolutionExpander.cpp
 235     ${LLVM_DIR}/lib/Analysis/ScalarEvolutionNormalization.cpp
 236     ${LLVM_DIR}/lib/Analysis/TypeBasedAliasAnalysis.cpp
 237     ${LLVM_DIR}/lib/Analysis/ValueTracking.cpp
 238     ${LLVM_DIR}/lib/CodeGen/AggressiveAntiDepBreaker.cpp
 239     ${LLVM_DIR}/lib/CodeGen/AllocationOrder.cpp
 240     ${LLVM_DIR}/lib/CodeGen/Analysis.cpp
 241     ${LLVM_DIR}/lib/CodeGen/BranchFolding.cpp
 242     ${LLVM_DIR}/lib/CodeGen/CalcSpillWeights.cpp
 243     ${LLVM_DIR}/lib/CodeGen/CallingConvLower.cpp
 244     ${LLVM_DIR}/lib/CodeGen/CodePlacementOpt.cpp
 245     ${LLVM_DIR}/lib/CodeGen/CriticalAntiDepBreaker.cpp
 246     ${LLVM_DIR}/lib/CodeGen/DeadMachineInstructionElim.cpp
 247     ${LLVM_DIR}/lib/CodeGen/DwarfEHPrepare.cpp
 248     ${LLVM_DIR}/lib/CodeGen/ELFCodeEmitter.cpp
 249     ${LLVM_DIR}/lib/CodeGen/ELFWriter.cpp
 250     ${LLVM_DIR}/lib/CodeGen/EdgeBundles.cpp
 251     ${LLVM_DIR}/lib/CodeGen/ExecutionDepsFix.cpp
 252     ${LLVM_DIR}/lib/CodeGen/ExpandISelPseudos.cpp
 253     ${LLVM_DIR}/lib/CodeGen/ExpandPostRAPseudos.cpp
 254     ${LLVM_DIR}/lib/CodeGen/GCMetadata.cpp
 255     ${LLVM_DIR}/lib/CodeGen/GCStrategy.cpp
 256     ${LLVM_DIR}/lib/CodeGen/InlineSpiller.cpp
 257     ${LLVM_DIR}/lib/CodeGen/InterferenceCache.cpp
 258     ${LLVM_DIR}/lib/CodeGen/IntrinsicLowering.cpp
 259     ${LLVM_DIR}/lib/CodeGen/LLVMTargetMachine.cpp
 260     ${LLVM_DIR}/lib/CodeGen/LatencyPriorityQueue.cpp
 261     ${LLVM_DIR}/lib/CodeGen/LexicalScopes.cpp
 262     ${LLVM_DIR}/lib/CodeGen/LiveDebugVariables.cpp
 263     ${LLVM_DIR}/lib/CodeGen/LiveInterval.cpp
 264     ${LLVM_DIR}/lib/CodeGen/LiveIntervalAnalysis.cpp
 265     ${LLVM_DIR}/lib/CodeGen/LiveIntervalUnion.cpp
 266     ${LLVM_DIR}/lib/CodeGen/LiveRangeCalc.cpp
 267     ${LLVM_DIR}/lib/CodeGen/LiveRangeEdit.cpp
 268     ${LLVM_DIR}/lib/CodeGen/LiveStackAnalysis.cpp
 269     ${LLVM_DIR}/lib/CodeGen/LiveVariables.cpp
 270     ${LLVM_DIR}/lib/CodeGen/LocalStackSlotAllocation.cpp
 271     ${LLVM_DIR}/lib/CodeGen/MachineBasicBlock.cpp
 272     ${LLVM_DIR}/lib/CodeGen/MachineCSE.cpp
 273     ${LLVM_DIR}/lib/CodeGen/MachineDominators.cpp
 274     ${LLVM_DIR}/lib/CodeGen/MachineFunction.cpp
 275     ${LLVM_DIR}/lib/CodeGen/MachineFunctionAnalysis.cpp
 276     ${LLVM_DIR}/lib/CodeGen/MachineFunctionPass.cpp
 277     ${LLVM_DIR}/lib/CodeGen/MachineFunctionPrinterPass.cpp
 278     ${LLVM_DIR}/lib/CodeGen/MachineInstr.cpp
 279     ${LLVM_DIR}/lib/CodeGen/MachineLICM.cpp
 280     ${LLVM_DIR}/lib/CodeGen/MachineLoopInfo.cpp
 281     ${LLVM_DIR}/lib/CodeGen/MachineModuleInfo.cpp
 282     ${LLVM_DIR}/lib/CodeGen/MachineModuleInfoImpls.cpp
 283     ${LLVM_DIR}/lib/CodeGen/MachinePassRegistry.cpp
 284     ${LLVM_DIR}/lib/CodeGen/MachineRegisterInfo.cpp
 285     ${LLVM_DIR}/lib/CodeGen/MachineSSAUpdater.cpp
 286     ${LLVM_DIR}/lib/CodeGen/MachineSink.cpp
 287     ${LLVM_DIR}/lib/CodeGen/MachineVerifier.cpp
 288     ${LLVM_DIR}/lib/CodeGen/ObjectCodeEmitter.cpp
 289     ${LLVM_DIR}/lib/CodeGen/OptimizePHIs.cpp
 290     ${LLVM_DIR}/lib/CodeGen/PHIElimination.cpp
 291     ${LLVM_DIR}/lib/CodeGen/PHIEliminationUtils.cpp
 292     ${LLVM_DIR}/lib/CodeGen/Passes.cpp
 293     ${LLVM_DIR}/lib/CodeGen/PeepholeOptimizer.cpp
 294     ${LLVM_DIR}/lib/CodeGen/PostRASchedulerList.cpp
 295     ${LLVM_DIR}/lib/CodeGen/ProcessImplicitDefs.cpp
 296     ${LLVM_DIR}/lib/CodeGen/PrologEpilogInserter.cpp
 297     ${LLVM_DIR}/lib/CodeGen/PseudoSourceValue.cpp
 298     ${LLVM_DIR}/lib/CodeGen/RegAllocBasic.cpp
 299     ${LLVM_DIR}/lib/CodeGen/RegAllocFast.cpp
 300     ${LLVM_DIR}/lib/CodeGen/RegAllocGreedy.cpp
 301     ${LLVM_DIR}/lib/CodeGen/RegAllocLinearScan.cpp
 302     ${LLVM_DIR}/lib/CodeGen/RegisterClassInfo.cpp
 303     ${LLVM_DIR}/lib/CodeGen/RegisterCoalescer.cpp
 304     ${LLVM_DIR}/lib/CodeGen/RegisterScavenging.cpp
 305     ${LLVM_DIR}/lib/CodeGen/RenderMachineFunction.cpp
 306     ${LLVM_DIR}/lib/CodeGen/ScheduleDAG.cpp
 307     ${LLVM_DIR}/lib/CodeGen/ScheduleDAGEmit.cpp
 308     ${LLVM_DIR}/lib/CodeGen/ScheduleDAGInstrs.cpp
 309     ${LLVM_DIR}/lib/CodeGen/ScheduleDAGPrinter.cpp
 310     ${LLVM_DIR}/lib/CodeGen/ScoreboardHazardRecognizer.cpp
 311     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/DAGCombiner.cpp
 312     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/FastISel.cpp
 313     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/FunctionLoweringInfo.cpp
 314     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/InstrEmitter.cpp
 315     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeDAG.cpp
 316     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeFloatTypes.cpp
 317     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeIntegerTypes.cpp
 318     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeTypes.cpp
 319     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeTypesGeneric.cpp
 320     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeVectorOps.cpp
 321     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/LegalizeVectorTypes.cpp
 322     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGFast.cpp
 323     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGList.cpp
 324     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGRRList.cpp
 325     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/ScheduleDAGSDNodes.cpp
 326     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAG.cpp
 327     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAGBuilder.cpp
 328     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAGISel.cpp
 329     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/SelectionDAGPrinter.cpp
 330     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/TargetLowering.cpp
 331     ${LLVM_DIR}/lib/CodeGen/SelectionDAG/TargetSelectionDAGInfo.cpp
 332     ${LLVM_DIR}/lib/CodeGen/ShrinkWrapping.cpp
 333     ${LLVM_DIR}/lib/CodeGen/SjLjEHPrepare.cpp
 334     ${LLVM_DIR}/lib/CodeGen/SlotIndexes.cpp
 335     ${LLVM_DIR}/lib/CodeGen/SpillPlacement.cpp
 336     ${LLVM_DIR}/lib/CodeGen/Spiller.cpp
 337     ${LLVM_DIR}/lib/CodeGen/SplitKit.cpp
 338     ${LLVM_DIR}/lib/CodeGen/StackProtector.cpp
 339     ${LLVM_DIR}/lib/CodeGen/StackSlotColoring.cpp
 340     ${LLVM_DIR}/lib/CodeGen/StrongPHIElimination.cpp
 341     ${LLVM_DIR}/lib/CodeGen/TailDuplication.cpp
 342     ${LLVM_DIR}/lib/CodeGen/TargetInstrInfoImpl.cpp
 343     ${LLVM_DIR}/lib/CodeGen/TargetLoweringObjectFileImpl.cpp
 344     ${LLVM_DIR}/lib/CodeGen/TwoAddressInstructionPass.cpp
 345     ${LLVM_DIR}/lib/CodeGen/UnreachableBlockElim.cpp
 346     ${LLVM_DIR}/lib/CodeGen/VirtRegMap.cpp
 347     ${LLVM_DIR}/lib/CodeGen/VirtRegRewriter.cpp
 348     ${LLVM_DIR}/lib/ExecutionEngine/ExecutionEngine.cpp
 349     ${LLVM_DIR}/lib/ExecutionEngine/JIT/Intercept.cpp
 350     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JIT.cpp
 351     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITDebugRegisterer.cpp
 352     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITDwarfEmitter.cpp
 353     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITEmitter.cpp
 354     ${LLVM_DIR}/lib/ExecutionEngine/JIT/JITMemoryManager.cpp
 355     ${LLVM_DIR}/lib/ExecutionEngine/JIT/OProfileJITEventListener.cpp
 356     ${LLVM_DIR}/lib/ExecutionEngine/TargetSelect.cpp
 357     ${LLVM_DIR}/lib/MC/ELFObjectWriter.cpp
 358     ${LLVM_DIR}/lib/MC/MCAsmBackend.cpp
 359     ${LLVM_DIR}/lib/MC/MCAsmInfo.cpp
 360     ${LLVM_DIR}/lib/MC/MCAsmInfoCOFF.cpp
 361     ${LLVM_DIR}/lib/MC/MCAsmInfoDarwin.cpp
 362     ${LLVM_DIR}/lib/MC/MCAsmStreamer.cpp
 363     ${LLVM_DIR}/lib/MC/MCAssembler.cpp
 364     ${LLVM_DIR}/lib/MC/MCCodeEmitter.cpp
 365     ${LLVM_DIR}/lib/MC/MCCodeGenInfo.cpp
 366     ${LLVM_DIR}/lib/MC/MCContext.cpp
 367     ${LLVM_DIR}/lib/MC/MCDwarf.cpp
 368     ${LLVM_DIR}/lib/MC/MCELF.cpp
 369     ${LLVM_DIR}/lib/MC/MCELFObjectTargetWriter.cpp
 370     ${LLVM_DIR}/lib/MC/MCELFStreamer.cpp
 371     ${LLVM_DIR}/lib/MC/MCExpr.cpp
 372     ${LLVM_DIR}/lib/MC/MCInst.cpp
 373     ${LLVM_DIR}/lib/MC/MCInstPrinter.cpp
 374     ${LLVM_DIR}/lib/MC/MCInstrAnalysis.cpp
 375     ${LLVM_DIR}/lib/MC/MCLoggingStreamer.cpp
 376     ${LLVM_DIR}/lib/MC/MCMachOStreamer.cpp
 377     ${LLVM_DIR}/lib/MC/MCMachObjectTargetWriter.cpp
 378     ${LLVM_DIR}/lib/MC/MCNullStreamer.cpp
 379     ${LLVM_DIR}/lib/MC/MCObjectFileInfo.cpp
 380     ${LLVM_DIR}/lib/MC/MCObjectStreamer.cpp
 381     ${LLVM_DIR}/lib/MC/MCObjectWriter.cpp
 382     ${LLVM_DIR}/lib/MC/MCSection.cpp
 383     ${LLVM_DIR}/lib/MC/MCSectionCOFF.cpp
 384     ${LLVM_DIR}/lib/MC/MCSectionELF.cpp
 385     ${LLVM_DIR}/lib/MC/MCSectionMachO.cpp
 386     ${LLVM_DIR}/lib/MC/MCStreamer.cpp
 387     ${LLVM_DIR}/lib/MC/MCSubtargetInfo.cpp
 388     ${LLVM_DIR}/lib/MC/MCSymbol.cpp
 389     ${LLVM_DIR}/lib/MC/MCWin64EH.cpp
 390     ${LLVM_DIR}/lib/MC/MachObjectWriter.cpp
 391     ${LLVM_DIR}/lib/MC/SubtargetFeature.cpp
 392     ${LLVM_DIR}/lib/MC/WinCOFFObjectWriter.cpp
 393     ${LLVM_DIR}/lib/MC/WinCOFFStreamer.cpp
 394     ${LLVM_DIR}/lib/Support/APFloat.cpp
 395     ${LLVM_DIR}/lib/Support/APInt.cpp
 396     ${LLVM_DIR}/lib/Support/Allocator.cpp
 397     ${LLVM_DIR}/lib/Support/Atomic.cpp
 398     ${LLVM_DIR}/lib/Support/BlockFrequency.cpp
 399     ${LLVM_DIR}/lib/Support/BranchProbability.cpp
 400     ${LLVM_DIR}/lib/Support/CommandLine.cpp
 401     ${LLVM_DIR}/lib/Support/ConstantRange.cpp
 402     ${LLVM_DIR}/lib/Support/CrashRecoveryContext.cpp
 403     ${LLVM_DIR}/lib/Support/DAGDeltaAlgorithm.cpp
 404     ${LLVM_DIR}/lib/Support/DataExtractor.cpp
 405     ${LLVM_DIR}/lib/Support/Debug.cpp
 406     ${LLVM_DIR}/lib/Support/DeltaAlgorithm.cpp
 407     ${LLVM_DIR}/lib/Support/Disassembler.cpp
 408     ${LLVM_DIR}/lib/Support/Dwarf.cpp
 409     ${LLVM_DIR}/lib/Support/DynamicLibrary.cpp
 410     ${LLVM_DIR}/lib/Support/Errno.cpp
 411     ${LLVM_DIR}/lib/Support/ErrorHandling.cpp
 412     ${LLVM_DIR}/lib/Support/FileUtilities.cpp
 413     ${LLVM_DIR}/lib/Support/FoldingSet.cpp
 414     ${LLVM_DIR}/lib/Support/FormattedStream.cpp
 415     ${LLVM_DIR}/lib/Support/GraphWriter.cpp
 416     ${LLVM_DIR}/lib/Support/Host.cpp
 417     ${LLVM_DIR}/lib/Support/IncludeFile.cpp
 418     ${LLVM_DIR}/lib/Support/IntEqClasses.cpp
 419     ${LLVM_DIR}/lib/Support/IntervalMap.cpp
 420     ${LLVM_DIR}/lib/Support/IsInf.cpp
 421     ${LLVM_DIR}/lib/Support/IsNAN.cpp
 422     ${LLVM_DIR}/lib/Support/ManagedStatic.cpp
 423     ${LLVM_DIR}/lib/Support/Memory.cpp
 424     ${LLVM_DIR}/lib/Support/MemoryBuffer.cpp
 425     ${LLVM_DIR}/lib/Support/MemoryObject.cpp
 426     ${LLVM_DIR}/lib/Support/Mutex.cpp
 427     ${LLVM_DIR}/lib/Support/Path.cpp
 428     ${LLVM_DIR}/lib/Support/PathV2.cpp
 429     ${LLVM_DIR}/lib/Support/PrettyStackTrace.cpp
 430     ${LLVM_DIR}/lib/Support/Process.cpp
 431     ${LLVM_DIR}/lib/Support/Program.cpp
 432     ${LLVM_DIR}/lib/Support/RWMutex.cpp
 433     ${LLVM_DIR}/lib/Support/SearchForAddressOfSpecialSymbol.cpp
 434     ${LLVM_DIR}/lib/Support/Signals.cpp
 435     ${LLVM_DIR}/lib/Support/SmallPtrSet.cpp
 436     ${LLVM_DIR}/lib/Support/SmallVector.cpp
 437     ${LLVM_DIR}/lib/Support/SourceMgr.cpp
 438     ${LLVM_DIR}/lib/Support/Statistic.cpp
 439     ${LLVM_DIR}/lib/Support/StringExtras.cpp
 440     ${LLVM_DIR}/lib/Support/StringMap.cpp
 441     ${LLVM_DIR}/lib/Support/StringPool.cpp
 442     ${LLVM_DIR}/lib/Support/StringRef.cpp
 443     ${LLVM_DIR}/lib/Support/SystemUtils.cpp
 444     ${LLVM_DIR}/lib/Support/TargetRegistry.cpp
 445     ${LLVM_DIR}/lib/Support/ThreadLocal.cpp
 446     ${LLVM_DIR}/lib/Support/Threading.cpp
 447     ${LLVM_DIR}/lib/Support/TimeValue.cpp
 448     ${LLVM_DIR}/lib/Support/Timer.cpp
 449     ${LLVM_DIR}/lib/Support/ToolOutputFile.cpp
 450     ${LLVM_DIR}/lib/Support/Triple.cpp
 451     ${LLVM_DIR}/lib/Support/Twine.cpp
 452     ${LLVM_DIR}/lib/Support/Valgrind.cpp
 453     ${LLVM_DIR}/lib/Support/circular_raw_ostream.cpp
 454     ${LLVM_DIR}/lib/Support/raw_os_ostream.cpp
 455     ${LLVM_DIR}/lib/Support/raw_ostream.cpp
 456     ${LLVM_DIR}/lib/Support/system_error.cpp
 457     ${LLVM_DIR}/lib/Target/Mangler.cpp
 458     ${LLVM_DIR}/lib/Target/TargetData.cpp
 459     ${LLVM_DIR}/lib/Target/TargetELFWriterInfo.cpp
 460     ${LLVM_DIR}/lib/Target/TargetFrameLowering.cpp
 461     ${LLVM_DIR}/lib/Target/TargetInstrInfo.cpp
 462     ${LLVM_DIR}/lib/Target/TargetLibraryInfo.cpp
 463     ${LLVM_DIR}/lib/Target/TargetLoweringObjectFile.cpp
 464     ${LLVM_DIR}/lib/Target/TargetMachine.cpp
 465     ${LLVM_DIR}/lib/Target/TargetRegisterInfo.cpp
 466     ${LLVM_DIR}/lib/Target/TargetSubtargetInfo.cpp
 467     ${LLVM_DIR}/lib/Target/X86/InstPrinter/X86ATTInstPrinter.cpp
 468     ${LLVM_DIR}/lib/Target/X86/InstPrinter/X86InstComments.cpp
 469     ${LLVM_DIR}/lib/Target/X86/InstPrinter/X86IntelInstPrinter.cpp
 470     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86AsmBackend.cpp
 471     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MCAsmInfo.cpp
 472     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MCCodeEmitter.cpp
 473     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MCTargetDesc.cpp
 474     ${LLVM_DIR}/lib/Target/X86/MCTargetDesc/X86MachObjectWriter.cpp
 475     ${LLVM_DIR}/lib/Target/X86/TargetInfo/X86TargetInfo.cpp
 476     ${LLVM_DIR}/lib/Target/X86/Utils/X86ShuffleDecode.cpp
 477     ${LLVM_DIR}/lib/Target/X86/X86CodeEmitter.cpp
 478     ${LLVM_DIR}/lib/Target/X86/X86ELFWriterInfo.cpp
 479     ${LLVM_DIR}/lib/Target/X86/X86FastISel.cpp
 480     ${LLVM_DIR}/lib/Target/X86/X86FloatingPoint.cpp
 481     ${LLVM_DIR}/lib/Target/X86/X86FrameLowering.cpp
 482     ${LLVM_DIR}/lib/Target/X86/X86ISelDAGToDAG.cpp
 483     ${LLVM_DIR}/lib/Target/X86/X86ISelLowering.cpp
 484     ${LLVM_DIR}/lib/Target/X86/X86InstrInfo.cpp
 485     ${LLVM_DIR}/lib/Target/X86/X86JITInfo.cpp
 486     ${LLVM_DIR}/lib/Target/X86/X86RegisterInfo.cpp
 487     ${LLVM_DIR}/lib/Target/X86/X86SelectionDAGInfo.cpp
 488     ${LLVM_DIR}/lib/Target/X86/X86Subtarget.cpp
 489     ${LLVM_DIR}/lib/Target/X86/X86TargetMachine.cpp
 490     ${LLVM_DIR}/lib/Target/X86/X86TargetObjectFile.cpp
 491     ${LLVM_DIR}/lib/Target/X86/X86VZeroUpper.cpp
 492     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineAddSub.cpp
 493     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineAndOrXor.cpp
 494     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineCalls.cpp
 495     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineCasts.cpp
 496     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineCompares.cpp
 497     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineLoadStoreAlloca.cpp
 498     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineMulDivRem.cpp
 499     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombinePHI.cpp
 500     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineSelect.cpp
 501     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineShifts.cpp
 502     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineSimplifyDemanded.cpp
 503     ${LLVM_DIR}/lib/Transforms/InstCombine/InstCombineVectorOps.cpp
 504     ${LLVM_DIR}/lib/Transforms/InstCombine/InstructionCombining.cpp
 505     ${LLVM_DIR}/lib/Transforms/Scalar/ADCE.cpp
 506     ${LLVM_DIR}/lib/Transforms/Scalar/CodeGenPrepare.cpp
 507     ${LLVM_DIR}/lib/Transforms/Scalar/DeadStoreElimination.cpp
 508     ${LLVM_DIR}/lib/Transforms/Scalar/GVN.cpp
 509     ${LLVM_DIR}/lib/Transforms/Scalar/LICM.cpp
 510     ${LLVM_DIR}/lib/Transforms/Scalar/LoopStrengthReduce.cpp
 511     ${LLVM_DIR}/lib/Transforms/Scalar/Reassociate.cpp
 512     ${LLVM_DIR}/lib/Transforms/Scalar/Reg2Mem.cpp
 513     ${LLVM_DIR}/lib/Transforms/Scalar/SCCP.cpp
 514     ${LLVM_DIR}/lib/Transforms/Scalar/ScalarReplAggregates.cpp
 515     ${LLVM_DIR}/lib/Transforms/Scalar/SimplifyCFGPass.cpp
 516     ${LLVM_DIR}/lib/Transforms/Utils/AddrModeMatcher.cpp
 517     ${LLVM_DIR}/lib/Transforms/Utils/BasicBlockUtils.cpp
 518     ${LLVM_DIR}/lib/Transforms/Utils/BreakCriticalEdges.cpp
 519     ${LLVM_DIR}/lib/Transforms/Utils/BuildLibCalls.cpp
 520     ${LLVM_DIR}/lib/Transforms/Utils/DemoteRegToStack.cpp
 521     ${LLVM_DIR}/lib/Transforms/Utils/InstructionNamer.cpp
 522     ${LLVM_DIR}/lib/Transforms/Utils/LCSSA.cpp
 523     ${LLVM_DIR}/lib/Transforms/Utils/Local.cpp
 524     ${LLVM_DIR}/lib/Transforms/Utils/LoopSimplify.cpp
 525     ${LLVM_DIR}/lib/Transforms/Utils/LowerInvoke.cpp
 526     ${LLVM_DIR}/lib/Transforms/Utils/LowerSwitch.cpp
 527     ${LLVM_DIR}/lib/Transforms/Utils/PromoteMemoryToRegister.cpp
 528     ${LLVM_DIR}/lib/Transforms/Utils/SSAUpdater.cpp
 529     ${LLVM_DIR}/lib/Transforms/Utils/SimplifyCFG.cpp
 530     ${LLVM_DIR}/lib/Transforms/Utils/UnifyFunctionExitNodes.cpp
 531     ${LLVM_DIR}/lib/VMCore/AsmWriter.cpp
 532     ${LLVM_DIR}/lib/VMCore/Attributes.cpp
 533     ${LLVM_DIR}/lib/VMCore/BasicBlock.cpp
 534     ${LLVM_DIR}/lib/VMCore/ConstantFold.cpp
 535     ${LLVM_DIR}/lib/VMCore/Constants.cpp
 536     ${LLVM_DIR}/lib/VMCore/DebugInfoProbe.cpp
 537     ${LLVM_DIR}/lib/VMCore/DebugLoc.cpp
 538     ${LLVM_DIR}/lib/VMCore/Dominators.cpp
 539     ${LLVM_DIR}/lib/VMCore/Function.cpp
 540     ${LLVM_DIR}/lib/VMCore/Globals.cpp
 541     ${LLVM_DIR}/lib/VMCore/IRBuilder.cpp
 542     ${LLVM_DIR}/lib/VMCore/InlineAsm.cpp
 543     ${LLVM_DIR}/lib/VMCore/Instruction.cpp
 544     ${LLVM_DIR}/lib/VMCore/Instructions.cpp
 545     ${LLVM_DIR}/lib/VMCore/IntrinsicInst.cpp
 546     ${LLVM_DIR}/lib/VMCore/LLVMContext.cpp
 547     ${LLVM_DIR}/lib/VMCore/LLVMContextImpl.cpp
 548     ${LLVM_DIR}/lib/VMCore/LeakDetector.cpp
 549     ${LLVM_DIR}/lib/VMCore/Metadata.cpp
 550     ${LLVM_DIR}/lib/VMCore/Module.cpp
 551     ${LLVM_DIR}/lib/VMCore/Pass.cpp
 552     ${LLVM_DIR}/lib/VMCore/PassManager.cpp
 553     ${LLVM_DIR}/lib/VMCore/PassRegistry.cpp
 554     ${LLVM_DIR}/lib/VMCore/PrintModulePass.cpp
 555     ${LLVM_DIR}/lib/VMCore/Type.cpp
 556     ${LLVM_DIR}/lib/VMCore/Use.cpp
 557     ${LLVM_DIR}/lib/VMCore/User.cpp
 558     ${LLVM_DIR}/lib/VMCore/Value.cpp
 559     ${LLVM_DIR}/lib/VMCore/ValueSymbolTable.cpp
 560     ${LLVM_DIR}/lib/VMCore/ValueTypes.cpp
 561     ${LLVM_DIR}/lib/VMCore/Verifier.cpp
 562 )
 563
 564 if(WIN32)
 565     set(LLVM_INCLUDE_DIR ${LLVM_DIR}/include)
 566 elseif(LINUX)
 567     set(LLVM_INCLUDE_DIR ${LLVM_DIR}/include-linux)
 568 elseif(APPLE)
 569     set(LLVM_INCLUDE_DIR ${LLVM_DIR}/include-osx)
 570 endif()
 571
 572 list(APPEND LLVM_INCLUDE_DIR
 573     ${LLVM_DIR}/include
 574     ${LLVM_DIR}/lib/Target/X86
 575 )
 576 add_library(llvm STATIC ${LLVM_LIST})
 577 set_target_properties(llvm PROPERTIES
 578     POSITION_INDEPENDENT_CODE 1
 579     INCLUDE_DIRECTORIES "${LLVM_INCLUDE_DIR}"
 580     COMPILE_DEFINITIONS "__STDC_CONSTANT_MACROS; __STDC_LIMIT_MACROS;"
 581     FOLDER "LLVM"
 582 )
 583
 584 ###########################################################
 585 # Subzero
 586 ###########################################################
 587
 588 if(${REACTOR_BACKEND} STREQUAL "Subzero")
 589     set(SUBZERO_LIST
 590         ${SUBZERO_DIR}/src/IceAssembler.cpp
 591         ${SUBZERO_DIR}/src/IceCfg.cpp
 592         ${SUBZERO_DIR}/src/IceCfgNode.cpp
 593         ${SUBZERO_DIR}/src/IceClFlags.cpp
 594         ${SUBZERO_DIR}/src/IceELFObjectWriter.cpp
 595         ${SUBZERO_DIR}/src/IceELFSection.cpp
 596         ${SUBZERO_DIR}/src/IceFixups.cpp
 597         ${SUBZERO_DIR}/src/IceGlobalContext.cpp
 598         ${SUBZERO_DIR}/src/IceGlobalInits.cpp
 599         ${SUBZERO_DIR}/src/IceInst.cpp
 600         ${SUBZERO_DIR}/src/IceInstrumentation.cpp
 601         ${SUBZERO_DIR}/src/IceIntrinsics.cpp
 602         ${SUBZERO_DIR}/src/IceLiveness.cpp
 603         ${SUBZERO_DIR}/src/IceLoopAnalyzer.cpp
 604         ${SUBZERO_DIR}/src/IceMangling.cpp
 605         ${SUBZERO_DIR}/src/IceMemory.cpp
 606         ${SUBZERO_DIR}/src/IceOperand.cpp
 607         ${SUBZERO_DIR}/src/IceRangeSpec.cpp
 608         ${SUBZERO_DIR}/src/IceRegAlloc.cpp
 609         ${SUBZERO_DIR}/src/IceRevision.cpp
 610         ${SUBZERO_DIR}/src/IceRNG.cpp
 611         ${SUBZERO_DIR}/src/IceSwitchLowering.cpp
 612         ${SUBZERO_DIR}/src/IceTargetLowering.cpp
 613         ${SUBZERO_DIR}/src/IceThreading.cpp
 614         ${SUBZERO_DIR}/src/IceTimerTree.cpp
 615         ${SUBZERO_DIR}/src/IceTypes.cpp
 616         ${SUBZERO_DIR}/src/IceVariableSplitting.cpp
 617     )
 618
 619     if(ARCH STREQUAL "x86_64")
 620         list(APPEND SUBZERO_LIST
 621             ${SUBZERO_DIR}/src/IceTargetLoweringX86.cpp
 622             ${SUBZERO_DIR}/src/IceInstX8664.cpp
 623             ${SUBZERO_DIR}/src/IceTargetLoweringX8664.cpp
 624         )
 625         set(SUBZERO_TARGET X8664)
 626     elseif(ARCH STREQUAL "x86")
 627         list(APPEND SUBZERO_LIST
 628             ${SUBZERO_DIR}/src/IceTargetLoweringX86.cpp
 629             ${SUBZERO_DIR}/src/IceInstX8632.cpp
 630             ${SUBZERO_DIR}/src/IceTargetLoweringX8632.cpp
 631         )
 632         set(SUBZERO_TARGET X8632)
 633     elseif(ARCH STREQUAL "arm")
 634         list(APPEND SUBZERO_LIST
 635             ${SUBZERO_DIR}/src/IceAssemblerARM32.cpp
 636             ${SUBZERO_DIR}/src/IceInstARM32.cpp
 637             ${SUBZERO_DIR}/src/IceTargetLoweringARM32.cpp
 638         )
 639         set(SUBZERO_TARGET ARM32)
 640     else()
 641         message(FATAL_ERROR "Architecture '${ARCH}' not supported by Subzero")
 642     endif()
 643
 644     file(GLOB_RECURSE SUBZERO_DEPENDENCIES_LIST
 645         ${SUBZERO_LLVM_DIR}/*.cpp
 646         ${SUBZERO_LLVM_DIR}/*.c
 647         ${SUBZERO_LLVM_DIR}/*.h
 648     )
 649
 650     set(SUBZERO_REACTOR_LIST
 651         ${SOURCE_DIR}/Reactor/SubzeroReactor.cpp
 652         ${SOURCE_DIR}/Reactor/Routine.cpp
 653         ${SOURCE_DIR}/Reactor/Optimizer.cpp
 654         ${SOURCE_DIR}/Reactor/Nucleus.hpp
 655         ${SOURCE_DIR}/Reactor/Routine.hpp
 656     )
 657
 658     set(SUBZERO_INCLUDE_DIR
 659         ${SUBZERO_DIR}/
 660         ${SUBZERO_LLVM_DIR}/include/
 661         ${SUBZERO_DIR}/pnacl-llvm/include/
 662      )
 663
 664     if(WIN32)
 665         list(APPEND SUBZERO_INCLUDE_DIR ${SUBZERO_LLVM_DIR}/build/Windows/include/)
 666     elseif(LINUX)
 667         list(APPEND SUBZERO_INCLUDE_DIR ${SUBZERO_LLVM_DIR}/build/Linux/include/)
 668     elseif(APPLE)
 669         list(APPEND SUBZERO_INCLUDE_DIR ${SUBZERO_LLVM_DIR}/build/MacOS/include/)
 670     endif()
 671
 672     add_library(ReactorSubzero STATIC
 673         ${SUBZERO_LIST}
 674         ${SUBZERO_DEPENDENCIES_LIST}
 675         ${SUBZERO_REACTOR_LIST}
 676     )
 677
 678     set_target_properties(ReactorSubzero PROPERTIES
 679         POSITION_INDEPENDENT_CODE 1
 680         INCLUDE_DIRECTORIES "${SUBZERO_INCLUDE_DIR}"
 681         COMPILE_DEFINITIONS "SZTARGET=${SUBZERO_TARGET}; ALLOW_DUMP=0; ALLOW_TIMERS=0; ALLOW_LLVM_CL=0; ALLOW_LLVM_IR=0; ALLOW_LLVM_IR_AS_INPUT=0; ALLOW_MINIMAL_BUILD=0; ALLOW_WASM=0; ICE_THREAD_LOCAL_HACK=0;"
 682         FOLDER "Subzero"
 683     )
 684
 685     if(WIN32)
 686         target_compile_definitions(ReactorSubzero PRIVATE SUBZERO_USE_MICROSOFT_ABI)
 687     endif()
 688 endif()
 689
 690 ###########################################################
 691 # Include Directories
 692 ###########################################################
 693
 694 set(COMMON_INCLUDE_DIR
 695     ${SOURCE_DIR}
 696     ${CMAKE_SOURCE_DIR}/include
 697     ${LLVM_INCLUDE_DIR}
 698 )
 699 set(OPENGL_INCLUDE_DIR
 700     ${OPENGL_DIR}
 701     ${COMMON_INCLUDE_DIR}
 702 )
 703
 704 ###########################################################
 705 # File Lists
 706 ###########################################################
 707
 708 file(GLOB_RECURSE SWIFTSHADER_LIST
 709     ${SOURCE_DIR}/Common/*.cpp
 710     ${SOURCE_DIR}/Common/*.h
 711     ${SOURCE_DIR}/Common/*.hpp
 712     ${SOURCE_DIR}/Renderer/*.cpp
 713     ${SOURCE_DIR}/Renderer/*.h
 714     ${SOURCE_DIR}/Renderer/*.hpp
 715     ${SOURCE_DIR}/Shader/*.cpp
 716     ${SOURCE_DIR}/Shader/*.h
 717     ${SOURCE_DIR}/Shader/*.hpp
 718 )
 719 list(APPEND SWIFTSHADER_LIST
 720     ${SOURCE_DIR}/Main/Config.cpp
 721     ${SOURCE_DIR}/Main/Config.hpp
 722     ${SOURCE_DIR}/Main/FrameBuffer.cpp
 723     ${SOURCE_DIR}/Main/FrameBuffer.hpp
 724     ${SOURCE_DIR}/Main/SwiftConfig.cpp
 725     ${SOURCE_DIR}/Main/SwiftConfig.hpp
 726 )
 727 list(REMOVE_ITEM SWIFTSHADER_LIST
 728     ${SOURCE_DIR}/Common/DebugAndroid.cpp
 729     ${SOURCE_DIR}/Common/DebugAndroid.hpp
 730     ${SOURCE_DIR}/Common/GrallocAndroid.cpp
 731     ${SOURCE_DIR}/Common/GrallocAndroid.hpp
 732 )
 733
 734 set(REACTOR_LLVM_LIST
 735     ${SOURCE_DIR}/Reactor/LLVMReactor.cpp
 736     ${SOURCE_DIR}/Reactor/Nucleus.hpp
 737     ${SOURCE_DIR}/Reactor/Routine.cpp
 738     ${SOURCE_DIR}/Reactor/Routine.hpp
 739     ${SOURCE_DIR}/Reactor/LLVMRoutine.cpp
 740     ${SOURCE_DIR}/Reactor/LLVMRoutine.hpp
 741     ${SOURCE_DIR}/Reactor/LLVMRoutineManager.cpp
 742     ${SOURCE_DIR}/Reactor/LLVMRoutineManager.hpp
 743 )
 744
 745 file(GLOB_RECURSE EGL_LIST
 746     ${OPENGL_DIR}/libEGL/*.cpp
 747     ${OPENGL_DIR}/libEGL/*.h
 748     ${OPENGL_DIR}/libEGL/*.hpp
 749     ${OPENGL_DIR}/common/Object.cpp
 750     ${OPENGL_DIR}/common/Object.hpp
 751     ${OPENGL_DIR}/common/debug.cpp
 752     ${OPENGL_DIR}/common/debug.h
 753     ${CMAKE_SOURCE_DIR}/include/*.h
 754 )
 755
 756 file(GLOB_RECURSE GL32_LIST
 757     ${OPENGL_DIR}/libGL/*.cpp
 758     ${OPENGL_DIR}/libGL/*.h
 759     ${OPENGL_DIR}/libGL/*.hpp
 760     ${OPENGL_DIR}/common/*.cpp
 761     ${OPENGL_DIR}/common/*.h
 762     ${OPENGL_DIR}/common/*.hpp
 763     ${CMAKE_SOURCE_DIR}/include/GL/*.h
 764 )
 765
 766 file(GLOB_RECURSE GLES2_LIST
 767     ${OPENGL_DIR}/libGLESv2/*.cpp
 768     ${OPENGL_DIR}/libGLESv2/*.h
 769     ${OPENGL_DIR}/libGLESv2/*.hpp
 770     ${OPENGL_DIR}/common/*.cpp
 771     ${OPENGL_DIR}/common/*.h
 772     ${OPENGL_DIR}/common/*.hpp
 773     ${CMAKE_SOURCE_DIR}/include/KHR/*.h
 774     ${CMAKE_SOURCE_DIR}/include/GLES2/*.h
 775     ${CMAKE_SOURCE_DIR}/include/GLES3/*.h
 776 )
 777
 778 file(GLOB_RECURSE GLES_CM_LIST
 779     ${OPENGL_DIR}/libGLES_CM/*.cpp
 780     ${OPENGL_DIR}/libGLES_CM/*.h
 781     ${OPENGL_DIR}/libGLES_CM/*.hpp
 782     ${OPENGL_DIR}/common/*.cpp
 783     ${OPENGL_DIR}/common/*.h
 784     ${OPENGL_DIR}/common/*.hpp
 785     ${CMAKE_SOURCE_DIR}/include/KHR/*.h
 786     ${CMAKE_SOURCE_DIR}/include/GLES/*.h
 787 )
 788
 789 file(GLOB_RECURSE OPENGL_COMPILER_LIST
 790     ${OPENGL_COMPILER_DIR}/*.cpp
 791     ${OPENGL_COMPILER_DIR}/*.h
 792     ${OPENGL_COMPILER_DIR}/*.hpp
 793 )
 794 file(GLOB_RECURSE OPENGL_COMPILER_OS_SPECIFIC_LIST
 795     ${OPENGL_COMPILER_DIR}/ossource*.cpp
 796     ${OPENGL_COMPILER_DIR}/ossource*.h
 797     ${OPENGL_COMPILER_DIR}/ossource*.hpp
 798 )
 799 list(REMOVE_ITEM OPENGL_COMPILER_LIST ${OPENGL_COMPILER_OS_SPECIFIC_LIST})
 800
 801 ###########################################################
 802 # Append OS specific files to lists
 803 ###########################################################
 804
 805 if(WIN32)
 806     list(APPEND SWIFTSHADER_LIST
 807         ${SOURCE_DIR}/Main/FrameBufferDD.cpp
 808         ${SOURCE_DIR}/Main/FrameBufferDD.hpp
 809         ${SOURCE_DIR}/Main/FrameBufferGDI.cpp
 810         ${SOURCE_DIR}/Main/FrameBufferGDI.hpp
 811         ${SOURCE_DIR}/Main/FrameBufferWin.cpp
 812         ${SOURCE_DIR}/Main/FrameBufferWin.hpp
 813     )
 814     list(APPEND OPENGL_COMPILER_LIST ${OPENGL_COMPILER_DIR}/ossource_win.cpp)
 815     list(APPEND EGL_LIST ${OPENGL_DIR}/libEGL/libEGL.rc)
 816     list(APPEND GL32_LIST ${OPENGL_DIR}/libGL/libGL.rc)
 817     list(APPEND GLES2_LIST ${OPENGL_DIR}/libGLESv2/libGLESv2.rc)
 818     list(APPEND GLES_CM_LIST ${OPENGL_DIR}/libGLES_CM/libGLES_CM.rc)
 819 elseif(LINUX)
 820     list(APPEND SWIFTSHADER_LIST
 821         ${SOURCE_DIR}/Main/FrameBufferX11.cpp
 822         ${SOURCE_DIR}/Main/FrameBufferX11.hpp
 823         ${SOURCE_DIR}/Common/SharedLibrary.hpp
 824         ${SOURCE_DIR}/Main/libX11.cpp
 825         ${SOURCE_DIR}/Main/libX11.hpp
 826     )
 827     list(APPEND EGL_LIST
 828         ${SOURCE_DIR}/Common/SharedLibrary.hpp
 829         ${SOURCE_DIR}/Main/libX11.cpp
 830         ${SOURCE_DIR}/Main/libX11.hpp
 831     )
 832     list(APPEND OPENGL_COMPILER_LIST
 833         ${OPENGL_COMPILER_DIR}/ossource_posix.cpp
 834     )
 835 elseif(APPLE)
 836     list(APPEND SWIFTSHADER_LIST
 837         ${SOURCE_DIR}/Main/FrameBufferOSX.mm
 838         ${SOURCE_DIR}/Main/FrameBufferOSX.hpp
 839     )
 840     list(APPEND EGL_LIST
 841         ${OPENGL_DIR}/libEGL/OSXUtils.mm
 842         ${OPENGL_DIR}/libEGL/OSXUtils.hpp
 843     )
 844     list(APPEND OPENGL_COMPILER_LIST
 845         ${OPENGL_COMPILER_DIR}/ossource_posix.cpp
 846     )
 847 endif()
 848
 849 if(WIN32)
 850     set(OS_LIBS odbc32 odbccp32 WS2_32 dxguid)
 851 elseif(LINUX)
 852     set(OS_LIBS dl pthread)
 853 elseif(APPLE)
 854     find_library(COCOA_FRAMEWORK Cocoa)
 855     find_library(QUARTZ_FRAMEWORK Quartz)
 856     set(OS_LIBS "${COCOA_FRAMEWORK}" "${QUARTZ_FRAMEWORK}")
 857 endif()
 858
 859 ###########################################################
 860 # SwiftShader Targets
 861 ###########################################################
 862
 863 add_library(SwiftShader STATIC ${SWIFTSHADER_LIST})
 864 set_target_properties(SwiftShader PROPERTIES
 865     INCLUDE_DIRECTORIES "${COMMON_INCLUDE_DIR}"
 866     POSITION_INDEPENDENT_CODE 1
 867     FOLDER "Core"
 868     COMPILE_DEFINITIONS "NO_SANITIZE_FUNCTION=;"
 869 )
 870 target_link_libraries(SwiftShader ${OS_LIBS})
 871
 872 add_library(ReactorLLVM STATIC ${REACTOR_LLVM_LIST})
 873 set_target_properties(ReactorLLVM PROPERTIES
 874     INCLUDE_DIRECTORIES "${COMMON_INCLUDE_DIR}"
 875     POSITION_INDEPENDENT_CODE 1
 876     FOLDER "Core"
 877 )
 878 target_link_libraries(ReactorLLVM llvm ${OS_LIBS})
 879
 880 if(${REACTOR_BACKEND} STREQUAL "LLVM")
 881     set(Reactor ReactorLLVM)
 882 elseif(${REACTOR_BACKEND} STREQUAL "Subzero")
 883     set(Reactor ReactorSubzero)
 884 else()
 885     message(FATAL_ERROR "REACTOR_BACKEND must be 'LLVM' or 'Subzero'")
 886 endif()
 887
 888 add_library(GLCompiler STATIC ${OPENGL_COMPILER_LIST})
 889 set_target_properties(GLCompiler PROPERTIES
 890     INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 891     POSITION_INDEPENDENT_CODE 1
 892     FOLDER "OpenGL"
 893 )
 894 target_link_libraries(GLCompiler ${OS_LIBS})
 895
 896 if(CMAKE_SIZEOF_VOID_P EQUAL 8)
 897     set(LIB_PREFIX "lib64")
 898 else()
 899     set(LIB_PREFIX "lib")
 900 endif()
 901
 902 if(BUILD_EGL)
 903     add_library(libEGL SHARED ${EGL_LIST})
 904     set_target_properties(libEGL PROPERTIES
 905         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 906         FOLDER "OpenGL"
 907         COMPILE_DEFINITIONS "EGL_EGLEXT_PROTOTYPES; EGLAPI=; NO_SANITIZE_FUNCTION=;"
 908         PREFIX ""
 909     )
 910     set_target_export_map(libEGL ${SOURCE_DIR}/OpenGL/libEGL)
 911     target_link_libraries(libEGL ${OS_LIBS})
 912     add_custom_command(
 913         TARGET libEGL
 914         POST_BUILD
 915         COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:libEGL>/translator
 916         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libEGL> $<TARGET_FILE_DIR:libEGL>/translator/${LIB_PREFIX}EGL_translator${CMAKE_SHARED_LIBRARY_SUFFIX}
 917         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_SOURCE_DIR}/out/${CMAKE_SYSTEM_NAME}/
 918         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libEGL> ${CMAKE_SOURCE_DIR}/out/${CMAKE_SYSTEM_NAME}/
 919     )
 920 endif()
 921
 922 if(BUILD_GL32)
 923     add_library(libGL SHARED ${GL32_LIST})
 924     set_target_properties(libGL PROPERTIES
 925         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 926         FOLDER "OpenGL"
 927         COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
 928         PREFIX ""
 929     )
 930     set_target_export_map(libGL ${SOURCE_DIR}/OpenGL/libGL)
 931     target_link_libraries(libGL SwiftShader ${Reactor} GLCompiler ${OS_LIBS})
 932 endif()
 933
 934 if(BUILD_GLESv2)
 935     add_library(libGLESv2 SHARED ${GLES2_LIST})
 936     set_target_properties(libGLESv2 PROPERTIES
 937         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 938         FOLDER "OpenGL"
 939         COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES; GL_API=; GL_APICALL=; NO_SANITIZE_FUNCTION=;"
 940         PREFIX ""
 941     )
 942     set_target_export_map(libGLESv2 ${SOURCE_DIR}/OpenGL/libGLESv2)
 943     target_link_libraries(libGLESv2 SwiftShader ${Reactor} GLCompiler ${OS_LIBS})
 944     add_custom_command(
 945         TARGET libGLESv2
 946         POST_BUILD
 947         COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:libGLESv2>/translator
 948         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libGLESv2> $<TARGET_FILE_DIR:libGLESv2>/translator/${LIB_PREFIX}GLES_V2_translator${CMAKE_SHARED_LIBRARY_SUFFIX}
 949         COMMAND ${CMAKE_COMMAND} -E make_directory ${CMAKE_SOURCE_DIR}/out/${CMAKE_SYSTEM_NAME}/
 950         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libGLESv2> ${CMAKE_SOURCE_DIR}/out/${CMAKE_SYSTEM_NAME}/
 951     )
 952 endif()
 953
 954 if(BUILD_GLES_CM)
 955     add_library(libGLES_CM SHARED ${GLES_CM_LIST})
 956     set_target_properties(libGLES_CM PROPERTIES
 957         INCLUDE_DIRECTORIES "${OPENGL_INCLUDE_DIR}"
 958         FOLDER "OpenGL"
 959         COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES; EGLAPI=; GL_API=; GL_APICALL=;"
 960         PREFIX ""
 961     )
 962     set_target_export_map(libGLES_CM ${SOURCE_DIR}/OpenGL/libGLES_CM)
 963     target_link_libraries(libGLES_CM SwiftShader ${Reactor} GLCompiler ${OS_LIBS})
 964     add_custom_command(
 965         TARGET libGLES_CM
 966         POST_BUILD
 967         COMMAND ${CMAKE_COMMAND} -E make_directory $<TARGET_FILE_DIR:libGLES_CM>/translator
 968         COMMAND ${CMAKE_COMMAND} -E copy $<TARGET_FILE:libGLES_CM> $<TARGET_FILE_DIR:libGLES_CM>/translator/${LIB_PREFIX}GLES_CM_translator${CMAKE_SHARED_LIBRARY_SUFFIX}
 969     )
 970 endif()
 971
 972 ###########################################################
 973 # Sample programs
 974 ###########################################################
 975
 976 if(BUILD_SAMPLES)
 977     if(WIN32)
 978         add_executable(OGLES2HelloAPI ${HELLO2_DIR}/OGLES2HelloAPI_Windows.cpp)
 979         set_target_properties(OGLES2HelloAPI PROPERTIES
 980             INCLUDE_DIRECTORIES "${CMAKE_SOURCE_DIR}/include"
 981             COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
 982             FOLDER "Samples"
 983         )
 984         target_link_libraries(OGLES2HelloAPI libEGL libGLESv2)
 985         set_property(TARGET OGLES2HelloAPI APPEND_STRING PROPERTY LINK_FLAGS "/SUBSYSTEM:WINDOWS")
 986         set(CMAKE_DEFAULT_STARTUP_PROJECT OGLES2HelloAPI)
 987     elseif(LINUX)
 988         add_executable(OGLES2HelloAPI ${HELLO2_DIR}/OGLES2HelloAPI_LinuxX11.cpp)
 989         set_target_properties(OGLES2HelloAPI PROPERTIES
 990             INCLUDE_DIRECTORIES "${CMAKE_SOURCE_DIR}/include"
 991             COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
 992         )
 993         target_link_libraries(OGLES2HelloAPI dl X11 libEGL libGLESv2)   # Explicitly link our "lib*" targets, not the platform provided "EGL" and "GLESv2"
 994     elseif(APPLE)
 995         add_executable(OGLES2HelloAPI MACOSX_BUNDLE
 996             ${HELLO2_DIR}/OGLES2HelloAPI_OSX.mm
 997             ${HELLO2_DIR}/Build/OSX/en.lproj/MainMenu.xib
 998         )
 999         set_target_properties(OGLES2HelloAPI PROPERTIES
1000             INCLUDE_DIRECTORIES "${CMAKE_SOURCE_DIR}/include"
1001             COMPILE_DEFINITIONS "GL_GLEXT_PROTOTYPES"
1002             MACOSX_BUNDLE_INFO_PLIST "${HELLO2_DIR}/Build/OSX/Info.plist"
1003         )
1004         target_link_libraries(OGLES2HelloAPI libEGL libGLESv2 ${OS_LIBS})
1005         set_source_files_properties(${HELLO2_DIR}/Build/OSX/en.lproj/MainMenu.xib PROPERTIES
1006             MACOSX_PACKAGE_LOCATION "Resources"
1007         )
1008     endif()
1009 endif()
1010
1011 if(BUILD_TESTS AND ${REACTOR_BACKEND} STREQUAL "Subzero")
1012     set(SUBZERO_TEST_LIST
1013         ${SOURCE_DIR}/Reactor/Main.cpp
1014         ${CMAKE_SOURCE_DIR}/third_party/googletest/googletest/src/gtest-all.cc
1015     )
1016
1017     set(SUBZERO_TEST_INCLUDE_DIR
1018         ${CMAKE_SOURCE_DIR}/third_party/googletest/googletest/include
1019         ${CMAKE_SOURCE_DIR}/third_party/googletest/googletest/
1020     )
1021
1022     add_executable(SubzeroTest ${SUBZERO_TEST_LIST})
1023     set_target_properties(SubzeroTest PROPERTIES
1024         INCLUDE_DIRECTORIES "${SUBZERO_TEST_INCLUDE_DIR}"
1025         FOLDER "Tests"
1026     )
1027     if(WIN32)
1028         target_link_libraries(SubzeroTest ReactorSubzero)
1029     else()
1030         target_link_libraries(SubzeroTest ReactorSubzero pthread dl)
1031     endif()
1032 endif()