configure.ac

   1 # intel-driver package version number
   2 m4_define([intel_driver_major_version], [1])
   3 m4_define([intel_driver_minor_version], [7])
   4 m4_define([intel_driver_micro_version], [1])
   5 m4_define([intel_driver_pre_version],   [1])
   6 m4_define([intel_driver_version],
   7           [intel_driver_major_version.intel_driver_minor_version.intel_driver_micro_version])
   8 m4_if(intel_driver_pre_version, [0], [], [
   9 m4_append([intel_driver_version], intel_driver_pre_version, [.pre])
  10 ])
  11
  12 # libva minimum version requirement
  13 m4_define([va_api_version], [0.39.2])
  14 m4_define([libva_package_version], [1.7.0])
  15
  16 # libdrm minimum version requirement
  17 m4_define([libdrm_version], [2.4.45])
  18
  19 AC_PREREQ([2.57])
  20 AC_INIT([intel_driver], [intel_driver_version], [haihao.xiang@intel.com],
  21         [libva-intel-driver])
  22 AC_CONFIG_SRCDIR([Makefile.am])
  23 AM_INIT_AUTOMAKE([1.9 tar-ustar])
  24
  25 AC_CONFIG_HEADERS([src/config.h])
  26
  27 INTEL_DRIVER_MAJOR_VERSION=intel_driver_major_version
  28 INTEL_DRIVER_MINOR_VERSION=intel_driver_minor_version
  29 INTEL_DRIVER_MICRO_VERSION=intel_driver_micro_version
  30 AC_DEFINE([INTEL_DRIVER_MAJOR_VERSION], [intel_driver_major_version], [Major version of the driver])
  31 AC_DEFINE([INTEL_DRIVER_MINOR_VERSION], [intel_driver_minor_version], [Minor version of the driver])
  32 AC_DEFINE([INTEL_DRIVER_MICRO_VERSION], [intel_driver_micro_version], [Micro version of the driver])
  33 AC_DEFINE([INTEL_DRIVER_PRE_VERSION], [intel_driver_pre_version], [Preversion of the driver])
  34
  35 INTEL_DRIVER_LT_LDFLAGS="-avoid-version"
  36 AC_SUBST(INTEL_DRIVER_LT_LDFLAGS)
  37
  38 dnl Use pretty build output with automake >= 1.11
  39 m4_ifdef([AM_SILENT_RULES], [AM_SILENT_RULES([yes])], [
  40     AM_DEFAULT_VERBOSITY=1
  41     AC_SUBST(AM_DEFAULT_VERBOSITY)
  42 ])
  43
  44 AC_ARG_ENABLE(drm,
  45     [AC_HELP_STRING([--enable-drm],
  46                     [build with VA/DRM API support @<:@default=yes@:>@])],
  47     [], [enable_drm="yes"])
  48
  49 AC_ARG_ENABLE(x11,
  50     [AC_HELP_STRING([--enable-x11],
  51                     [build with VA/X11 API support @<:@default=yes@:>@])],
  52     [], [enable_x11="yes"])
  53
  54 AC_ARG_ENABLE([wayland],
  55     [AC_HELP_STRING([--enable-wayland],
  56                     [build with VA/Wayland API support @<:@default=yes@:>@])],
  57     [], [enable_wayland="yes"])
  58
  59 AC_ARG_ENABLE([hybrid-codec],
  60     [AC_HELP_STRING([--enable-hybrid-codec],
  61                     [build with hybrid codec support @<:@default=no@:>@])],
  62     [], [enable_hybrid_codec="no"])
  63
  64 AC_DISABLE_STATIC
  65 AC_PROG_LIBTOOL
  66 AC_PROG_CC
  67 AM_PROG_CC_C_O
  68
  69 AC_C_BIGENDIAN
  70 AC_HEADER_STDC
  71 AC_SYS_LARGEFILE
  72 AC_CHECK_LIB([m], [sin])
  73 AC_CHECK_FUNCS([log2f])
  74 AC_CHECK_PROGS([PYTHON2], [python2 python])
  75
  76 LIBVA_PACKAGE_VERSION=libva_package_version
  77 AC_SUBST(LIBVA_PACKAGE_VERSION)
  78
  79 dnl Check for recent enough DRM
  80 LIBDRM_VERSION=libdrm_version
  81 PKG_CHECK_MODULES([DRM], [libdrm >= $LIBDRM_VERSION])
  82 AC_SUBST(LIBDRM_VERSION)
  83
  84 dnl Check for gen4asm
  85 PKG_CHECK_MODULES(GEN4ASM, [intel-gen4asm >= 1.9], [gen4asm=yes], [gen4asm=no])
  86 AC_PATH_PROG([GEN4ASM], [intel-gen4asm])
  87 AS_IF([test "x$GEN4ASM" = "x" ], [AM_CONDITIONAL(HAVE_GEN4ASM, false)],
  88     [AM_CONDITIONAL(HAVE_GEN4ASM, [test x$gen4asm = xyes])])
  89
  90 dnl Check for git
  91 AC_ARG_VAR([GIT], [Path to git program, if any])
  92 AC_PATH_PROG([GIT], [git])
  93 AM_CONDITIONAL([HAVE_GIT], [test -n "$GIT"])
  94
  95 dnl Check for VA-API
  96 PKG_CHECK_MODULES(LIBVA_DEPS,     [libva >= va_api_version])
  97
  98 dnl Check for VA/DRM API
  99 USE_DRM="$enable_drm"
 100 if test "$USE_DRM" = "yes"; then
 101     PKG_CHECK_MODULES(LIBVA_DRM_DEPS, [libva-drm],
 102       [AC_DEFINE([HAVE_VA_DRM], [1], [Defined to 1 if VA/DRM API is enabled])],
 103       [USE_DRM="no"])
 104
 105     # Check for <drm_fourcc.h>
 106     if test "$USE_DRM" = "yes"; then
 107         saved_CPPFLAGS="$CPPFLAGS"
 108         CPPFLAGS="$CPPFLAGS $DRM_CFLAGS"
 109         AC_CHECK_HEADERS([drm_fourcc.h], [:], [USE_DRM="no"])
 110         CPPFLAGS="$saved_CPPFLAGS"
 111     fi
 112 fi
 113 AM_CONDITIONAL(USE_DRM, test "$USE_DRM" = "yes")
 114
 115 if test "$enable_hybrid_codec" = "yes"; then
 116     AC_DEFINE([HAVE_HYBRID_CODEC], [1], [Defined to 1 if hybrid codec is needed])
 117 fi
 118
 119 VA_VERSION=`$PKG_CONFIG --modversion libva`
 120 VA_MAJOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f1`
 121 VA_MINOR_VERSION=`echo "$VA_VERSION" | cut -d'.' -f2`
 122 VA_MICRO_VERSION=`echo "$VA_VERSION" | cut -d'.' -f3`
 123 VA_VERSION_STR="$VA_VERSION"
 124
 125 va_full_version_int=`expr ${VA_MAJOR_VERSION:-0} "*" 1000000 + \
 126                           ${VA_MINOR_VERSION:-0} "*" 10000   + \
 127                           ${VA_MICRO_VERSION:-0} "*" 100     + \
 128                           0`
 129 VA_DRIVER_INIT_FUNC="__vaDriverInit_${VA_MAJOR_VERSION}_${VA_MINOR_VERSION}"
 130 AC_DEFINE_UNQUOTED([VA_DRIVER_INIT_FUNC], [$VA_DRIVER_INIT_FUNC],
 131     [Define driver entry-point])
 132
 133 dnl Check for VA/DRM API
 134 USE_X11="$enable_x11"
 135 if test "$USE_X11" = "yes"; then
 136     PKG_CHECK_MODULES(LIBVA_X11_DEPS, [libva-x11],
 137       [AC_DEFINE([HAVE_VA_X11], [1], [Defined to 1 if VA/X11 API is enabled])],
 138       [USE_X11="no"])
 139 fi
 140 AM_CONDITIONAL(USE_X11, test "$USE_X11" = "yes")
 141
 142 dnl Check for VA-API drivers path
 143 AC_ARG_VAR(LIBVA_DRIVERS_PATH, [drivers install path])
 144 if test -z "$LIBVA_DRIVERS_PATH"; then
 145     AC_MSG_CHECKING([for VA drivers path])
 146     LIBVA_DRIVERS_PATH=`$PKG_CONFIG libva --variable driverdir`
 147 fi
 148 if test -z "$LIBVA_DRIVERS_PATH"; then
 149     LIBVA_DRIVERS_PATH="${libdir}/xorg/modules/drivers"
 150 fi
 151 AC_MSG_RESULT([$LIBVA_DRIVERS_PATH])
 152 AC_SUBST(LIBVA_DRIVERS_PATH)
 153
 154 # Check for EGL
 155 if test "$enable_wayland" = "yes"; then
 156     enable_egl="yes"
 157 fi
 158
 159 USE_EGL="no"
 160 if test "$enable_egl" = "yes"; then
 161     PKG_CHECK_MODULES([EGL], [egl], [USE_EGL="yes"], [USE_EGL="no"])
 162     saved_CPPFLAGS="$CPPFLAGS"
 163     saved_LIBS="$LIBS"
 164     CPPFLAGS="$CPPFLAGS $EGL_CFLAGS"
 165     LIBS="$LIBS $EGL_LIBS"
 166     AC_CHECK_HEADERS([EGL/egl.h], [:], [USE_EGL="no"])
 167     AC_CHECK_LIB([EGL], [eglGetDisplay], [:], [USE_EGL="no"])
 168     CPPFLAGS="$saved_CPPFLAGS"
 169     LIBS="$saved_LIBS"
 170 fi
 171 AM_CONDITIONAL(USE_EGL, test "$USE_EGL" = "yes")
 172
 173 # Check for Wayland
 174 USE_WAYLAND="no"
 175 if test "$enable_wayland" = "yes"; then
 176     PKG_CHECK_MODULES([WAYLAND], [wayland-client], [USE_WAYLAND="yes"], [:])
 177     PKG_CHECK_MODULES([LIBVA_WAYLAND_DEPS], [libva-wayland],
 178         [AC_DEFINE([HAVE_VA_WAYLAND], [1], [Defined to 1 if VA/Wayland API is enabled])],
 179         [USE_WAYLAND="no"])
 180 fi
 181 AM_CONDITIONAL(USE_WAYLAND, test "$USE_WAYLAND" = "yes")
 182
 183 m4_ifdef([WAYLAND_SCANNER_RULES],
 184     [WAYLAND_SCANNER_RULES(['$(top_builddir)/src/wayland'])],
 185     [wayland_scanner_rules=""; AC_SUBST(wayland_scanner_rules)])
 186
 187 AC_OUTPUT([
 188     Makefile
 189     debian.upstream/Makefile
 190     src/Makefile
 191     src/shaders/Makefile
 192     src/shaders/h264/Makefile
 193     src/shaders/h264/ildb/Makefile
 194     src/shaders/h264/mc/Makefile
 195     src/shaders/mpeg2/Makefile
 196     src/shaders/mpeg2/vld/Makefile
 197     src/shaders/post_processing/Makefile
 198     src/shaders/post_processing/gen5_6/Makefile
 199     src/shaders/post_processing/gen7/Makefile
 200     src/shaders/post_processing/gen75/Makefile
 201     src/shaders/post_processing/gen8/Makefile
 202     src/shaders/post_processing/gen9/Makefile
 203     src/shaders/render/Makefile
 204     src/shaders/utils/Makefile
 205     src/shaders/vme/Makefile
 206     src/wayland/Makefile
 207 ])
 208
 209 dnl Print summary
 210 BACKENDS=""
 211 AS_IF([test "$USE_DRM" = "yes"], [BACKENDS="$BACKENDS drm"])
 212 AS_IF([test "$USE_X11" = "yes"], [BACKENDS="$BACKENDS x11"])
 213 AS_IF([test "$USE_WAYLAND" = "yes"], [BACKENDS="$BACKENDS wayland"])
 214
 215 echo
 216 echo $PACKAGE configuration summary:
 217 echo
 218 echo VA-API version ................... : $VA_VERSION_STR
 219 echo VA-API drivers path .............. : $LIBVA_DRIVERS_PATH
 220 echo Windowing systems ................ : $BACKENDS
 221 echo