configure.ac

   1 # intel-vaapi-driver package version number
   2 m4_define([intel_vaapi_driver_major_version], [2])
   3 m4_define([intel_vaapi_driver_minor_version], [0])
   4 m4_define([intel_vaapi_driver_micro_version], [1])
   5 m4_define([intel_vaapi_driver_pre_version],   [1])
   6 m4_define([intel_vaapi_driver_version],
   7           [intel_vaapi_driver_major_version.intel_vaapi_driver_minor_version.intel_vaapi_driver_micro_version])
   8 m4_if(intel_vaapi_driver_pre_version, [0], [], [
   9 m4_append([intel_vaapi_driver_version], intel_vaapi_driver_pre_version, [.pre])
  10 ])
  11
  12 # libva minimum version requirement
  13 m4_define([va_api_version], [1.0.0])
  14
  15 # libdrm minimum version requirement
  16 m4_define([libdrm_version], [2.4.52])
  17
  18 # Wayland minimum version requirement
  19 # 1.11.0 for wl_proxy_create_wrapper
  20 m4_define([wayland_api_version], [1.11.0])
  21
  22 AC_PREREQ([2.57])
  23 AC_INIT([intel_vaapi_driver],
  24         [intel_vaapi_driver_version],
  25         [https://github.com/01org/intel-vaapi-driver/issues/new],
  26         [intel-vaapi-driver],
  27         [https://github.com/01org/intel-vaapi-driver])
  28 AC_CONFIG_SRCDIR([Makefile.am])
  29 AM_INIT_AUTOMAKE([1.9 tar-ustar])
  30
  31 AC_CONFIG_HEADERS([src/config.h])
  32
  33 INTEL_DRIVER_MAJOR_VERSION=intel_vaapi_driver_major_version
  34 INTEL_DRIVER_MINOR_VERSION=intel_vaapi_driver_minor_version
  35 INTEL_DRIVER_MICRO_VERSION=intel_vaapi_driver_micro_version
  36 AC_DEFINE([INTEL_DRIVER_MAJOR_VERSION], [intel_vaapi_driver_major_version], [Major version of the driver])
  37 AC_DEFINE([INTEL_DRIVER_MINOR_VERSION], [intel_vaapi_driver_minor_version], [Minor version of the driver])
  38 AC_DEFINE([INTEL_DRIVER_MICRO_VERSION], [intel_vaapi_driver_micro_version], [Micro version of the driver])
  39 AC_DEFINE([INTEL_DRIVER_PRE_VERSION], [intel_vaapi_driver_pre_version], [Preversion of the driver])
  40
  41 INTEL_DRIVER_LT_LDFLAGS="-avoid-version"
  42 AC_SUBST(INTEL_DRIVER_LT_LDFLAGS)
  43
  44 dnl Use pretty build output with automake >= 1.11
  45 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  46     AM_DEFAULT_VERBOSITY=1
  47     AC_SUBST(AM_DEFAULT_VERBOSITY)
  48 ])
  49
  50 AC_ARG_ENABLE(drm,
  51     [AC_HELP_STRING([--enable-drm],
  52                     [build with VA/DRM API support @<:@default=yes@:>@])],
  53     [], [enable_drm="yes"])
  54
  55 AC_ARG_ENABLE(x11,
  56     [AC_HELP_STRING([--enable-x11],
  57                     [build with VA/X11 API support @<:@default=yes@:>@])],
  58     [], [enable_x11="yes"])
  59
  60 AC_ARG_ENABLE([wayland],
  61     [AC_HELP_STRING([--enable-wayland],
  62                     [build with VA/Wayland API support @<:@default=yes@:>@])],
  63     [], [enable_wayland="yes"])
  64
  65 AC_ARG_ENABLE([hybrid-codec],
  66     [AC_HELP_STRING([--enable-hybrid-codec],
  67                     [build with hybrid codec support @<:@default=no@:>@])],
  68     [], [enable_hybrid_codec="no"])
  69
  70 AC_ARG_ENABLE([tests],
  71     [AC_HELP_STRING([--enable-tests],
  72                     [build tests @<:@default=no@:>@])],
  73     [], [enable_tests="no"])
  74
  75 AC_DISABLE_STATIC
  76 AC_PROG_LIBTOOL
  77 AC_PROG_CC
  78 AM_PROG_CC_C_O
  79 AC_PROG_CXX
  80 AC_C_BIGENDIAN
  81 AC_HEADER_STDC
  82 AC_SYS_LARGEFILE
  83 AC_CHECK_LIB([m], [sin])
  84 AC_CHECK_FUNCS([log2f])
  85 AC_CHECK_PROGS([PYTHON2], [python2 python])
  86
  87 LIBVA_PACKAGE_VERSION=libva_package_version
  88 AC_SUBST(LIBVA_PACKAGE_VERSION)
  89
  90 dnl Check for recent enough DRM
  91 LIBDRM_VERSION=libdrm_version
  92 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
  93 AC_SUBST(LIBDRM_VERSION)
  94
  95 dnl Check for gen4asm
  96 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.9], [gen4asm=yes], [gen4asm=no])
  97 AC_PATH_PROG([GEN4ASM], [intel-gen4asm])
  98 AS_IF([test "x$GEN4ASM" = "x" ], [AM_CONDITIONAL(HAVE_GEN4ASM, false)],
  99     [AM_CONDITIONAL(HAVE_GEN4ASM, [test x$gen4asm = xyes])])
 100
 101 dnl Check for git
 102 AC_ARG_VAR([GIT], [Path to git program, if any])
 103 AC_PATH_PROG([GIT], [git])
 104 AM_CONDITIONAL([HAVE_GIT], [test -n "$GIT"])
 105
 106 dnl Check for VA-API
 107 PKG_CHECK_MODULES(LIBVA_DEPS,     [libva >= va_api_version])
 108
 109 dnl Check for VA/DRM API
 110 USE_DRM="$enable_drm"
 111 if test "$USE_DRM" = "yes"; then
 112     PKG_CHECK_MODULES(LIBVA_DRM_DEPS, [libva-drm],
 113       [AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is enabled])],
 114       [USE_DRM="no"])
 115
 116     # Check for <drm_fourcc.h>
 117     if test "$USE_DRM" = "yes"; then
 118         saved_CPPFLAGS="$CPPFLAGS"
 119         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 120         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM="no"])
 121         CPPFLAGS="$saved_CPPFLAGS"
 122     fi
 123 fi
 124 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 125
 126 if test "$enable_hybrid_codec" = "yes"; then
 127     AC_DEFINE([HAVE_HYBRID_CODEC], [1], [Defined to 1 if hybrid codec is needed])
 128 fi
 129
 130 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" = "yes")
 131
 132 VA_VERSION=`$PKG_CONFIG --modversion libva`
 133 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 134 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 135 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 136 VA_VERSION_STR="$VA_VERSION"
 137
 138 va_full_version_int=`expr ${VA_MAJOR_VERSION:-0} "*" 1000000 + \
 139                           ${VA_MINOR_VERSION:-0} "*" 10000   + \
 140                           ${VA_MICRO_VERSION:-0} "*" 100     + \
 141                           0`
 142 VA_DRIVER_INIT_FUNC="__vaDriverInit_${VA_MAJOR_VERSION}_${VA_MINOR_VERSION}"
 143 AC_DEFINE_UNQUOTED([VA_DRIVER_INIT_FUNC], [$VA_DRIVER_INIT_FUNC],
 144     [Define driver entry-point])
 145
 146 dnl Check for VA/DRM API
 147 USE_X11="$enable_x11"
 148
 149 dnl Check for X11
 150 if test "$enable_x11" = "yes"; then
 151     USE_X11="yes"
 152     PKG_CHECK_MODULES([X11],    [x11],    [:], [USE_X11="no"])
 153     PKG_CHECK_MODULES([XEXT],   [xext],   [:], [USE_X11="no"])
 154     PKG_CHECK_MODULES([XFIXES], [xfixes], [:], [USE_X11="no"])
 155 fi
 156
 157 if test "$USE_X11" = "yes"; then
 158     PKG_CHECK_MODULES(LIBVA_X11_DEPS, [libva-x11],
 159       [AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is enabled])],
 160       [USE_X11="no"])
 161 fi
 162 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 163
 164 dnl Check for VA-API drivers path
 165 AC_ARG_VAR(LIBVA_DRIVERS_PATH, [drivers install path])
 166 if test -z "$LIBVA_DRIVERS_PATH"; then
 167     AC_MSG_CHECKING([for VA drivers path])
 168     LIBVA_DRIVERS_PATH=`$PKG_CONFIG libva --variable driverdir`
 169 fi
 170 if test -z "$LIBVA_DRIVERS_PATH"; then
 171     LIBVA_DRIVERS_PATH="${libdir}/xorg/modules/drivers"
 172 fi
 173 AC_MSG_RESULT([$LIBVA_DRIVERS_PATH])
 174 AC_SUBST(LIBVA_DRIVERS_PATH)
 175
 176 # Check for EGL
 177 if test "$enable_wayland" = "yes"; then
 178     enable_egl="yes"
 179 fi
 180
 181 USE_EGL="no"
 182 if test "$enable_egl" = "yes"; then
 183     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [USE_EGL="no"])
 184     saved_CPPFLAGS="$CPPFLAGS"
 185     saved_LIBS="$LIBS"
 186     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 187     LIBS="$LIBS $EGL_LIBS"
 188     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 189     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 190     CPPFLAGS="$saved_CPPFLAGS"
 191     LIBS="$saved_LIBS"
 192 fi
 193 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 194
 195 # Check for Wayland
 196 USE_WAYLAND="no"
 197 if test "$enable_wayland" = "yes"; then
 198     PKG_CHECK_MODULES([LIBVA_WAYLAND_DEPS], [libva-wayland],
 199         [USE_WAYLAND="yes"], [:])
 200
 201     if test "$USE_WAYLAND" = "yes"; then
 202
 203         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client >= wayland_api_version],
 204         [INCLUDES="$INCLUDES $WAYLAND_CLIENT_CFLAGS"], [:])
 205         WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
 206         AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
 207                      [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
 208
 209         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 210                   [Defined to 1 if VA/Wayland API is enabled])
 211     fi
 212 fi
 213 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 214
 215 AC_OUTPUT([
 216     Makefile
 217     src/Makefile
 218     src/shaders/Makefile
 219     src/shaders/brc/Makefile
 220     src/shaders/brc/bsw/Makefile
 221     src/shaders/brc/skl/Makefile
 222     src/shaders/brc/cnl/Makefile
 223     src/shaders/h264/Makefile
 224     src/shaders/h264/ildb/Makefile
 225     src/shaders/h264/mc/Makefile
 226     src/shaders/mpeg2/Makefile
 227     src/shaders/mpeg2/vld/Makefile
 228     src/shaders/post_processing/Makefile
 229     src/shaders/post_processing/gen5_6/Makefile
 230     src/shaders/post_processing/gen7/Makefile
 231     src/shaders/post_processing/gen75/Makefile
 232     src/shaders/post_processing/gen8/Makefile
 233     src/shaders/post_processing/gen9/Makefile
 234     src/shaders/render/Makefile
 235     src/shaders/utils/Makefile
 236     src/shaders/vme/Makefile
 237     test/Makefile
 238 ])
 239
 240 dnl Print summary
 241 BACKENDS=""
 242 AS_IF([test "$USE_DRM" = "yes"], [BACKENDS="$BACKENDS drm"])
 243 AS_IF([test "$USE_X11" = "yes"], [BACKENDS="$BACKENDS x11"])
 244 AS_IF([test "$USE_WAYLAND" = "yes"], [BACKENDS="$BACKENDS wayland"])
 245
 246 echo
 247 echo $PACKAGE configuration summary:
 248 echo
 249 echo VA-API version ................... : $VA_VERSION_STR
 250 echo VA-API drivers path .............. : $LIBVA_DRIVERS_PATH
 251 echo Windowing systems ................ : $BACKENDS
 252 echo Build tests ...................... : $enable_tests
 253 echo