configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [33])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [0])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 # Wayland minimum version number
  81 m4_define([wayland_api_version], [0.95.0])
  82
  83 AC_PREREQ(2.57)
  84 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  85 AC_CONFIG_SRCDIR([Makefile.am])
  86 AC_CONFIG_MACRO_DIR([m4])
  87 AM_INIT_AUTOMAKE([dist-bzip2])
  88
  89 AM_CONFIG_HEADER([config.h])
  90 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  91
  92 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  93 AC_SUBST(TODAY)
  94
  95 VA_API_MAJOR_VERSION=va_api_major_version
  96 VA_API_MINOR_VERSION=va_api_minor_version
  97 VA_API_MICRO_VERSION=va_api_micro_version
  98 VA_API_VERSION=va_api_version
  99 AC_SUBST(VA_API_MAJOR_VERSION)
 100 AC_SUBST(VA_API_MINOR_VERSION)
 101 AC_SUBST(VA_API_MICRO_VERSION)
 102 AC_SUBST(VA_API_VERSION)
 103
 104 LIBVA_MAJOR_VERSION=libva_major_version
 105 LIBVA_MINOR_VERSION=libva_minor_version
 106 LIBVA_MICRO_VERSION=libva_micro_version
 107 LIBVA_VERSION=libva_version
 108 AC_SUBST(LIBVA_MAJOR_VERSION)
 109 AC_SUBST(LIBVA_MINOR_VERSION)
 110 AC_SUBST(LIBVA_MICRO_VERSION)
 111 AC_SUBST(LIBVA_VERSION)
 112
 113 LIBVA_LT_CURRENT=libva_lt_current
 114 LIBVA_LT_REV=libva_lt_revision
 115 LIBVA_LT_AGE=libva_lt_age
 116 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 117 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 118 AC_SUBST(LIBVA_LT_VERSION)
 119 AC_SUBST(LIBVA_LT_LDFLAGS)
 120
 121 AC_ARG_ENABLE(docs,
 122     [AC_HELP_STRING([--enable-docs],
 123                     [build Doxygen documentation @<:@default=no@:>@])],
 124     [], [enable_docs="no"])
 125
 126 AC_ARG_ENABLE(drm,
 127     [AC_HELP_STRING([--enable-drm],
 128                     [build with VA/DRM API support @<:@default=yes@:>@])],
 129     [], [enable_drm="yes"])
 130
 131 AC_ARG_ENABLE(x11,
 132     [AC_HELP_STRING([--enable-x11],
 133                     [build with VA/X11 API support @<:@default=yes@:>@])],
 134     [], [enable_x11="yes"])
 135
 136 AC_ARG_ENABLE(glx,
 137     [AC_HELP_STRING([--enable-glx],
 138                     [build with VA/GLX API support @<:@default=yes@:>@])],
 139     [], [enable_glx="yes"])
 140
 141 AC_ARG_ENABLE(egl,
 142     [AC_HELP_STRING([--enable-egl],
 143                     [build with VA/EGL API support @<:@default=yes@:>@])],
 144     [], [enable_egl="yes"])
 145
 146 AC_ARG_ENABLE([wayland],
 147     [AC_HELP_STRING([--enable-wayland],
 148                     [build with VA/Wayland API support @<:@default=yes@:>@])],
 149     [], [enable_wayland="yes"])
 150
 151 AC_ARG_ENABLE(dummy-driver,
 152     [AC_HELP_STRING([--enable-dummy-driver],
 153                     [build dummy video driver @<:@default=yes@:>@])],
 154     [], [enable_dummy_driver="yes"])
 155 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 156
 157 AC_ARG_WITH(drivers-path,
 158     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 159                     [drivers path])],
 160     [], [with_drivers_path="$libdir/dri"])
 161
 162 LIBVA_DRIVERS_PATH="$with_drivers_path"
 163 AC_SUBST(LIBVA_DRIVERS_PATH)
 164
 165 AC_DISABLE_STATIC
 166 AC_PROG_LIBTOOL
 167 AC_PROG_CC
 168 AC_PROG_CXX
 169 AM_PROG_CC_C_O
 170 PKG_PROG_PKG_CONFIG
 171
 172 AC_HEADER_STDC
 173 AC_SYS_LARGEFILE
 174
 175 # Check for Doxygen
 176 if test "$enable_docs" = "yes"; then
 177     AC_CHECK_TOOL([DOXYGEN], [doxygen], [enable_docs="no"])
 178 fi
 179 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 180
 181 # Check for __attribute__((visibility()))
 182 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 183     ac_cv_have_gnuc_visibility_attribute,
 184     [cat > conftest.c <<EOF
 185 int foo __attribute__ ((visibility ("hidden"))) = 1;
 186 int bar __attribute__ ((visibility ("protected"))) = 1;
 187 EOF
 188     ac_cv_have_gnuc_visibility_attribute="no"
 189     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 190         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 191             if grep '\.protected.*bar' conftest.s >/dev/null; then
 192                 ac_cv_have_gnuc_visibility_attribute="yes"
 193             fi
 194         fi
 195     fi
 196     rm -f conftest.[cs]
 197 ])
 198 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 199     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 200               [Defined to 1 if GCC visibility attribute is supported])
 201 fi
 202
 203 # Check for DRM (mandatory)
 204 LIBDRM_VERSION=libdrm_version
 205 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 206 AC_SUBST(LIBDRM_VERSION)
 207
 208 USE_DRM="no"
 209 if test "$enable_drm" = "yes"; then
 210     USE_DRM="yes"
 211     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 212 fi
 213 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 214
 215 # Check for X11
 216 USE_X11="no"
 217 if test "$enable_x11" = "yes"; then
 218     USE_X11="yes"
 219     PKG_CHECK_MODULES([X11],    [x11],    [:], [USE_X11="no"])
 220     PKG_CHECK_MODULES([XEXT],   [xext],   [:], [USE_X11="no"])
 221     PKG_CHECK_MODULES([XFIXES], [xfixes], [:], [USE_X11="no"])
 222     if test "$USE_X11" = "yes"; then
 223         AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 224     fi
 225 fi
 226 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 227
 228 # Check for GLX
 229 USE_GLX="no"
 230 if test "$USE_X11:$enable_glx" = "yes:yes"; then
 231     PKG_CHECK_MODULES([GLX], [gl x11], [USE_GLX="yes"], [:])
 232     saved_CPPFLAGS="$CPPFLAGS"
 233     saved_LIBS="$LIBS"
 234     CPPFLAGS="$CPPFLAGS $GLX_CFLAGS"
 235     LIBS="$LIBS $GLX_LIBS"
 236     AC_CHECK_HEADERS([GL/gl.h GL/glx.h], [:], [USE_GLX="no"])
 237     AC_CHECK_LIB([GL], [glXCreateContext], [:] [USE_GLX="no"])
 238     CPPFLAGS="$saved_CPPFLAGS"
 239     LIBS="$saved_LIBS"
 240     if test "$USE_GLX" = "yes"; then
 241         AC_DEFINE([HAVE_VA_GLX], [1], [Defined to 1 if VA/GLX API is built])
 242     fi
 243 fi
 244 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 245
 246 # Check for EGL
 247 USE_EGL="no"
 248 if test "$enable_egl" = "yes"; then
 249     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [:])
 250     saved_CPPFLAGS="$CPPFLAGS"
 251     saved_LIBS="$LIBS"
 252     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 253     LIBS="$LIBS $EGL_LIBS"
 254     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 255     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 256     CPPFLAGS="$saved_CPPFLAGS"
 257     LIBS="$saved_LIBS"
 258     if test "$USE_EGL" = "yes"; then
 259         AC_DEFINE([HAVE_VA_EGL], [1], [Defined to 1 if VA/EGL API is built])
 260     fi
 261 fi
 262 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 263
 264 # Check for Wayland
 265 WAYLAND_API_VERSION=wayland_api_version
 266 AC_SUBST(WAYLAND_API_VERSION)
 267
 268 USE_WAYLAND="no"
 269 if test "$enable_wayland" = "yes"; then
 270     PKG_CHECK_MODULES([WAYLAND], [wayland-client >= wayland_api_version],
 271         [USE_WAYLAND="yes"], [:])
 272     if test "$USE_WAYLAND" = "yes"; then
 273         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 274                   [Defined to 1 if VA/Wayland API is built])
 275     fi
 276 fi
 277 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 278
 279 m4_ifdef([WAYLAND_SCANNER_RULES],
 280     [WAYLAND_SCANNER_RULES(['$(top_srcdir)/va/wayland/protocol'])],
 281     [wayland_scanner_rules=""; AC_SUBST(wayland_scanner_rules)])
 282
 283 pkgconfigdir=${libdir}/pkgconfig
 284 AC_SUBST(pkgconfigdir)
 285
 286 # Check for builds without backend
 287 if test "$USE_DRM:$USE_X11:$USE_WAYLAND" = "no:no:no"; then
 288     AC_MSG_ERROR([Please select at least one backend (DRM, X11, Wayland)])
 289 fi
 290
 291 AC_OUTPUT([
 292     Makefile
 293     debian.upstream/Makefile
 294     debian.upstream/changelog
 295     debian.upstream/control
 296     debian.upstream/libva$LIBVA_MAJOR_VERSION.install:\
 297 debian.upstream/libva.install.in
 298     debian.upstream/libva-drm$LIBVA_MAJOR_VERSION.install:\
 299 debian.upstream/libva-drm.install.in
 300     debian.upstream/libva-egl$LIBVA_MAJOR_VERSION.install:\
 301 debian.upstream/libva-egl.install.in
 302     debian.upstream/libva-glx$LIBVA_MAJOR_VERSION.install:\
 303 debian.upstream/libva-glx.install.in
 304     debian.upstream/libva-wayland$LIBVA_MAJOR_VERSION.install:\
 305 debian.upstream/libva-wayland.install.in
 306     debian.upstream/libva-x11-$LIBVA_MAJOR_VERSION.install:\
 307 debian.upstream/libva-x11.install.in
 308     doc/Makefile
 309     dummy_drv_video/Makefile
 310     pkgconfig/Makefile
 311     pkgconfig/libva-drm.pc
 312     pkgconfig/libva-egl.pc
 313     pkgconfig/libva-glx.pc
 314     pkgconfig/libva-tpi.pc
 315     pkgconfig/libva-wayland.pc
 316     pkgconfig/libva-x11.pc
 317     pkgconfig/libva.pc
 318     test/Makefile
 319     test/basic/Makefile
 320     test/common/Makefile
 321     test/decode/Makefile
 322     test/encode/Makefile
 323     test/putsurface/Makefile
 324     test/v4l_h264/Makefile
 325     test/v4l_h264/decode/Makefile
 326     test/v4l_h264/encode/Makefile
 327     test/vainfo/Makefile
 328     va/Makefile
 329     va/drm/Makefile
 330     va/egl/Makefile
 331     va/glx/Makefile
 332     va/va_version.h
 333     va/wayland/Makefile
 334     va/wayland/protocol/Makefile
 335     va/x11/Makefile
 336 ])
 337
 338 # Print a small summary
 339 BACKENDS=""
 340 AS_IF([test x$USE_DRM = xyes], [BACKENDS="$BACKENDS drm"])
 341 AS_IF([test x$USE_X11 = xyes], [BACKENDS="$BACKENDS x11"])
 342 AS_IF([test x$USE_GLX = xyes], [BACKENDS="$BACKENDS glx"])
 343 AS_IF([test x$USE_EGL = xyes], [BACKENDS="$BACKENDS egl"])
 344 AS_IF([test x$USE_WAYLAND = xyes], [BACKENDS="$BACKENDS wayland"])
 345
 346 echo
 347 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 348 echo
 349 echo Installation prefix .............. : $prefix
 350 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 351 echo Extra window systems ............. : $BACKENDS
 352 echo Build dummy driver ............... : $enable_dummy_driver
 353 echo Build documentation .............. : $enable_docs
 354 echo