configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [40])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [3])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 # Wayland minimum version number
  81 m4_define([wayland_api_version], [1.0.0])
  82
  83 AC_PREREQ(2.57)
  84 AC_INIT([libva],
  85         [libva_version],
  86         [https://github.com/01org/libva/issues/new],
  87         [libva],
  88         [https://github.com/01org/libva])
  89
  90 AC_CONFIG_SRCDIR([Makefile.am])
  91 AC_CONFIG_MACRO_DIR([m4])
  92 AM_INIT_AUTOMAKE([dist-bzip2])
  93
  94 AC_CONFIG_HEADERS([config.h])
  95 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  96
  97 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  98 AC_SUBST(TODAY)
  99
 100 VA_API_MAJOR_VERSION=va_api_major_version
 101 VA_API_MINOR_VERSION=va_api_minor_version
 102 VA_API_MICRO_VERSION=va_api_micro_version
 103 VA_API_VERSION=va_api_version
 104 AC_SUBST(VA_API_MAJOR_VERSION)
 105 AC_SUBST(VA_API_MINOR_VERSION)
 106 AC_SUBST(VA_API_MICRO_VERSION)
 107 AC_SUBST(VA_API_VERSION)
 108
 109 LIBVA_MAJOR_VERSION=libva_major_version
 110 LIBVA_MINOR_VERSION=libva_minor_version
 111 LIBVA_MICRO_VERSION=libva_micro_version
 112 LIBVA_VERSION=libva_version
 113 AC_SUBST(LIBVA_MAJOR_VERSION)
 114 AC_SUBST(LIBVA_MINOR_VERSION)
 115 AC_SUBST(LIBVA_MICRO_VERSION)
 116 AC_SUBST(LIBVA_VERSION)
 117
 118 LIBVA_LT_CURRENT=libva_lt_current
 119 LIBVA_LT_REV=libva_lt_revision
 120 LIBVA_LT_AGE=libva_lt_age
 121 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 122 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 123 AC_SUBST(LIBVA_LT_VERSION)
 124 AC_SUBST(LIBVA_LT_LDFLAGS)
 125
 126 AC_ARG_ENABLE(docs,
 127     [AC_HELP_STRING([--enable-docs],
 128                     [build Doxygen documentation @<:@default=no@:>@])],
 129     [], [enable_docs="no"])
 130
 131 AC_ARG_ENABLE(drm,
 132     [AC_HELP_STRING([--enable-drm],
 133                     [build with VA/DRM API support @<:@default=yes@:>@])],
 134     [], [enable_drm="yes"])
 135
 136 AC_ARG_ENABLE(x11,
 137     [AC_HELP_STRING([--enable-x11],
 138                     [build with VA/X11 API support @<:@default=yes@:>@])],
 139     [], [enable_x11="yes"])
 140
 141 AC_ARG_ENABLE(glx,
 142     [AC_HELP_STRING([--enable-glx],
 143                     [build with VA/GLX API support @<:@default=yes@:>@])],
 144     [], [enable_glx="yes"])
 145
 146 AC_ARG_ENABLE(egl,
 147     [AC_HELP_STRING([--enable-egl],
 148                     [build with VA/EGL API support @<:@default=yes@:>@])],
 149     [], [enable_egl="yes"])
 150
 151 AC_ARG_ENABLE([wayland],
 152     [AC_HELP_STRING([--enable-wayland],
 153                     [build with VA/Wayland API support @<:@default=yes@:>@])],
 154     [], [enable_wayland="yes"])
 155
 156 AC_ARG_ENABLE([va-messaging],
 157     [AC_HELP_STRING([--enable-va-messaging],
 158                     [build with va info and error messaging @<:@default=yes@:>@])],
 159     [], [enable_va_messaging="yes"])
 160
 161 AC_ARG_WITH(drivers-path,
 162     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 163                     [drivers path])],
 164     [], [with_drivers_path="$libdir/dri"])
 165
 166 LIBVA_DRIVERS_PATH="$with_drivers_path"
 167 AC_SUBST(LIBVA_DRIVERS_PATH)
 168
 169 AC_DISABLE_STATIC
 170 AC_PROG_LIBTOOL
 171 AC_PROG_CC
 172 AC_PROG_CXX
 173 AM_PROG_CC_C_O
 174 PKG_PROG_PKG_CONFIG
 175
 176 AC_HEADER_STDC
 177 AC_SYS_LARGEFILE
 178
 179 # Check for Doxygen
 180 if test "$enable_docs" = "yes"; then
 181     AC_CHECK_TOOL([DOXYGEN], [doxygen], [no])
 182     if test "$DOXYGEN" = "no"; then
 183        enable_docs="no"
 184     fi
 185 fi
 186 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 187
 188 # Check for va messaging
 189 if test "$enable_va_messaging" = "yes"; then
 190     AC_DEFINE([ENABLE_VA_MESSAGING], [1], [Defined to 1 if va messaging is needed])
 191 fi
 192
 193 # Check for __attribute__((visibility()))
 194 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 195     ac_cv_have_gnuc_visibility_attribute,
 196     [cat > conftest.c <<EOF
 197 int foo __attribute__ ((visibility ("hidden"))) = 1;
 198 int bar __attribute__ ((visibility ("protected"))) = 1;
 199 EOF
 200     ac_cv_have_gnuc_visibility_attribute="no"
 201     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 202         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 203             if grep '\.protected.*bar' conftest.s >/dev/null; then
 204                 ac_cv_have_gnuc_visibility_attribute="yes"
 205             fi
 206         fi
 207     fi
 208     rm -f conftest.[cs]
 209 ])
 210 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 211     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 212               [Defined to 1 if GCC visibility attribute is supported])
 213 fi
 214
 215 # Check for DRM (mandatory)
 216 LIBDRM_VERSION=libdrm_version
 217 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 218 AC_SUBST(LIBDRM_VERSION)
 219
 220 USE_DRM="no"
 221 if test "$enable_drm" = "yes"; then
 222     USE_DRM="yes"
 223     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 224 fi
 225 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 226
 227 # Check for X11
 228 USE_X11="no"
 229 if test "$enable_x11" = "yes"; then
 230     USE_X11="yes"
 231     PKG_CHECK_MODULES([X11],    [x11],    [:], [USE_X11="no"])
 232     PKG_CHECK_MODULES([XEXT],   [xext],   [:], [USE_X11="no"])
 233     PKG_CHECK_MODULES([XFIXES], [xfixes], [:], [USE_X11="no"])
 234     if test "$USE_X11" = "yes"; then
 235         AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 236     fi
 237 fi
 238 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 239
 240 # Check for GLX
 241 USE_GLX="no"
 242 if test "$USE_X11:$enable_glx" = "yes:yes"; then
 243     PKG_CHECK_MODULES([GLX], [gl x11], [USE_GLX="yes"], [:])
 244     saved_CPPFLAGS="$CPPFLAGS"
 245     saved_LIBS="$LIBS"
 246     CPPFLAGS="$CPPFLAGS $GLX_CFLAGS"
 247     LIBS="$LIBS $GLX_LIBS"
 248     AC_CHECK_HEADERS([GL/gl.h GL/glx.h], [:], [USE_GLX="no"])
 249     AC_CHECK_LIB([GL], [glXCreateContext], [:] [USE_GLX="no"])
 250     CPPFLAGS="$saved_CPPFLAGS"
 251     LIBS="$saved_LIBS"
 252     if test "$USE_GLX" = "yes"; then
 253         AC_DEFINE([HAVE_VA_GLX], [1], [Defined to 1 if VA/GLX API is built])
 254     fi
 255 fi
 256 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 257
 258 # Check for EGL
 259 USE_EGL="no"
 260 if test "$enable_egl" = "yes"; then
 261     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [:])
 262     saved_CPPFLAGS="$CPPFLAGS"
 263     saved_LIBS="$LIBS"
 264     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 265     LIBS="$LIBS $EGL_LIBS"
 266     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 267     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 268     CPPFLAGS="$saved_CPPFLAGS"
 269     LIBS="$saved_LIBS"
 270     if test "$USE_EGL" = "yes"; then
 271         AC_DEFINE([HAVE_VA_EGL], [1], [Defined to 1 if VA/EGL API is built])
 272     fi
 273 fi
 274 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 275
 276 # Check for Wayland
 277 WAYLAND_API_VERSION=wayland_api_version
 278 AC_SUBST(WAYLAND_API_VERSION)
 279
 280 USE_WAYLAND="no"
 281 if test "$enable_wayland" = "yes"; then
 282     PKG_CHECK_MODULES([WAYLAND], [wayland-client >= wayland_api_version],
 283         [USE_WAYLAND="yes"], [:])
 284     if test "$USE_WAYLAND" = "yes"; then
 285
 286         WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
 287         AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
 288                      [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
 289         if test "x$WAYLAND_SCANNER" = "x"; then
 290             AC_MSG_ERROR([wayland-scanner not found: Install it or use --disable-wayland])
 291         fi
 292
 293         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 294                   [Defined to 1 if VA/Wayland API is built])
 295     fi
 296 fi
 297
 298 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 299
 300 pkgconfigdir=${libdir}/pkgconfig
 301 AC_SUBST(pkgconfigdir)
 302
 303 # Check for builds without backend
 304 if test "$USE_DRM:$USE_X11:$USE_WAYLAND" = "no:no:no"; then
 305     AC_MSG_ERROR([Please select at least one backend (DRM, X11, Wayland)])
 306 fi
 307
 308 AC_OUTPUT([
 309     Makefile
 310     doc/Makefile
 311     pkgconfig/Makefile
 312     pkgconfig/libva-drm.pc
 313     pkgconfig/libva-egl.pc
 314     pkgconfig/libva-glx.pc
 315     pkgconfig/libva-tpi.pc
 316     pkgconfig/libva-wayland.pc
 317     pkgconfig/libva-x11.pc
 318     pkgconfig/libva.pc
 319     va/Makefile
 320     va/drm/Makefile
 321     va/egl/Makefile
 322     va/glx/Makefile
 323     va/va_version.h
 324     va/wayland/Makefile
 325     va/x11/Makefile
 326 ])
 327
 328 # Print a small summary
 329 BACKENDS=""
 330 AS_IF([test x$USE_DRM = xyes], [BACKENDS="$BACKENDS drm"])
 331 AS_IF([test x$USE_X11 = xyes], [BACKENDS="$BACKENDS x11"])
 332 AS_IF([test x$USE_GLX = xyes], [BACKENDS="$BACKENDS glx"])
 333 AS_IF([test x$USE_EGL = xyes], [BACKENDS="$BACKENDS egl"])
 334 AS_IF([test x$USE_WAYLAND = xyes], [BACKENDS="$BACKENDS wayland"])
 335
 336 echo
 337 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 338 echo
 339 echo Installation prefix .............. : $prefix
 340 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 341 echo Extra window systems ............. : $BACKENDS
 342 echo Build documentation .............. : $enable_docs
 343 echo Build with messaging ............. : $enable_va_messaging
 344 echo