configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [32])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [16])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 AC_PREREQ(2.57)
  81 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  82 AC_CONFIG_SRCDIR([Makefile.am])
  83 AM_INIT_AUTOMAKE([dist-bzip2])
  84
  85 AM_CONFIG_HEADER([config.h])
  86 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  87
  88 VA_API_MAJOR_VERSION=va_api_major_version
  89 VA_API_MINOR_VERSION=va_api_minor_version
  90 VA_API_MICRO_VERSION=va_api_micro_version
  91 VA_API_VERSION=va_api_version
  92 AC_SUBST(VA_API_MAJOR_VERSION)
  93 AC_SUBST(VA_API_MINOR_VERSION)
  94 AC_SUBST(VA_API_MICRO_VERSION)
  95 AC_SUBST(VA_API_VERSION)
  96
  97 LIBVA_MAJOR_VERSION=libva_major_version
  98 LIBVA_MINOR_VERSION=libva_minor_version
  99 LIBVA_MICRO_VERSION=libva_micro_version
 100 LIBVA_VERSION=libva_version
 101 AC_SUBST(LIBVA_MAJOR_VERSION)
 102 AC_SUBST(LIBVA_MINOR_VERSION)
 103 AC_SUBST(LIBVA_MICRO_VERSION)
 104 AC_SUBST(LIBVA_VERSION)
 105
 106 LIBVA_LT_CURRENT=libva_lt_current
 107 LIBVA_LT_REV=libva_lt_revision
 108 LIBVA_LT_AGE=libva_lt_age
 109 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 110 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 111 AC_SUBST(LIBVA_LT_VERSION)
 112 AC_SUBST(LIBVA_LT_LDFLAGS)
 113
 114 AC_ARG_ENABLE(docs,
 115     [AC_HELP_STRING([--enable-docs],
 116                     [build Doxygen documentation @<:@default=no@:>@])],
 117     [], [enable_docs="no"])
 118
 119 AC_ARG_ENABLE(glx,
 120     [AC_HELP_STRING([--enable-glx],
 121                     [build with GLX support @<:@default=yes@:>@])],
 122     [], [enable_glx="yes"])
 123
 124 AC_ARG_ENABLE(dummy-driver,
 125     [AC_HELP_STRING([--enable-dummy-driver],
 126                     [build dummy video driver @<:@default=yes@:>@])],
 127     [], [enable_dummy_driver="yes"])
 128 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 129
 130 AC_ARG_ENABLE(dummy-backend,
 131     [AC_HELP_STRING([--enable-dummy-backend],
 132                     [build dummy libva backend])],
 133     [], [enable_dummy_backend="no"])
 134
 135 AC_ARG_WITH(drivers-path,
 136     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 137                     [drivers path])],
 138     [], [with_drivers_path="$libdir/dri"])
 139
 140 LIBVA_DRIVERS_PATH="$with_drivers_path"
 141 AC_SUBST(LIBVA_DRIVERS_PATH)
 142
 143 AC_DISABLE_STATIC
 144 AC_PROG_LIBTOOL
 145 AC_PROG_CC
 146 AC_PROG_CXX
 147
 148 AC_HEADER_STDC
 149 AC_SYS_LARGEFILE
 150
 151 PKG_CHECK_MODULES([X11], [x11])
 152 PKG_CHECK_MODULES([XEXT],[xext])
 153 PKG_CHECK_MODULES([XFIXES], [xfixes])
 154
 155 # Check for Doxygen
 156 if test "$enable_docs" = "yes"; then
 157     AC_CHECK_TOOL([DOXYGEN], [doxygen], [enable_docs="no"])
 158 fi
 159 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 160
 161 # Check for recent enough DRM
 162 LIBDRM_VERSION=libdrm_version
 163 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 164 AC_SUBST(LIBDRM_VERSION)
 165
 166 if test x$enable_dummy_backend = xyes; then
 167     PKG_CHECK_MODULES([UDEV], [libudev], [libudev=yes], [libudev=no])
 168 fi
 169 if test x$libudev = xno; then
 170    enable_dummy_backend=no
 171 fi
 172 AM_CONDITIONAL(BUILD_DUMMY_BACKEND, test x$enable_dummy_backend = xyes)
 173
 174 # Check for OpenGL (X11)
 175 USE_GLX="no"
 176 GL_DEPS_CFLAGS=""
 177 GL_DEPS_LIBS=""
 178 if test x$enable_glx = xyes; then
 179     AC_CHECK_HEADERS([GL/gl.h])
 180     AC_CHECK_HEADERS([GL/glx.h])
 181     AC_CHECK_LIB(GL, glXCreateContext, [
 182         USE_GLX="yes"
 183         GL_DEPS_LIBS="-lX11 -lGL"
 184     ])
 185 fi
 186 AC_SUBST(GL_DEPS_CFLAGS)
 187 AC_SUBST(GL_DEPS_LIBS)
 188 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 189
 190 # TBD: Check for EGL
 191 USE_EGL="yes"
 192 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 193
 194 # We only need the headers, we don't link against the DRM libraries
 195 LIBVA_CFLAGS="$DRM_CFLAGS"
 196 AC_SUBST(LIBVA_CFLAGS)
 197 AC_SUBST(LIBVA_LIBS)
 198
 199 pkgconfigdir=${libdir}/pkgconfig
 200 AC_SUBST(pkgconfigdir)
 201
 202 LIBVA_DISPLAY=x11
 203 libvacorelib=libva.la
 204 libvabackendlib=libva-$LIBVA_DISPLAY.la
 205 AC_SUBST([libvacorelib])
 206 AC_SUBST([libvabackendlib])
 207
 208 AC_OUTPUT([
 209     Makefile
 210     debian.upstream/Makefile
 211     doc/Makefile
 212     dummy_drv_video/Makefile
 213     pkgconfig/Makefile
 214     pkgconfig/libva-egl.pc
 215     pkgconfig/libva-glx.pc
 216     pkgconfig/libva-tpi.pc
 217     pkgconfig/libva-x11.pc
 218     pkgconfig/libva.pc
 219     test/Makefile
 220     test/basic/Makefile
 221     test/decode/Makefile
 222     test/encode/Makefile
 223     test/putsurface/Makefile
 224     test/vainfo/Makefile
 225     va/Makefile
 226     va/dummy/Makefile
 227     va/egl/Makefile
 228     va/glx/Makefile
 229     va/va_version.h
 230     va/x11/Makefile
 231 ])
 232
 233 # Print a small summary
 234
 235 echo ""
 236 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 237 echo ""
 238
 239 echo " \95 Global :"
 240 echo "     Prefix: ${prefix}"
 241 echo ""
 242
 243 AS_IF([test x$enable_dummy_driver = xyes], [DRIVERS="dummy $DRIVERS"])
 244
 245 echo " \95 Drivers: ${DRIVERS}"
 246
 247 AS_IF([test x$USE_GLX = xyes], [BACKENDS="glx $BACKENDS"])
 248 AS_IF([test x$USE_EGL = xyes], [BACKENDS="egl $BACKENDS"])
 249
 250 BACKENDS="x11 $BACKENDS"
 251 AS_IF([test x$enable_dummy_backend = xyes], [BACKENDS="dummy
 252 $BACKENDS"])
 253
 254 echo " \95 Winsys : ${BACKENDS}"
 255 echo " \95 Documentation : ${enable_docs}"