configure.ac

   1 # Copyright (c) 2007 Intel Corporation. All Rights Reserved.
   2 #
   3 # Permission is hereby granted, free of charge, to any person obtaining a
   4 # copy of this software and associated documentation files (the
   5 # "Software"), to deal in the Software without restriction, including
   6 # without limitation the rights to use, copy, modify, merge, publish,
   7 # distribute, sub license, and/or sell copies of the Software, and to
   8 # permit persons to whom the Software is furnished to do so, subject to
   9 # the following conditions:
  10 #
  11 # The above copyright notice and this permission notice (including the
  12 # next paragraph) shall be included in all copies or substantial portions
  13 # of the Software.
  14 #
  15 # THE SOFTWARE IS PROVIDED "AS IS", WITHOUT WARRANTY OF ANY KIND, EXPRESS
  16 # OR IMPLIED, INCLUDING BUT NOT LIMITED TO THE WARRANTIES OF
  17 # MERCHANTABILITY, FITNESS FOR A PARTICULAR PURPOSE AND NON-INFRINGEMENT.
  18 # IN NO EVENT SHALL PRECISION INSIGHT AND/OR ITS SUPPLIERS BE LIABLE FOR
  19 # ANY CLAIM, DAMAGES OR OTHER LIABILITY, WHETHER IN AN ACTION OF CONTRACT,
  20 # TORT OR OTHERWISE, ARISING FROM, OUT OF OR IN CONNECTION WITH THE
  21 # SOFTWARE OR THE USE OR OTHER DEALINGS IN THE SOFTWARE.
  22
  23 # libva package version number, (as distinct from shared library version)
  24 m4_define([libva_major_version], [0])
  25 m4_define([libva_minor_version], [31])
  26 m4_define([libva_micro_version], [0])
  27
  28 m4_define([libva_version],
  29           [libva_major_version.libva_minor_version.libva_micro_version])
  30
  31 # if the library source code has changed, increment revision
  32 m4_define([libva_lt_revision], [0])
  33 # if any interface was added/removed/changed, then inc current, reset revision
  34 m4_define([libva_lt_current], [1])
  35 # if any interface was added since last public release, then increment age
  36 # if any interface was removed since last public release, then set age to 0
  37 m4_define([libva_lt_age], [0])
  38
  39 AC_PREREQ(2.57)
  40 AC_INIT([libva], [libva_version], [waldo.bastian@intel.com], libva)
  41 AC_CONFIG_SRCDIR([Makefile.am])
  42 AM_INIT_AUTOMAKE([dist-bzip2])
  43
  44 AM_CONFIG_HEADER([config.h])
  45
  46 LIBVA_MAJOR_VERSION=libva_major_version
  47 LIBVA_MINOR_VERSION=libva_minor_version
  48 LIBVA_MICRO_VERSION=libva_micro_version
  49 LIBVA_VERSION=libva_version
  50 AC_SUBST(LIBVA_MAJOR_VERSION)
  51 AC_SUBST(LIBVA_MINOR_VERSION)
  52 AC_SUBST(LIBVA_MICRO_VERSION)
  53 AC_SUBST(LIBVA_VERSION)
  54
  55 LIBVA_LT_CURRENT=libva_lt_current
  56 LIBVA_LT_REV=libva_lt_revision
  57 LIBVA_LT_AGE=libva_lt_age
  58 LIBVA_LT_VERSION="$LIBVA_LT_CURRENT:$LIBVA_LT_REV:$LIBVA_LT_AGE"
  59 LIBVA_LT_LDFLAGS="-version-info $LIBVA_LT_VERSION"
  60 AC_SUBST(LIBVA_LT_VERSION)
  61 AC_SUBST(LIBVA_LT_LDFLAGS)
  62
  63 AC_ARG_ENABLE(dummy-driver,
  64               [AC_HELP_STRING([--enable-dummy-driver],
  65                               [build dummy video driver])],
  66               [], [enable_dummy_driver=yes])
  67 AM_CONDITIONAL(BUILD_DUMMY_DRIVER, test x$enable_dummy_driver = xyes)
  68
  69 AC_ARG_ENABLE(i965-driver,
  70               [AC_HELP_STRING([--enable-i965-driver],
  71                               [build i965 video driver])],
  72               [], [enable_i965_driver=no])
  73
  74 AC_ARG_WITH(drivers-path,
  75             [AC_HELP_STRING([--with-drivers-path=[[path]]], [drivers path])],,
  76             [with_drivers_path="$libdir/dri"])
  77
  78 LIBVA_DRIVERS_PATH="$with_drivers_path"
  79 AC_SUBST(LIBVA_DRIVERS_PATH)
  80
  81 AC_DISABLE_STATIC
  82 AC_PROG_LIBTOOL
  83 AC_PROG_CC
  84
  85 AC_HEADER_STDC
  86 AC_SYS_LARGEFILE
  87
  88 PKG_CHECK_MODULES([X11], [x11])
  89 PKG_CHECK_MODULES([XEXT],[xext])
  90 PKG_CHECK_MODULES([XFIXES], [xfixes])
  91 PKG_CHECK_MODULES([DRM], [libdrm])
  92
  93 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.0], [gen4asm=yes], [gen4asm=no])
  94 AM_CONDITIONAL(HAVE_GEN4ASM, test x$gen4asm = xyes)
  95
  96 # Check for libdrm >= 2.4 (needed for i965_drv_video.so)
  97 if test x$enable_i965_driver = xyes && ! $PKG_CONFIG --atleast-version=2.4 libdrm; then
  98     AC_MSG_WARN([libdrm < 2.4 found, disabling build of i965 video driver])
  99     enable_i965_driver=no
 100 fi
 101 AM_CONDITIONAL(BUILD_I965_DRIVER, test x$enable_i965_driver = xyes)
 102
 103 # We only need the headers, we don't link against the DRM libraries
 104 LIBVA_CFLAGS="$DRM_CFLAGS"
 105 AC_SUBST(LIBVA_CFLAGS)
 106 AC_SUBST(LIBVA_LIBS)
 107
 108 pkgconfigdir=${libdir}/pkgconfig
 109 AC_SUBST(pkgconfigdir)
 110
 111 LIBVA_DISPLAY=x11
 112 libvacorelib=libva.la
 113 libvabackendlib=libva-$LIBVA_DISPLAY.la
 114 AC_SUBST([libvacorelib])
 115 AC_SUBST([libvabackendlib])
 116
 117 AC_OUTPUT([
 118         Makefile
 119         src/Makefile
 120         src/va_version.h
 121         src/x11/Makefile
 122         dummy_drv_video/Makefile
 123         i965_drv_video/Makefile
 124         i965_drv_video/shaders/Makefile
 125         i965_drv_video/shaders/mpeg2/Makefile
 126         i965_drv_video/shaders/mpeg2/vld/Makefile
 127         i965_drv_video/shaders/render/Makefile
 128         test/Makefile
 129         test/basic/Makefile
 130         test/decode/Makefile
 131         test/putsurface/Makefile
 132         test/encode/Makefile
 133         libva.pc
 134         libva-x11.pc
 135 ])
 136