arch/x86/kernel/entry_64.S

   1 /*
   2  *  linux/arch/x86_64/entry.S
   3  *
   4  *  Copyright (C) 1991, 1992  Linus Torvalds
   5  *  Copyright (C) 2000, 2001, 2002  Andi Kleen SuSE Labs
   6  *  Copyright (C) 2000  Pavel Machek <pavel@suse.cz>
   7  */
   8
   9 /*
  10  * entry.S contains the system-call and fault low-level handling routines.
  11  *
  12  * Some of this is documented in Documentation/x86/entry_64.txt
  13  *
  14  * NOTE: This code handles signal-recognition, which happens every time
  15  * after an interrupt and after each system call.
  16  *
  17  * Normal syscalls and interrupts don't save a full stack frame, this is
  18  * only done for syscall tracing, signals or fork/exec et.al.
  19  *
  20  * A note on terminology:
  21  * - top of stack: Architecture defined interrupt frame from SS to RIP
  22  * at the top of the kernel process stack.
  23  * - partial stack frame: partially saved registers up to R11.
  24  * - full stack frame: Like partial stack frame, but all register saved.
  25  *
  26  * Some macro usage:
  27  * - CFI macros are used to generate dwarf2 unwind information for better
  28  * backtraces. They don't change any code.
  29  * - SAVE_ALL/RESTORE_ALL - Save/restore all registers
  30  * - SAVE_ARGS/RESTORE_ARGS - Save/restore registers that C functions modify.
  31  * There are unfortunately lots of special cases where some registers
  32  * not touched. The macro is a big mess that should be cleaned up.
  33  * - SAVE_REST/RESTORE_REST - Handle the registers not saved by SAVE_ARGS.
  34  * Gives a full stack frame.
  35  * - ENTRY/END Define functions in the symbol table.
  36  * - FIXUP_TOP_OF_STACK/RESTORE_TOP_OF_STACK - Fix up the hardware stack
  37  * frame that is otherwise undefined after a SYSCALL
  38  * - TRACE_IRQ_* - Trace hard interrupt state for lock debugging.
  39  * - errorentry/paranoidentry/zeroentry - Define exception entry points.
  40  */
  41
  42 #include <linux/linkage.h>
  43 #include <asm/segment.h>
  44 #include <asm/cache.h>
  45 #include <asm/errno.h>
  46 #include <asm/dwarf2.h>
  47 #include <asm/calling.h>
  48 #include <asm/asm-offsets.h>
  49 #include <asm/msr.h>
  50 #include <asm/unistd.h>
  51 #include <asm/thread_info.h>
  52 #include <asm/hw_irq.h>
  53 #include <asm/page_types.h>
  54 #include <asm/irqflags.h>
  55 #include <asm/paravirt.h>
  56 #include <asm/ftrace.h>
  57 #include <asm/percpu.h>
  58 #include <asm/asm.h>
  59 #include <asm/context_tracking.h>
  60 #include <asm/smap.h>
  61 #include <asm/pgtable_types.h>
  62 #include <linux/err.h>
  63
  64 /* Avoid __ASSEMBLER__'ifying <linux/audit.h> just for this.  */
  65 #include <linux/elf-em.h>
  66 #define AUDIT_ARCH_X86_64       (EM_X86_64|__AUDIT_ARCH_64BIT|__AUDIT_ARCH_LE)
  67 #define __AUDIT_ARCH_64BIT 0x80000000
  68 #define __AUDIT_ARCH_LE    0x40000000
  69
  70         .code64
  71         .section .entry.text, "ax"
  72
  73 #ifdef CONFIG_FUNCTION_TRACER
  74
  75 #ifdef CC_USING_FENTRY
  76 # define function_hook  __fentry__
  77 #else
  78 # define function_hook  mcount
  79 #endif
  80
  81 #ifdef CONFIG_DYNAMIC_FTRACE
  82
  83 ENTRY(function_hook)
  84         retq
  85 END(function_hook)
  86
  87 /* skip is set if stack has been adjusted */
  88 .macro ftrace_caller_setup skip=0
  89         MCOUNT_SAVE_FRAME \skip
  90
  91         /* Load the ftrace_ops into the 3rd parameter */
  92         movq function_trace_op(%rip), %rdx
  93
  94         /* Load ip into the first parameter */
  95         movq RIP(%rsp), %rdi
  96         subq $MCOUNT_INSN_SIZE, %rdi
  97         /* Load the parent_ip into the second parameter */
  98 #ifdef CC_USING_FENTRY
  99         movq SS+16(%rsp), %rsi
 100 #else
 101         movq 8(%rbp), %rsi
 102 #endif
 103 .endm
 104
 105 ENTRY(ftrace_caller)
 106         /* Check if tracing was disabled (quick check) */
 107         cmpl $0, function_trace_stop
 108         jne  ftrace_stub
 109
 110         ftrace_caller_setup
 111         /* regs go into 4th parameter (but make it NULL) */
 112         movq $0, %rcx
 113
 114 GLOBAL(ftrace_call)
 115         call ftrace_stub
 116
 117         MCOUNT_RESTORE_FRAME
 118 ftrace_return:
 119
 120 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 121 GLOBAL(ftrace_graph_call)
 122         jmp ftrace_stub
 123 #endif
 124
 125 GLOBAL(ftrace_stub)
 126         retq
 127 END(ftrace_caller)
 128
 129 ENTRY(ftrace_regs_caller)
 130         /* Save the current flags before compare (in SS location)*/
 131         pushfq
 132
 133         /* Check if tracing was disabled (quick check) */
 134         cmpl $0, function_trace_stop
 135         jne  ftrace_restore_flags
 136
 137         /* skip=8 to skip flags saved in SS */
 138         ftrace_caller_setup 8
 139
 140         /* Save the rest of pt_regs */
 141         movq %r15, R15(%rsp)
 142         movq %r14, R14(%rsp)
 143         movq %r13, R13(%rsp)
 144         movq %r12, R12(%rsp)
 145         movq %r11, R11(%rsp)
 146         movq %r10, R10(%rsp)
 147         movq %rbp, RBP(%rsp)
 148         movq %rbx, RBX(%rsp)
 149         /* Copy saved flags */
 150         movq SS(%rsp), %rcx
 151         movq %rcx, EFLAGS(%rsp)
 152         /* Kernel segments */
 153         movq $__KERNEL_DS, %rcx
 154         movq %rcx, SS(%rsp)
 155         movq $__KERNEL_CS, %rcx
 156         movq %rcx, CS(%rsp)
 157         /* Stack - skipping return address */
 158         leaq SS+16(%rsp), %rcx
 159         movq %rcx, RSP(%rsp)
 160
 161         /* regs go into 4th parameter */
 162         leaq (%rsp), %rcx
 163
 164 GLOBAL(ftrace_regs_call)
 165         call ftrace_stub
 166
 167         /* Copy flags back to SS, to restore them */
 168         movq EFLAGS(%rsp), %rax
 169         movq %rax, SS(%rsp)
 170
 171         /* Handlers can change the RIP */
 172         movq RIP(%rsp), %rax
 173         movq %rax, SS+8(%rsp)
 174
 175         /* restore the rest of pt_regs */
 176         movq R15(%rsp), %r15
 177         movq R14(%rsp), %r14
 178         movq R13(%rsp), %r13
 179         movq R12(%rsp), %r12
 180         movq R10(%rsp), %r10
 181         movq RBP(%rsp), %rbp
 182         movq RBX(%rsp), %rbx
 183
 184         /* skip=8 to skip flags saved in SS */
 185         MCOUNT_RESTORE_FRAME 8
 186
 187         /* Restore flags */
 188         popfq
 189
 190         jmp ftrace_return
 191 ftrace_restore_flags:
 192         popfq
 193         jmp  ftrace_stub
 194
 195 END(ftrace_regs_caller)
 196
 197
 198 #else /* ! CONFIG_DYNAMIC_FTRACE */
 199
 200 ENTRY(function_hook)
 201         cmpl $0, function_trace_stop
 202         jne  ftrace_stub
 203
 204         cmpq $ftrace_stub, ftrace_trace_function
 205         jnz trace
 206
 207 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 208         cmpq $ftrace_stub, ftrace_graph_return
 209         jnz ftrace_graph_caller
 210
 211         cmpq $ftrace_graph_entry_stub, ftrace_graph_entry
 212         jnz ftrace_graph_caller
 213 #endif
 214
 215 GLOBAL(ftrace_stub)
 216         retq
 217
 218 trace:
 219         MCOUNT_SAVE_FRAME
 220
 221         movq RIP(%rsp), %rdi
 222 #ifdef CC_USING_FENTRY
 223         movq SS+16(%rsp), %rsi
 224 #else
 225         movq 8(%rbp), %rsi
 226 #endif
 227         subq $MCOUNT_INSN_SIZE, %rdi
 228
 229         call   *ftrace_trace_function
 230
 231         MCOUNT_RESTORE_FRAME
 232
 233         jmp ftrace_stub
 234 END(function_hook)
 235 #endif /* CONFIG_DYNAMIC_FTRACE */
 236 #endif /* CONFIG_FUNCTION_TRACER */
 237
 238 #ifdef CONFIG_FUNCTION_GRAPH_TRACER
 239 ENTRY(ftrace_graph_caller)
 240         MCOUNT_SAVE_FRAME
 241
 242 #ifdef CC_USING_FENTRY
 243         leaq SS+16(%rsp), %rdi
 244         movq $0, %rdx   /* No framepointers needed */
 245 #else
 246         leaq 8(%rbp), %rdi
 247         movq (%rbp), %rdx
 248 #endif
 249         movq RIP(%rsp), %rsi
 250         subq $MCOUNT_INSN_SIZE, %rsi
 251
 252         call    prepare_ftrace_return
 253
 254         MCOUNT_RESTORE_FRAME
 255
 256         retq
 257 END(ftrace_graph_caller)
 258
 259 GLOBAL(return_to_handler)
 260         subq  $24, %rsp
 261
 262         /* Save the return values */
 263         movq %rax, (%rsp)
 264         movq %rdx, 8(%rsp)
 265         movq %rbp, %rdi
 266
 267         call ftrace_return_to_handler
 268
 269         movq %rax, %rdi
 270         movq 8(%rsp), %rdx
 271         movq (%rsp), %rax
 272         addq $24, %rsp
 273         jmp *%rdi
 274 #endif
 275
 276
 277 #ifndef CONFIG_PREEMPT
 278 #define retint_kernel retint_restore_args
 279 #endif
 280
 281 #ifdef CONFIG_PARAVIRT
 282 ENTRY(native_usergs_sysret64)
 283         swapgs
 284         sysretq
 285 ENDPROC(native_usergs_sysret64)
 286 #endif /* CONFIG_PARAVIRT */
 287
 288
 289 .macro TRACE_IRQS_IRETQ offset=ARGOFFSET
 290 #ifdef CONFIG_TRACE_IRQFLAGS
 291         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 292         jnc  1f
 293         TRACE_IRQS_ON
 294 1:
 295 #endif
 296 .endm
 297
 298 /*
 299  * When dynamic function tracer is enabled it will add a breakpoint
 300  * to all locations that it is about to modify, sync CPUs, update
 301  * all the code, sync CPUs, then remove the breakpoints. In this time
 302  * if lockdep is enabled, it might jump back into the debug handler
 303  * outside the updating of the IST protection. (TRACE_IRQS_ON/OFF).
 304  *
 305  * We need to change the IDT table before calling TRACE_IRQS_ON/OFF to
 306  * make sure the stack pointer does not get reset back to the top
 307  * of the debug stack, and instead just reuses the current stack.
 308  */
 309 #if defined(CONFIG_DYNAMIC_FTRACE) && defined(CONFIG_TRACE_IRQFLAGS)
 310
 311 .macro TRACE_IRQS_OFF_DEBUG
 312         call debug_stack_set_zero
 313         TRACE_IRQS_OFF
 314         call debug_stack_reset
 315 .endm
 316
 317 .macro TRACE_IRQS_ON_DEBUG
 318         call debug_stack_set_zero
 319         TRACE_IRQS_ON
 320         call debug_stack_reset
 321 .endm
 322
 323 .macro TRACE_IRQS_IRETQ_DEBUG offset=ARGOFFSET
 324         bt   $9,EFLAGS-\offset(%rsp)    /* interrupts off? */
 325         jnc  1f
 326         TRACE_IRQS_ON_DEBUG
 327 1:
 328 .endm
 329
 330 #else
 331 # define TRACE_IRQS_OFF_DEBUG           TRACE_IRQS_OFF
 332 # define TRACE_IRQS_ON_DEBUG            TRACE_IRQS_ON
 333 # define TRACE_IRQS_IRETQ_DEBUG         TRACE_IRQS_IRETQ
 334 #endif
 335
 336 /*
 337  * C code is not supposed to know about undefined top of stack. Every time
 338  * a C function with an pt_regs argument is called from the SYSCALL based
 339  * fast path FIXUP_TOP_OF_STACK is needed.
 340  * RESTORE_TOP_OF_STACK syncs the syscall state after any possible ptregs
 341  * manipulation.
 342  */
 343
 344         /* %rsp:at FRAMEEND */
 345         .macro FIXUP_TOP_OF_STACK tmp offset=0
 346         movq PER_CPU_VAR(old_rsp),\tmp
 347         movq \tmp,RSP+\offset(%rsp)
 348         movq $__USER_DS,SS+\offset(%rsp)
 349         movq $__USER_CS,CS+\offset(%rsp)
 350         movq $-1,RCX+\offset(%rsp)
 351         movq R11+\offset(%rsp),\tmp  /* get eflags */
 352         movq \tmp,EFLAGS+\offset(%rsp)
 353         .endm
 354
 355         .macro RESTORE_TOP_OF_STACK tmp offset=0
 356         movq RSP+\offset(%rsp),\tmp
 357         movq \tmp,PER_CPU_VAR(old_rsp)
 358         movq EFLAGS+\offset(%rsp),\tmp
 359         movq \tmp,R11+\offset(%rsp)
 360         .endm
 361
 362         .macro FAKE_STACK_FRAME child_rip
 363         /* push in order ss, rsp, eflags, cs, rip */
 364         xorl %eax, %eax
 365         pushq_cfi $__KERNEL_DS /* ss */
 366         /*CFI_REL_OFFSET        ss,0*/
 367         pushq_cfi %rax /* rsp */
 368         CFI_REL_OFFSET  rsp,0
 369         pushq_cfi $(X86_EFLAGS_IF|X86_EFLAGS_BIT1) /* eflags - interrupts on */
 370         /*CFI_REL_OFFSET        rflags,0*/
 371         pushq_cfi $__KERNEL_CS /* cs */
 372         /*CFI_REL_OFFSET        cs,0*/
 373         pushq_cfi \child_rip /* rip */
 374         CFI_REL_OFFSET  rip,0
 375         pushq_cfi %rax /* orig rax */
 376         .endm
 377
 378         .macro UNFAKE_STACK_FRAME
 379         addq $8*6, %rsp
 380         CFI_ADJUST_CFA_OFFSET   -(6*8)
 381         .endm
 382
 383 /*
 384  * initial frame state for interrupts (and exceptions without error code)
 385  */
 386         .macro EMPTY_FRAME start=1 offset=0
 387         .if \start
 388         CFI_STARTPROC simple
 389         CFI_SIGNAL_FRAME
 390         CFI_DEF_CFA rsp,8+\offset
 391         .else
 392         CFI_DEF_CFA_OFFSET 8+\offset
 393         .endif
 394         .endm
 395
 396 /*
 397  * initial frame state for interrupts (and exceptions without error code)
 398  */
 399         .macro INTR_FRAME start=1 offset=0
 400         EMPTY_FRAME \start, SS+8+\offset-RIP
 401         /*CFI_REL_OFFSET ss, SS+\offset-RIP*/
 402         CFI_REL_OFFSET rsp, RSP+\offset-RIP
 403         /*CFI_REL_OFFSET rflags, EFLAGS+\offset-RIP*/
 404         /*CFI_REL_OFFSET cs, CS+\offset-RIP*/
 405         CFI_REL_OFFSET rip, RIP+\offset-RIP
 406         .endm
 407
 408 /*
 409  * initial frame state for exceptions with error code (and interrupts
 410  * with vector already pushed)
 411  */
 412         .macro XCPT_FRAME start=1 offset=0
 413         INTR_FRAME \start, RIP+\offset-ORIG_RAX
 414         /*CFI_REL_OFFSET orig_rax, ORIG_RAX-ORIG_RAX*/
 415         .endm
 416
 417 /*
 418  * frame that enables calling into C.
 419  */
 420         .macro PARTIAL_FRAME start=1 offset=0
 421         XCPT_FRAME \start, ORIG_RAX+\offset-ARGOFFSET
 422         CFI_REL_OFFSET rdi, RDI+\offset-ARGOFFSET
 423         CFI_REL_OFFSET rsi, RSI+\offset-ARGOFFSET
 424         CFI_REL_OFFSET rdx, RDX+\offset-ARGOFFSET
 425         CFI_REL_OFFSET rcx, RCX+\offset-ARGOFFSET
 426         CFI_REL_OFFSET rax, RAX+\offset-ARGOFFSET
 427         CFI_REL_OFFSET r8, R8+\offset-ARGOFFSET
 428         CFI_REL_OFFSET r9, R9+\offset-ARGOFFSET
 429         CFI_REL_OFFSET r10, R10+\offset-ARGOFFSET
 430         CFI_REL_OFFSET r11, R11+\offset-ARGOFFSET
 431         .endm
 432
 433 /*
 434  * frame that enables passing a complete pt_regs to a C function.
 435  */
 436         .macro DEFAULT_FRAME start=1 offset=0
 437         PARTIAL_FRAME \start, R11+\offset-R15
 438         CFI_REL_OFFSET rbx, RBX+\offset
 439         CFI_REL_OFFSET rbp, RBP+\offset
 440         CFI_REL_OFFSET r12, R12+\offset
 441         CFI_REL_OFFSET r13, R13+\offset
 442         CFI_REL_OFFSET r14, R14+\offset
 443         CFI_REL_OFFSET r15, R15+\offset
 444         .endm
 445
 446 /* save partial stack frame */
 447         .macro SAVE_ARGS_IRQ
 448         cld
 449         /* start from rbp in pt_regs and jump over */
 450         movq_cfi rdi, (RDI-RBP)
 451         movq_cfi rsi, (RSI-RBP)
 452         movq_cfi rdx, (RDX-RBP)
 453         movq_cfi rcx, (RCX-RBP)
 454         movq_cfi rax, (RAX-RBP)
 455         movq_cfi  r8,  (R8-RBP)
 456         movq_cfi  r9,  (R9-RBP)
 457         movq_cfi r10, (R10-RBP)
 458         movq_cfi r11, (R11-RBP)
 459
 460         /* Save rbp so that we can unwind from get_irq_regs() */
 461         movq_cfi rbp, 0
 462
 463         /* Save previous stack value */
 464         movq %rsp, %rsi
 465
 466         leaq -RBP(%rsp),%rdi    /* arg1 for handler */
 467         testl $3, CS-RBP(%rsi)
 468         je 1f
 469         SWAPGS
 470         /*
 471          * irq_count is used to check if a CPU is already on an interrupt stack
 472          * or not. While this is essentially redundant with preempt_count it is
 473          * a little cheaper to use a separate counter in the PDA (short of
 474          * moving irq_enter into assembly, which would be too much work)
 475          */
 476 1:      incl PER_CPU_VAR(irq_count)
 477         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
 478         CFI_DEF_CFA_REGISTER    rsi
 479
 480         /* Store previous stack value */
 481         pushq %rsi
 482         CFI_ESCAPE      0x0f /* DW_CFA_def_cfa_expression */, 6, \
 483                         0x77 /* DW_OP_breg7 */, 0, \
 484                         0x06 /* DW_OP_deref */, \
 485                         0x08 /* DW_OP_const1u */, SS+8-RBP, \
 486                         0x22 /* DW_OP_plus */
 487         /* We entered an interrupt context - irqs are off: */
 488         TRACE_IRQS_OFF
 489         .endm
 490
 491 ENTRY(save_rest)
 492         PARTIAL_FRAME 1 (REST_SKIP+8)
 493         movq 5*8+16(%rsp), %r11 /* save return address */
 494         movq_cfi rbx, RBX+16
 495         movq_cfi rbp, RBP+16
 496         movq_cfi r12, R12+16
 497         movq_cfi r13, R13+16
 498         movq_cfi r14, R14+16
 499         movq_cfi r15, R15+16
 500         movq %r11, 8(%rsp)      /* return address */
 501         FIXUP_TOP_OF_STACK %r11, 16
 502         ret
 503         CFI_ENDPROC
 504 END(save_rest)
 505
 506 /* save complete stack frame */
 507         .pushsection .kprobes.text, "ax"
 508 ENTRY(save_paranoid)
 509         XCPT_FRAME 1 RDI+8
 510         cld
 511         movq_cfi rdi, RDI+8
 512         movq_cfi rsi, RSI+8
 513         movq_cfi rdx, RDX+8
 514         movq_cfi rcx, RCX+8
 515         movq_cfi rax, RAX+8
 516         movq_cfi r8, R8+8
 517         movq_cfi r9, R9+8
 518         movq_cfi r10, R10+8
 519         movq_cfi r11, R11+8
 520         movq_cfi rbx, RBX+8
 521         movq_cfi rbp, RBP+8
 522         movq_cfi r12, R12+8
 523         movq_cfi r13, R13+8
 524         movq_cfi r14, R14+8
 525         movq_cfi r15, R15+8
 526         movl $1,%ebx
 527         movl $MSR_GS_BASE,%ecx
 528         rdmsr
 529         testl %edx,%edx
 530         js 1f   /* negative -> in kernel */
 531         SWAPGS
 532         xorl %ebx,%ebx
 533 1:      ret
 534         CFI_ENDPROC
 535 END(save_paranoid)
 536         .popsection
 537
 538 /*
 539  * A newly forked process directly context switches into this address.
 540  *
 541  * rdi: prev task we switched from
 542  */
 543 ENTRY(ret_from_fork)
 544         DEFAULT_FRAME
 545
 546         LOCK ; btr $TIF_FORK,TI_flags(%r8)
 547
 548         pushq_cfi $0x0002
 549         popfq_cfi                               # reset kernel eflags
 550
 551         call schedule_tail                      # rdi: 'prev' task parameter
 552
 553         GET_THREAD_INFO(%rcx)
 554
 555         RESTORE_REST
 556
 557         testl $3, CS-ARGOFFSET(%rsp)            # from kernel_thread?
 558         jz   1f
 559
 560         testl $_TIF_IA32, TI_flags(%rcx)        # 32-bit compat task needs IRET
 561         jnz  int_ret_from_sys_call
 562
 563         RESTORE_TOP_OF_STACK %rdi, -ARGOFFSET
 564         jmp ret_from_sys_call                   # go to the SYSRET fastpath
 565
 566 1:
 567         subq $REST_SKIP, %rsp   # leave space for volatiles
 568         CFI_ADJUST_CFA_OFFSET   REST_SKIP
 569         movq %rbp, %rdi
 570         call *%rbx
 571         movl $0, RAX(%rsp)
 572         RESTORE_REST
 573         jmp int_ret_from_sys_call
 574         CFI_ENDPROC
 575 END(ret_from_fork)
 576
 577 /*
 578  * System call entry. Up to 6 arguments in registers are supported.
 579  *
 580  * SYSCALL does not save anything on the stack and does not change the
 581  * stack pointer.  However, it does mask the flags register for us, so
 582  * CLD and CLAC are not needed.
 583  */
 584
 585 /*
 586  * Register setup:
 587  * rax  system call number
 588  * rdi  arg0
 589  * rcx  return address for syscall/sysret, C arg3
 590  * rsi  arg1
 591  * rdx  arg2
 592  * r10  arg3    (--> moved to rcx for C)
 593  * r8   arg4
 594  * r9   arg5
 595  * r11  eflags for syscall/sysret, temporary for C
 596  * r12-r15,rbp,rbx saved by C code, not touched.
 597  *
 598  * Interrupts are off on entry.
 599  * Only called from user space.
 600  *
 601  * XXX  if we had a free scratch register we could save the RSP into the stack frame
 602  *      and report it properly in ps. Unfortunately we haven't.
 603  *
 604  * When user can change the frames always force IRET. That is because
 605  * it deals with uncanonical addresses better. SYSRET has trouble
 606  * with them due to bugs in both AMD and Intel CPUs.
 607  */
 608
 609 ENTRY(system_call)
 610         CFI_STARTPROC   simple
 611         CFI_SIGNAL_FRAME
 612         CFI_DEF_CFA     rsp,KERNEL_STACK_OFFSET
 613         CFI_REGISTER    rip,rcx
 614         /*CFI_REGISTER  rflags,r11*/
 615         SWAPGS_UNSAFE_STACK
 616         /*
 617          * A hypervisor implementation might want to use a label
 618          * after the swapgs, so that it can do the swapgs
 619          * for the guest and jump here on syscall.
 620          */
 621 GLOBAL(system_call_after_swapgs)
 622
 623         movq    %rsp,PER_CPU_VAR(old_rsp)
 624         movq    PER_CPU_VAR(kernel_stack),%rsp
 625         /*
 626          * No need to follow this irqs off/on section - it's straight
 627          * and short:
 628          */
 629         ENABLE_INTERRUPTS(CLBR_NONE)
 630         SAVE_ARGS 8,0
 631         movq  %rax,ORIG_RAX-ARGOFFSET(%rsp)
 632         movq  %rcx,RIP-ARGOFFSET(%rsp)
 633         CFI_REL_OFFSET rip,RIP-ARGOFFSET
 634         testl $_TIF_WORK_SYSCALL_ENTRY,TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 635         jnz tracesys
 636 system_call_fastpath:
 637 #if __SYSCALL_MASK == ~0
 638         cmpq $__NR_syscall_max,%rax
 639 #else
 640         andl $__SYSCALL_MASK,%eax
 641         cmpl $__NR_syscall_max,%eax
 642 #endif
 643         ja badsys
 644         movq %r10,%rcx
 645         call *sys_call_table(,%rax,8)  # XXX:    rip relative
 646         movq %rax,RAX-ARGOFFSET(%rsp)
 647 /*
 648  * Syscall return path ending with SYSRET (fast path)
 649  * Has incomplete stack frame and undefined top of stack.
 650  */
 651 ret_from_sys_call:
 652         movl $_TIF_ALLWORK_MASK,%edi
 653         /* edi: flagmask */
 654 sysret_check:
 655         LOCKDEP_SYS_EXIT
 656         DISABLE_INTERRUPTS(CLBR_NONE)
 657         TRACE_IRQS_OFF
 658         movl TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET),%edx
 659         andl %edi,%edx
 660         jnz  sysret_careful
 661         CFI_REMEMBER_STATE
 662         /*
 663          * sysretq will re-enable interrupts:
 664          */
 665         TRACE_IRQS_ON
 666         movq RIP-ARGOFFSET(%rsp),%rcx
 667         CFI_REGISTER    rip,rcx
 668         RESTORE_ARGS 1,-ARG_SKIP,0
 669         /*CFI_REGISTER  rflags,r11*/
 670         movq    PER_CPU_VAR(old_rsp), %rsp
 671         USERGS_SYSRET64
 672
 673         CFI_RESTORE_STATE
 674         /* Handle reschedules */
 675         /* edx: work, edi: workmask */
 676 sysret_careful:
 677         bt $TIF_NEED_RESCHED,%edx
 678         jnc sysret_signal
 679         TRACE_IRQS_ON
 680         ENABLE_INTERRUPTS(CLBR_NONE)
 681         pushq_cfi %rdi
 682         SCHEDULE_USER
 683         popq_cfi %rdi
 684         jmp sysret_check
 685
 686         /* Handle a signal */
 687 sysret_signal:
 688         TRACE_IRQS_ON
 689         ENABLE_INTERRUPTS(CLBR_NONE)
 690 #ifdef CONFIG_AUDITSYSCALL
 691         bt $TIF_SYSCALL_AUDIT,%edx
 692         jc sysret_audit
 693 #endif
 694         /*
 695          * We have a signal, or exit tracing or single-step.
 696          * These all wind up with the iret return path anyway,
 697          * so just join that path right now.
 698          */
 699         FIXUP_TOP_OF_STACK %r11, -ARGOFFSET
 700         jmp int_check_syscall_exit_work
 701
 702 badsys:
 703         movq $-ENOSYS,RAX-ARGOFFSET(%rsp)
 704         jmp ret_from_sys_call
 705
 706 #ifdef CONFIG_AUDITSYSCALL
 707         /*
 708          * Fast path for syscall audit without full syscall trace.
 709          * We just call __audit_syscall_entry() directly, and then
 710          * jump back to the normal fast path.
 711          */
 712 auditsys:
 713         movq %r10,%r9                   /* 6th arg: 4th syscall arg */
 714         movq %rdx,%r8                   /* 5th arg: 3rd syscall arg */
 715         movq %rsi,%rcx                  /* 4th arg: 2nd syscall arg */
 716         movq %rdi,%rdx                  /* 3rd arg: 1st syscall arg */
 717         movq %rax,%rsi                  /* 2nd arg: syscall number */
 718         movl $AUDIT_ARCH_X86_64,%edi    /* 1st arg: audit arch */
 719         call __audit_syscall_entry
 720         LOAD_ARGS 0             /* reload call-clobbered registers */
 721         jmp system_call_fastpath
 722
 723         /*
 724          * Return fast path for syscall audit.  Call __audit_syscall_exit()
 725          * directly and then jump back to the fast path with TIF_SYSCALL_AUDIT
 726          * masked off.
 727          */
 728 sysret_audit:
 729         movq RAX-ARGOFFSET(%rsp),%rsi   /* second arg, syscall return value */
 730         cmpq $-MAX_ERRNO,%rsi   /* is it < -MAX_ERRNO? */
 731         setbe %al               /* 1 if so, 0 if not */
 732         movzbl %al,%edi         /* zero-extend that into %edi */
 733         call __audit_syscall_exit
 734         movl $(_TIF_ALLWORK_MASK & ~_TIF_SYSCALL_AUDIT),%edi
 735         jmp sysret_check
 736 #endif  /* CONFIG_AUDITSYSCALL */
 737
 738         /* Do syscall tracing */
 739 tracesys:
 740 #ifdef CONFIG_AUDITSYSCALL
 741         testl $(_TIF_WORK_SYSCALL_ENTRY & ~_TIF_SYSCALL_AUDIT),TI_flags+THREAD_INFO(%rsp,RIP-ARGOFFSET)
 742         jz auditsys
 743 #endif
 744         SAVE_REST
 745         movq $-ENOSYS,RAX(%rsp) /* ptrace can change this for a bad syscall */
 746         FIXUP_TOP_OF_STACK %rdi
 747         movq %rsp,%rdi
 748         call syscall_trace_enter
 749         /*
 750          * Reload arg registers from stack in case ptrace changed them.
 751          * We don't reload %rax because syscall_trace_enter() returned
 752          * the value it wants us to use in the table lookup.
 753          */
 754         LOAD_ARGS ARGOFFSET, 1
 755         RESTORE_REST
 756 #if __SYSCALL_MASK == ~0
 757         cmpq $__NR_syscall_max,%rax
 758 #else
 759         andl $__SYSCALL_MASK,%eax
 760         cmpl $__NR_syscall_max,%eax
 761 #endif
 762         ja   int_ret_from_sys_call      /* RAX(%rsp) set to -ENOSYS above */
 763         movq %r10,%rcx  /* fixup for C */
 764         call *sys_call_table(,%rax,8)
 765         movq %rax,RAX-ARGOFFSET(%rsp)
 766         /* Use IRET because user could have changed frame */
 767
 768 /*
 769  * Syscall return path ending with IRET.
 770  * Has correct top of stack, but partial stack frame.
 771  */
 772 GLOBAL(int_ret_from_sys_call)
 773         DISABLE_INTERRUPTS(CLBR_NONE)
 774         TRACE_IRQS_OFF
 775         movl $_TIF_ALLWORK_MASK,%edi
 776         /* edi: mask to check */
 777 GLOBAL(int_with_check)
 778         LOCKDEP_SYS_EXIT_IRQ
 779         GET_THREAD_INFO(%rcx)
 780         movl TI_flags(%rcx),%edx
 781         andl %edi,%edx
 782         jnz   int_careful
 783         andl    $~TS_COMPAT,TI_status(%rcx)
 784         jmp   retint_swapgs
 785
 786         /* Either reschedule or signal or syscall exit tracking needed. */
 787         /* First do a reschedule test. */
 788         /* edx: work, edi: workmask */
 789 int_careful:
 790         bt $TIF_NEED_RESCHED,%edx
 791         jnc  int_very_careful
 792         TRACE_IRQS_ON
 793         ENABLE_INTERRUPTS(CLBR_NONE)
 794         pushq_cfi %rdi
 795         SCHEDULE_USER
 796         popq_cfi %rdi
 797         DISABLE_INTERRUPTS(CLBR_NONE)
 798         TRACE_IRQS_OFF
 799         jmp int_with_check
 800
 801         /* handle signals and tracing -- both require a full stack frame */
 802 int_very_careful:
 803         TRACE_IRQS_ON
 804         ENABLE_INTERRUPTS(CLBR_NONE)
 805 int_check_syscall_exit_work:
 806         SAVE_REST
 807         /* Check for syscall exit trace */
 808         testl $_TIF_WORK_SYSCALL_EXIT,%edx
 809         jz int_signal
 810         pushq_cfi %rdi
 811         leaq 8(%rsp),%rdi       # &ptregs -> arg1
 812         call syscall_trace_leave
 813         popq_cfi %rdi
 814         andl $~(_TIF_WORK_SYSCALL_EXIT|_TIF_SYSCALL_EMU),%edi
 815         jmp int_restore_rest
 816
 817 int_signal:
 818         testl $_TIF_DO_NOTIFY_MASK,%edx
 819         jz 1f
 820         movq %rsp,%rdi          # &ptregs -> arg1
 821         xorl %esi,%esi          # oldset -> arg2
 822         call do_notify_resume
 823 1:      movl $_TIF_WORK_MASK,%edi
 824 int_restore_rest:
 825         RESTORE_REST
 826         DISABLE_INTERRUPTS(CLBR_NONE)
 827         TRACE_IRQS_OFF
 828         jmp int_with_check
 829         CFI_ENDPROC
 830 END(system_call)
 831
 832         .macro FORK_LIKE func
 833 ENTRY(stub_\func)
 834         CFI_STARTPROC
 835         popq    %r11                    /* save return address */
 836         PARTIAL_FRAME 0
 837         SAVE_REST
 838         pushq   %r11                    /* put it back on stack */
 839         FIXUP_TOP_OF_STACK %r11, 8
 840         DEFAULT_FRAME 0 8               /* offset 8: return address */
 841         call sys_\func
 842         RESTORE_TOP_OF_STACK %r11, 8
 843         ret $REST_SKIP          /* pop extended registers */
 844         CFI_ENDPROC
 845 END(stub_\func)
 846         .endm
 847
 848         .macro FIXED_FRAME label,func
 849 ENTRY(\label)
 850         CFI_STARTPROC
 851         PARTIAL_FRAME 0 8               /* offset 8: return address */
 852         FIXUP_TOP_OF_STACK %r11, 8-ARGOFFSET
 853         call \func
 854         RESTORE_TOP_OF_STACK %r11, 8-ARGOFFSET
 855         ret
 856         CFI_ENDPROC
 857 END(\label)
 858         .endm
 859
 860         FORK_LIKE  clone
 861         FORK_LIKE  fork
 862         FORK_LIKE  vfork
 863         FIXED_FRAME stub_iopl, sys_iopl
 864
 865 ENTRY(ptregscall_common)
 866         DEFAULT_FRAME 1 8       /* offset 8: return address */
 867         RESTORE_TOP_OF_STACK %r11, 8
 868         movq_cfi_restore R15+8, r15
 869         movq_cfi_restore R14+8, r14
 870         movq_cfi_restore R13+8, r13
 871         movq_cfi_restore R12+8, r12
 872         movq_cfi_restore RBP+8, rbp
 873         movq_cfi_restore RBX+8, rbx
 874         ret $REST_SKIP          /* pop extended registers */
 875         CFI_ENDPROC
 876 END(ptregscall_common)
 877
 878 ENTRY(stub_execve)
 879         CFI_STARTPROC
 880         addq $8, %rsp
 881         PARTIAL_FRAME 0
 882         SAVE_REST
 883         FIXUP_TOP_OF_STACK %r11
 884         call sys_execve
 885         movq %rax,RAX(%rsp)
 886         RESTORE_REST
 887         jmp int_ret_from_sys_call
 888         CFI_ENDPROC
 889 END(stub_execve)
 890
 891 /*
 892  * sigreturn is special because it needs to restore all registers on return.
 893  * This cannot be done with SYSRET, so use the IRET return path instead.
 894  */
 895 ENTRY(stub_rt_sigreturn)
 896         CFI_STARTPROC
 897         addq $8, %rsp
 898         PARTIAL_FRAME 0
 899         SAVE_REST
 900         FIXUP_TOP_OF_STACK %r11
 901         call sys_rt_sigreturn
 902         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 903         RESTORE_REST
 904         jmp int_ret_from_sys_call
 905         CFI_ENDPROC
 906 END(stub_rt_sigreturn)
 907
 908 #ifdef CONFIG_X86_X32_ABI
 909 ENTRY(stub_x32_rt_sigreturn)
 910         CFI_STARTPROC
 911         addq $8, %rsp
 912         PARTIAL_FRAME 0
 913         SAVE_REST
 914         FIXUP_TOP_OF_STACK %r11
 915         call sys32_x32_rt_sigreturn
 916         movq %rax,RAX(%rsp) # fixme, this could be done at the higher layer
 917         RESTORE_REST
 918         jmp int_ret_from_sys_call
 919         CFI_ENDPROC
 920 END(stub_x32_rt_sigreturn)
 921
 922 ENTRY(stub_x32_execve)
 923         CFI_STARTPROC
 924         addq $8, %rsp
 925         PARTIAL_FRAME 0
 926         SAVE_REST
 927         FIXUP_TOP_OF_STACK %r11
 928         call compat_sys_execve
 929         RESTORE_TOP_OF_STACK %r11
 930         movq %rax,RAX(%rsp)
 931         RESTORE_REST
 932         jmp int_ret_from_sys_call
 933         CFI_ENDPROC
 934 END(stub_x32_execve)
 935
 936 #endif
 937
 938 /*
 939  * Build the entry stubs and pointer table with some assembler magic.
 940  * We pack 7 stubs into a single 32-byte chunk, which will fit in a
 941  * single cache line on all modern x86 implementations.
 942  */
 943         .section .init.rodata,"a"
 944 ENTRY(interrupt)
 945         .section .entry.text
 946         .p2align 5
 947         .p2align CONFIG_X86_L1_CACHE_SHIFT
 948 ENTRY(irq_entries_start)
 949         INTR_FRAME
 950 vector=FIRST_EXTERNAL_VECTOR
 951 .rept (NR_VECTORS-FIRST_EXTERNAL_VECTOR+6)/7
 952         .balign 32
 953   .rept 7
 954     .if vector < NR_VECTORS
 955       .if vector <> FIRST_EXTERNAL_VECTOR
 956         CFI_ADJUST_CFA_OFFSET -8
 957       .endif
 958 1:      pushq_cfi $(~vector+0x80)       /* Note: always in signed byte range */
 959       .if ((vector-FIRST_EXTERNAL_VECTOR)%7) <> 6
 960         jmp 2f
 961       .endif
 962       .previous
 963         .quad 1b
 964       .section .entry.text
 965 vector=vector+1
 966     .endif
 967   .endr
 968 2:      jmp common_interrupt
 969 .endr
 970         CFI_ENDPROC
 971 END(irq_entries_start)
 972
 973 .previous
 974 END(interrupt)
 975 .previous
 976
 977 /*
 978  * Interrupt entry/exit.
 979  *
 980  * Interrupt entry points save only callee clobbered registers in fast path.
 981  *
 982  * Entry runs with interrupts off.
 983  */
 984
 985 /* 0(%rsp): ~(interrupt number) */
 986         .macro interrupt func
 987         /* reserve pt_regs for scratch regs and rbp */
 988         subq $ORIG_RAX-RBP, %rsp
 989         CFI_ADJUST_CFA_OFFSET ORIG_RAX-RBP
 990         SAVE_ARGS_IRQ
 991         call \func
 992         .endm
 993
 994 /*
 995  * Interrupt entry/exit should be protected against kprobes
 996  */
 997         .pushsection .kprobes.text, "ax"
 998         /*
 999          * The interrupt stubs push (~vector+0x80) onto the stack and
1000          * then jump to common_interrupt.
1001          */
1002         .p2align CONFIG_X86_L1_CACHE_SHIFT
1003 common_interrupt:
1004         XCPT_FRAME
1005         ASM_CLAC
1006         addq $-0x80,(%rsp)              /* Adjust vector to [-256,-1] range */
1007         interrupt do_IRQ
1008         /* 0(%rsp): old_rsp-ARGOFFSET */
1009 ret_from_intr:
1010         DISABLE_INTERRUPTS(CLBR_NONE)
1011         TRACE_IRQS_OFF
1012         decl PER_CPU_VAR(irq_count)
1013
1014         /* Restore saved previous stack */
1015         popq %rsi
1016         CFI_DEF_CFA rsi,SS+8-RBP        /* reg/off reset after def_cfa_expr */
1017         leaq ARGOFFSET-RBP(%rsi), %rsp
1018         CFI_DEF_CFA_REGISTER    rsp
1019         CFI_ADJUST_CFA_OFFSET   RBP-ARGOFFSET
1020
1021 exit_intr:
1022         GET_THREAD_INFO(%rcx)
1023         testl $3,CS-ARGOFFSET(%rsp)
1024         je retint_kernel
1025
1026         /* Interrupt came from user space */
1027         /*
1028          * Has a correct top of stack, but a partial stack frame
1029          * %rcx: thread info. Interrupts off.
1030          */
1031 retint_with_reschedule:
1032         movl $_TIF_WORK_MASK,%edi
1033 retint_check:
1034         LOCKDEP_SYS_EXIT_IRQ
1035         movl TI_flags(%rcx),%edx
1036         andl %edi,%edx
1037         CFI_REMEMBER_STATE
1038         jnz  retint_careful
1039
1040 retint_swapgs:          /* return to user-space */
1041         /*
1042          * The iretq could re-enable interrupts:
1043          */
1044         DISABLE_INTERRUPTS(CLBR_ANY)
1045         TRACE_IRQS_IRETQ
1046         SWAPGS
1047         jmp restore_args
1048
1049 retint_restore_args:    /* return to kernel space */
1050         DISABLE_INTERRUPTS(CLBR_ANY)
1051         /*
1052          * The iretq could re-enable interrupts:
1053          */
1054         TRACE_IRQS_IRETQ
1055 restore_args:
1056         RESTORE_ARGS 1,8,1
1057
1058 irq_return:
1059         /*
1060          * Are we returning to a stack segment from the LDT?  Note: in
1061          * 64-bit mode SS:RSP on the exception stack is always valid.
1062          */
1063 #ifdef CONFIG_X86_ESPFIX64
1064         testb $4,(SS-RIP)(%rsp)
1065         jnz irq_return_ldt
1066 #endif
1067
1068 irq_return_iret:
1069         INTERRUPT_RETURN
1070         _ASM_EXTABLE(irq_return_iret, bad_iret)
1071
1072 #ifdef CONFIG_PARAVIRT
1073 ENTRY(native_iret)
1074         iretq
1075         _ASM_EXTABLE(native_iret, bad_iret)
1076 #endif
1077
1078 #ifdef CONFIG_X86_ESPFIX64
1079 irq_return_ldt:
1080         pushq_cfi %rax
1081         pushq_cfi %rdi
1082         SWAPGS
1083         movq PER_CPU_VAR(espfix_waddr),%rdi
1084         movq %rax,(0*8)(%rdi)   /* RAX */
1085         movq (2*8)(%rsp),%rax   /* RIP */
1086         movq %rax,(1*8)(%rdi)
1087         movq (3*8)(%rsp),%rax   /* CS */
1088         movq %rax,(2*8)(%rdi)
1089         movq (4*8)(%rsp),%rax   /* RFLAGS */
1090         movq %rax,(3*8)(%rdi)
1091         movq (6*8)(%rsp),%rax   /* SS */
1092         movq %rax,(5*8)(%rdi)
1093         movq (5*8)(%rsp),%rax   /* RSP */
1094         movq %rax,(4*8)(%rdi)
1095         andl $0xffff0000,%eax
1096         popq_cfi %rdi
1097         orq PER_CPU_VAR(espfix_stack),%rax
1098         SWAPGS
1099         movq %rax,%rsp
1100         popq_cfi %rax
1101         jmp irq_return_iret
1102 #endif
1103
1104         .section .fixup,"ax"
1105 bad_iret:
1106         /*
1107          * The iret traps when the %cs or %ss being restored is bogus.
1108          * We've lost the original trap vector and error code.
1109          * #GPF is the most likely one to get for an invalid selector.
1110          * So pretend we completed the iret and took the #GPF in user mode.
1111          *
1112          * We are now running with the kernel GS after exception recovery.
1113          * But error_entry expects us to have user GS to match the user %cs,
1114          * so swap back.
1115          */
1116         pushq $0
1117
1118         SWAPGS
1119         jmp general_protection
1120
1121         .previous
1122
1123         /* edi: workmask, edx: work */
1124 retint_careful:
1125         CFI_RESTORE_STATE
1126         bt    $TIF_NEED_RESCHED,%edx
1127         jnc   retint_signal
1128         TRACE_IRQS_ON
1129         ENABLE_INTERRUPTS(CLBR_NONE)
1130         pushq_cfi %rdi
1131         SCHEDULE_USER
1132         popq_cfi %rdi
1133         GET_THREAD_INFO(%rcx)
1134         DISABLE_INTERRUPTS(CLBR_NONE)
1135         TRACE_IRQS_OFF
1136         jmp retint_check
1137
1138 retint_signal:
1139         testl $_TIF_DO_NOTIFY_MASK,%edx
1140         jz    retint_swapgs
1141         TRACE_IRQS_ON
1142         ENABLE_INTERRUPTS(CLBR_NONE)
1143         SAVE_REST
1144         movq $-1,ORIG_RAX(%rsp)
1145         xorl %esi,%esi          # oldset
1146         movq %rsp,%rdi          # &pt_regs
1147         call do_notify_resume
1148         RESTORE_REST
1149         DISABLE_INTERRUPTS(CLBR_NONE)
1150         TRACE_IRQS_OFF
1151         GET_THREAD_INFO(%rcx)
1152         jmp retint_with_reschedule
1153
1154 #ifdef CONFIG_PREEMPT
1155         /* Returning to kernel space. Check if we need preemption */
1156         /* rcx:  threadinfo. interrupts off. */
1157 ENTRY(retint_kernel)
1158         cmpl $0,TI_preempt_count(%rcx)
1159         jnz  retint_restore_args
1160         bt  $TIF_NEED_RESCHED,TI_flags(%rcx)
1161         jnc  retint_restore_args
1162         bt   $9,EFLAGS-ARGOFFSET(%rsp)  /* interrupts off? */
1163         jnc  retint_restore_args
1164         call preempt_schedule_irq
1165         jmp exit_intr
1166 #endif
1167         CFI_ENDPROC
1168 END(common_interrupt)
1169
1170         /*
1171          * If IRET takes a fault on the espfix stack, then we
1172          * end up promoting it to a doublefault.  In that case,
1173          * modify the stack to make it look like we just entered
1174          * the #GP handler from user space, similar to bad_iret.
1175          */
1176 #ifdef CONFIG_X86_ESPFIX64
1177         ALIGN
1178 __do_double_fault:
1179         XCPT_FRAME 1 RDI+8
1180         movq RSP(%rdi),%rax             /* Trap on the espfix stack? */
1181         sarq $PGDIR_SHIFT,%rax
1182         cmpl $ESPFIX_PGD_ENTRY,%eax
1183         jne do_double_fault             /* No, just deliver the fault */
1184         cmpl $__KERNEL_CS,CS(%rdi)
1185         jne do_double_fault
1186         movq RIP(%rdi),%rax
1187         cmpq $irq_return_iret,%rax
1188 #ifdef CONFIG_PARAVIRT
1189         je 1f
1190         cmpq $native_iret,%rax
1191 #endif
1192         jne do_double_fault             /* This shouldn't happen... */
1193 1:
1194         movq PER_CPU_VAR(kernel_stack),%rax
1195         subq $(6*8-KERNEL_STACK_OFFSET),%rax    /* Reset to original stack */
1196         movq %rax,RSP(%rdi)
1197         movq $0,(%rax)                  /* Missing (lost) #GP error code */
1198         movq $general_protection,RIP(%rdi)
1199         retq
1200         CFI_ENDPROC
1201 END(__do_double_fault)
1202 #else
1203 # define __do_double_fault do_double_fault
1204 #endif
1205
1206 /*
1207  * End of kprobes section
1208  */
1209        .popsection
1210
1211 /*
1212  * APIC interrupts.
1213  */
1214 .macro apicinterrupt num sym do_sym
1215 ENTRY(\sym)
1216         INTR_FRAME
1217         ASM_CLAC
1218         pushq_cfi $~(\num)
1219 .Lcommon_\sym:
1220         interrupt \do_sym
1221         jmp ret_from_intr
1222         CFI_ENDPROC
1223 END(\sym)
1224 .endm
1225
1226 #ifdef CONFIG_SMP
1227 apicinterrupt IRQ_MOVE_CLEANUP_VECTOR \
1228         irq_move_cleanup_interrupt smp_irq_move_cleanup_interrupt
1229 apicinterrupt REBOOT_VECTOR \
1230         reboot_interrupt smp_reboot_interrupt
1231 #endif
1232
1233 #ifdef CONFIG_X86_UV
1234 apicinterrupt UV_BAU_MESSAGE \
1235         uv_bau_message_intr1 uv_bau_message_interrupt
1236 #endif
1237 apicinterrupt LOCAL_TIMER_VECTOR \
1238         apic_timer_interrupt smp_apic_timer_interrupt
1239 apicinterrupt X86_PLATFORM_IPI_VECTOR \
1240         x86_platform_ipi smp_x86_platform_ipi
1241
1242 #ifdef CONFIG_HAVE_KVM
1243 apicinterrupt POSTED_INTR_VECTOR \
1244         kvm_posted_intr_ipi smp_kvm_posted_intr_ipi
1245 #endif
1246
1247 apicinterrupt THRESHOLD_APIC_VECTOR \
1248         threshold_interrupt smp_threshold_interrupt
1249 apicinterrupt THERMAL_APIC_VECTOR \
1250         thermal_interrupt smp_thermal_interrupt
1251
1252 #ifdef CONFIG_SMP
1253 apicinterrupt CALL_FUNCTION_SINGLE_VECTOR \
1254         call_function_single_interrupt smp_call_function_single_interrupt
1255 apicinterrupt CALL_FUNCTION_VECTOR \
1256         call_function_interrupt smp_call_function_interrupt
1257 apicinterrupt RESCHEDULE_VECTOR \
1258         reschedule_interrupt smp_reschedule_interrupt
1259 #endif
1260
1261 apicinterrupt ERROR_APIC_VECTOR \
1262         error_interrupt smp_error_interrupt
1263 apicinterrupt SPURIOUS_APIC_VECTOR \
1264         spurious_interrupt smp_spurious_interrupt
1265
1266 #ifdef CONFIG_IRQ_WORK
1267 apicinterrupt IRQ_WORK_VECTOR \
1268         irq_work_interrupt smp_irq_work_interrupt
1269 #endif
1270
1271 /*
1272  * Exception entry points.
1273  */
1274 .macro zeroentry sym do_sym
1275 ENTRY(\sym)
1276         INTR_FRAME
1277         ASM_CLAC
1278         PARAVIRT_ADJUST_EXCEPTION_FRAME
1279         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1280         subq $ORIG_RAX-R15, %rsp
1281         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1282         call error_entry
1283         DEFAULT_FRAME 0
1284         movq %rsp,%rdi          /* pt_regs pointer */
1285         xorl %esi,%esi          /* no error code */
1286         call \do_sym
1287         jmp error_exit          /* %ebx: no swapgs flag */
1288         CFI_ENDPROC
1289 END(\sym)
1290 .endm
1291
1292 .macro paranoidzeroentry sym do_sym
1293 ENTRY(\sym)
1294         INTR_FRAME
1295         ASM_CLAC
1296         PARAVIRT_ADJUST_EXCEPTION_FRAME
1297         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1298         subq $ORIG_RAX-R15, %rsp
1299         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1300         call save_paranoid
1301         TRACE_IRQS_OFF
1302         movq %rsp,%rdi          /* pt_regs pointer */
1303         xorl %esi,%esi          /* no error code */
1304         call \do_sym
1305         jmp paranoid_exit       /* %ebx: no swapgs flag */
1306         CFI_ENDPROC
1307 END(\sym)
1308 .endm
1309
1310 #define INIT_TSS_IST(x) PER_CPU_VAR(init_tss) + (TSS_ist + ((x) - 1) * 8)
1311 .macro paranoidzeroentry_ist sym do_sym ist
1312 ENTRY(\sym)
1313         INTR_FRAME
1314         ASM_CLAC
1315         PARAVIRT_ADJUST_EXCEPTION_FRAME
1316         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1317         subq $ORIG_RAX-R15, %rsp
1318         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1319         call save_paranoid
1320         TRACE_IRQS_OFF_DEBUG
1321         movq %rsp,%rdi          /* pt_regs pointer */
1322         xorl %esi,%esi          /* no error code */
1323         subq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1324         call \do_sym
1325         addq $EXCEPTION_STKSZ, INIT_TSS_IST(\ist)
1326         jmp paranoid_exit       /* %ebx: no swapgs flag */
1327         CFI_ENDPROC
1328 END(\sym)
1329 .endm
1330
1331 .macro errorentry sym do_sym
1332 ENTRY(\sym)
1333         XCPT_FRAME
1334         ASM_CLAC
1335         PARAVIRT_ADJUST_EXCEPTION_FRAME
1336         subq $ORIG_RAX-R15, %rsp
1337         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1338         call error_entry
1339         DEFAULT_FRAME 0
1340         movq %rsp,%rdi                  /* pt_regs pointer */
1341         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1342         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1343         call \do_sym
1344         jmp error_exit                  /* %ebx: no swapgs flag */
1345         CFI_ENDPROC
1346 END(\sym)
1347 .endm
1348
1349         /* error code is on the stack already */
1350 .macro paranoiderrorentry sym do_sym
1351 ENTRY(\sym)
1352         XCPT_FRAME
1353         ASM_CLAC
1354         PARAVIRT_ADJUST_EXCEPTION_FRAME
1355         subq $ORIG_RAX-R15, %rsp
1356         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1357         call save_paranoid
1358         DEFAULT_FRAME 0
1359         TRACE_IRQS_OFF
1360         movq %rsp,%rdi                  /* pt_regs pointer */
1361         movq ORIG_RAX(%rsp),%rsi        /* get error code */
1362         movq $-1,ORIG_RAX(%rsp)         /* no syscall to restart */
1363         call \do_sym
1364         jmp paranoid_exit               /* %ebx: no swapgs flag */
1365         CFI_ENDPROC
1366 END(\sym)
1367 .endm
1368
1369 zeroentry divide_error do_divide_error
1370 zeroentry overflow do_overflow
1371 zeroentry bounds do_bounds
1372 zeroentry invalid_op do_invalid_op
1373 zeroentry device_not_available do_device_not_available
1374 paranoiderrorentry double_fault __do_double_fault
1375 zeroentry coprocessor_segment_overrun do_coprocessor_segment_overrun
1376 errorentry invalid_TSS do_invalid_TSS
1377 errorentry segment_not_present do_segment_not_present
1378 zeroentry spurious_interrupt_bug do_spurious_interrupt_bug
1379 zeroentry coprocessor_error do_coprocessor_error
1380 errorentry alignment_check do_alignment_check
1381 zeroentry simd_coprocessor_error do_simd_coprocessor_error
1382
1383
1384         /* Reload gs selector with exception handling */
1385         /* edi:  new selector */
1386 ENTRY(native_load_gs_index)
1387         CFI_STARTPROC
1388         pushfq_cfi
1389         DISABLE_INTERRUPTS(CLBR_ANY & ~CLBR_RDI)
1390         SWAPGS
1391 gs_change:
1392         movl %edi,%gs
1393 2:      mfence          /* workaround */
1394         SWAPGS
1395         popfq_cfi
1396         ret
1397         CFI_ENDPROC
1398 END(native_load_gs_index)
1399
1400         _ASM_EXTABLE(gs_change,bad_gs)
1401         .section .fixup,"ax"
1402         /* running with kernelgs */
1403 bad_gs:
1404         SWAPGS                  /* switch back to user gs */
1405         xorl %eax,%eax
1406         movl %eax,%gs
1407         jmp  2b
1408         .previous
1409
1410 /* Call softirq on interrupt stack. Interrupts are off. */
1411 ENTRY(call_softirq)
1412         CFI_STARTPROC
1413         pushq_cfi %rbp
1414         CFI_REL_OFFSET rbp,0
1415         mov  %rsp,%rbp
1416         CFI_DEF_CFA_REGISTER rbp
1417         incl PER_CPU_VAR(irq_count)
1418         cmove PER_CPU_VAR(irq_stack_ptr),%rsp
1419         push  %rbp                      # backlink for old unwinder
1420         call __do_softirq
1421         leaveq
1422         CFI_RESTORE             rbp
1423         CFI_DEF_CFA_REGISTER    rsp
1424         CFI_ADJUST_CFA_OFFSET   -8
1425         decl PER_CPU_VAR(irq_count)
1426         ret
1427         CFI_ENDPROC
1428 END(call_softirq)
1429
1430 #ifdef CONFIG_XEN
1431 zeroentry xen_hypervisor_callback xen_do_hypervisor_callback
1432
1433 /*
1434  * A note on the "critical region" in our callback handler.
1435  * We want to avoid stacking callback handlers due to events occurring
1436  * during handling of the last event. To do this, we keep events disabled
1437  * until we've done all processing. HOWEVER, we must enable events before
1438  * popping the stack frame (can't be done atomically) and so it would still
1439  * be possible to get enough handler activations to overflow the stack.
1440  * Although unlikely, bugs of that kind are hard to track down, so we'd
1441  * like to avoid the possibility.
1442  * So, on entry to the handler we detect whether we interrupted an
1443  * existing activation in its critical region -- if so, we pop the current
1444  * activation and restart the handler using the previous one.
1445  */
1446 ENTRY(xen_do_hypervisor_callback)   # do_hypervisor_callback(struct *pt_regs)
1447         CFI_STARTPROC
1448 /*
1449  * Since we don't modify %rdi, evtchn_do_upall(struct *pt_regs) will
1450  * see the correct pointer to the pt_regs
1451  */
1452         movq %rdi, %rsp            # we don't return, adjust the stack frame
1453         CFI_ENDPROC
1454         DEFAULT_FRAME
1455 11:     incl PER_CPU_VAR(irq_count)
1456         movq %rsp,%rbp
1457         CFI_DEF_CFA_REGISTER rbp
1458         cmovzq PER_CPU_VAR(irq_stack_ptr),%rsp
1459         pushq %rbp                      # backlink for old unwinder
1460         call xen_evtchn_do_upcall
1461         popq %rsp
1462         CFI_DEF_CFA_REGISTER rsp
1463         decl PER_CPU_VAR(irq_count)
1464         jmp  error_exit
1465         CFI_ENDPROC
1466 END(xen_do_hypervisor_callback)
1467
1468 /*
1469  * Hypervisor uses this for application faults while it executes.
1470  * We get here for two reasons:
1471  *  1. Fault while reloading DS, ES, FS or GS
1472  *  2. Fault while executing IRET
1473  * Category 1 we do not need to fix up as Xen has already reloaded all segment
1474  * registers that could be reloaded and zeroed the others.
1475  * Category 2 we fix up by killing the current process. We cannot use the
1476  * normal Linux return path in this case because if we use the IRET hypercall
1477  * to pop the stack frame we end up in an infinite loop of failsafe callbacks.
1478  * We distinguish between categories by comparing each saved segment register
1479  * with its current contents: any discrepancy means we in category 1.
1480  */
1481 ENTRY(xen_failsafe_callback)
1482         INTR_FRAME 1 (6*8)
1483         /*CFI_REL_OFFSET gs,GS*/
1484         /*CFI_REL_OFFSET fs,FS*/
1485         /*CFI_REL_OFFSET es,ES*/
1486         /*CFI_REL_OFFSET ds,DS*/
1487         CFI_REL_OFFSET r11,8
1488         CFI_REL_OFFSET rcx,0
1489         movw %ds,%cx
1490         cmpw %cx,0x10(%rsp)
1491         CFI_REMEMBER_STATE
1492         jne 1f
1493         movw %es,%cx
1494         cmpw %cx,0x18(%rsp)
1495         jne 1f
1496         movw %fs,%cx
1497         cmpw %cx,0x20(%rsp)
1498         jne 1f
1499         movw %gs,%cx
1500         cmpw %cx,0x28(%rsp)
1501         jne 1f
1502         /* All segments match their saved values => Category 2 (Bad IRET). */
1503         movq (%rsp),%rcx
1504         CFI_RESTORE rcx
1505         movq 8(%rsp),%r11
1506         CFI_RESTORE r11
1507         addq $0x30,%rsp
1508         CFI_ADJUST_CFA_OFFSET -0x30
1509         pushq_cfi $0    /* RIP */
1510         pushq_cfi %r11
1511         pushq_cfi %rcx
1512         jmp general_protection
1513         CFI_RESTORE_STATE
1514 1:      /* Segment mismatch => Category 1 (Bad segment). Retry the IRET. */
1515         movq (%rsp),%rcx
1516         CFI_RESTORE rcx
1517         movq 8(%rsp),%r11
1518         CFI_RESTORE r11
1519         addq $0x30,%rsp
1520         CFI_ADJUST_CFA_OFFSET -0x30
1521         pushq_cfi $-1 /* orig_ax = -1 => not a system call */
1522         SAVE_ALL
1523         jmp error_exit
1524         CFI_ENDPROC
1525 END(xen_failsafe_callback)
1526
1527 apicinterrupt HYPERVISOR_CALLBACK_VECTOR \
1528         xen_hvm_callback_vector xen_evtchn_do_upcall
1529
1530 #endif /* CONFIG_XEN */
1531
1532 #if IS_ENABLED(CONFIG_HYPERV)
1533 apicinterrupt HYPERVISOR_CALLBACK_VECTOR \
1534         hyperv_callback_vector hyperv_vector_handler
1535 #endif /* CONFIG_HYPERV */
1536
1537 /*
1538  * Some functions should be protected against kprobes
1539  */
1540         .pushsection .kprobes.text, "ax"
1541
1542 paranoidzeroentry_ist debug do_debug DEBUG_STACK
1543 paranoidzeroentry_ist int3 do_int3 DEBUG_STACK
1544 paranoiderrorentry stack_segment do_stack_segment
1545 #ifdef CONFIG_XEN
1546 zeroentry xen_debug do_debug
1547 zeroentry xen_int3 do_int3
1548 errorentry xen_stack_segment do_stack_segment
1549 #endif
1550 errorentry general_protection do_general_protection
1551 errorentry page_fault do_page_fault
1552 #ifdef CONFIG_KVM_GUEST
1553 errorentry async_page_fault do_async_page_fault
1554 #endif
1555 #ifdef CONFIG_X86_MCE
1556 paranoidzeroentry machine_check *machine_check_vector(%rip)
1557 #endif
1558
1559         /*
1560          * "Paranoid" exit path from exception stack.
1561          * Paranoid because this is used by NMIs and cannot take
1562          * any kernel state for granted.
1563          * We don't do kernel preemption checks here, because only
1564          * NMI should be common and it does not enable IRQs and
1565          * cannot get reschedule ticks.
1566          *
1567          * "trace" is 0 for the NMI handler only, because irq-tracing
1568          * is fundamentally NMI-unsafe. (we cannot change the soft and
1569          * hard flags at once, atomically)
1570          */
1571
1572         /* ebx: no swapgs flag */
1573 ENTRY(paranoid_exit)
1574         DEFAULT_FRAME
1575         DISABLE_INTERRUPTS(CLBR_NONE)
1576         TRACE_IRQS_OFF_DEBUG
1577         testl %ebx,%ebx                         /* swapgs needed? */
1578         jnz paranoid_restore
1579         testl $3,CS(%rsp)
1580         jnz   paranoid_userspace
1581 paranoid_swapgs:
1582         TRACE_IRQS_IRETQ 0
1583         SWAPGS_UNSAFE_STACK
1584         RESTORE_ALL 8
1585         jmp irq_return
1586 paranoid_restore:
1587         TRACE_IRQS_IRETQ_DEBUG 0
1588         RESTORE_ALL 8
1589         jmp irq_return
1590 paranoid_userspace:
1591         GET_THREAD_INFO(%rcx)
1592         movl TI_flags(%rcx),%ebx
1593         andl $_TIF_WORK_MASK,%ebx
1594         jz paranoid_swapgs
1595         movq %rsp,%rdi                  /* &pt_regs */
1596         call sync_regs
1597         movq %rax,%rsp                  /* switch stack for scheduling */
1598         testl $_TIF_NEED_RESCHED,%ebx
1599         jnz paranoid_schedule
1600         movl %ebx,%edx                  /* arg3: thread flags */
1601         TRACE_IRQS_ON
1602         ENABLE_INTERRUPTS(CLBR_NONE)
1603         xorl %esi,%esi                  /* arg2: oldset */
1604         movq %rsp,%rdi                  /* arg1: &pt_regs */
1605         call do_notify_resume
1606         DISABLE_INTERRUPTS(CLBR_NONE)
1607         TRACE_IRQS_OFF
1608         jmp paranoid_userspace
1609 paranoid_schedule:
1610         TRACE_IRQS_ON
1611         ENABLE_INTERRUPTS(CLBR_ANY)
1612         SCHEDULE_USER
1613         DISABLE_INTERRUPTS(CLBR_ANY)
1614         TRACE_IRQS_OFF
1615         jmp paranoid_userspace
1616         CFI_ENDPROC
1617 END(paranoid_exit)
1618
1619 /*
1620  * Exception entry point. This expects an error code/orig_rax on the stack.
1621  * returns in "no swapgs flag" in %ebx.
1622  */
1623 ENTRY(error_entry)
1624         XCPT_FRAME
1625         CFI_ADJUST_CFA_OFFSET 15*8
1626         /* oldrax contains error code */
1627         cld
1628         movq_cfi rdi, RDI+8
1629         movq_cfi rsi, RSI+8
1630         movq_cfi rdx, RDX+8
1631         movq_cfi rcx, RCX+8
1632         movq_cfi rax, RAX+8
1633         movq_cfi  r8,  R8+8
1634         movq_cfi  r9,  R9+8
1635         movq_cfi r10, R10+8
1636         movq_cfi r11, R11+8
1637         movq_cfi rbx, RBX+8
1638         movq_cfi rbp, RBP+8
1639         movq_cfi r12, R12+8
1640         movq_cfi r13, R13+8
1641         movq_cfi r14, R14+8
1642         movq_cfi r15, R15+8
1643         xorl %ebx,%ebx
1644         testl $3,CS+8(%rsp)
1645         je error_kernelspace
1646 error_swapgs:
1647         SWAPGS
1648 error_sti:
1649         TRACE_IRQS_OFF
1650         ret
1651
1652 /*
1653  * There are two places in the kernel that can potentially fault with
1654  * usergs. Handle them here. The exception handlers after iret run with
1655  * kernel gs again, so don't set the user space flag. B stepping K8s
1656  * sometimes report an truncated RIP for IRET exceptions returning to
1657  * compat mode. Check for these here too.
1658  */
1659 error_kernelspace:
1660         incl %ebx
1661         leaq irq_return_iret(%rip),%rcx
1662         cmpq %rcx,RIP+8(%rsp)
1663         je error_swapgs
1664         movl %ecx,%eax  /* zero extend */
1665         cmpq %rax,RIP+8(%rsp)
1666         je bstep_iret
1667         cmpq $gs_change,RIP+8(%rsp)
1668         je error_swapgs
1669         jmp error_sti
1670
1671 bstep_iret:
1672         /* Fix truncated RIP */
1673         movq %rcx,RIP+8(%rsp)
1674         jmp error_swapgs
1675         CFI_ENDPROC
1676 END(error_entry)
1677
1678
1679 /* ebx: no swapgs flag (1: don't need swapgs, 0: need it) */
1680 ENTRY(error_exit)
1681         DEFAULT_FRAME
1682         movl %ebx,%eax
1683         RESTORE_REST
1684         DISABLE_INTERRUPTS(CLBR_NONE)
1685         TRACE_IRQS_OFF
1686         GET_THREAD_INFO(%rcx)
1687         testl %eax,%eax
1688         jne retint_kernel
1689         LOCKDEP_SYS_EXIT_IRQ
1690         movl TI_flags(%rcx),%edx
1691         movl $_TIF_WORK_MASK,%edi
1692         andl %edi,%edx
1693         jnz retint_careful
1694         jmp retint_swapgs
1695         CFI_ENDPROC
1696 END(error_exit)
1697
1698 /*
1699  * Test if a given stack is an NMI stack or not.
1700  */
1701         .macro test_in_nmi reg stack nmi_ret normal_ret
1702         cmpq %\reg, \stack
1703         ja \normal_ret
1704         subq $EXCEPTION_STKSZ, %\reg
1705         cmpq %\reg, \stack
1706         jb \normal_ret
1707         jmp \nmi_ret
1708         .endm
1709
1710         /* runs on exception stack */
1711 ENTRY(nmi)
1712         INTR_FRAME
1713         PARAVIRT_ADJUST_EXCEPTION_FRAME
1714         /*
1715          * We allow breakpoints in NMIs. If a breakpoint occurs, then
1716          * the iretq it performs will take us out of NMI context.
1717          * This means that we can have nested NMIs where the next
1718          * NMI is using the top of the stack of the previous NMI. We
1719          * can't let it execute because the nested NMI will corrupt the
1720          * stack of the previous NMI. NMI handlers are not re-entrant
1721          * anyway.
1722          *
1723          * To handle this case we do the following:
1724          *  Check the a special location on the stack that contains
1725          *  a variable that is set when NMIs are executing.
1726          *  The interrupted task's stack is also checked to see if it
1727          *  is an NMI stack.
1728          *  If the variable is not set and the stack is not the NMI
1729          *  stack then:
1730          *    o Set the special variable on the stack
1731          *    o Copy the interrupt frame into a "saved" location on the stack
1732          *    o Copy the interrupt frame into a "copy" location on the stack
1733          *    o Continue processing the NMI
1734          *  If the variable is set or the previous stack is the NMI stack:
1735          *    o Modify the "copy" location to jump to the repeate_nmi
1736          *    o return back to the first NMI
1737          *
1738          * Now on exit of the first NMI, we first clear the stack variable
1739          * The NMI stack will tell any nested NMIs at that point that it is
1740          * nested. Then we pop the stack normally with iret, and if there was
1741          * a nested NMI that updated the copy interrupt stack frame, a
1742          * jump will be made to the repeat_nmi code that will handle the second
1743          * NMI.
1744          */
1745
1746         /* Use %rdx as out temp variable throughout */
1747         pushq_cfi %rdx
1748         CFI_REL_OFFSET rdx, 0
1749
1750         /*
1751          * If %cs was not the kernel segment, then the NMI triggered in user
1752          * space, which means it is definitely not nested.
1753          */
1754         cmpl $__KERNEL_CS, 16(%rsp)
1755         jne first_nmi
1756
1757         /*
1758          * Check the special variable on the stack to see if NMIs are
1759          * executing.
1760          */
1761         cmpl $1, -8(%rsp)
1762         je nested_nmi
1763
1764         /*
1765          * Now test if the previous stack was an NMI stack.
1766          * We need the double check. We check the NMI stack to satisfy the
1767          * race when the first NMI clears the variable before returning.
1768          * We check the variable because the first NMI could be in a
1769          * breakpoint routine using a breakpoint stack.
1770          */
1771         lea 6*8(%rsp), %rdx
1772         test_in_nmi rdx, 4*8(%rsp), nested_nmi, first_nmi
1773         CFI_REMEMBER_STATE
1774
1775 nested_nmi:
1776         /*
1777          * Do nothing if we interrupted the fixup in repeat_nmi.
1778          * It's about to repeat the NMI handler, so we are fine
1779          * with ignoring this one.
1780          */
1781         movq $repeat_nmi, %rdx
1782         cmpq 8(%rsp), %rdx
1783         ja 1f
1784         movq $end_repeat_nmi, %rdx
1785         cmpq 8(%rsp), %rdx
1786         ja nested_nmi_out
1787
1788 1:
1789         /* Set up the interrupted NMIs stack to jump to repeat_nmi */
1790         leaq -1*8(%rsp), %rdx
1791         movq %rdx, %rsp
1792         CFI_ADJUST_CFA_OFFSET 1*8
1793         leaq -10*8(%rsp), %rdx
1794         pushq_cfi $__KERNEL_DS
1795         pushq_cfi %rdx
1796         pushfq_cfi
1797         pushq_cfi $__KERNEL_CS
1798         pushq_cfi $repeat_nmi
1799
1800         /* Put stack back */
1801         addq $(6*8), %rsp
1802         CFI_ADJUST_CFA_OFFSET -6*8
1803
1804 nested_nmi_out:
1805         popq_cfi %rdx
1806         CFI_RESTORE rdx
1807
1808         /* No need to check faults here */
1809         INTERRUPT_RETURN
1810
1811         CFI_RESTORE_STATE
1812 first_nmi:
1813         /*
1814          * Because nested NMIs will use the pushed location that we
1815          * stored in rdx, we must keep that space available.
1816          * Here's what our stack frame will look like:
1817          * +-------------------------+
1818          * | original SS             |
1819          * | original Return RSP     |
1820          * | original RFLAGS         |
1821          * | original CS             |
1822          * | original RIP            |
1823          * +-------------------------+
1824          * | temp storage for rdx    |
1825          * +-------------------------+
1826          * | NMI executing variable  |
1827          * +-------------------------+
1828          * | copied SS               |
1829          * | copied Return RSP       |
1830          * | copied RFLAGS           |
1831          * | copied CS               |
1832          * | copied RIP              |
1833          * +-------------------------+
1834          * | Saved SS                |
1835          * | Saved Return RSP        |
1836          * | Saved RFLAGS            |
1837          * | Saved CS                |
1838          * | Saved RIP               |
1839          * +-------------------------+
1840          * | pt_regs                 |
1841          * +-------------------------+
1842          *
1843          * The saved stack frame is used to fix up the copied stack frame
1844          * that a nested NMI may change to make the interrupted NMI iret jump
1845          * to the repeat_nmi. The original stack frame and the temp storage
1846          * is also used by nested NMIs and can not be trusted on exit.
1847          */
1848         /* Do not pop rdx, nested NMIs will corrupt that part of the stack */
1849         movq (%rsp), %rdx
1850         CFI_RESTORE rdx
1851
1852         /* Set the NMI executing variable on the stack. */
1853         pushq_cfi $1
1854
1855         /*
1856          * Leave room for the "copied" frame
1857          */
1858         subq $(5*8), %rsp
1859         CFI_ADJUST_CFA_OFFSET 5*8
1860
1861         /* Copy the stack frame to the Saved frame */
1862         .rept 5
1863         pushq_cfi 11*8(%rsp)
1864         .endr
1865         CFI_DEF_CFA_OFFSET SS+8-RIP
1866
1867         /* Everything up to here is safe from nested NMIs */
1868
1869         /*
1870          * If there was a nested NMI, the first NMI's iret will return
1871          * here. But NMIs are still enabled and we can take another
1872          * nested NMI. The nested NMI checks the interrupted RIP to see
1873          * if it is between repeat_nmi and end_repeat_nmi, and if so
1874          * it will just return, as we are about to repeat an NMI anyway.
1875          * This makes it safe to copy to the stack frame that a nested
1876          * NMI will update.
1877          */
1878 repeat_nmi:
1879         /*
1880          * Update the stack variable to say we are still in NMI (the update
1881          * is benign for the non-repeat case, where 1 was pushed just above
1882          * to this very stack slot).
1883          */
1884         movq $1, 10*8(%rsp)
1885
1886         /* Make another copy, this one may be modified by nested NMIs */
1887         addq $(10*8), %rsp
1888         CFI_ADJUST_CFA_OFFSET -10*8
1889         .rept 5
1890         pushq_cfi -6*8(%rsp)
1891         .endr
1892         subq $(5*8), %rsp
1893         CFI_DEF_CFA_OFFSET SS+8-RIP
1894 end_repeat_nmi:
1895
1896         /*
1897          * Everything below this point can be preempted by a nested
1898          * NMI if the first NMI took an exception and reset our iret stack
1899          * so that we repeat another NMI.
1900          */
1901         pushq_cfi $-1           /* ORIG_RAX: no syscall to restart */
1902         subq $ORIG_RAX-R15, %rsp
1903         CFI_ADJUST_CFA_OFFSET ORIG_RAX-R15
1904         /*
1905          * Use save_paranoid to handle SWAPGS, but no need to use paranoid_exit
1906          * as we should not be calling schedule in NMI context.
1907          * Even with normal interrupts enabled. An NMI should not be
1908          * setting NEED_RESCHED or anything that normal interrupts and
1909          * exceptions might do.
1910          */
1911         call save_paranoid
1912         DEFAULT_FRAME 0
1913
1914         /*
1915          * Save off the CR2 register. If we take a page fault in the NMI then
1916          * it could corrupt the CR2 value. If the NMI preempts a page fault
1917          * handler before it was able to read the CR2 register, and then the
1918          * NMI itself takes a page fault, the page fault that was preempted
1919          * will read the information from the NMI page fault and not the
1920          * origin fault. Save it off and restore it if it changes.
1921          * Use the r12 callee-saved register.
1922          */
1923         movq %cr2, %r12
1924
1925         /* paranoidentry do_nmi, 0; without TRACE_IRQS_OFF */
1926         movq %rsp,%rdi
1927         movq $-1,%rsi
1928         call do_nmi
1929
1930         /* Did the NMI take a page fault? Restore cr2 if it did */
1931         movq %cr2, %rcx
1932         cmpq %rcx, %r12
1933         je 1f
1934         movq %r12, %cr2
1935 1:
1936
1937         testl %ebx,%ebx                         /* swapgs needed? */
1938         jnz nmi_restore
1939 nmi_swapgs:
1940         SWAPGS_UNSAFE_STACK
1941 nmi_restore:
1942         /* Pop the extra iret frame at once */
1943         RESTORE_ALL 6*8
1944
1945         /* Clear the NMI executing stack variable */
1946         movq $0, 5*8(%rsp)
1947         jmp irq_return
1948         CFI_ENDPROC
1949 END(nmi)
1950
1951 ENTRY(ignore_sysret)
1952         CFI_STARTPROC
1953         mov $-ENOSYS,%eax
1954         sysret
1955         CFI_ENDPROC
1956 END(ignore_sysret)
1957
1958 /*
1959  * End of kprobes section
1960  */
1961         .popsection