configure.ac

   1 # intel-vaapi-driver package version number
   2 m4_define([intel_vaapi_driver_major_version], [1])
   3 m4_define([intel_vaapi_driver_minor_version], [8])
   4 m4_define([intel_vaapi_driver_micro_version], [2])
   5 m4_define([intel_vaapi_driver_pre_version],   [1])
   6 m4_define([intel_vaapi_driver_version],
   7           [intel_vaapi_driver_major_version.intel_vaapi_driver_minor_version.intel_vaapi_driver_micro_version])
   8 m4_if(intel_vaapi_driver_pre_version, [0], [], [
   9 m4_append([intel_vaapi_driver_version], intel_vaapi_driver_pre_version, [.pre])
  10 ])
  11
  12 # libva minimum version requirement
  13 m4_define([va_api_version], [0.39.4])
  14 m4_define([libva_package_version], [1.7.3])
  15
  16 # libdrm minimum version requirement
  17 m4_define([libdrm_version], [2.4.52])
  18
  19 AC_PREREQ([2.57])
  20 AC_INIT([intel_vaapi_driver],
  21         [intel_vaapi_driver_version],
  22         [https://github.com/01org/intel-vaapi-driver/issues/new],
  23         [intel-vaapi-driver],
  24         [https://github.com/01org/intel-vaapi-driver])
  25 AC_CONFIG_SRCDIR([Makefile.am])
  26 AM_INIT_AUTOMAKE([1.9 tar-ustar])
  27
  28 AC_CONFIG_HEADERS([src/config.h])
  29
  30 INTEL_DRIVER_MAJOR_VERSION=intel_vaapi_driver_major_version
  31 INTEL_DRIVER_MINOR_VERSION=intel_vaapi_driver_minor_version
  32 INTEL_DRIVER_MICRO_VERSION=intel_vaapi_driver_micro_version
  33 AC_DEFINE([INTEL_DRIVER_MAJOR_VERSION], [intel_vaapi_driver_major_version], [Major version of the driver])
  34 AC_DEFINE([INTEL_DRIVER_MINOR_VERSION], [intel_vaapi_driver_minor_version], [Minor version of the driver])
  35 AC_DEFINE([INTEL_DRIVER_MICRO_VERSION], [intel_vaapi_driver_micro_version], [Micro version of the driver])
  36 AC_DEFINE([INTEL_DRIVER_PRE_VERSION], [intel_vaapi_driver_pre_version], [Preversion of the driver])
  37
  38 INTEL_DRIVER_LT_LDFLAGS="-avoid-version"
  39 AC_SUBST(INTEL_DRIVER_LT_LDFLAGS)
  40
  41 dnl Use pretty build output with automake >= 1.11
  42 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  43     AM_DEFAULT_VERBOSITY=1
  44     AC_SUBST(AM_DEFAULT_VERBOSITY)
  45 ])
  46
  47 AC_ARG_ENABLE(drm,
  48     [AC_HELP_STRING([--enable-drm],
  49                     [build with VA/DRM API support @<:@default=yes@:>@])],
  50     [], [enable_drm="yes"])
  51
  52 AC_ARG_ENABLE(x11,
  53     [AC_HELP_STRING([--enable-x11],
  54                     [build with VA/X11 API support @<:@default=yes@:>@])],
  55     [], [enable_x11="yes"])
  56
  57 AC_ARG_ENABLE([wayland],
  58     [AC_HELP_STRING([--enable-wayland],
  59                     [build with VA/Wayland API support @<:@default=yes@:>@])],
  60     [], [enable_wayland="yes"])
  61
  62 AC_ARG_ENABLE([hybrid-codec],
  63     [AC_HELP_STRING([--enable-hybrid-codec],
  64                     [build with hybrid codec support @<:@default=no@:>@])],
  65     [], [enable_hybrid_codec="no"])
  66
  67 AC_ARG_ENABLE([tests],
  68     [AC_HELP_STRING([--enable-tests],
  69                     [build tests @<:@default=no@:>@])],
  70     [], [enable_tests="no"])
  71
  72 AC_DISABLE_STATIC
  73 AC_PROG_LIBTOOL
  74 AC_PROG_CC
  75 AM_PROG_CC_C_O
  76 AC_PROG_CXX
  77 AC_C_BIGENDIAN
  78 AC_HEADER_STDC
  79 AC_SYS_LARGEFILE
  80 AC_CHECK_LIB([m], [sin])
  81 AC_CHECK_FUNCS([log2f])
  82 AC_CHECK_PROGS([PYTHON2], [python2 python])
  83
  84 LIBVA_PACKAGE_VERSION=libva_package_version
  85 AC_SUBST(LIBVA_PACKAGE_VERSION)
  86
  87 dnl Check for recent enough DRM
  88 LIBDRM_VERSION=libdrm_version
  89 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
  90 AC_SUBST(LIBDRM_VERSION)
  91
  92 dnl Check for gen4asm
  93 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.9], [gen4asm=yes], [gen4asm=no])
  94 AC_PATH_PROG([GEN4ASM], [intel-gen4asm])
  95 AS_IF([test "x$GEN4ASM" = "x" ], [AM_CONDITIONAL(HAVE_GEN4ASM, false)],
  96     [AM_CONDITIONAL(HAVE_GEN4ASM, [test x$gen4asm = xyes])])
  97
  98 dnl Check for git
  99 AC_ARG_VAR([GIT], [Path to git program, if any])
 100 AC_PATH_PROG([GIT], [git])
 101 AM_CONDITIONAL([HAVE_GIT], [test -n "$GIT"])
 102
 103 dnl Check for VA-API
 104 PKG_CHECK_MODULES(LIBVA_DEPS,     [libva >= va_api_version])
 105
 106 dnl Check for VA/DRM API
 107 USE_DRM="$enable_drm"
 108 if test "$USE_DRM" = "yes"; then
 109     PKG_CHECK_MODULES(LIBVA_DRM_DEPS, [libva-drm],
 110       [AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is enabled])],
 111       [USE_DRM="no"])
 112
 113     # Check for <drm_fourcc.h>
 114     if test "$USE_DRM" = "yes"; then
 115         saved_CPPFLAGS="$CPPFLAGS"
 116         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 117         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM="no"])
 118         CPPFLAGS="$saved_CPPFLAGS"
 119     fi
 120 fi
 121 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 122
 123 if test "$enable_hybrid_codec" = "yes"; then
 124     AC_DEFINE([HAVE_HYBRID_CODEC], [1], [Defined to 1 if hybrid codec is needed])
 125 fi
 126
 127 AM_CONDITIONAL(ENABLE_TESTS, test "$enable_tests" = "yes")
 128
 129 VA_VERSION=`$PKG_CONFIG --modversion libva`
 130 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 131 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 132 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 133 VA_VERSION_STR="$VA_VERSION"
 134
 135 va_full_version_int=`expr ${VA_MAJOR_VERSION:-0} "*" 1000000 + \
 136                           ${VA_MINOR_VERSION:-0} "*" 10000   + \
 137                           ${VA_MICRO_VERSION:-0} "*" 100     + \
 138                           0`
 139 VA_DRIVER_INIT_FUNC="__vaDriverInit_${VA_MAJOR_VERSION}_${VA_MINOR_VERSION}"
 140 AC_DEFINE_UNQUOTED([VA_DRIVER_INIT_FUNC], [$VA_DRIVER_INIT_FUNC],
 141     [Define driver entry-point])
 142
 143 dnl Check for VA/DRM API
 144 USE_X11="$enable_x11"
 145
 146 dnl Check for X11
 147 if test "$enable_x11" = "yes"; then
 148     USE_X11="yes"
 149     PKG_CHECK_MODULES([X11],    [x11],    [:], [USE_X11="no"])
 150     PKG_CHECK_MODULES([XEXT],   [xext],   [:], [USE_X11="no"])
 151     PKG_CHECK_MODULES([XFIXES], [xfixes], [:], [USE_X11="no"])
 152 fi
 153
 154 if test "$USE_X11" = "yes"; then
 155     PKG_CHECK_MODULES(LIBVA_X11_DEPS, [libva-x11],
 156       [AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is enabled])],
 157       [USE_X11="no"])
 158 fi
 159 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 160
 161 dnl Check for VA-API drivers path
 162 AC_ARG_VAR(LIBVA_DRIVERS_PATH, [drivers install path])
 163 if test -z "$LIBVA_DRIVERS_PATH"; then
 164     AC_MSG_CHECKING([for VA drivers path])
 165     LIBVA_DRIVERS_PATH=`$PKG_CONFIG libva --variable driverdir`
 166 fi
 167 if test -z "$LIBVA_DRIVERS_PATH"; then
 168     LIBVA_DRIVERS_PATH="${libdir}/xorg/modules/drivers"
 169 fi
 170 AC_MSG_RESULT([$LIBVA_DRIVERS_PATH])
 171 AC_SUBST(LIBVA_DRIVERS_PATH)
 172
 173 # Check for EGL
 174 if test "$enable_wayland" = "yes"; then
 175     enable_egl="yes"
 176 fi
 177
 178 USE_EGL="no"
 179 if test "$enable_egl" = "yes"; then
 180     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [USE_EGL="no"])
 181     saved_CPPFLAGS="$CPPFLAGS"
 182     saved_LIBS="$LIBS"
 183     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 184     LIBS="$LIBS $EGL_LIBS"
 185     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 186     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 187     CPPFLAGS="$saved_CPPFLAGS"
 188     LIBS="$saved_LIBS"
 189 fi
 190 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 191
 192 # Check for Wayland
 193 USE_WAYLAND="no"
 194 if test "$enable_wayland" = "yes"; then
 195     PKG_CHECK_MODULES([LIBVA_WAYLAND_DEPS], [libva-wayland],
 196         [USE_WAYLAND="yes"], [:])
 197
 198     if test "$USE_WAYLAND" = "yes"; then
 199
 200         PKG_CHECK_MODULES([WAYLAND_CLIENT], [wayland-client],
 201         [INCLUDES="$INCLUDES $WAYLAND_CLIENT_CFLAGS"], [:])
 202         WAYLAND_PREFIX=`$PKG_CONFIG --variable=prefix wayland-client`
 203         AC_PATH_PROG([WAYLAND_SCANNER], [wayland-scanner],,
 204                      [${WAYLAND_PREFIX}/bin$PATH_SEPARATOR$PATH])
 205
 206         AC_DEFINE([HAVE_VA_WAYLAND], [1],
 207                   [Defined to 1 if VA/Wayland API is enabled])
 208     fi
 209 fi
 210 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 211
 212 AC_OUTPUT([
 213     Makefile
 214     src/Makefile
 215     src/shaders/Makefile
 216     src/shaders/brc/Makefile
 217     src/shaders/brc/bsw/Makefile
 218     src/shaders/brc/skl/Makefile
 219     src/shaders/h264/Makefile
 220     src/shaders/h264/ildb/Makefile
 221     src/shaders/h264/mc/Makefile
 222     src/shaders/mpeg2/Makefile
 223     src/shaders/mpeg2/vld/Makefile
 224     src/shaders/post_processing/Makefile
 225     src/shaders/post_processing/gen5_6/Makefile
 226     src/shaders/post_processing/gen7/Makefile
 227     src/shaders/post_processing/gen75/Makefile
 228     src/shaders/post_processing/gen8/Makefile
 229     src/shaders/post_processing/gen9/Makefile
 230     src/shaders/render/Makefile
 231     src/shaders/utils/Makefile
 232     src/shaders/vme/Makefile
 233     test/Makefile
 234 ])
 235
 236 dnl Print summary
 237 BACKENDS=""
 238 AS_IF([test "$USE_DRM" = "yes"], [BACKENDS="$BACKENDS drm"])
 239 AS_IF([test "$USE_X11" = "yes"], [BACKENDS="$BACKENDS x11"])
 240 AS_IF([test "$USE_WAYLAND" = "yes"], [BACKENDS="$BACKENDS wayland"])
 241
 242 echo
 243 echo $PACKAGE configuration summary:
 244 echo
 245 echo VA-API version ................... : $VA_VERSION_STR
 246 echo VA-API drivers path .............. : $LIBVA_DRIVERS_PATH
 247 echo Windowing systems ................ : $BACKENDS
 248 echo Build tests ...................... : $enable_tests
 249 echo