configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # VA-API version
  24 # - increment major for any ABI change (which shall not occur!)
  25 # - increment minor for any interface change (e.g. new/modified function)
  26 # - increment micro for any other change (new flag, new codec definition, etc.)
  27 # - reset micro version to zero when minor version is incremented
  28 # - reset minor version to zero when major version is incremented
  29 m4_define([va_api_major_version], [0])
  30 m4_define([va_api_minor_version], [40])
  31 m4_define([va_api_micro_version], [0])
  32
  33 m4_define([va_api_version],
  34           [va_api_major_version.va_api_minor_version.va_api_micro_version])
  35
  36 # libva package version number, (as distinct from shared library version)
  37 # XXX: we want the package version to remain at 1.0.x for VA-API 0.32.y
  38 #
  39 # - major version is automatically generated from VA-API major version
  40 # - minor version is automatically generated from VA-API minor version
  41 # - increment micro for any library release
  42 # - reset micro version to zero when VA-API major or minor version is changed
  43 m4_define([libva_major_version], [m4_eval(va_api_major_version + 1)])
  44 m4_define([libva_minor_version], [m4_eval(va_api_minor_version - 32)])
  45 m4_define([libva_micro_version], [0])
  46 m4_define([libva_pre_version],   [1])
  47
  48 m4_define([libva_version],
  49           [libva_major_version.libva_minor_version.libva_micro_version])
  50 m4_if(libva_pre_version, [0], [], [
  51 m4_append([libva_version], libva_pre_version, [.pre])
  52 ])
  53
  54 # libva library version number (generated, do not change)
  55 # XXX: we want the SONAME to remain at libva.so.1 for VA-API major == 0
  56 #
  57 # The library name is generated libva.<x>.<y>.0 where
  58 # <x> = VA-API major version + 1
  59 # <y> = 100 * VA-API minor version + VA-API micro version
  60 #
  61 # For example:
  62 # VA-API 0.32.0 generates libva.so.1.3200.0
  63 # VA-API 0.34.1 generates libva.so.1.3401.0
  64 # VA-API 1.2.13 generates libva.so.2.213.0
  65 m4_define([libva_interface_bias], [m4_eval(va_api_major_version + 1)])
  66 m4_define([libva_interface_age],  [0])
  67 m4_define([libva_binary_age],
  68           [m4_eval(100 * va_api_minor_version + va_api_micro_version - libva_interface_age)])
  69
  70 m4_define([libva_lt_current],
  71           [m4_eval(100 * va_api_minor_version + va_api_micro_version + libva_interface_bias)])
  72 m4_define([libva_lt_revision],
  73           [m4_eval(libva_interface_age)])
  74 m4_define([libva_lt_age],
  75           [m4_eval(libva_binary_age - libva_interface_age)])
  76
  77 # libdrm minimun version requirement
  78 m4_define([libdrm_version], [2.4])
  79
  80 # Wayland minimum version number
  81 m4_define([wayland_api_version], [1.0.0])
  82
  83 AC_PREREQ(2.57)
  84 AC_INIT([libva],
  85         [libva_version],
  86         [https://github.com/01org/libva/issues/new],
  87         [libva],
  88         [https://github.com/01org/libva])
  89
  90 AC_CONFIG_SRCDIR([Makefile.am])
  91 AC_CONFIG_MACRO_DIR([m4])
  92 AM_INIT_AUTOMAKE([dist-bzip2])
  93
  94 AC_CONFIG_HEADERS([config.h])
  95 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])])
  96
  97 TODAY="`LC_ALL=C date +'%a, %d %b %Y %X %z'`"
  98 AC_SUBST(TODAY)
  99
 100 VA_API_MAJOR_VERSION=va_api_major_version
 101 VA_API_MINOR_VERSION=va_api_minor_version
 102 VA_API_MICRO_VERSION=va_api_micro_version
 103 VA_API_VERSION=va_api_version
 104 AC_SUBST(VA_API_MAJOR_VERSION)
 105 AC_SUBST(VA_API_MINOR_VERSION)
 106 AC_SUBST(VA_API_MICRO_VERSION)
 107 AC_SUBST(VA_API_VERSION)
 108
 109 LIBVA_MAJOR_VERSION=libva_major_version
 110 LIBVA_MINOR_VERSION=libva_minor_version
 111 LIBVA_MICRO_VERSION=libva_micro_version
 112 LIBVA_VERSION=libva_version
 113 AC_SUBST(LIBVA_MAJOR_VERSION)
 114 AC_SUBST(LIBVA_MINOR_VERSION)
 115 AC_SUBST(LIBVA_MICRO_VERSION)
 116 AC_SUBST(LIBVA_VERSION)
 117
 118 LIBVA_LT_CURRENT=libva_lt_current
 119 LIBVA_LT_REV=libva_lt_revision
 120 LIBVA_LT_AGE=libva_lt_age
 121 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
 122 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
 123 AC_SUBST(LIBVA_LT_VERSION)
 124 AC_SUBST(LIBVA_LT_LDFLAGS)
 125
 126 AC_ARG_ENABLE(docs,
 127     [AC_HELP_STRING([--enable-docs],
 128                     [build Doxygen documentation @<:@default=no@:>@])],
 129     [], [enable_docs="no"])
 130
 131 AC_ARG_ENABLE(drm,
 132     [AC_HELP_STRING([--enable-drm],
 133                     [build with VA/DRM API support @<:@default=yes@:>@])],
 134     [], [enable_drm="yes"])
 135
 136 AC_ARG_ENABLE(x11,
 137     [AC_HELP_STRING([--enable-x11],
 138                     [build with VA/X11 API support @<:@default=yes@:>@])],
 139     [], [enable_x11="yes"])
 140
 141 AC_ARG_ENABLE(glx,
 142     [AC_HELP_STRING([--enable-glx],
 143                     [build with VA/GLX API support @<:@default=yes@:>@])],
 144     [], [enable_glx="yes"])
 145
 146 AC_ARG_ENABLE(egl,
 147     [AC_HELP_STRING([--enable-egl],
 148                     [build with VA/EGL API support @<:@default=yes@:>@])],
 149     [], [enable_egl="yes"])
 150
 151 AC_ARG_ENABLE([wayland],
 152     [AC_HELP_STRING([--enable-wayland],
 153                     [build with VA/Wayland API support @<:@default=yes@:>@])],
 154     [], [enable_wayland="yes"])
 155
 156 AC_ARG_ENABLE(dummy-driver,
 157     [AC_HELP_STRING([--enable-dummy-driver],
 158                     [build dummy video driver @<:@default=yes@:>@])],
 159     [], [enable_dummy_driver="yes"])
 160 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
 161
 162 AC_ARG_WITH(drivers-path,
 163     [AC_HELP_STRING([--with-drivers-path=[[path]]],
 164                     [drivers path])],
 165     [], [with_drivers_path="$libdir/dri"])
 166
 167 LIBVA_DRIVERS_PATH="$with_drivers_path"
 168 AC_SUBST(LIBVA_DRIVERS_PATH)
 169
 170 AC_DISABLE_STATIC
 171 AC_PROG_LIBTOOL
 172 AC_PROG_CC
 173 AC_PROG_CXX
 174 AM_PROG_CC_C_O
 175 PKG_PROG_PKG_CONFIG
 176
 177 AC_HEADER_STDC
 178 AC_SYS_LARGEFILE
 179
 180 # Check for Doxygen
 181 if test "$enable_docs" = "yes"; then
 182     AC_CHECK_TOOL([DOXYGEN], [doxygen], [no])
 183     if test "$DOXYGEN" = "no"; then
 184        enable_docs="no"
 185     fi
 186 fi
 187 AM_CONDITIONAL(ENABLE_DOCS, test "$enable_docs" = "yes")
 188
 189 # Check for __attribute__((visibility()))
 190 AC_CACHE_CHECK([whether __attribute__((visibility())) is supported],
 191     ac_cv_have_gnuc_visibility_attribute,
 192     [cat > conftest.c <<EOF
 193 int foo __attribute__ ((visibility ("hidden"))) = 1;
 194 int bar __attribute__ ((visibility ("protected"))) = 1;
 195 EOF
 196     ac_cv_have_gnuc_visibility_attribute="no"
 197     if ${CC-cc} -Werror -S conftest.c -o conftest.s >/dev/null 2>&1; then
 198         if grep '\.hidden.*foo' conftest.s >/dev/null; then
 199             if grep '\.protected.*bar' conftest.s >/dev/null; then
 200                 ac_cv_have_gnuc_visibility_attribute="yes"
 201             fi
 202         fi
 203     fi
 204     rm -f conftest.[cs]
 205 ])
 206 if test "$ac_cv_have_gnuc_visibility_attribute" = "yes"; then
 207     AC_DEFINE([HAVE_GNUC_VISIBILITY_ATTRIBUTE], [1],
 208               [Defined to 1 if GCC visibility attribute is supported])
 209 fi
 210
 211 # Check for DRM (mandatory)
 212 LIBDRM_VERSION=libdrm_version
 213 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
 214 AC_SUBST(LIBDRM_VERSION)
 215
 216 USE_DRM="no"
 217 if test "$enable_drm" = "yes"; then
 218     USE_DRM="yes"
 219     AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is built])
 220 fi
 221 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 222
 223 # Check for X11
 224 USE_X11="no"
 225 if test "$enable_x11" = "yes"; then
 226     USE_X11="yes"
 227     PKG_CHECK_MODULES([X11],    [x11],    [:], [USE_X11="no"])
 228     PKG_CHECK_MODULES([XEXT],   [xext],   [:], [USE_X11="no"])
 229     PKG_CHECK_MODULES([XFIXES], [xfixes], [:], [USE_X11="no"])
 230     if test "$USE_X11" = "yes"; then
 231         AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is built])
 232     fi
 233 fi
 234 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 235
 236 # Check for GLX
 237 USE_GLX="no"
 238 if test "$USE_X11:$enable_glx" = "yes:yes"; then
 239     PKG_CHECK_MODULES([GLX], [gl x11], [USE_GLX="yes"], [:])
 240     saved_CPPFLAGS="$CPPFLAGS"
 241     saved_LIBS="$LIBS"
 242     CPPFLAGS="$CPPFLAGS $GLX_CFLAGS"
 243     LIBS="$LIBS $GLX_LIBS"
 244     AC_CHECK_HEADERS([GL/gl.h GL/glx.h], [:], [USE_GLX="no"])
 245     AC_CHECK_LIB([GL], [glXCreateContext], [:] [USE_GLX="no"])
 246     CPPFLAGS="$saved_CPPFLAGS"
 247     LIBS="$saved_LIBS"
 248     if test "$USE_GLX" = "yes"; then
 249         AC_DEFINE([HAVE_VA_GLX], [1], [Defined to 1 if VA/GLX API is built])
 250     fi
 251 fi
 252 AM_CONDITIONAL(USE_GLX, test "$USE_GLX" = "yes")
 253
 254 # Check for EGL
 255 USE_EGL="no"
 256 if test "$enable_egl" = "yes"; then
 257     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [:])
 258     saved_CPPFLAGS="$CPPFLAGS"
 259     saved_LIBS="$LIBS"
 260     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 261     LIBS="$LIBS $EGL_LIBS"
 262     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 263     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 264     CPPFLAGS="$saved_CPPFLAGS"
 265     LIBS="$saved_LIBS"
 266     if test "$USE_EGL" = "yes"; then
 267         AC_DEFINE([HAVE_VA_EGL], [1], [Defined to 1 if VA/EGL API is built])
 268     fi
 269 fi
 270 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 271
 272 # Check for Wayland
 273 WAYLAND_API_VERSION=wayland_api_version
 274 AC_SUBST(WAYLAND_API_VERSION)
 275
 276 USE_WAYLAND="no"
 277 if test "$enable_wayland" = "yes"; then
 278     PKG_CHECK_MODULES([WAYLAND], [wayland-client >= wayland_api_version],
 279         [USE_WAYLAND="yes"], [:])
 280     if test "$USE_WAYLAND" = "yes"; then
 281
 282         WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
 283         AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
 284                      [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
 285
 286         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 287                   [Defined to 1 if VA/Wayland API is built])
 288     fi
 289 fi
 290
 291 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 292
 293 pkgconfigdir=${libdir}/pkgconfig
 294 AC_SUBST(pkgconfigdir)
 295
 296 # Check for builds without backend
 297 if test "$USE_DRM:$USE_X11:$USE_WAYLAND" = "no:no:no"; then
 298     AC_MSG_ERROR([Please select at least one backend (DRM, X11, Wayland)])
 299 fi
 300
 301 # Define __vaDriverInit*() function name for dummy backend
 302 VA_DRIVER_INIT_FUNC="__vaDriverInit_${VA_API_MAJOR_VERSION}_${VA_API_MINOR_VERSION}"
 303 AC_DEFINE_UNQUOTED([VA_DRIVER_INIT_FUNC], [$VA_DRIVER_INIT_FUNC],
 304     [Defined to the versioned __vaDriverInit function name])
 305
 306 AC_OUTPUT([
 307     Makefile
 308     debian.upstream/Makefile
 309     debian.upstream/changelog
 310     debian.upstream/control
 311     debian.upstream/libva$LIBVA_MAJOR_VERSION.install:\
 312 debian.upstream/libva.install.in
 313     debian.upstream/libva-drm$LIBVA_MAJOR_VERSION.install:\
 314 debian.upstream/libva-drm.install.in
 315     debian.upstream/libva-egl$LIBVA_MAJOR_VERSION.install:\
 316 debian.upstream/libva-egl.install.in
 317     debian.upstream/libva-glx$LIBVA_MAJOR_VERSION.install:\
 318 debian.upstream/libva-glx.install.in
 319     debian.upstream/libva-wayland$LIBVA_MAJOR_VERSION.install:\
 320 debian.upstream/libva-wayland.install.in
 321     debian.upstream/libva-x11-$LIBVA_MAJOR_VERSION.install:\
 322 debian.upstream/libva-x11.install.in
 323     doc/Makefile
 324     dummy_drv_video/Makefile
 325     pkgconfig/Makefile
 326     pkgconfig/libva-drm.pc
 327     pkgconfig/libva-egl.pc
 328     pkgconfig/libva-glx.pc
 329     pkgconfig/libva-tpi.pc
 330     pkgconfig/libva-wayland.pc
 331     pkgconfig/libva-x11.pc
 332     pkgconfig/libva.pc
 333     test/Makefile
 334     test/basic/Makefile
 335     test/common/Makefile
 336     test/decode/Makefile
 337     test/encode/Makefile
 338     test/putsurface/Makefile
 339     test/vainfo/Makefile
 340     va/Makefile
 341     va/drm/Makefile
 342     va/egl/Makefile
 343     va/glx/Makefile
 344     va/va_version.h
 345     va/wayland/Makefile
 346     va/x11/Makefile
 347 ])
 348
 349 # Print a small summary
 350 BACKENDS=""
 351 AS_IF([test x$USE_DRM = xyes], [BACKENDS="$BACKENDS drm"])
 352 AS_IF([test x$USE_X11 = xyes], [BACKENDS="$BACKENDS x11"])
 353 AS_IF([test x$USE_GLX = xyes], [BACKENDS="$BACKENDS glx"])
 354 AS_IF([test x$USE_EGL = xyes], [BACKENDS="$BACKENDS egl"])
 355 AS_IF([test x$USE_WAYLAND = xyes], [BACKENDS="$BACKENDS wayland"])
 356
 357 echo
 358 echo "libva - ${LIBVA_VERSION} (VA-API ${VA_API_VERSION})"
 359 echo
 360 echo Installation prefix .............. : $prefix
 361 echo Default driver path .............. : $LIBVA_DRIVERS_PATH
 362 echo Extra window systems ............. : $BACKENDS
 363 echo Build dummy driver ............... : $enable_dummy_driver
 364 echo Build documentation .............. : $enable_docs
 365 echo